configure.ac

   1 # ocaml-libvirt
   2 # Copyright (C) 2007 Red Hat Inc., Richard W.M. Jones
   3 #
   4 # This library is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU Lesser General Public
   6 # License as published by the Free Software Foundation; either
   7 # version 2 of the License, or (at your option) any later version.
   8 #
   9 # This library is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Lesser General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Lesser General Public
  15 # License along with this library; if not, write to the Free Software
  16 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  17
  18 dnl Process this file with autoconf to produce a configure script.
  19
  20 AC_INIT(ocaml-libvirt,0.4.0.2)
  21
  22 dnl Check for basic C environment.
  23 AC_PROG_CC
  24 AC_PROG_INSTALL
  25 AC_PROG_CPP
  26
  27 AC_C_PROTOTYPES
  28 test "x$U" != "x" && AC_MSG_ERROR(Compiler not ANSI compliant)
  29
  30 AC_PROG_CC_C_O
  31
  32 dnl Select some C flags based on the host type.
  33 AC_CANONICAL_HOST
  34
  35 DEBUG="-g"
  36 WARNINGS="-Wall -Werror"
  37 CFLAGS_FPIC="-fPIC"
  38 WIN32=no
  39 case "$host" in
  40   *-*-mingw*)
  41     WARNINGS="$WARNINGS -Wno-unused"
  42     CFLAGS_FPIC=""
  43     WIN32=yes
  44 esac
  45 AC_SUBST(DEBUG)
  46 AC_SUBST(WARNINGS)
  47 AC_SUBST(CFLAGS_FPIC)
  48 AC_SUBST(WIN32)
  49
  50 dnl Check for libvirt development environment.
  51 AC_ARG_WITH(libvirt,
  52         AC_HELP_STRING([--with-libvirt=PATH],[Set path to installed libvirt]),
  53         [if test "x$withval" != "x"; then
  54            CFLAGS="$CFLAGS -I$withval/include"
  55            LDFLAGS="$LDFLAGS -L$withval/lib"
  56          fi
  57         ])
  58 AC_CHECK_LIB(virt,virConnectOpen,
  59         [],
  60         AC_MSG_ERROR([You must install libvirt library]))
  61 AC_CHECK_HEADER([libvirt/libvirt.h],
  62         [],
  63         AC_MSG_ERROR([You must install libvirt development package]))
  64
  65 dnl Check for libvirt >= 0.2.1 (our minimum supported version).
  66 dnl See: http://libvirt.org/hvsupport.html
  67 AC_CHECK_FUNC(virConnectGetCapabilities,
  68         [],
  69         AC_MSG_ERROR([You must have libvirt >= 0.2.1]))
  70
  71 dnl Check for optional libvirt functions added since 0.2.1.
  72 dnl See: http://libvirt.org/hvsupport.html
  73 AC_CHECK_FUNCS([virConnectGetHostname virConnectGetURI virDomainBlockStats virDomainGetSchedulerParameters virDomainGetSchedulerType virDomainInterfaceStats virDomainMigrate virDomainSetSchedulerParameters virNodeGetFreeMemory virNodeGetCellsFreeMemory])
  74
  75 dnl We also use <libvirt/virterror.h>
  76 AC_CHECK_HEADER([libvirt/virterror.h],
  77         [],
  78         AC_MSG_ERROR([You must install libvirt development package]))
  79
  80 dnl Check for optional ncurses.
  81 AC_CHECK_LIB(ncurses,initscr)
  82
  83 dnl Check for basic OCaml environment & findlib.
  84 dnl Note that findlib is not necessary, but things will work better
  85 dnl if it is present.
  86 AC_PROG_OCAML
  87 AC_PROG_FINDLIB
  88
  89 if test "x$OCAMLFIND" != "x"; then
  90     dnl Use ocamlfind to find the required packages ...
  91
  92     dnl Check for required OCaml packages.
  93     AC_CHECK_OCAML_PKG(unix)
  94     if test "x$pkg_unix" != "xyes"; then
  95         AC_MSG_ERROR([Cannot find required OCaml package 'unix'])
  96     fi
  97
  98     dnl Check for optional OCaml packages.
  99     AC_CHECK_OCAML_PKG(extlib)
 100     AC_CHECK_OCAML_PKG(lablgtk2)
 101     AC_CHECK_OCAML_PKG(curses)
 102     AC_CHECK_OCAML_PKG(gettext)
 103     AC_CHECK_OCAML_PKG(xml-light)
 104     AC_CHECK_OCAML_PKG(csv)
 105     AC_CHECK_OCAML_PKG(calendar)
 106
 107     AC_SUBST(pkg_unix)
 108     AC_SUBST(pkg_extlib)
 109     AC_SUBST(pkg_lablgtk2)
 110     AC_SUBST(pkg_curses)
 111     AC_SUBST(pkg_gettext)
 112     AC_SUBST(pkg_xml_light)
 113     AC_SUBST(pkg_csv)
 114     AC_SUBST(pkg_calendar)
 115 else
 116     dnl Use a basic module test if there is no findlib ...
 117
 118     dnl Check for required OCaml modules.
 119     AC_CHECK_OCAML_MODULE(unix,pkg_unix,Unix,[.])
 120     if test "x$pkg_unix" = "xno"; then
 121         AC_MSG_ERROR([Cannot find required OCaml package 'unix'])
 122     fi
 123
 124     dnl Check for optional OCaml modules.
 125     AC_CHECK_OCAML_MODULE(extlib,pkg_extlib,ExtString,[+extlib])
 126     AC_CHECK_OCAML_MODULE(lablgtk2,pkg_lablgtk2,GMain,[+lablgtk2])
 127     AC_CHECK_OCAML_MODULE(curses,pkg_curses,Curses,[+curses])
 128     AC_CHECK_OCAML_MODULE(gettext,pkg_gettext,Gettext,[+gettext]) dnl XXX
 129     AC_CHECK_OCAML_MODULE(xml-light,pkg_xml_light,Xml,[+xml-light])
 130     AC_CHECK_OCAML_MODULE(csv,pkg_csv,Csv,[+csv])
 131     AC_CHECK_OCAML_MODULE(calendar,pkg_calendar,Calendar,[+calendar])
 132 fi
 133
 134 dnl Which subpackages (== subdirs) will we build?
 135 subdirs="libvirt examples mlvirsh"
 136 if test "x$pkg_lablgtk2" != "xno"; then
 137     subdirs="$subdirs virt-ctrl"
 138 fi
 139 if test "x$pkg_extlib" != "xno" -a "x$pkg_curses" != "xno"; then
 140     subdirs="$subdirs virt-top"
 141 fi
 142 if test "x$pkg_extlib" != "xno" -a "x$pkg_xml_light" != "xno"; then
 143     subdirs="$subdirs virt-df"
 144 fi
 145 AC_SUBST(subdirs)
 146
 147 dnl Check for optional perldoc (for building manual pages).
 148 AC_CHECK_PROG(HAVE_PERLDOC,perldoc,perldoc)
 149
 150 dnl Check for optional NSIS (for building a Windows installer).
 151 AC_ARG_WITH([nsis],
 152         [AS_HELP_STRING([--with-nsis],
 153             [use NSIS to build a Windows installer])],
 154         [],
 155         [with_nsis=no])
 156
 157 MAKENSIS=
 158 LIBVIRT_DLL_PATH=
 159 LIBXDR_DLL_PATH=
 160 LIBXML2_DLL_PATH=
 161 GNUTLS_DLL_PATH=
 162 GTK_PATH=
 163 GTK_DLL_PATH=
 164
 165 [
 166 msys_to_win_dir () {
 167     eval pushd "\$$1" > /dev/null
 168     eval $1=`pwd -W`
 169     popd > /dev/null
 170 }
 171 ]
 172
 173 if test "x$with_nsis" != "xno"; then
 174     AC_PATH_PROG(MAKENSIS,makensis,[],[$with_nsis:$PATH])
 175     if test "x$MAKENSIS" = "x"; then
 176         AC_MSG_FAILURE([--with-nsis was given, but could not find MAKENSIS.EXE])
 177     fi
 178
 179     # MAKENSIS is set so we will build a rule for making a Windows
 180     # installer.  To support this, generate wininstaller.nsis.
 181     saved_IFS=$IFS
 182     IFS=$PATH_SEPARATOR
 183     for d in $PATH; do
 184         IFS=$saved_IFS
 185         echo Checking $d for DLLs ... >&5
 186         if test -f "$d/libvirt-0.dll"; then
 187             LIBVIRT_DLL_PATH="$d"
 188         fi
 189         if test -f "$d/libxdr.dll"; then
 190             LIBXDR_DLL_PATH="$d"
 191         fi
 192         if test -f "$d/libxml2-2.dll"; then
 193             LIBXML2_DLL_PATH="$d"
 194         fi
 195         if test -f "$d/libgpg-error-0.dll"; then
 196             GNUTLS_DLL_PATH="$d"
 197         fi
 198         if test -f "$d/libgtk-win32-2.0-0.dll"; then
 199             GTK_DLL_PATH="$d"
 200             GTK_PATH="$d/.."
 201         fi
 202     done
 203     IFS=$saved_IFS
 204
 205     if test "x$LIBVIRT_DLL_PATH" = "x"; then
 206         AC_MSG_FAILURE([cannot find libvirt-0.dll in PATH])
 207     fi
 208     if test "x$LIBXDR_DLL_PATH" = "x"; then
 209         AC_MSG_FAILURE([cannot find libxdr.dll in PATH])
 210     fi
 211     if test "x$LIBXML2_DLL_PATH" = "x"; then
 212         AC_MSG_FAILURE([cannot find libxml2-2.dll in PATH])
 213     fi
 214     if test "x$GNUTLS_DLL_PATH" = "x"; then
 215         AC_MSG_FAILURE([cannot find GnuTLS DLLs in PATH])
 216     fi
 217     if test "x$GTK_DLL_PATH" = "x"; then
 218         AC_MSG_WARN([cannot find GTK DLLs in PATH])
 219     fi
 220
 221     # Change the paths to Windows paths.
 222     msys_to_win_dir LIBVIRT_DLL_PATH
 223     msys_to_win_dir LIBXDR_DLL_PATH
 224     msys_to_win_dir LIBXML2_DLL_PATH
 225     msys_to_win_dir GNUTLS_DLL_PATH
 226     if test "x$GTK_DLL_PATH" != "x"; then
 227         msys_to_win_dir GTK_DLL_PATH
 228         msys_to_win_dir GTK_PATH
 229     fi
 230 fi
 231 AC_SUBST(MAKENSIS)
 232 AC_SUBST(LIBVIRT_DLL_PATH)
 233 AC_SUBST(LIBXDR_DLL_PATH)
 234 AC_SUBST(LIBXML2_DLL_PATH)
 235 AC_SUBST(GNUTLS_DLL_PATH)
 236 AC_SUBST(GTK_DLL_PATH)
 237 AC_SUBST(GTK_PATH)
 238
 239 dnl Summary.
 240 echo "------------------------------------------------------------"
 241 echo "Thanks for downloading" $PACKAGE_STRING
 242 echo " subpackages to build : $subdirs"
 243 echo "------------------------------------------------------------"
 244
 245 dnl Produce output files.
 246 AC_CONFIG_HEADERS([config.h])
 247 AC_CONFIG_FILES([META
 248         libvirt/libvirt_version.ml
 249         Makefile
 250         Make.rules
 251         libvirt/Makefile
 252         examples/Makefile
 253         mlvirsh/Makefile
 254         virt-ctrl/Makefile
 255         virt-top/Makefile
 256         virt-df/Makefile
 257         ])
 258 if test "x$MAKENSIS" != "x"; then
 259         AC_CONFIG_FILES([wininstaller.nsis])
 260 fi
 261 AC_OUTPUT