configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2010 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [7])
  21 m4_define([libguestfs_release], [23])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 dnl Stable or unstable version?
  41 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  42 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  43             AC_MSG_RESULT([stable])
  44        ],[
  45             AC_MSG_RESULT([unstable])
  46             AC_MSG_NOTICE([
  47 ***
  48 This is a development version of libguestfs. Some APIs may be unstable
  49 until they appear in a stable release of libguestfs (at which point
  50 the C API and ABI is guaranteed to remain stable forever).  For
  51 more information about stable and development branches of libguestfs
  52 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  53 ***])
  54        ])
  55
  56 dnl Early gnulib initialization.
  57 gl_EARLY
  58 gl_INIT
  59
  60 AC_PROG_LIBTOOL
  61
  62 dnl Check for basic C environment.
  63 AC_PROG_CC_STDC
  64 AC_PROG_INSTALL
  65 AC_PROG_CPP
  66
  67 AC_ARG_ENABLE([gcc-warnings],
  68   [AS_HELP_STRING([--enable-gcc-warnings],
  69                   [turn on lots of GCC warnings (for developers)])],
  70   [case $enableval in
  71      yes|no) ;;
  72      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  73    esac
  74    gl_gcc_warnings=$enableval],
  75   [gl_gcc_warnings=no]
  76 )
  77
  78 if test "$gl_gcc_warnings" = yes; then
  79   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  80   AC_SUBST([WERROR_CFLAGS])
  81
  82   nw=
  83   # This, $nw, is the list of warnings we disable.
  84   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  85   nw="$nw -Waggregate-return"       # anachronistic
  86   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  87   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  88   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  89   nw="$nw -Wcast-qual"              # Too many warnings for now
  90   nw="$nw -Wconversion"             # Too many warnings for now
  91   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  92   nw="$nw -Wsign-conversion"        # Too many warnings for now
  93   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  94   nw="$nw -Wunreachable-code"       # Too many warnings for now
  95   nw="$nw -Wpadded"                 # Our structs are not padded
  96   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  97   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  98   nw="$nw -Wvla"                    # two warnings in mount.c
  99   # things I might fix soon:
 100   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 101   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 102   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 103   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 104                                     # was not possible, safe to ignore
 105   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 106   nw="$nw -Wlong-long"              # Allow long long since it's required
 107                                     # by Python, Ruby and xstrtoll.
 108   nw="$nw -Wstack-protector"        # Don't warn about stack-protector
 109                                     # failures (seen on Ubuntu).
 110
 111   gl_MANYWARN_ALL_GCC([ws])
 112   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 113   for w in $ws; do
 114     gl_WARN_ADD([$w])
 115   done
 116   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 117   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 118   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 119
 120   # In spite of excluding -Wlogical-op above, it is enabled, as of
 121   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 122   gl_WARN_ADD([-Wno-logical-op])
 123
 124   # Work around warning in src/inspect.c.  This seems to be a bug in gcc 4.5.1.
 125   gl_WARN_ADD([-Wno-strict-overflow])
 126
 127   gl_WARN_ADD([-fdiagnostics-show-option])
 128
 129   AC_SUBST([WARN_CFLAGS])
 130
 131   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 132   AC_DEFINE([_FORTIFY_SOURCE], [2],
 133     [enable compile-time and run-time bounds-checking, and some warnings])
 134   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 135 fi
 136
 137 AC_C_PROTOTYPES
 138 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 139
 140 AM_PROG_CC_C_O
 141
 142 dnl Work out how to specify the linker script to the linker.
 143 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 144 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 145     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 146 AC_SUBST(VERSION_SCRIPT_FLAGS)
 147
 148 dnl Check support for 64 bit file offsets.
 149 AC_SYS_LARGEFILE
 150
 151 dnl Check sizeof long.
 152 AC_CHECK_SIZEOF([long])
 153
 154 dnl Define a C symbol for the host CPU architecture.
 155 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 156
 157 dnl Headers.
 158 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 159
 160 dnl Functions.
 161 AC_CHECK_FUNCS([posix_fallocate])
 162
 163 dnl Build the daemon?
 164 AC_MSG_CHECKING([if we should build the daemon])
 165 AC_ARG_ENABLE([daemon],
 166         [AS_HELP_STRING([--enable-daemon],
 167           [enable building the daemon @<:@default=yes@:>@])],
 168         [],
 169         [enable_daemon=yes])
 170 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 171 AC_MSG_RESULT([$enable_daemon])
 172
 173 dnl Build the appliance?
 174 AC_MSG_CHECKING([if we should build the appliance])
 175 AC_ARG_ENABLE([appliance],
 176         [AS_HELP_STRING([--enable-appliance],
 177           [enable building the appliance @<:@default=yes@:>@])],
 178         [],
 179         [enable_appliance=yes])
 180 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 181 AC_MSG_RESULT([$enable_appliance])
 182
 183 if test "x$enable_appliance" = "xyes"; then
 184     dnl Check for febootstrap >= 3.0
 185     AC_CHECK_PROG([FEBOOTSTRAP],
 186                   [febootstrap],[febootstrap],[no])
 187     test "x$FEBOOTSTRAP" = "xno" &&
 188         AC_MSG_ERROR([febootstrap must be installed])
 189     dnl febootstrap 2.x did not support the --version parameter
 190     $FEBOOTSTRAP --version >/dev/null 2>&1 ||
 191         AC_MSG_ERROR([febootstrap >= 3.0 must be installed, your version is too old])
 192
 193     dnl Pass a febootstrap --yum-config option.
 194     AC_MSG_CHECKING([if user requested febootstrap --yum-config option])
 195     AC_ARG_WITH([febootstrap-yum-config],
 196         [AS_HELP_STRING([--with-febootstrap-yum-config=FILE],
 197           [pass febootstrap --yum-config option @<:@default=no@:>@])],
 198         [FEBOOTSTRAP_YUM_CONFIG="$withval"],
 199         [FEBOOTSTRAP_YUM_CONFIG=no])
 200     AC_MSG_RESULT([$FEBOOTSTRAP_YUM_CONFIG])
 201     AC_SUBST([FEBOOTSTRAP_YUM_CONFIG])
 202
 203     dnl Which distro?
 204     dnl
 205     dnl This used to be Very Important but is now just used to select
 206     dnl which packages to install in the appliance, since the package
 207     dnl names vary slightly across distros.  (See appliance/packagelist.in)
 208     AC_MSG_CHECKING([which Linux distro for package names])
 209     DISTRO=REDHAT
 210     if test -f /etc/debian_version; then
 211         DISTRO=DEBIAN
 212         if grep -q 'DISTRIB_ID=Ubuntu' /etc/lsb-release 2>/dev/null; then
 213             DISTRO=UBUNTU
 214         fi
 215     fi
 216     if test -f /etc/arch-release; then
 217         DISTRO=ARCHLINUX
 218     fi
 219     AC_MSG_RESULT([$DISTRO])
 220     AC_SUBST([DISTRO])
 221 fi
 222
 223 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 224 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 225 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 226 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 227         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 228         ])
 229
 230 dnl Check for cpio which isn't in the default Pardus install amazingly.
 231 AC_CHECK_PROG([CPIO],[cpio],[cpio],[no])
 232 test "x$CPIO" = "xno" &&
 233      AC_MSG_ERROR([cpio must be installed])
 234
 235 dnl Check for gperf.
 236 AC_CHECK_PROG([GPERF],[gperf],[gperf],[no])
 237 test "x$GPERF" = "xno" &&
 238      AC_MSG_ERROR([gperf must be installed])
 239
 240 dnl Check for pod2man, pod2text, pod2html.
 241 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 242 test "x$POD2MAN" = "xno" &&
 243      AC_MSG_ERROR([pod2man must be installed])
 244 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 245 test "x$POD2TEXT" = "xno" &&
 246      AC_MSG_ERROR([pod2text must be installed])
 247 AC_CHECK_PROG([POD2HTML],[pod2html],[pod2html],[no])
 248 test "x$POD2HTML" = "xno" &&
 249      AC_MSG_ERROR([pod2html must be installed])
 250
 251 dnl Check for mkisofs.
 252 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 253         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 254 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 255
 256 dnl Check for optional xmllint.
 257 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 258 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 259
 260 dnl po4a for translating man pages and POD files (optional).
 261 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
 262 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
 263
 264 dnl Check for db_dump, db_load (optional).
 265 AC_CHECK_PROGS([DB_DUMP],
 266                [db_dump db4_dump db4.8_dump db4.7_dump db4.6_dump],[no])
 267 AC_CHECK_PROGS([DB_LOAD],
 268                [db_load db4_load db4.8_load db4.7_load db4.6_load],[no])
 269 if test "x$DB_DUMP" != "xno"; then
 270     AC_DEFINE_UNQUOTED([DB_DUMP],["$DB_DUMP"],[Name of db_dump program.])
 271 fi
 272 if test "x$DB_LOAD" != "xno"; then
 273     AC_DEFINE_UNQUOTED([DB_LOAD],["$DB_LOAD"],[Name of db_load program.])
 274 fi
 275
 276 dnl Check for QEMU for running binaries on this $host_cpu, fall
 277 dnl back to basic 'qemu'.  Allow the user to override it.
 278 default_qemu="qemu-kvm kvm qemu-system-$host_cpu qemu"
 279 AC_ARG_WITH([qemu],
 280         [AS_HELP_STRING([--with-qemu],
 281           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 282         [],
 283         [with_qemu="$default_qemu"])
 284 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 285         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 286 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 287 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 288
 289 dnl Check that the chosen qemu has virtio-serial support.
 290 if test "x$vmchannel_test" != "xno"; then
 291     AC_MSG_CHECKING([for virtio-serial support in $QEMU])
 292     if $QEMU -nographic -device \? 2>&1 | grep -sq virtio-serial; then
 293         AC_MSG_RESULT([yes])
 294         vmchannel_guestfwd=guestfwd
 295     else
 296         AC_MSG_RESULT([no])
 297         AC_MSG_FAILURE(
 298 [I did not find virtio-serial support in
 299 $QEMU.
 300
 301 virtio-serial support in qemu or KVM is essential for libguestfs
 302 to operate.
 303
 304 Usually this means that you have to install a newer version of qemu
 305 and/or KVM.  Please read the relevant section in the README file for
 306 more information about this.
 307
 308 You can override this test by setting the environment variable
 309 vmchannel_test=no  However if you don't have the right support
 310 in your qemu, then this just delays the pain.
 311
 312 If I am using the wrong qemu or you want to compile qemu from source
 313 and install it in another location, then you should configure with
 314 the --with-qemu option.
 315 ])
 316     fi
 317 fi
 318
 319 dnl Set default drive interface used by the guestfs_add_drive_opts call
 320 dnl ('-drive ...,if=...' option to qemu).
 321 dnl
 322 dnl If you encounter performance problems with virtio (RHBZ#509383)
 323 dnl then try '--with-drive-if=ide'.
 324 AC_ARG_WITH([drive-if],
 325         [AS_HELP_STRING([--with-drive-if],
 326           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 327         [],
 328         [with_drive_if=virtio])
 329 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 330
 331 dnl Set interface used by the network.  Normally you should
 332 dnl leave this at the default (virtio-net-pci) but you can use the
 333 dnl alternative (ne2k_pci) because of bugs in virtio networking
 334 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 335 AC_ARG_WITH([net-if],
 336         [AS_HELP_STRING([--with-net-if],
 337           [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
 338         [],
 339         [with_net_if=virtio-net-pci])
 340 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 341
 342 dnl Enable packet dumps when in verbose mode.  This generates lots
 343 dnl of debug info, only useful for people debugging the RPC mechanism.
 344 AC_ARG_ENABLE([packet-dump],
 345         [AS_HELP_STRING([--enable-packet-dump],
 346           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 347         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 348         [])
 349
 350 dnl Readline.
 351 AC_ARG_WITH([readline],
 352     [AS_HELP_STRING([--with-readline],
 353         [support fancy command line editing @<:@default=check@:>@])],
 354     [],
 355     [with_readline=check])
 356
 357 LIBREADLINE=
 358 AS_IF([test "x$with_readline" != xno],
 359     [AC_CHECK_LIB([readline], [main],
 360         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 361          AC_DEFINE([HAVE_LIBREADLINE], [1],
 362                    [Define if you have libreadline])
 363         ],
 364         [if test "x$with_readline" != xcheck; then
 365          AC_MSG_FAILURE(
 366              [--with-readline was given, but test for readline failed])
 367          fi
 368         ], -lncurses)
 369      old_LIBS="$LIBS"
 370      LIBS="$LIBS $LIBREADLINE"
 371      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 372      LIBS="$old_LIBS"
 373     ])
 374
 375 dnl For i18n.
 376 AM_GNU_GETTEXT([external])
 377
 378 dnl libmagic (highly recommended)
 379 AC_CHECK_LIB([magic],[magic_file],
 380         [AC_CHECK_HEADER([magic.h],
 381                 [AC_SUBST([MAGIC_LIBS], ["-lmagic"])
 382                  AC_DEFINE([HAVE_LIBMAGIC],[1],[libmagic found at compile time.])
 383                 ], [])
 384         ],
 385         [AC_MSG_WARN([libmagic not found, some core features will be disabled])])
 386
 387 dnl Check for PCRE (highly recommended)
 388 PKG_CHECK_MODULES([PCRE], [libpcre],
 389         [AC_SUBST([PCRE_CFLAGS])
 390          AC_SUBST([PCRE_LIBS])
 391          AC_DEFINE([HAVE_PCRE],[1],[PCRE found at compile time.])
 392         ],
 393         [AC_MSG_WARN([PCRE not found, some core features will be disabled])])
 394
 395 dnl libvirt (highly recommended)
 396 PKG_CHECK_MODULES([LIBVIRT], [libvirt],
 397         [AC_SUBST([LIBVIRT_CFLAGS])
 398          AC_SUBST([LIBVIRT_LIBS])
 399          AC_DEFINE([HAVE_LIBVIRT],[1],[libvirt found at compile time.])
 400         ],
 401         [AC_MSG_WARN([libvirt not found, some core features will be disabled])])
 402 AM_CONDITIONAL([HAVE_LIBVIRT],[test "x$LIBVIRT_LIBS" != "x"])
 403
 404 dnl libxml2 (highly recommended)
 405 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0],
 406         [AC_SUBST([LIBXML2_CFLAGS])
 407          AC_SUBST([LIBXML2_LIBS])
 408          AC_DEFINE([HAVE_LIBXML2],[1],[libxml2 found at compile time.])
 409         ],
 410         [AC_MSG_WARN([libxml2 not found, some core features will be disabled])])
 411 AM_CONDITIONAL([HAVE_LIBXML2],[test "x$LIBXML2_LIBS" != "x"])
 412
 413 dnl hivex library (highly recommended)
 414 dnl This used to be a part of libguestfs, but was spun off into its
 415 dnl own separate upstream project in libguestfs 1.0.85.
 416 PKG_CHECK_MODULES([HIVEX], [hivex],
 417         [AC_SUBST([HIVEX_CFLAGS])
 418          AC_SUBST([HIVEX_LIBS])
 419          AC_DEFINE([HAVE_HIVEX],[1],[hivex library found at compile time.])
 420         ],
 421         [AC_MSG_WARN([hivex not found, some core features will be disabled])])
 422
 423 dnl FUSE is optional to build the FUSE module.
 424 AC_ARG_ENABLE([fuse],
 425         AS_HELP_STRING([--disable-fuse], [Disable FUSE (guestmount) support]),
 426         [],
 427         [enable_fuse=yes])
 428 AS_IF([test "x$enable_fuse" != "xno"],
 429         [PKG_CHECK_MODULES([FUSE],[fuse],,[
 430                 enable_fuse=no
 431                 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])])
 432 AM_CONDITIONAL([HAVE_FUSE],[test "x$enable_fuse" != "xno"])
 433
 434 dnl Check for OCaml (optional, for OCaml bindings).
 435 OCAMLC=no
 436 OCAMLFIND=no
 437 AC_ARG_ENABLE([ocaml],
 438         AS_HELP_STRING([--disable-ocaml], [Disable OCaml language bindings]),
 439         [],
 440         [enable_ocaml=yes])
 441 AS_IF([test "x$enable_ocaml" != "xno"],
 442         [dnl OCAMLC and OCAMLFIND have to be unset first, otherwise
 443          dnl AC_CHECK_TOOL (inside AC_PROG_OCAML) will not look.
 444          OCAMLC=
 445          OCAMLFIND=
 446          AC_PROG_OCAML
 447          AC_PROG_FINDLIB
 448         ])
 449 AM_CONDITIONAL([HAVE_OCAML],
 450                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
 451
 452 dnl Check for Perl (optional, for Perl bindings).
 453 PERL=no
 454 AC_ARG_ENABLE([perl],
 455         AS_HELP_STRING([--disable-perl], [Disable Perl language bindings]),
 456         [],
 457         [enable_perl=yes])
 458 AS_IF([test "x$enable_perl" != "xno"],
 459         [
 460         PERL=
 461         AC_CHECK_PROG([PERL],[perl],[perl],[no])
 462
 463         dnl Check for Perl modules that must be present to compile and
 464         dnl test the Perl bindings.
 465         missing_perl_modules=no
 466         for pm in Test::More ExtUtils::MakeMaker; do
 467             AC_MSG_CHECKING([for $pm])
 468             if ! perl -M$pm -e1 >/dev/null 2>&1; then
 469                 AC_MSG_RESULT([no])
 470                 missing_perl_modules=yes
 471             else
 472                 AC_MSG_RESULT([yes])
 473             fi
 474         done
 475         if test "x$missing_perl_modules" = "xyes"; then
 476             AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 477         fi
 478         ])
 479 AM_CONDITIONAL([HAVE_PERL],
 480     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 481
 482 dnl Check for Python (optional, for Python bindings).
 483 PYTHON_PREFIX=
 484 PYTHON_VERSION=
 485 PYTHON_INCLUDEDIR=
 486 PYTHON_INSTALLDIR=
 487
 488 AC_ARG_ENABLE([python],
 489         AS_HELP_STRING([--disable-python], [Disable Python language bindings]),
 490         [],
 491         [enable_python=yes])
 492 AS_IF([test "x$enable_python" != "xno"],
 493         [
 494         AC_CHECK_PROG([PYTHON],[python],[python],[no])
 495
 496         if test "x$PYTHON" != "xno"; then
 497             AC_MSG_CHECKING([Python prefix])
 498             PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 499             AC_MSG_RESULT([$PYTHON_PREFIX])
 500
 501             AC_MSG_CHECKING([Python version])
 502             PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 503             AC_MSG_RESULT([$PYTHON_VERSION])
 504
 505             for d in \
 506                 $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 507                 /usr/include/python$PYTHON_VERSION \
 508                 /usr/local/include/python$PYTHON_VERSION
 509             do
 510                 AC_MSG_CHECKING([Python.h in $d])
 511                 if test -r "$d/Python.h"; then
 512                     AC_MSG_RESULT([found])
 513                     PYTHON_INCLUDEDIR=$d
 514                     break
 515                 fi
 516                 AC_MSG_RESULT([not found])
 517             done
 518             if test "x$PYTHON_INCLUDEDIR" = "x"; then
 519                 AC_MSG_WARN([Python include directory not found])
 520             fi
 521
 522             AC_ARG_WITH([python-installdir],
 523                         [AS_HELP_STRING([--with-python-installdir],
 524                                         [directory to install python modules @<:@default=check@:>@])],
 525                         [PYTHON_INSTALLDIR="$withval"
 526                         AC_MSG_NOTICE([Python install dir $PYTHON_INSTALLDIR])],
 527                         [PYTHON_INSTALLDIR=check])
 528
 529             if test "x$PYTHON_INSTALLDIR" = "xcheck"; then
 530                 PYTHON_INSTALLDIR=
 531                 for d in \
 532                     $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 533                     $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 534                     /usr/lib64/python$PYTHON_VERSION/site-packages \
 535                     /usr/lib/python$PYTHON_VERSION/site-packages \
 536                     /usr/local/lib/python$PYTHON_VERSION/site-packages
 537                 do
 538                     AC_MSG_CHECKING([for $d])
 539                     if test -d "$d"; then
 540                         AC_MSG_RESULT([found])
 541                         PYTHON_INSTALLDIR=$d
 542                         break
 543                     fi
 544                     AC_MSG_RESULT([not found])
 545                 done
 546                 if test "x$PYTHON_INSTALLDIR" = "x"; then
 547                     AC_MSG_WARN([Python site-packages directory not found])
 548                 fi
 549             fi
 550
 551             old_LIBS="$LIBS"
 552             LIBS="$LIBS -lpython$PYTHON_VERSION"
 553             AC_CHECK_FUNCS([PyCapsule_New])
 554             LIBS="$old_LIBS"
 555         fi
 556
 557         AC_SUBST(PYTHON_PREFIX)
 558         AC_SUBST(PYTHON_VERSION)
 559         AC_SUBST(PYTHON_INCLUDEDIR)
 560         AC_SUBST(PYTHON_INSTALLDIR)
 561         ])
 562 AM_CONDITIONAL([HAVE_PYTHON],
 563     [test "x$PYTHON" != "xno" && test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_INSTALLDIR" != "x"])
 564
 565 dnl Check for Ruby and rake (optional, for Ruby bindings).
 566 AC_ARG_ENABLE([ruby],
 567         AS_HELP_STRING([--disable-ruby], [Disable Ruby language bindings]),
 568         [],
 569         [enable_ruby=yes])
 570 AS_IF([test "x$enable_ruby" != "xno"],
 571         [
 572         AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 573         AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 574         ])
 575 AM_CONDITIONAL([HAVE_RUBY],
 576     [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
 577
 578 dnl Check for Java.
 579 AC_ARG_WITH(java_home,
 580     [AS_HELP_STRING([--with-java-home],
 581         [specify path to JDK directory @<:@default=check@:>@])],
 582     [],
 583     [with_java_home=check])
 584
 585 if test "x$with_java_home" != "xno"; then
 586     if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
 587     then
 588         # Reject unsafe characters in $JAVA_HOME
 589         jh_lf='
 590 '
 591         case $JAVA_HOME in
 592           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 593             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 594         esac
 595         if test -d "$with_java_home"; then
 596             JAVA_HOME="$with_java_home"
 597         else
 598             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 599         fi
 600     fi
 601
 602     if test "x$JAVA_HOME" = "x"; then
 603         # Look for Java in some likely locations.
 604         for d in \
 605             /usr/lib/jvm/java \
 606             /usr/lib/jvm/java-6-openjdk
 607         do
 608             if test -d $d && test -f $d/bin/java; then
 609                 JAVA_HOME=$d
 610                 break
 611             fi
 612         done
 613     fi
 614
 615     if test "x$JAVA_HOME" != "x"; then
 616         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 617         if test ! -x "$JAVA_HOME/bin/java"; then
 618             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 619         else
 620             JAVA="$JAVA_HOME/bin/java"
 621         fi
 622         if test ! -x "$JAVA_HOME/bin/javac"; then
 623             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 624         else
 625             JAVAC="$JAVA_HOME/bin/javac"
 626         fi
 627         if test ! -x "$JAVA_HOME/bin/javah"; then
 628             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 629         else
 630             JAVAH="$JAVA_HOME/bin/javah"
 631         fi
 632         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 633             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 634         else
 635             JAVADOC="$JAVA_HOME/bin/javadoc"
 636         fi
 637         if test ! -x "$JAVA_HOME/bin/jar"; then
 638             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 639         else
 640             JAR="$JAVA_HOME/bin/jar"
 641         fi
 642         java_version=`$JAVA -version 2>&1 | grep "java version"`
 643         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 644
 645         dnl Find jni.h.
 646         AC_MSG_CHECKING([for jni.h])
 647         if test -f "$JAVA_HOME/include/jni.h"; then
 648             JNI_CFLAGS="-I$JAVA_HOME/include"
 649         else
 650             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 651                 head=`find $JAVA_HOME -name jni.h | tail -1`
 652                 dir=`dirname "$head"`
 653                 JNI_CFLAGS="-I$dir"
 654             else
 655                 AC_MSG_FAILURE([missing jni.h header file])
 656             fi
 657         fi
 658         AC_MSG_RESULT([$JNI_CFLAGS])
 659
 660         dnl Find jni_md.h.
 661         AC_MSG_CHECKING([for jni_md.h])
 662         case "$build_os" in
 663         *linux*) system="linux" ;;
 664         *SunOS*) system="solaris" ;;
 665         *cygwin*) system="win32" ;;
 666         *) system="$build_os" ;;
 667         esac
 668         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 669             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 670         else
 671             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 672                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 673                 dir=`dirname "$head"`
 674                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 675             else
 676                 AC_MSG_FAILURE([missing jni_md.h header file])
 677             fi
 678         fi
 679         AC_MSG_RESULT([$JNI_CFLAGS])
 680
 681         dnl Need extra version flag?
 682         AC_MSG_CHECKING([extra javac flags])
 683         JAVAC_FLAGS=
 684         javac_version=`$JAVAC -version 2>&1`
 685         case "$javac_version" in
 686         *Eclipse*)
 687             JAVAC_FLAGS="-source 1.5" ;;
 688         esac
 689         AC_MSG_RESULT([$JAVAC_FLAGS])
 690
 691         dnl Where to install jarfiles.
 692         dnl XXX How to make it configurable?
 693         JAR_INSTALL_DIR=\${prefix}/share/java
 694         JNI_INSTALL_DIR=\${libdir}
 695
 696         dnl JNI version.
 697         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 698         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 699         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 700         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 701     fi
 702 fi
 703
 704 AC_SUBST(JAVA_HOME)
 705 AC_SUBST(JAVA)
 706 AC_SUBST(JAVAC)
 707 AC_SUBST(JAVAH)
 708 AC_SUBST(JAVADOC)
 709 AC_SUBST(JAR)
 710 AC_SUBST(JNI_CFLAGS)
 711 AC_SUBST(JAVAC_FLAGS)
 712 AC_SUBST(JAR_INSTALL_DIR)
 713 AC_SUBST(JNI_INSTALL_DIR)
 714 AC_SUBST(JNI_VERSION_INFO)
 715
 716 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 717
 718 dnl Check for Haskell (GHC).
 719 GHC=no
 720 AC_ARG_ENABLE([haskell],
 721         AS_HELP_STRING([--disable-haskell], [Disable Haskell language bindings]),
 722         [],
 723         [enable_haskell=yes])
 724 AS_IF([test "x$enable_haskell" != "xno"],
 725         [
 726         GHC=
 727         AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 728         ])
 729 AM_CONDITIONAL([HAVE_HASKELL],
 730     [test "x$GHC" != "xno"])
 731
 732 dnl PHP
 733 PHP=no
 734 AC_ARG_ENABLE([php],
 735         AS_HELP_STRING([--disable-php], [Disable PHP language bindings]),
 736         [],
 737         [enable_php=yes])
 738 AS_IF([test "x$enable_php" != "xno"],
 739         [
 740         PHP=
 741         AC_CHECK_PROG([PHP],[php],[php],[no])
 742         AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
 743         ])
 744 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
 745
 746 dnl Check for Perl modules needed by Perl virt tools (virt-df, etc.)
 747 AS_IF([test "x$PERL" != "xno"],
 748         [
 749         missing_perl_modules=no
 750         for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper Locale::TextDomain Win::Hivex Win::Hivex::Regedit String::ShellQuote; do
 751             AC_MSG_CHECKING([for $pm])
 752             if ! $PERL -M$pm -e1 >/dev/null 2>&1; then
 753                 AC_MSG_RESULT([no])
 754                 missing_perl_modules=yes
 755             else
 756                 AC_MSG_RESULT([yes])
 757             fi
 758         done
 759         if test "x$missing_perl_modules" = "xyes"; then
 760             AC_MSG_WARN([some Perl modules required to compile the Perl virt-* tools are missing])
 761         fi
 762         ])
 763
 764 AM_CONDITIONAL([HAVE_TOOLS],
 765     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 766
 767 dnl Library versioning.
 768 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 769 AC_SUBST(MAX_PROC_NR)
 770
 771 dnl Replace libtool with a wrapper that clobbers dependency_libs in *.la files
 772 dnl http://lists.fedoraproject.org/pipermail/devel/2010-November/146343.html
 773 LIBTOOL='$(SHELL) $(top_srcdir)/libtool-kill-dependency_libs.sh $(top_builddir)/libtool'
 774 AC_SUBST([LIBTOOL])
 775
 776 dnl Run in subdirs.
 777 if test "x$enable_daemon" = "xyes"; then
 778     AC_CONFIG_SUBDIRS([daemon])
 779 fi
 780
 781 dnl Produce output files.
 782 AC_CONFIG_HEADERS([config.h])
 783 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 784 AC_CONFIG_FILES([podwrapper.sh],
 785                 [chmod +x podwrapper.sh])
 786 AC_CONFIG_FILES([Makefile
 787                  generator/Makefile
 788                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 789                  appliance/Makefile
 790                  images/Makefile
 791                  capitests/Makefile
 792                  regressions/Makefile
 793                  test-tool/Makefile
 794                  ocaml/Makefile ocaml/examples/Makefile
 795                  perl/Makefile
 796                  python/Makefile python/examples/Makefile
 797                  ruby/Makefile ruby/Rakefile ruby/examples/Makefile
 798                  java/Makefile
 799                  haskell/Makefile
 800                  inspector/Makefile
 801                  tools/Makefile
 802                  libguestfs.pc
 803                  gnulib/lib/Makefile
 804                  gnulib/tests/Makefile
 805                  fuse/Makefile
 806                  po-docs/Makefile
 807                  po-docs/ja/Makefile
 808                  php/Makefile
 809                  csharp/Makefile
 810                  cat/Makefile
 811                  df/Makefile
 812                  rescue/Makefile
 813                  debian/changelog
 814                  ocaml/META perl/Makefile.PL])
 815 AC_OUTPUT
 816
 817 dnl Produce summary.
 818 echo
 819 echo
 820 echo "------------------------------------------------------------"
 821 echo "Thank you for downloading $PACKAGE_STRING"
 822 echo
 823 echo "This is how we have configured the optional components for you today:"
 824 echo
 825 echo    "Daemon .............................. $enable_daemon"
 826 echo    "Appliance ........................... $enable_appliance"
 827 echo    "QEMU ................................ $QEMU"
 828 echo -n "OCaml bindings ...................... "
 829 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 830 echo -n "Perl bindings ....................... "
 831 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 832 echo -n "Python bindings ..................... "
 833 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 834 echo -n "Ruby bindings ....................... "
 835 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 836 echo -n "Java bindings ....................... "
 837 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 838 echo -n "Haskell bindings .................... "
 839 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 840 echo -n "PHP bindings ........................ "
 841 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 842 echo -n "virt-* tools ........................ "
 843 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 844 echo "FUSE filesystem ..................... $enable_fuse"
 845 echo
 846 echo "If any optional component is configured 'no' when you expected 'yes'"
 847 echo "then you should check the preceeding messages."
 848 echo
 849 echo "Please report bugs back to the mailing list:"
 850 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 851 echo
 852 echo "Next you should type 'make' to build the package,"
 853 echo "then 'make check' to run the tests."
 854 echo "------------------------------------------------------------"