configure.ac

   1 # ocaml-libvirt
   2 # Copyright (C) 2007-2008 Red Hat Inc., Richard W.M. Jones
   3 #
   4 # This library is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU Lesser General Public
   6 # License as published by the Free Software Foundation; either
   7 # version 2 of the License, or (at your option) any later version.
   8 #
   9 # This library is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Lesser General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Lesser General Public
  15 # License along with this library; if not, write to the Free Software
  16 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  17
  18 dnl Process this file with autoconf to produce a configure script.
  19
  20 AC_INIT(ocaml-libvirt,0.6.1.0)
  21
  22 dnl Check for basic C environment.
  23 AC_PROG_CC
  24 AC_PROG_INSTALL
  25 AC_PROG_CPP
  26
  27 AC_C_PROTOTYPES
  28 test "x$U" != "x" && AC_MSG_ERROR(Compiler not ANSI compliant)
  29
  30 AC_PROG_CC_C_O
  31
  32 dnl Select some C flags based on the host type.
  33 AC_CANONICAL_HOST
  34
  35 DEBUG="-g"
  36 WARNINGS="-Wall -Werror"
  37 CFLAGS_FPIC="-fPIC"
  38 WIN32=no
  39 case "$host" in
  40   *-*-mingw*)
  41     WARNINGS="$WARNINGS -Wno-unused"
  42     CFLAGS_FPIC=""
  43     WIN32=yes
  44 esac
  45 AC_SUBST(DEBUG)
  46 AC_SUBST(WARNINGS)
  47 AC_SUBST(CFLAGS_FPIC)
  48 AC_SUBST(WIN32)
  49
  50 dnl Check for libvirt development environment.
  51 AC_ARG_WITH(libvirt,
  52         AC_HELP_STRING([--with-libvirt=PATH],[Set path to installed libvirt]),
  53         [if test "x$withval" != "x"; then
  54            CFLAGS="$CFLAGS -I$withval/include"
  55            LDFLAGS="$LDFLAGS -L$withval/lib"
  56          fi
  57         ])
  58 AC_CHECK_LIB(virt,virConnectOpen,
  59         [],
  60         AC_MSG_ERROR([You must install libvirt library]))
  61 AC_CHECK_HEADER([libvirt/libvirt.h],
  62         [],
  63         AC_MSG_ERROR([You must install libvirt development package]))
  64
  65 dnl We also use <libvirt/virterror.h>
  66 AC_CHECK_HEADER([libvirt/virterror.h],
  67         [],
  68         AC_MSG_ERROR([You must install libvirt development package]))
  69
  70 dnl Check for libvirt >= 0.2.1 (our minimum supported version).
  71 dnl See: http://libvirt.org/hvsupport.html
  72 AC_CHECK_FUNC(virConnectGetCapabilities,
  73         [],
  74         AC_MSG_ERROR([You must have libvirt >= 0.2.1]))
  75
  76 dnl Check for optional libvirt functions added since 0.2.1.
  77 dnl See: http://libvirt.org/hvsupport.html
  78 AC_CHECK_FUNCS([virConnectGetHostname \
  79                 virConnectGetURI \
  80                 virDomainBlockStats \
  81                 virDomainGetSchedulerParameters \
  82                 virDomainGetSchedulerType \
  83                 virDomainInterfaceStats \
  84                 virDomainMigrate \
  85                 virDomainSetSchedulerParameters \
  86                 virNodeGetFreeMemory \
  87                 virNodeGetCellsFreeMemory \
  88                 virStoragePoolGetConnect \
  89                 virConnectNumOfStoragePools \
  90                 virConnectListStoragePools \
  91                 virConnectNumOfDefinedStoragePools \
  92                 virConnectListDefinedStoragePools \
  93                 virStoragePoolLookupByName \
  94                 virStoragePoolLookupByUUID \
  95                 virStoragePoolLookupByUUIDString \
  96                 virStoragePoolLookupByVolume \
  97                 virStoragePoolCreateXML \
  98                 virStoragePoolDefineXML \
  99                 virStoragePoolBuild \
 100                 virStoragePoolUndefine \
 101                 virStoragePoolCreate \
 102                 virStoragePoolDestroy \
 103                 virStoragePoolDelete \
 104                 virStoragePoolFree \
 105                 virStoragePoolRefresh \
 106                 virStoragePoolGetName \
 107                 virStoragePoolGetUUID \
 108                 virStoragePoolGetUUIDString \
 109                 virStoragePoolGetInfo \
 110                 virStoragePoolGetXMLDesc \
 111                 virStoragePoolGetAutostart \
 112                 virStoragePoolSetAutostart \
 113                 virStoragePoolNumOfVolumes \
 114                 virStoragePoolListVolumes \
 115                 virStorageVolLookupByName \
 116                 virStorageVolLookupByKey \
 117                 virStorageVolLookupByPath \
 118                 virStorageVolGetName \
 119                 virStorageVolGetKey \
 120                 virStorageVolCreateXML \
 121                 virStorageVolDelete \
 122                 virStorageVolFree \
 123                 virStorageVolGetInfo \
 124                 virStorageVolGetXMLDesc \
 125                 virStorageVolGetPath \
 126                 virDomainBlockPeek \
 127                 virDomainMemoryPeek \
 128                 virConnectListAllDomains \
 129 ])
 130
 131 dnl Check for optional types added since 0.2.1.
 132 AC_CHECK_TYPES([virStoragePoolPtr, virStorageVolPtr],,,
 133                [#include <libvirt/libvirt.h>])
 134
 135 dnl Check for basic OCaml environment & findlib.
 136 AC_PROG_OCAML
 137 AC_PROG_FINDLIB
 138
 139 if test "x$OCAMLFIND" = "x"; then
 140     AC_MSG_ERROR([OCaml findlib is required])
 141 fi
 142
 143 dnl Use ocamlfind to find the required packages ...
 144
 145 dnl Check for required OCaml packages.
 146 AC_CHECK_OCAML_PKG(unix)
 147 if test "x$pkg_unix" != "xyes"; then
 148     AC_MSG_ERROR([Cannot find required OCaml package 'unix'])
 149 fi
 150
 151 dnl Check for optional OCaml packages.
 152 AC_CHECK_OCAML_PKG(gettext)
 153
 154 AC_SUBST(pkg_gettext)
 155
 156 dnl Check for recommended ocaml-gettext tool.
 157 AC_CHECK_PROG(OCAML_GETTEXT,ocaml-gettext,ocaml-gettext)
 158
 159 dnl Check for optional NSIS (for building a Windows installer).
 160 dnl XXX This probably doesn't work at the moment XXX
 161 AC_ARG_WITH([nsis],
 162         [AS_HELP_STRING([--with-nsis],
 163             [use NSIS to build a Windows installer])],
 164         [],
 165         [with_nsis=no])
 166
 167 MAKENSIS=
 168 LIBVIRT_DLL_PATH=
 169 LIBXDR_DLL_PATH=
 170 LIBXML2_DLL_PATH=
 171 GNUTLS_DLL_PATH=
 172 GTK_PATH=
 173 GTK_DLL_PATH=
 174
 175 [
 176 msys_to_win_dir () {
 177     eval pushd "\$$1" > /dev/null
 178     eval $1=`pwd -W`
 179     popd > /dev/null
 180 }
 181 ]
 182
 183 if test "x$with_nsis" != "xno"; then
 184     AC_PATH_PROG(MAKENSIS,makensis,[],[$with_nsis:$PATH])
 185     if test "x$MAKENSIS" = "x"; then
 186         AC_MSG_FAILURE([--with-nsis was given, but could not find MAKENSIS.EXE])
 187     fi
 188
 189     # MAKENSIS is set so we will build a rule for making a Windows
 190     # installer.  To support this, generate wininstaller.nsis.
 191     saved_IFS=$IFS
 192     IFS=$PATH_SEPARATOR
 193     for d in $PATH; do
 194         IFS=$saved_IFS
 195         echo Checking $d for DLLs ... >&5
 196         if test -f "$d/libvirt-0.dll"; then
 197             LIBVIRT_DLL_PATH="$d"
 198         fi
 199         if test -f "$d/libxdr.dll"; then
 200             LIBXDR_DLL_PATH="$d"
 201         fi
 202         if test -f "$d/libxml2-2.dll"; then
 203             LIBXML2_DLL_PATH="$d"
 204         fi
 205         if test -f "$d/libgpg-error-0.dll"; then
 206             GNUTLS_DLL_PATH="$d"
 207         fi
 208         if test -f "$d/libgtk-win32-2.0-0.dll"; then
 209             GTK_DLL_PATH="$d"
 210             GTK_PATH="$d/.."
 211         fi
 212     done
 213     IFS=$saved_IFS
 214
 215     if test "x$LIBVIRT_DLL_PATH" = "x"; then
 216         AC_MSG_FAILURE([cannot find libvirt-0.dll in PATH])
 217     fi
 218     if test "x$LIBXDR_DLL_PATH" = "x"; then
 219         AC_MSG_FAILURE([cannot find libxdr.dll in PATH])
 220     fi
 221     if test "x$LIBXML2_DLL_PATH" = "x"; then
 222         AC_MSG_FAILURE([cannot find libxml2-2.dll in PATH])
 223     fi
 224     if test "x$GNUTLS_DLL_PATH" = "x"; then
 225         AC_MSG_FAILURE([cannot find GnuTLS DLLs in PATH])
 226     fi
 227     if test "x$GTK_DLL_PATH" = "x"; then
 228         AC_MSG_WARN([cannot find GTK DLLs in PATH])
 229     fi
 230
 231     # Change the paths to Windows paths.
 232     msys_to_win_dir LIBVIRT_DLL_PATH
 233     msys_to_win_dir LIBXDR_DLL_PATH
 234     msys_to_win_dir LIBXML2_DLL_PATH
 235     msys_to_win_dir GNUTLS_DLL_PATH
 236     if test "x$GTK_DLL_PATH" != "x"; then
 237         msys_to_win_dir GTK_DLL_PATH
 238         msys_to_win_dir GTK_PATH
 239     fi
 240 fi
 241 AC_SUBST(MAKENSIS)
 242 AC_SUBST(LIBVIRT_DLL_PATH)
 243 AC_SUBST(LIBXDR_DLL_PATH)
 244 AC_SUBST(LIBXML2_DLL_PATH)
 245 AC_SUBST(GNUTLS_DLL_PATH)
 246 AC_SUBST(GTK_DLL_PATH)
 247 AC_SUBST(GTK_PATH)
 248
 249 dnl Write gettext modules for the programs.
 250 dnl http://www.le-gall.net/sylvain+violaine/documentation/ocaml-gettext/html/reference-manual/ch03s04.html
 251 for d in mlvirsh; do
 252     f=`echo $d | tr - _`_gettext.ml
 253     AC_MSG_NOTICE([creating $d/$f])
 254     rm -f $d/$f
 255     echo "(* This file is generated automatically by ./configure. *)" > $d/$f
 256     if test "x$pkg_gettext" != "xno"; then
 257         # Gettext module is available, so use it.
 258         cat <<EOT >>$d/$f
 259 module Gettext = Gettext.Program (
 260   struct
 261     let textdomain = "$d"
 262     let codeset = None
 263     let dir = None
 264     let dependencies = [[]]
 265   end
 266 ) (GettextStub.Native)
 267 EOT
 268     else
 269         # No gettext module is available, so fake the translation functions.
 270         cat <<EOT >>$d/$f
 271 module Gettext = struct
 272   external s_ : string -> string = "%identity"
 273   external f_ : ('a -> 'b, 'c, 'd) format -> ('a -> 'b, 'c, 'd) format
 274     = "%identity"
 275   let sn_ : string -> string -> int -> string
 276     = fun s p n -> if n = 1 then s else p
 277   let fn_ : ('a -> 'b, 'c, 'd) format -> ('a -> 'b, 'c, 'd) format -> int
 278       -> ('a -> 'b, 'c, 'd) format
 279     = fun s p n -> if n = 1 then s else p
 280 end
 281 EOT
 282     fi
 283 done
 284
 285 dnl Summary.
 286 echo "------------------------------------------------------------"
 287 echo "Thanks for downloading" $PACKAGE_STRING
 288 echo "------------------------------------------------------------"
 289
 290 dnl Produce output files.
 291 AC_CONFIG_HEADERS([config.h])
 292 AC_CONFIG_FILES([META
 293         libvirt/libvirt_version.ml
 294         Makefile
 295         Make.rules
 296         po/Makefile
 297         libvirt/Makefile
 298         examples/Makefile
 299         mlvirsh/Makefile
 300         ])
 301 if test "x$MAKENSIS" != "x"; then
 302         AC_CONFIG_FILES([wininstaller.nsis])
 303 fi
 304 AC_OUTPUT