configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 AC_INIT([libguestfs],[1.0.45])
  19 AM_INIT_AUTOMAKE
  20
  21 AC_CONFIG_MACRO_DIR([m4])
  22
  23 AC_PROG_LIBTOOL
  24
  25 dnl Check for basic C environment.
  26 AC_PROG_CC_STDC
  27 AC_PROG_INSTALL
  28 AC_PROG_CPP
  29
  30 AC_C_PROTOTYPES
  31 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
  32
  33 AM_PROG_CC_C_O
  34
  35 dnl Check support for 64 bit file offsets.
  36 AC_SYS_LARGEFILE
  37
  38 dnl Check sizeof long.
  39 AC_CHECK_SIZEOF([long])
  40
  41 dnl Headers.
  42 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h])
  43
  44 dnl Check for rpcgen and XDR library.  rpcgen is optional.
  45 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
  46 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
  47 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
  48         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
  49         ])
  50
  51 dnl Check for pod2man and pod2text.
  52 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
  53 test "x$POD2MAN" = "xno" &&
  54      AC_MSG_ERROR([pod2man must be installed])
  55 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
  56 test "x$POD2TEXT" = "xno" &&
  57      AC_MSG_ERROR([pod2text must be installed])
  58
  59 dnl Check for mksquashfs.
  60 AC_PATH_PROGS([MKSQUASHFS],[mksquashfs],[no],
  61         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
  62 test "x$MKSQUASHFS" = "xno" && AC_MSG_ERROR([mksquashfs must be installed])
  63
  64 dnl Check for QEMU for running binaries on this $host_cpu, fall
  65 dnl back to basic 'qemu'.  Allow the user to override it.
  66 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
  67 AC_ARG_WITH([qemu],
  68         [AS_HELP_STRING([--with-qemu],
  69           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
  70         [],
  71         [with_qemu="$default_qemu"])
  72 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
  73         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
  74 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
  75 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
  76
  77 dnl Check that the chosen qemu has vmchannel support.
  78 dnl http://lists.gnu.org/archive/html/qemu-devel/2009-02/msg01042.html
  79 if test "x$vmchannel_test" != "xno"; then
  80     AC_MSG_CHECKING([for vmchannel support in $QEMU])
  81     vmchannelout=`$QEMU -net channel /dev/zero 2>&1 ||:`
  82     echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
  83     if ! echo $vmchannelout | grep -sq "vmchannel wrong port number" ; then
  84         AC_MSG_RESULT([no])
  85         AC_MSG_FAILURE(
  86 [I did not find vmchannel support in $QEMU.
  87
  88 vmchannel support is vital for libguestfs to operate.  You need a version
  89 of qemu >= 0.10, or the following patch backported to earlier versions:
  90
  91 http://lists.gnu.org/archive/html/qemu-devel/2009-02/msg01042.html
  92
  93 You can override this test by setting the environment variable
  94 vmchannel_test=no  However if you don't have vmchannel support
  95 in your qemu, then this just delays the pain.
  96
  97 If I am using the wrong qemu or you want to compile qemu from source
  98 and install it in another location, then you should configure with
  99 the --with-qemu option.
 100 ])
 101     fi
 102     AC_MSG_RESULT([yes])
 103 fi
 104
 105 dnl Check for febootstrap etc.
 106 AC_CHECK_PROG([FEBOOTSTRAP],
 107         [febootstrap],[febootstrap],[no])
 108 test "x$FEBOOTSTRAP" = "xno" && \
 109      AC_MSG_ERROR([febootstrap must be installed])
 110 AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 111         [febootstrap-run],[febootstrap-run],[no])
 112 test "x$FEBOOTSTRAP_RUN" = "xno" && \
 113      AC_MSG_ERROR([febootstrap-run must be installed])
 114 AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 115         [febootstrap-install],[febootstrap-install],[no])
 116 test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 117      AC_MSG_ERROR([febootstrap-install must be installed])
 118 AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 119         [febootstrap-minimize],[febootstrap-minimize],[no])
 120 test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 121      AC_MSG_ERROR([febootstrap-minimize must be installed])
 122 AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 123         [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 124 test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 125      AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 126
 127 dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 128 dnl of febootstrap, but old versions will fail with yum).
 129 AC_CHECK_PROG([FAKECHROOT],
 130         [fakechroot],[fakechroot],[no])
 131 test "x$FAKECHROOT" = "xno" && \
 132     AC_MSG_ERROR([fakechroot must be installed])
 133
 134 AC_MSG_CHECKING([fakechroot version])
 135 fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 136 if test -z "$fakechroot_version"; then
 137     AC_MSG_RESULT([failed])
 138     AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 139 else
 140     AC_MSG_RESULT([$fakechroot_version])
 141     fakechroot_major=`echo $fakechroot_version | awk -F. '{print $1}'`
 142     fakechroot_minor=`echo $fakechroot_version | awk -F. '{print $2}'`
 143     if test "$fakechroot_major" -lt 2 -o \
 144             \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
 145         AC_MSG_ERROR([fakechroot version must be >= 2.9])
 146     fi
 147 fi
 148
 149 dnl --with-repo to specify a Fedora repository.
 150 AC_ARG_WITH([repo],
 151         [AS_HELP_STRING([--with-repo],
 152           [set name of Fedora repository @<:@default=fedora-11@:>@])],
 153         [],
 154         [with_repo=fedora-11])
 155 REPO="$with_repo"
 156 AC_SUBST(REPO)
 157 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 158
 159 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 160
 161 dnl --with-updates to specify a Fedora updates repository.
 162 AC_ARG_WITH([updates],
 163         [AS_HELP_STRING([--with-updates],
 164           [set name of Fedora updates repository @<:@default=updates-released-f11@:>@])],
 165         [],
 166         [with_updates=updates-released-f11])
 167 UPDATES="$with_updates"
 168 AC_SUBST(UPDATES)
 169 AC_DEFINE_UNQUOTED([UPDATES],["$UPDATES"],[Name of Fedora updates repository.])
 170
 171 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 172
 173 dnl --with-mirror to specify a local Fedora mirror.
 174 AC_ARG_WITH([mirror],
 175         [AS_HELP_STRING([--with-mirror],
 176           [set URI of a local Fedora mirror])],
 177         [],
 178         [with_mirror=])
 179 MIRROR="$with_mirror"
 180 AC_SUBST(MIRROR)
 181
 182 dnl Build the supermin appliance?  Please see README file before
 183 dnl enabling this option.
 184 AC_ARG_ENABLE([supermin],
 185         [AS_HELP_STRING([--enable-supermin],
 186           [enable supermin appliance (see README) @<:@default=no@:>@])],
 187         [],
 188         [enable_supermin=no])
 189 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 190
 191 dnl Readline.
 192 AC_ARG_WITH([readline],
 193     [AS_HELP_STRING([--with-readline],
 194         [support fancy command line editing @<:@default=check@:>@])],
 195     [],
 196     [with_readline=check])
 197
 198 LIBREADLINE=
 199 AS_IF([test "x$with_readline" != xno],
 200     [AC_CHECK_LIB([readline], [main],
 201         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 202          AC_DEFINE([HAVE_LIBREADLINE], [1],
 203                    [Define if you have libreadline])
 204         ],
 205         [if test "x$with_readline" != xcheck; then
 206          AC_MSG_FAILURE(
 207              [--with-readline was given, but test for readline failed])
 208          fi
 209         ], -lncurses)])
 210
 211 dnl For i18n.
 212 AM_GNU_GETTEXT([external])
 213 AM_GNU_GETTEXT_VERSION([0.14])
 214
 215 dnl Check for OCaml (optional, for OCaml bindings).
 216 AC_PROG_OCAML
 217 AC_PROG_FINDLIB
 218 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
 219
 220 dnl Check for Perl (optional, for Perl bindings).
 221 dnl XXX This isn't quite right, we should check for Perl devel library.
 222 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 223
 224 dnl Check for Perl modules that must be present to compile and
 225 dnl test the Perl bindings.
 226 missing_perl_modules=no
 227 for pm in Test::More Test::Pod Test::Pod::Coverage ExtUtils::MakeMaker; do
 228     AC_MSG_CHECKING([for $pm])
 229     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 230         AC_MSG_RESULT([no])
 231         missing_perl_modules=yes
 232     else
 233         AC_MSG_RESULT([yes])
 234     fi
 235 done
 236 if test "x$missing_perl_modules" = "xyes"; then
 237     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 238 fi
 239
 240 AM_CONDITIONAL([HAVE_PERL],
 241     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 242
 243 dnl Check for Python (optional, for Python bindings).
 244 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 245
 246 PYTHON_PREFIX=
 247 PYTHON_VERSION=
 248 PYTHON_INCLUDEDIR=
 249 PYTHON_SITE_PACKAGES=
 250
 251 if test "x$PYTHON" != "xno"; then
 252     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 253     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 254     for d in \
 255         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 256         /usr/include/python$PYTHON_VERSION \
 257         /usr/local/include/python$PYTHON_VERSION
 258     do
 259         AC_MSG_CHECKING([Python.h in $d])
 260         if test -r "$d/Python.h"; then
 261             AC_MSG_RESULT([found])
 262             PYTHON_INCLUDEDIR=$d
 263             break
 264         fi
 265         AC_MSG_RESULT([not found])
 266     done
 267     for d in \
 268         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 269         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 270         /usr/lib64/python$PYTHON_VERSION/site-packages \
 271         /usr/lib/python$PYTHON_VERSION/site-packages \
 272         /usr/local/lib/python$PYTHON_VERSION/site-packages
 273     do
 274         AC_MSG_CHECKING([for $d])
 275         if test -d "$d"; then
 276             AC_MSG_RESULT([found])
 277             PYTHON_SITE_PACKAGES=$d
 278             break
 279         fi
 280         AC_MSG_RESULT([not found])
 281     done
 282 fi
 283
 284 AC_SUBST(PYTHON_PREFIX)
 285 AC_SUBST(PYTHON_VERSION)
 286 AC_SUBST(PYTHON_INCLUDEDIR)
 287 AC_SUBST(PYTHON_SITE_PACKAGES)
 288
 289 AM_CONDITIONAL([HAVE_PYTHON],
 290     [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
 291
 292 dnl Check for Ruby and rake (optional, for Ruby bindings).
 293 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 294 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 295
 296 AM_CONDITIONAL([HAVE_RUBY],
 297     [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
 298
 299 dnl Check for Java.
 300 AC_ARG_WITH(java_home,
 301     [AS_HELP_STRING([--with-java-home],
 302         [specify path to JDK directory @<:@default=check@:>@])],
 303     [],
 304     [with_java_home=check])
 305
 306 if test "x$with_java_home" != "xno"; then
 307     if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
 308     then
 309         if test -d "$with_java_home"; then
 310             JAVA_HOME="$with_java_home"
 311         else
 312             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 313         fi
 314     fi
 315
 316     if test "x$JAVA_HOME" = "x"; then
 317         # Look for Java in some likely locations.
 318         for d in \
 319             /usr/lib/jvm/java \
 320             /usr/lib/jvm/java-6-openjdk
 321         do
 322             if test -d $d -a -f $d/bin/java; then
 323                 JAVA_HOME=$d
 324                 break
 325             fi
 326         done
 327     fi
 328
 329     if test "x$JAVA_HOME" != "x"; then
 330         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 331         if test ! -x "$JAVA_HOME/bin/java"; then
 332             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 333         else
 334             JAVA="$JAVA_HOME/bin/java"
 335         fi
 336         if test ! -x "$JAVA_HOME/bin/javac"; then
 337             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 338         else
 339             JAVAC="$JAVA_HOME/bin/javac"
 340         fi
 341         if test ! -x "$JAVA_HOME/bin/javah"; then
 342             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 343         else
 344             JAVAH="$JAVA_HOME/bin/javah"
 345         fi
 346         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 347             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 348         else
 349             JAVADOC="$JAVA_HOME/bin/javadoc"
 350         fi
 351         if test ! -x "$JAVA_HOME/bin/jar"; then
 352             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 353         else
 354             JAR="$JAVA_HOME/bin/jar"
 355         fi
 356         java_version=`$JAVA -version 2>&1 | grep "java version"`
 357         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 358
 359         dnl Find jni.h.
 360         AC_MSG_CHECKING([for jni.h])
 361         if test -f "$JAVA_HOME/include/jni.h"; then
 362             JNI_CFLAGS="-I$JAVA_HOME/include"
 363         else
 364             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 365                 head=`find $JAVA_HOME -name jni.h | tail -1`
 366                 dir=`dirname $head`
 367                 JNI_CFLAGS="-I$dir"
 368             else
 369                 AC_MSG_FAILURE([missing jni.h header file])
 370             fi
 371         fi
 372         AC_MSG_RESULT([$JNI_CFLAGS])
 373
 374         dnl Find jni_md.h.
 375         AC_MSG_CHECKING([for jni_md.h])
 376         case "$build_os" in
 377         *linux*) system="linux" ;;
 378         *SunOS*) system="solaris" ;;
 379         *cygwin*) system="win32" ;;
 380         *) system="$build_os" ;;
 381         esac
 382         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 383             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 384         else
 385             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 386                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 387                 dir=`dirname $head`
 388                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 389             else
 390                 AC_MSG_FAILURE([missing jni_md.h header file])
 391             fi
 392         fi
 393         AC_MSG_RESULT([$JNI_CFLAGS])
 394
 395         dnl Need extra version flag?
 396         AC_MSG_CHECKING([extra javac flags])
 397         JAVAC_FLAGS=
 398         javac_version=`$JAVAC -version 2>&1`
 399         case "$javac_version" in
 400         *Eclipse*)
 401             JAVAC_FLAGS="-source 1.5" ;;
 402         esac
 403         AC_MSG_RESULT([$JAVAC_FLAGS])
 404
 405         dnl Where to install jarfiles.
 406         dnl XXX How to make it configurable?
 407         JAR_INSTALL_DIR=\${prefix}/share/java
 408         JNI_INSTALL_DIR=\${libdir}
 409
 410         dnl JNI version.
 411         jni_major_version=`echo $VERSION | awk -F. '{print $1}'`
 412         jni_minor_version=`echo $VERSION | awk -F. '{print $2}'`
 413         jni_micro_version=`echo $VERSION | awk -F. '{print $3}'`
 414         JNI_VERSION_INFO=`expr $jni_major_version + $jni_minor_version`:$jni_micro_version:$jni_minor_version
 415     fi
 416 fi
 417
 418 AC_SUBST(JAVA_HOME)
 419 AC_SUBST(JAVA)
 420 AC_SUBST(JAVAC)
 421 AC_SUBST(JAVAH)
 422 AC_SUBST(JAVADOC)
 423 AC_SUBST(JAR)
 424 AC_SUBST(JNI_CFLAGS)
 425 AC_SUBST(JAVAC_FLAGS)
 426 AC_SUBST(JAR_INSTALL_DIR)
 427 AC_SUBST(JNI_INSTALL_DIR)
 428 AC_SUBST(JNI_VERSION_INFO)
 429
 430 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 431
 432 dnl Check for Haskell (GHC).
 433 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 434
 435 AM_CONDITIONAL([HAVE_HASKELL],
 436     [test "x$GHC" != "xno"])
 437
 438 dnl Check for Perl modules needed by the inspector.
 439 missing_perl_modules=no
 440 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper; do
 441     AC_MSG_CHECKING([for $pm])
 442     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 443         AC_MSG_RESULT([no])
 444         missing_perl_modules=yes
 445     else
 446         AC_MSG_RESULT([yes])
 447     fi
 448 done
 449 if test "x$missing_perl_modules" = "xyes"; then
 450     AC_MSG_WARN([some Perl modules required to compile virt-inspector are missing])
 451 fi
 452
 453 AM_CONDITIONAL([HAVE_INSPECTOR],
 454     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 455
 456 dnl Run in subdirs.
 457 AC_CONFIG_SUBDIRS([daemon])
 458
 459 dnl Produce output files.
 460 AC_CONFIG_HEADERS([config.h])
 461 AC_CONFIG_FILES([Makefile
 462                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 463                  appliance/Makefile
 464                  appliance/make.sh appliance/update.sh
 465                  images/Makefile
 466                  capitests/Makefile
 467                  regressions/Makefile
 468                  ocaml/Makefile ocaml/examples/Makefile
 469                  perl/Makefile
 470                  python/Makefile
 471                  ruby/Makefile ruby/Rakefile
 472                  java/Makefile
 473                  haskell/Makefile
 474                  inspector/Makefile
 475                  libguestfs.pc
 476                  ocaml/META perl/Makefile.PL])
 477 AC_OUTPUT
 478
 479 dnl WTF?
 480 chmod +x appliance/make.sh appliance/update.sh
 481
 482 dnl Produce summary.
 483 echo
 484 echo
 485 echo "------------------------------------------------------------"
 486 echo "Thank you for downloading $PACKAGE_STRING"
 487 echo
 488 echo "This is how we have configured the optional components for you today:"
 489 echo
 490 echo    "QEMU ................................ $QEMU"
 491 echo -n "OCaml bindings ...................... "
 492 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 493 echo -n "Perl bindings ....................... "
 494 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 495 echo -n "Python bindings ..................... "
 496 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 497 echo -n "Ruby bindings ....................... "
 498 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 499 echo -n "Java bindings ....................... "
 500 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 501 echo -n "Haskell bindings .................... "
 502 if test "x$HAVE_HASKELL" = "x"; then echo "yes"; else echo "no"; fi
 503 echo -n "virt-inspector ...................... "
 504 if test "x$HAVE_INSPECTOR" = "x"; then echo "yes"; else echo "no"; fi
 505 echo "supermin appliance .................. $enable_supermin"
 506 echo
 507 echo "If any optional component is configured 'no' when you expected 'yes'"
 508 echo "then you should check the preceeding messages."
 509 echo
 510 echo "Please report bugs back to the fedora-virt mailing list:"
 511 echo "http://www.redhat.com/mailman/listinfo/fedora-virt"
 512 echo
 513 echo "Next you should type 'make' to build the package,"
 514 echo "then 'make check' to run the tests."
 515 echo "------------------------------------------------------------"