configure.ac

   1 # ocaml-libvirt
   2 # Copyright (C) 2007-2008 Red Hat Inc., Richard W.M. Jones
   3 #
   4 # This library is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU Lesser General Public
   6 # License as published by the Free Software Foundation; either
   7 # version 2 of the License, or (at your option) any later version.
   8 #
   9 # This library is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Lesser General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Lesser General Public
  15 # License along with this library; if not, write to the Free Software
  16 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  17
  18 dnl Process this file with autoconf to produce a configure script.
  19
  20 AC_INIT(ocaml-libvirt,0.4.4.2)
  21
  22 dnl Check for basic C environment.
  23 AC_PROG_CC
  24 AC_PROG_INSTALL
  25 AC_PROG_CPP
  26
  27 AC_C_PROTOTYPES
  28 test "x$U" != "x" && AC_MSG_ERROR(Compiler not ANSI compliant)
  29
  30 AC_PROG_CC_C_O
  31
  32 dnl Select some C flags based on the host type.
  33 AC_CANONICAL_HOST
  34
  35 DEBUG="-g"
  36 WARNINGS="-Wall -Werror"
  37 CFLAGS_FPIC="-fPIC"
  38 WIN32=no
  39 case "$host" in
  40   *-*-mingw*)
  41     WARNINGS="$WARNINGS -Wno-unused"
  42     CFLAGS_FPIC=""
  43     WIN32=yes
  44 esac
  45 AC_SUBST(DEBUG)
  46 AC_SUBST(WARNINGS)
  47 AC_SUBST(CFLAGS_FPIC)
  48 AC_SUBST(WIN32)
  49
  50 dnl Check for libvirt development environment.
  51 AC_ARG_WITH(libvirt,
  52         AC_HELP_STRING([--with-libvirt=PATH],[Set path to installed libvirt]),
  53         [if test "x$withval" != "x"; then
  54            CFLAGS="$CFLAGS -I$withval/include"
  55            LDFLAGS="$LDFLAGS -L$withval/lib"
  56          fi
  57         ])
  58 AC_CHECK_LIB(virt,virConnectOpen,
  59         [],
  60         AC_MSG_ERROR([You must install libvirt library]))
  61 AC_CHECK_HEADER([libvirt/libvirt.h],
  62         [],
  63         AC_MSG_ERROR([You must install libvirt development package]))
  64
  65 dnl We also use <libvirt/virterror.h>
  66 AC_CHECK_HEADER([libvirt/virterror.h],
  67         [],
  68         AC_MSG_ERROR([You must install libvirt development package]))
  69
  70 dnl Check for libvirt >= 0.2.1 (our minimum supported version).
  71 dnl See: http://libvirt.org/hvsupport.html
  72 AC_CHECK_FUNC(virConnectGetCapabilities,
  73         [],
  74         AC_MSG_ERROR([You must have libvirt >= 0.2.1]))
  75
  76 dnl Check for optional libvirt functions added since 0.2.1.
  77 dnl See: http://libvirt.org/hvsupport.html
  78 AC_CHECK_FUNCS([virConnectGetHostname \
  79                 virConnectGetURI \
  80                 virDomainBlockStats \
  81                 virDomainGetSchedulerParameters \
  82                 virDomainGetSchedulerType \
  83                 virDomainInterfaceStats \
  84                 virDomainMigrate \
  85                 virDomainSetSchedulerParameters \
  86                 virNodeGetFreeMemory \
  87                 virNodeGetCellsFreeMemory \
  88                 virStoragePoolGetConnect \
  89                 virConnectNumOfStoragePools \
  90                 virConnectListStoragePools \
  91                 virConnectNumOfDefinedStoragePools \
  92                 virConnectListDefinedStoragePools \
  93                 virStoragePoolLookupByName \
  94                 virStoragePoolLookupByUUID \
  95                 virStoragePoolLookupByUUIDString \
  96                 virStoragePoolLookupByVolume \
  97                 virStoragePoolCreateXML \
  98                 virStoragePoolDefineXML \
  99                 virStoragePoolBuild \
 100                 virStoragePoolUndefine \
 101                 virStoragePoolCreate \
 102                 virStoragePoolDestroy \
 103                 virStoragePoolDelete \
 104                 virStoragePoolFree \
 105                 virStoragePoolRefresh \
 106                 virStoragePoolGetName \
 107                 virStoragePoolGetUUID \
 108                 virStoragePoolGetUUIDString \
 109                 virStoragePoolGetInfo \
 110                 virStoragePoolGetXMLDesc \
 111                 virStoragePoolGetAutostart \
 112                 virStoragePoolSetAutostart \
 113                 virStoragePoolNumOfVolumes \
 114                 virStoragePoolListVolumes \
 115                 virStorageVolLookupByName \
 116                 virStorageVolLookupByKey \
 117                 virStorageVolLookupByPath \
 118                 virStorageVolGetName \
 119                 virStorageVolGetKey \
 120                 virStorageVolCreateXML \
 121                 virStorageVolDelete \
 122                 virStorageVolFree \
 123                 virStorageVolGetInfo \
 124                 virStorageVolGetXMLDesc \
 125                 virStorageVolGetPath \
 126                 virDomainBlockPeek \
 127                 virDomainMemoryPeek \
 128 ])
 129
 130 # This jobs API was never published and is due to get overhauled
 131 # in the near future:
 132 #               virJobGetInfo
 133 #               virJobGetDomain
 134 #               virJobGetNetwork
 135 #               virJobCancel
 136 #               virJobFree
 137 #               virDomainCreateLinuxJob
 138 #               virDomainSaveJob
 139 #               virDomainRestoreJob
 140 #               virDomainCoreDumpJob
 141 #               virDomainCreateJob
 142 #               virNetworkCreateXMLJob
 143 #               virNetworkCreateJob
 144
 145 dnl Check for optional types added since 0.2.1.
 146 AC_CHECK_TYPES([virJobPtr, virStoragePoolPtr, virStorageVolPtr],,,
 147                [#include <libvirt/libvirt.h>])
 148
 149 dnl Check for basic OCaml environment & findlib.
 150 AC_PROG_OCAML
 151 AC_PROG_FINDLIB
 152
 153 if test "x$OCAMLFIND" = "x"; then
 154     AC_MSG_ERROR([OCaml findlib is required])
 155 fi
 156
 157 dnl Use ocamlfind to find the required packages ...
 158
 159 dnl Check for required OCaml packages.
 160 AC_CHECK_OCAML_PKG(unix)
 161 if test "x$pkg_unix" != "xyes"; then
 162     AC_MSG_ERROR([Cannot find required OCaml package 'unix'])
 163 fi
 164
 165 dnl Check for optional OCaml packages.
 166 AC_CHECK_OCAML_PKG(gettext)
 167
 168 AC_SUBST(pkg_gettext)
 169
 170 dnl Check for recommended ocaml-gettext tool.
 171 AC_CHECK_PROG(OCAML_GETTEXT,ocaml-gettext,ocaml-gettext)
 172
 173 dnl Check for optional NSIS (for building a Windows installer).
 174 dnl XXX This probably doesn't work at the moment XXX
 175 AC_ARG_WITH([nsis],
 176         [AS_HELP_STRING([--with-nsis],
 177             [use NSIS to build a Windows installer])],
 178         [],
 179         [with_nsis=no])
 180
 181 MAKENSIS=
 182 LIBVIRT_DLL_PATH=
 183 LIBXDR_DLL_PATH=
 184 LIBXML2_DLL_PATH=
 185 GNUTLS_DLL_PATH=
 186 GTK_PATH=
 187 GTK_DLL_PATH=
 188
 189 [
 190 msys_to_win_dir () {
 191     eval pushd "\$$1" > /dev/null
 192     eval $1=`pwd -W`
 193     popd > /dev/null
 194 }
 195 ]
 196
 197 if test "x$with_nsis" != "xno"; then
 198     AC_PATH_PROG(MAKENSIS,makensis,[],[$with_nsis:$PATH])
 199     if test "x$MAKENSIS" = "x"; then
 200         AC_MSG_FAILURE([--with-nsis was given, but could not find MAKENSIS.EXE])
 201     fi
 202
 203     # MAKENSIS is set so we will build a rule for making a Windows
 204     # installer.  To support this, generate wininstaller.nsis.
 205     saved_IFS=$IFS
 206     IFS=$PATH_SEPARATOR
 207     for d in $PATH; do
 208         IFS=$saved_IFS
 209         echo Checking $d for DLLs ... >&5
 210         if test -f "$d/libvirt-0.dll"; then
 211             LIBVIRT_DLL_PATH="$d"
 212         fi
 213         if test -f "$d/libxdr.dll"; then
 214             LIBXDR_DLL_PATH="$d"
 215         fi
 216         if test -f "$d/libxml2-2.dll"; then
 217             LIBXML2_DLL_PATH="$d"
 218         fi
 219         if test -f "$d/libgpg-error-0.dll"; then
 220             GNUTLS_DLL_PATH="$d"
 221         fi
 222         if test -f "$d/libgtk-win32-2.0-0.dll"; then
 223             GTK_DLL_PATH="$d"
 224             GTK_PATH="$d/.."
 225         fi
 226     done
 227     IFS=$saved_IFS
 228
 229     if test "x$LIBVIRT_DLL_PATH" = "x"; then
 230         AC_MSG_FAILURE([cannot find libvirt-0.dll in PATH])
 231     fi
 232     if test "x$LIBXDR_DLL_PATH" = "x"; then
 233         AC_MSG_FAILURE([cannot find libxdr.dll in PATH])
 234     fi
 235     if test "x$LIBXML2_DLL_PATH" = "x"; then
 236         AC_MSG_FAILURE([cannot find libxml2-2.dll in PATH])
 237     fi
 238     if test "x$GNUTLS_DLL_PATH" = "x"; then
 239         AC_MSG_FAILURE([cannot find GnuTLS DLLs in PATH])
 240     fi
 241     if test "x$GTK_DLL_PATH" = "x"; then
 242         AC_MSG_WARN([cannot find GTK DLLs in PATH])
 243     fi
 244
 245     # Change the paths to Windows paths.
 246     msys_to_win_dir LIBVIRT_DLL_PATH
 247     msys_to_win_dir LIBXDR_DLL_PATH
 248     msys_to_win_dir LIBXML2_DLL_PATH
 249     msys_to_win_dir GNUTLS_DLL_PATH
 250     if test "x$GTK_DLL_PATH" != "x"; then
 251         msys_to_win_dir GTK_DLL_PATH
 252         msys_to_win_dir GTK_PATH
 253     fi
 254 fi
 255 AC_SUBST(MAKENSIS)
 256 AC_SUBST(LIBVIRT_DLL_PATH)
 257 AC_SUBST(LIBXDR_DLL_PATH)
 258 AC_SUBST(LIBXML2_DLL_PATH)
 259 AC_SUBST(GNUTLS_DLL_PATH)
 260 AC_SUBST(GTK_DLL_PATH)
 261 AC_SUBST(GTK_PATH)
 262
 263 dnl Write gettext modules for the programs.
 264 dnl http://www.le-gall.net/sylvain+violaine/documentation/ocaml-gettext/html/reference-manual/ch03s04.html
 265 for d in mlvirsh; do
 266     f=`echo $d | tr - _`_gettext.ml
 267     AC_MSG_NOTICE([creating $d/$f])
 268     rm -f $d/$f
 269     echo "(* This file is generated automatically by ./configure. *)" > $d/$f
 270     if test "x$pkg_gettext" != "xno"; then
 271         # Gettext module is available, so use it.
 272         cat <<EOT >>$d/$f
 273 module Gettext = Gettext.Program (
 274   struct
 275     let textdomain = "$d"
 276     let codeset = None
 277     let dir = None
 278     let dependencies = [[]]
 279   end
 280 ) (GettextStub.Native)
 281 EOT
 282     else
 283         # No gettext module is available, so fake the translation functions.
 284         cat <<EOT >>$d/$f
 285 module Gettext = struct
 286   external s_ : string -> string = "%identity"
 287   external f_ : ('a -> 'b, 'c, 'd) format -> ('a -> 'b, 'c, 'd) format
 288     = "%identity"
 289   let sn_ : string -> string -> int -> string
 290     = fun s p n -> if n = 1 then s else p
 291   let fn_ : ('a -> 'b, 'c, 'd) format -> ('a -> 'b, 'c, 'd) format -> int
 292       -> ('a -> 'b, 'c, 'd) format
 293     = fun s p n -> if n = 1 then s else p
 294 end
 295 EOT
 296     fi
 297 done
 298
 299 dnl Summary.
 300 echo "------------------------------------------------------------"
 301 echo "Thanks for downloading" $PACKAGE_STRING
 302 echo "------------------------------------------------------------"
 303
 304 dnl Produce output files.
 305 AC_CONFIG_HEADERS([config.h])
 306 AC_CONFIG_FILES([META
 307         libvirt/libvirt_version.ml
 308         Makefile
 309         Make.rules
 310         po/Makefile
 311         libvirt/Makefile
 312         examples/Makefile
 313         mlvirsh/Makefile
 314         ])
 315 if test "x$MAKENSIS" != "x"; then
 316         AC_CONFIG_FILES([wininstaller.nsis])
 317 fi
 318 AC_OUTPUT