configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2011 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # The major, minor, and release fields MUST be numbers.  Packagers can
  19 # add extra information using --with-extra="..." which may be any
  20 # freeform string.
  21 m4_define([libguestfs_major],   [1])
  22 m4_define([libguestfs_minor],   [15])
  23 m4_define([libguestfs_release], [1])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Stable or unstable version?
  35 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  36 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  37             AC_MSG_RESULT([stable])
  38        ],[
  39             AC_MSG_RESULT([unstable])
  40             AC_MSG_NOTICE([
  41 ***
  42 This is a development version of libguestfs. Some APIs may be unstable
  43 until they appear in a stable release of libguestfs (at which point
  44 the C API and ABI is guaranteed to remain stable forever).  For
  45 more information about stable and development branches of libguestfs
  46 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  47 ***])
  48        ])
  49
  50 dnl Extra string, a freeform string defined by packagers.
  51 AC_ARG_WITH([extra],
  52   [AS_HELP_STRING([--with-extra],
  53                   [extra version string (for use by packagers)])],
  54   [libguestfs_extra="$withval"],
  55   [libguestfs_extra=]
  56 )
  57
  58 AC_MSG_NOTICE([libguestfs version libguestfs_major.libguestfs_minor.libguestfs_release$libguestfs_extra])
  59
  60 dnl Split up the version string.
  61 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  62 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  63 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  64 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_EXTRA],["$libguestfs_extra"],[Extra version string])
  65
  66 dnl Early gnulib initialization.
  67 gl_EARLY
  68 gl_INIT
  69
  70 AC_PROG_LIBTOOL
  71
  72 AC_PROG_SED
  73
  74 dnl Check for basic C environment.
  75 AC_PROG_CC_STDC
  76 AC_PROG_INSTALL
  77 AC_PROG_CPP
  78
  79 AC_ARG_ENABLE([gcc-warnings],
  80   [AS_HELP_STRING([--enable-gcc-warnings],
  81                   [turn on lots of GCC warnings (for developers)])],
  82   [case $enableval in
  83      yes|no) ;;
  84      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  85    esac
  86    gl_gcc_warnings=$enableval],
  87   [gl_gcc_warnings=no]
  88 )
  89
  90 if test "$gl_gcc_warnings" = yes; then
  91   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  92   AC_SUBST([WERROR_CFLAGS])
  93
  94   nw=
  95   # This, $nw, is the list of warnings we disable.
  96   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  97   nw="$nw -Waggregate-return"       # anachronistic
  98   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  99   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 100   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 101   nw="$nw -Wcast-qual"              # Too many warnings for now
 102   nw="$nw -Wconversion"             # Too many warnings for now
 103   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 104   nw="$nw -Wsign-conversion"        # Too many warnings for now
 105   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 106   nw="$nw -Wunreachable-code"       # Too many warnings for now
 107   nw="$nw -Wpadded"                 # Our structs are not padded
 108   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 109   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 110   nw="$nw -Wvla"                    # two warnings in mount.c
 111   # things I might fix soon:
 112   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 113   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 114   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 115   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 116                                     # was not possible, safe to ignore
 117   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 118   nw="$nw -Wlong-long"              # Allow long long since it's required
 119                                     # by Python, Ruby and xstrtoll.
 120   nw="$nw -Wstack-protector"        # Don't warn about stack-protector
 121                                     # failures (seen on Ubuntu).
 122   nw="$nw -Wmissing-noreturn"       # Don't warn about missed noreturn funcs
 123                                     # (seen on Ubuntu).
 124
 125   gl_MANYWARN_ALL_GCC([ws])
 126   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 127   for w in $ws; do
 128     gl_WARN_ADD([$w])
 129   done
 130   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 131   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 132   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 133
 134   # In spite of excluding -Wlogical-op above, it is enabled, as of
 135   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 136   gl_WARN_ADD([-Wno-logical-op])
 137
 138   # Work around warning in src/inspect.c.  This seems to be a bug in gcc 4.5.1.
 139   gl_WARN_ADD([-Wno-strict-overflow])
 140
 141   gl_WARN_ADD([-fdiagnostics-show-option])
 142
 143   AC_SUBST([WARN_CFLAGS])
 144
 145   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 146   AC_DEFINE([_FORTIFY_SOURCE], [2],
 147     [enable compile-time and run-time bounds-checking, and some warnings])
 148   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 149 fi
 150
 151 AC_C_PROTOTYPES
 152 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 153
 154 AM_PROG_CC_C_O
 155
 156 dnl Work out how to specify the linker script to the linker.
 157 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 158 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 159     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 160 AC_SUBST(VERSION_SCRIPT_FLAGS)
 161
 162 dnl Check support for 64 bit file offsets.
 163 AC_SYS_LARGEFILE
 164
 165 dnl Check sizeof long.
 166 AC_CHECK_SIZEOF([long])
 167
 168 dnl Check if dirent (readdir) supports d_type member.
 169 AC_STRUCT_DIRENT_D_TYPE
 170
 171 dnl Check if stat has the required fields.
 172 AC_STRUCT_ST_BLOCKS
 173 AC_CHECK_MEMBER([struct stat.st_blksize],[
 174         AC_DEFINE([HAVE_STRUCT_STAT_ST_BLKSIZE],[1],[Define to 1 if 'st_blksize' is a member of 'struct stat'])])
 175
 176 dnl Define a C symbol for the host CPU architecture.
 177 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 178
 179 dnl Headers.
 180 AC_CHECK_HEADERS([\
 181         attr/xattr.h \
 182         byteswap.h \
 183         endian.h \
 184         errno.h \
 185         printf.h \
 186         sys/inotify.h \
 187         sys/socket.h \
 188         sys/statvfs.h \
 189         sys/types.h \
 190         sys/un.h \
 191         sys/wait.h \
 192         windows.h \
 193         sys/xattr.h])
 194
 195 dnl Functions.
 196 AC_CHECK_FUNCS([\
 197         futimens \
 198         getxattr \
 199         htonl \
 200         htons \
 201         inotify_init1 \
 202         lgetxattr \
 203         listxattr \
 204         llistxattr \
 205         lsetxattr \
 206         lremovexattr \
 207         mknod \
 208         ntohl \
 209         ntohs \
 210         posix_fallocate \
 211         realpath \
 212         removexattr \
 213         setitimer \
 214         setxattr \
 215         sigaction \
 216         statvfs \
 217         sync])
 218
 219 dnl For modified printf in the daemon, we need glibc either (old-style)
 220 dnl register_printf_function or (new-style) register_printf_specifier.
 221 AC_CHECK_FUNC([register_printf_specifier],[
 222         AC_DEFINE([HAVE_REGISTER_PRINTF_SPECIFIER],[1],
 223                 [Define to 1 if you have new-style register_printf_specifier])
 224         ],[
 225         AC_CHECK_FUNC([register_printf_function],[
 226                 AC_DEFINE([HAVE_REGISTER_PRINTF_FUNCTION],[1],
 227                         [Define to 1 if you have old-style register_printf_function])
 228                 ],[
 229                 AC_MSG_FAILURE(
 230 [No support for glibc-style extended printf formatters.
 231
 232 This means you either have a very old glibc (pre-2.0) or you
 233 are using some other libc where this is not supported.])])])
 234
 235 dnl Build the daemon?
 236 AC_MSG_CHECKING([if we should build the daemon])
 237 AC_ARG_ENABLE([daemon],
 238         [AS_HELP_STRING([--enable-daemon],
 239           [enable building the daemon @<:@default=yes@:>@])],
 240         [],
 241         [enable_daemon=yes])
 242 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 243 AC_MSG_RESULT([$enable_daemon])
 244
 245 if test "x$enable_daemon" = "xyes"; then
 246         dnl Install the daemon (for libguestfs live service)
 247         AC_MSG_CHECKING([if we should install the daemon])
 248         AC_ARG_ENABLE([install-daemon],
 249                 [AS_HELP_STRING([--enable-install-daemon],
 250                   [enable installing the daemon under $sbindir @<:@default=no@:>@])],
 251                 [],
 252                 [enable_install_daemon=no])
 253         AM_CONDITIONAL([INSTALL_DAEMON],[test "x$enable_install_daemon" = "xyes"])
 254         AC_MSG_RESULT([$enable_install_daemon])
 255 fi
 256
 257 dnl Build the appliance?
 258 AC_MSG_CHECKING([if we should build the appliance])
 259 AC_ARG_ENABLE([appliance],
 260         [AS_HELP_STRING([--enable-appliance],
 261           [enable building the appliance @<:@default=yes@:>@])],
 262         [],
 263         [enable_appliance=yes])
 264 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 265 AC_MSG_RESULT([$enable_appliance])
 266
 267 if test "x$enable_appliance" = "xyes"; then
 268     dnl Check for febootstrap >= 3.0
 269     AC_CHECK_PROG([FEBOOTSTRAP],
 270                   [febootstrap],[febootstrap],[no])
 271     test "x$FEBOOTSTRAP" = "xno" &&
 272         AC_MSG_ERROR([febootstrap must be installed])
 273     dnl febootstrap 2.x did not support the --version parameter
 274     $FEBOOTSTRAP --version >&AS_MESSAGE_LOG_FD 2>&1 ||
 275         AC_MSG_ERROR([febootstrap >= 3.0 must be installed, your version is too old])
 276
 277     dnl Pass a febootstrap --yum-config option.
 278     AC_MSG_CHECKING([if user requested febootstrap --yum-config option])
 279     AC_ARG_WITH([febootstrap-yum-config],
 280         [AS_HELP_STRING([--with-febootstrap-yum-config=FILE],
 281           [pass febootstrap --yum-config option @<:@default=no@:>@])],
 282         [FEBOOTSTRAP_YUM_CONFIG="$withval"],
 283         [FEBOOTSTRAP_YUM_CONFIG=no])
 284     AC_MSG_RESULT([$FEBOOTSTRAP_YUM_CONFIG])
 285     AC_SUBST([FEBOOTSTRAP_YUM_CONFIG])
 286
 287     dnl Which distro?
 288     dnl
 289     dnl This used to be Very Important but is now just used to select
 290     dnl which packages to install in the appliance, since the package
 291     dnl names vary slightly across distros.  (See
 292     dnl appliance/packagelist.in and appliance/excludelist.in)
 293     AC_MSG_CHECKING([which Linux distro for package names])
 294     DISTRO=REDHAT
 295     if test -f /etc/debian_version; then
 296         DISTRO=DEBIAN
 297         if grep -q 'DISTRIB_ID=Ubuntu' /etc/lsb-release 2>&AS_MESSAGE_LOG_FD; then
 298             DISTRO=UBUNTU
 299         fi
 300     fi
 301     if test -f /etc/arch-release; then
 302         DISTRO=ARCHLINUX
 303     fi
 304     AC_MSG_RESULT([$DISTRO])
 305     AC_SUBST([DISTRO])
 306 fi
 307
 308 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 309 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 310 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 311 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 312         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 313         ])
 314
 315 dnl Check for Augeas (now optional).
 316 AC_CHECK_LIB([augeas],[aug_match],[
 317         have_augeas=yes
 318         AUGEAS_LIB="-laugeas"
 319
 320         old_LIBS="$LIBS"
 321         LIBS="$LIBS $AUGEAS_LIB"
 322         dnl Check for functions not available in earlier versions of Augeas.
 323         AC_CHECK_FUNCS([aug_load aug_defvar aug_defnode])
 324         LIBS="$old_LIBS"
 325
 326         ],[have_augeas=no])
 327 if test "x$have_augeas" = "xyes"; then
 328         AC_DEFINE([HAVE_AUGEAS],[1],[Define to 1 if you have Augeas])
 329 fi
 330 AC_SUBST([AUGEAS_LIB])
 331
 332 dnl Check for libselinux (optional).
 333 AC_CHECK_HEADERS([selinux/selinux.h])
 334 AC_CHECK_LIB([selinux],[setexeccon],[
 335         have_libselinux="$ac_cv_header_selinux_selinux_h"
 336         SELINUX_LIB="-lselinux"
 337
 338         old_LIBS="$LIBS"
 339         LIBS="$LIBS $SELINUX_LIB"
 340         AC_CHECK_FUNCS([setcon getcon])
 341         LIBS="$old_LIBS"
 342
 343         ],[have_libselinux=no])
 344 if test "x$have_libselinux" = "xyes"; then
 345         AC_DEFINE([HAVE_LIBSELINUX],[1],[Define to 1 if you have libselinux])
 346 fi
 347 AC_SUBST([SELINUX_LIB])
 348
 349 dnl Check for systemtap/DTrace userspace probes (optional).
 350 dnl http://sourceware.org/systemtap/wiki/AddingUserSpaceProbingToApps
 351 AC_CHECK_HEADERS([sys/sdt.h])
 352 dnl AC_CHECK_PROG([DTRACE],[dtrace],[dtrace],[no])
 353
 354 dnl Check for cpio which isn't in the default Pardus install amazingly.
 355 AC_CHECK_PROG([CPIO],[cpio],[cpio],[no])
 356 test "x$CPIO" = "xno" &&
 357      AC_MSG_ERROR([cpio must be installed])
 358
 359 dnl Check for gperf.
 360 AC_CHECK_PROG([GPERF],[gperf],[gperf],[no])
 361 test "x$GPERF" = "xno" &&
 362      AC_MSG_ERROR([gperf must be installed])
 363
 364 dnl Check for pod2man, pod2text, pod2html.
 365 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 366 test "x$POD2MAN" = "xno" &&
 367      AC_MSG_ERROR([pod2man must be installed])
 368 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 369 test "x$POD2TEXT" = "xno" &&
 370      AC_MSG_ERROR([pod2text must be installed])
 371 AC_CHECK_PROG([POD2HTML],[pod2html],[pod2html],[no])
 372 test "x$POD2HTML" = "xno" &&
 373      AC_MSG_ERROR([pod2html must be installed])
 374
 375 dnl Check if pod2man, pod2text take --stderr and -u options (not in RHEL 5).
 376 AC_MSG_CHECKING([if pod2man takes --stderr option])
 377 if "$POD2MAN" --stderr >&AS_MESSAGE_LOG_FD 2>&1; then
 378     AC_MSG_RESULT([yes])
 379     POD2_STDERR_OPTION="--stderr"
 380 else
 381     AC_MSG_RESULT([no])
 382     POD2_STDERR_OPTION=""
 383 fi
 384 AC_SUBST([POD2_STDERR_OPTION])
 385
 386 AC_MSG_CHECKING([if pod2man takes -u option])
 387 if "$POD2MAN" -u >&AS_MESSAGE_LOG_FD 2>&1; then
 388     AC_MSG_RESULT([yes])
 389     POD2_UTF8_OPTION="-u"
 390 else
 391     AC_MSG_RESULT([no])
 392     POD2_UTF8_OPTION=""
 393 fi
 394 AC_SUBST([POD2_UTF8_OPTION])
 395
 396 dnl Check for genisoimage.
 397 AC_PATH_PROGS([GENISOIMAGE],[genisoimage],[no],
 398         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 399 test "x$GENISOIMAGE" = "xno" && AC_MSG_ERROR([genisoimage must be installed])
 400
 401 dnl Check for optional xmllint.
 402 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 403 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 404
 405 dnl po4a for translating man pages and POD files (optional).
 406 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
 407 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
 408
 409 dnl Check for db_dump, db_load (optional).
 410 AC_CHECK_PROGS([DB_DUMP],
 411                [db_dump db4_dump db4.8_dump db4.7_dump db4.6_dump],[no])
 412 AC_CHECK_PROGS([DB_LOAD],
 413                [db_load db4_load db4.8_load db4.7_load db4.6_load],[no])
 414 if test "x$DB_DUMP" != "xno"; then
 415     AC_DEFINE_UNQUOTED([DB_DUMP],["$DB_DUMP"],[Name of db_dump program.])
 416 fi
 417 if test "x$DB_LOAD" != "xno"; then
 418     AC_DEFINE_UNQUOTED([DB_LOAD],["$DB_LOAD"],[Name of db_load program.])
 419 fi
 420
 421 dnl Check for QEMU for running binaries on this $host_cpu, fall
 422 dnl back to basic 'qemu'.  Allow the user to override it.
 423 default_qemu="qemu-kvm kvm qemu-system-$host_cpu qemu"
 424 AC_ARG_WITH([qemu],
 425         [AS_HELP_STRING([--with-qemu],
 426           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 427         [],
 428         [with_qemu="$default_qemu"])
 429 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 430         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 431 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 432 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 433
 434 dnl Check that the chosen qemu has virtio-serial support.
 435 if test "x$vmchannel_test" != "xno"; then
 436     AC_MSG_CHECKING([that $QEMU -help works])
 437     if $QEMU -help >&AS_MESSAGE_LOG_FD 2>&1; then
 438         AC_MSG_RESULT([yes])
 439     else
 440         AC_MSG_RESULT([no])
 441         AC_MSG_FAILURE(
 442 [$QEMU -help: command failed.
 443
 444 This could be a very old version of qemu, or qemu might not be
 445 working.
 446 ])
 447     fi
 448
 449     dnl qemu 0.15 was released with broken support for '-machine',
 450     dnl requiring you to add the machine type: '-machine pc,[...]'.
 451     dnl The problem is that 'pc' is only applicable for PC-like
 452     dnl hardware, so we cannot do this as a general solution.  Since
 453     dnl qemu 0.15, this problem has been fixed so now the default
 454     dnl machine type is chosen (qemu commit 2645c6dcaf6ea2a51a).
 455     dnl
 456     dnl We need to work out if this qemu is the broken version, so we
 457     dnl can add 'pc' just for this broken version.
 458     dnl
 459     dnl Note that old qemu didn't support the '-machine' option at all.
 460     dnl
 461     dnl We use the -kernel option for testing this, because this option
 462     dnl is processed very late, after qemu has set up the machine.
 463     AC_MSG_CHECKING([for broken '-machine accel=tcg' option in $QEMU])
 464     LC_ALL=C $QEMU -nographic -machine accel=tcg -kernel /NO_SUCH_FILE \
 465              > config1.tmp 2>&1
 466     LC_ALL=C $QEMU -nographic -machine pc,accel=tcg -kernel /NO_SUCH_FILE \
 467              > config2.tmp 2>&1
 468     if cmp -s config1.tmp config2.tmp; then
 469         AC_MSG_RESULT([no])
 470     else
 471         AC_MSG_RESULT([yes])
 472         AC_DEFINE([QEMU_MACHINE_TYPE_IS_BROKEN],[1],[qemu -machine accel=tcg option is broken (in qemu 0.15 only)])
 473     fi
 474     rm config1.tmp config2.tmp
 475
 476     dnl See if the '-machine [pc,]accel=tcg' option is required in
 477     dnl order to run the virtio-serial test below.  This happens when
 478     dnl we run qemu-kvm inside a VM without forcing TCG:
 479     dnl
 480     dnl   Could not access KVM kernel module: No such file or directory
 481     dnl   failed to initialize KVM: No such file or directory
 482     dnl   No accelerator found!
 483     AC_MSG_CHECKING([if -machine @<:@pc,@:>@accel=tcg option is required to test virtio-serial feature])
 484     if $QEMU -nographic -device \? >/dev/null 2>&1; then
 485         :
 486     elif $QEMU -machine accel=tcg -nographic -device \? >/dev/null 2>&1; then
 487         QEMU_EXTRA_OPTIONS_FOR_TEST="-machine accel=tcg"
 488     elif $QEMU -machine pc,accel=tcg -nographic -device \? >/dev/null 2>&1; then
 489         QEMU_EXTRA_OPTIONS_FOR_TEST="-machine pc,accel=tcg"
 490     # else nothing ... it'll fail below.
 491     fi
 492     AC_MSG_RESULT([$QEMU_EXTRA_OPTIONS_FOR_TEST])
 493
 494     AC_MSG_CHECKING([for virtio-serial support in $QEMU])
 495     if $QEMU $QEMU_EXTRA_OPTIONS_FOR_TEST -nographic -device \? 2>&1 | grep -sq virtio-serial; then
 496         AC_MSG_RESULT([yes])
 497     else
 498         AC_MSG_RESULT([no])
 499         AC_MSG_FAILURE(
 500 [I did not find virtio-serial support in
 501 $QEMU.
 502
 503 virtio-serial support in qemu or KVM is essential for libguestfs
 504 to operate.
 505
 506 Usually this means that you have to install a newer version of qemu
 507 and/or KVM.  Please read the relevant section in the README file for
 508 more information about this.
 509
 510 You can override this test by setting the environment variable
 511 vmchannel_test=no  However if you don't have the right support
 512 in your qemu, then this just delays the pain.
 513
 514 If I am using the wrong qemu or you want to compile qemu from source
 515 and install it in another location, then you should configure with
 516 the --with-qemu option.
 517 ])
 518     fi
 519 fi
 520
 521 dnl Set default drive interface used by the guestfs_add_drive_opts call
 522 dnl ('-drive ...,if=...' option to qemu).
 523 dnl
 524 dnl If you encounter performance problems with virtio (RHBZ#509383)
 525 dnl then try '--with-drive-if=ide'.
 526 AC_ARG_WITH([drive-if],
 527         [AS_HELP_STRING([--with-drive-if],
 528           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 529         [],
 530         [with_drive_if=virtio])
 531 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 532
 533 dnl Set interface used by the network.  Normally you should
 534 dnl leave this at the default (virtio-net-pci) but you can use the
 535 dnl alternative (ne2k_pci) because of bugs in virtio networking
 536 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 537 AC_ARG_WITH([net-if],
 538         [AS_HELP_STRING([--with-net-if],
 539           [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
 540         [],
 541         [with_net_if=virtio-net-pci])
 542 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 543
 544 dnl Enable packet dumps when in verbose mode.  This generates lots
 545 dnl of debug info, only useful for people debugging the RPC mechanism.
 546 AC_ARG_ENABLE([packet-dump],
 547         [AS_HELP_STRING([--enable-packet-dump],
 548           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 549         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 550         [])
 551
 552 dnl Readline.
 553 AC_ARG_WITH([readline],
 554     [AS_HELP_STRING([--with-readline],
 555         [support fancy command line editing @<:@default=check@:>@])],
 556     [],
 557     [with_readline=check])
 558
 559 LIBREADLINE=
 560 AS_IF([test "x$with_readline" != xno],
 561     [AC_CHECK_LIB([readline], [main],
 562         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 563          AC_DEFINE([HAVE_LIBREADLINE], [1],
 564                    [Define if you have libreadline])
 565         ],
 566         [if test "x$with_readline" != xcheck; then
 567          AC_MSG_FAILURE(
 568              [--with-readline was given, but test for readline failed])
 569          fi
 570         ], -lncurses)
 571      old_LIBS="$LIBS"
 572      LIBS="$LIBS $LIBREADLINE"
 573      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 574      LIBS="$old_LIBS"
 575     ])
 576
 577 dnl For i18n.
 578 AM_GNU_GETTEXT([external])
 579
 580 dnl Check for PCRE (required)
 581 PKG_CHECK_MODULES([PCRE], [libpcre])
 582
 583 dnl libmagic (highly recommended)
 584 AC_CHECK_LIB([magic],[magic_file],
 585         [AC_CHECK_HEADER([magic.h],
 586                 [AC_SUBST([MAGIC_LIBS], ["-lmagic"])
 587                  AC_DEFINE([HAVE_LIBMAGIC],[1],[libmagic found at compile time.])
 588                 ], [])
 589         ],
 590         [AC_MSG_WARN([libmagic not found, some core features will be disabled])])
 591
 592 dnl libvirt (highly recommended)
 593 PKG_CHECK_MODULES([LIBVIRT], [libvirt],
 594         [AC_SUBST([LIBVIRT_CFLAGS])
 595          AC_SUBST([LIBVIRT_LIBS])
 596          AC_DEFINE([HAVE_LIBVIRT],[1],[libvirt found at compile time.])
 597         ],
 598         [AC_MSG_WARN([libvirt not found, some core features will be disabled])])
 599 AM_CONDITIONAL([HAVE_LIBVIRT],[test "x$LIBVIRT_LIBS" != "x"])
 600
 601 dnl libxml2 (highly recommended)
 602 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0],
 603         [AC_SUBST([LIBXML2_CFLAGS])
 604          AC_SUBST([LIBXML2_LIBS])
 605          AC_DEFINE([HAVE_LIBXML2],[1],[libxml2 found at compile time.])
 606         ],
 607         [AC_MSG_WARN([libxml2 not found, some core features will be disabled])])
 608 AM_CONDITIONAL([HAVE_LIBXML2],[test "x$LIBXML2_LIBS" != "x"])
 609
 610 dnl libconfig (highly recommended)
 611 PKG_CHECK_MODULES([LIBCONFIG], [libconfig],
 612         [AC_SUBST([LIBCONFIG_CFLAGS])
 613          AC_SUBST([LIBCONFIG_LIBS])
 614          AC_DEFINE([HAVE_LIBCONFIG],[1],[libconfig found at compile time.])
 615         ],
 616         [AC_MSG_WARN([libconfig not found, some features will be disabled])])
 617 AM_CONDITIONAL([HAVE_LIBCONFIG],[test "x$LIBCONFIG_LIBS" != "x"])
 618
 619 dnl hivex library (highly recommended)
 620 dnl This used to be a part of libguestfs, but was spun off into its
 621 dnl own separate upstream project in libguestfs 1.0.85.
 622 PKG_CHECK_MODULES([HIVEX], [hivex],
 623         [AC_SUBST([HIVEX_CFLAGS])
 624          AC_SUBST([HIVEX_LIBS])
 625          AC_DEFINE([HAVE_HIVEX],[1],[hivex library found at compile time.])
 626         ],
 627         [AC_MSG_WARN([hivex not found, some core features will be disabled])])
 628 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HIVEX_LIBS" != "x"])
 629
 630 dnl FUSE is optional to build the FUSE module.
 631 AC_ARG_ENABLE([fuse],
 632         AS_HELP_STRING([--disable-fuse], [Disable FUSE (guestmount) support]),
 633         [],
 634         [enable_fuse=yes])
 635 AS_IF([test "x$enable_fuse" != "xno"],
 636         [PKG_CHECK_MODULES([FUSE],[fuse],,[
 637                 enable_fuse=no
 638                 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])])
 639 AM_CONDITIONAL([HAVE_FUSE],[test "x$enable_fuse" != "xno"])
 640
 641 dnl Check for OCaml (optional, for OCaml bindings).
 642 OCAMLC=no
 643 OCAMLFIND=no
 644 AC_ARG_ENABLE([ocaml],
 645         AS_HELP_STRING([--disable-ocaml], [Disable OCaml language bindings]),
 646         [],
 647         [enable_ocaml=yes])
 648 AS_IF([test "x$enable_ocaml" != "xno"],
 649         [dnl OCAMLC and OCAMLFIND have to be unset first, otherwise
 650          dnl AC_CHECK_TOOL (inside AC_PROG_OCAML) will not look.
 651          OCAMLC=
 652          OCAMLFIND=
 653          AC_PROG_OCAML
 654          AC_PROG_FINDLIB
 655
 656          AS_IF([test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"],
 657                 [AC_CHECK_OCAML_PKG([pcre])])
 658         ])
 659 AM_CONDITIONAL([HAVE_OCAML],
 660                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
 661 AM_CONDITIONAL([HAVE_OCAML_PCRE],
 662                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno" && test "x$OCAML_PKG_pcre" != "xno"])
 663 AM_CONDITIONAL([HAVE_OCAMLDOC],
 664                [test "x$OCAMLDOC" != "xno"])
 665
 666 dnl Check for Perl (optional, for Perl bindings).
 667 PERL=no
 668 AC_ARG_ENABLE([perl],
 669         AS_HELP_STRING([--disable-perl], [Disable Perl language bindings]),
 670         [],
 671         [enable_perl=yes])
 672 AS_IF([test "x$enable_perl" != "xno"],
 673         [
 674         PERL=
 675         AC_CHECK_PROG([PERL],[perl],[perl],[no])
 676
 677         dnl Check for Perl modules that must be present to compile and
 678         dnl test the Perl bindings.
 679         missing_perl_modules=no
 680         for pm in Test::More ExtUtils::MakeMaker; do
 681             AC_MSG_CHECKING([for $pm])
 682             if ! perl -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
 683                 AC_MSG_RESULT([no])
 684                 missing_perl_modules=yes
 685             else
 686                 AC_MSG_RESULT([yes])
 687             fi
 688         done
 689         if test "x$missing_perl_modules" = "xyes"; then
 690             AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 691         fi
 692         ])
 693 AM_CONDITIONAL([HAVE_PERL],
 694     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 695
 696 dnl Check for Python (optional, for Python bindings).
 697 PYTHON_PREFIX=
 698 PYTHON_VERSION=
 699 PYTHON_INCLUDEDIR=
 700 PYTHON_INSTALLDIR=
 701
 702 AC_ARG_ENABLE([python],
 703         AS_HELP_STRING([--disable-python], [Disable Python language bindings]),
 704         [],
 705         [enable_python=yes])
 706 AS_IF([test "x$enable_python" != "xno"],
 707         [
 708         AC_CHECK_PROG([PYTHON],[python],[python],[no])
 709
 710         if test "x$PYTHON" != "xno"; then
 711             AC_MSG_CHECKING([Python prefix])
 712             PYTHON_PREFIX=`$PYTHON -c "import sys; print (sys.prefix)"`
 713             AC_MSG_RESULT([$PYTHON_PREFIX])
 714
 715             AC_MSG_CHECKING([Python version])
 716             PYTHON_VERSION_MAJOR=`$PYTHON -c "import sys; print (sys.version_info.major)"`
 717             PYTHON_VERSION_MINOR=`$PYTHON -c "import sys; print (sys.version_info.minor)"`
 718             PYTHON_VERSION="$PYTHON_VERSION_MAJOR.$PYTHON_VERSION_MINOR"
 719             AC_MSG_RESULT([$PYTHON_VERSION])
 720
 721             AC_MSG_CHECKING([for Python include path])
 722             if test -z "$PYTHON_INCLUDEDIR"; then
 723                 python_path=`$PYTHON -c "import distutils.sysconfig; \
 724                                          print (distutils.sysconfig.get_python_inc ());"`
 725                 PYTHON_INCLUDEDIR=$python_path
 726             fi
 727             AC_MSG_RESULT([$PYTHON_INCLUDEDIR])
 728
 729             AC_ARG_WITH([python-installdir],
 730                         [AS_HELP_STRING([--with-python-installdir],
 731                                         [directory to install python modules @<:@default=check@:>@])],
 732                         [PYTHON_INSTALLDIR="$withval"
 733                         AC_MSG_NOTICE([Python install dir $PYTHON_INSTALLDIR])],
 734                         [PYTHON_INSTALLDIR=check])
 735
 736             if test "x$PYTHON_INSTALLDIR" = "xcheck"; then
 737                 PYTHON_INSTALLDIR=
 738                 AC_MSG_CHECKING([for Python site-packages path])
 739                 if test -z "$PYTHON_INSTALLDIR"; then
 740                     PYTHON_INSTALLDIR=`$PYTHON -c "import distutils.sysconfig; \
 741                                                    print (distutils.sysconfig.get_python_lib(1,0));"`
 742                 fi
 743                 AC_MSG_RESULT([$PYTHON_INSTALLDIR])
 744             fi
 745
 746             dnl Look for libpython and some optional symbols in it.
 747             old_LIBS="$LIBS"
 748             if test "x$PYTHON_VERSION_MAJOR" = "x3"; then
 749                 dnl libpython3 is called "libpython3.Xmu.so"
 750                 LIBPYTHON="python${PYTHON_VERSION}mu"
 751             else
 752                 LIBPYTHON="python$PYTHON_VERSION"
 753             fi
 754             AC_CHECK_LIB([$LIBPYTHON], [PyList_Size], [],
 755                          [AC_MSG_FAILURE([$LIBPYTHON is not installed])])
 756
 757             AC_CHECK_FUNCS([PyCapsule_New \
 758                             PyString_AsString])
 759             LIBS="$old_LIBS"
 760         fi
 761
 762         AC_SUBST(PYTHON_PREFIX)
 763         AC_SUBST(PYTHON_VERSION)
 764         AC_SUBST(PYTHON_INCLUDEDIR)
 765         AC_SUBST(PYTHON_INSTALLDIR)
 766         ])
 767 AM_CONDITIONAL([HAVE_PYTHON],
 768     [test "x$PYTHON" != "xno" && test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_INSTALLDIR" != "x"])
 769
 770 dnl Check for Ruby and rake (optional, for Ruby bindings).
 771 AC_ARG_ENABLE([ruby],
 772         AS_HELP_STRING([--disable-ruby], [Disable Ruby language bindings]),
 773         [],
 774         [enable_ruby=yes])
 775 AS_IF([test "x$enable_ruby" != "xno"],
 776         [
 777         AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 778         AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 779         ])
 780 AM_CONDITIONAL([HAVE_RUBY],
 781     [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
 782
 783 dnl Check for Java.
 784 AC_ARG_WITH(java_home,
 785     [AS_HELP_STRING([--with-java-home],
 786         [specify path to JDK directory @<:@default=check@:>@])],
 787     [],
 788     [with_java_home=check])
 789
 790 if test "x$with_java_home" != "xno"; then
 791     if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
 792     then
 793         # Reject unsafe characters in $JAVA_HOME
 794         jh_lf='
 795 '
 796         case $JAVA_HOME in
 797           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 798             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 799         esac
 800         if test -d "$with_java_home"; then
 801             JAVA_HOME="$with_java_home"
 802         else
 803             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 804         fi
 805     fi
 806
 807     if test "x$JAVA_HOME" = "x"; then
 808         # Look for Java in some likely locations.
 809         for d in \
 810             /usr/lib/jvm/java \
 811             /usr/lib/jvm/java-6-openjdk
 812         do
 813             if test -d $d && test -f $d/bin/java; then
 814                 JAVA_HOME=$d
 815                 break
 816             fi
 817         done
 818     fi
 819
 820     if test "x$JAVA_HOME" != "x"; then
 821         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 822         if test ! -x "$JAVA_HOME/bin/java"; then
 823             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 824         else
 825             JAVA="$JAVA_HOME/bin/java"
 826         fi
 827         if test ! -x "$JAVA_HOME/bin/javac"; then
 828             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 829         else
 830             JAVAC="$JAVA_HOME/bin/javac"
 831         fi
 832         if test ! -x "$JAVA_HOME/bin/javah"; then
 833             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 834         else
 835             JAVAH="$JAVA_HOME/bin/javah"
 836         fi
 837         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 838             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 839         else
 840             JAVADOC="$JAVA_HOME/bin/javadoc"
 841         fi
 842         if test ! -x "$JAVA_HOME/bin/jar"; then
 843             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 844         else
 845             JAR="$JAVA_HOME/bin/jar"
 846         fi
 847         java_version=`$JAVA -version 2>&1 | grep "java version"`
 848         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 849
 850         dnl Find jni.h.
 851         AC_MSG_CHECKING([for jni.h])
 852         if test -f "$JAVA_HOME/include/jni.h"; then
 853             JNI_CFLAGS="-I$JAVA_HOME/include"
 854         else
 855             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 856                 head=`find $JAVA_HOME -name jni.h | tail -1`
 857                 dir=`dirname "$head"`
 858                 JNI_CFLAGS="-I$dir"
 859             else
 860                 AC_MSG_FAILURE([missing jni.h header file])
 861             fi
 862         fi
 863         AC_MSG_RESULT([$JNI_CFLAGS])
 864
 865         dnl Find jni_md.h.
 866         AC_MSG_CHECKING([for jni_md.h])
 867         case "$build_os" in
 868         *linux*) system="linux" ;;
 869         *SunOS*) system="solaris" ;;
 870         *cygwin*) system="win32" ;;
 871         *) system="$build_os" ;;
 872         esac
 873         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 874             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 875         else
 876             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 877                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 878                 dir=`dirname "$head"`
 879                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 880             else
 881                 AC_MSG_FAILURE([missing jni_md.h header file])
 882             fi
 883         fi
 884         AC_MSG_RESULT([$JNI_CFLAGS])
 885
 886         dnl Need extra version flag?
 887         AC_MSG_CHECKING([extra javac flags])
 888         JAVAC_FLAGS=
 889         javac_version=`$JAVAC -version 2>&1`
 890         case "$javac_version" in
 891         *Eclipse*)
 892             JAVAC_FLAGS="-source 1.5" ;;
 893         esac
 894         AC_MSG_RESULT([$JAVAC_FLAGS])
 895
 896         dnl Where to install jarfiles.
 897         dnl XXX How to make it configurable?
 898         JAR_INSTALL_DIR=\${prefix}/share/java
 899         JNI_INSTALL_DIR=\${libdir}
 900
 901         dnl JNI version.
 902         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 903         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 904         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 905         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 906     fi
 907 fi
 908
 909 AC_SUBST(JAVA_HOME)
 910 AC_SUBST(JAVA)
 911 AC_SUBST(JAVAC)
 912 AC_SUBST(JAVAH)
 913 AC_SUBST(JAVADOC)
 914 AC_SUBST(JAR)
 915 AC_SUBST(JNI_CFLAGS)
 916 AC_SUBST(JAVAC_FLAGS)
 917 AC_SUBST(JAR_INSTALL_DIR)
 918 AC_SUBST(JNI_INSTALL_DIR)
 919 AC_SUBST(JNI_VERSION_INFO)
 920
 921 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 922
 923 dnl Check for Haskell (GHC).
 924 GHC=no
 925 AC_ARG_ENABLE([haskell],
 926         AS_HELP_STRING([--disable-haskell], [Disable Haskell language bindings]),
 927         [],
 928         [enable_haskell=yes])
 929 AS_IF([test "x$enable_haskell" != "xno"],
 930         [
 931         GHC=
 932         AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 933         ])
 934 AM_CONDITIONAL([HAVE_HASKELL],
 935     [test "x$GHC" != "xno"])
 936
 937 dnl PHP
 938 PHP=no
 939 AC_ARG_ENABLE([php],
 940         AS_HELP_STRING([--disable-php], [Disable PHP language bindings]),
 941         [],
 942         [enable_php=yes])
 943 AS_IF([test "x$enable_php" != "xno"],
 944         [
 945         PHP=
 946         AC_CHECK_PROG([PHP],[php],[php],[no])
 947         AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
 948         ])
 949 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
 950
 951 dnl Erlang
 952 ERLANG=no
 953 AC_ARG_ENABLE([erlang],
 954     AS_HELP_STRING([--disable-erlang], [Disable Erlang language bindings]),
 955          [],
 956          [enable_erlang=yes])
 957 # NB: Don't use AS_IF here: it doesn't work.
 958 if test "x$enable_erlang" != "xno"; then
 959         ERLANG=
 960         AC_ERLANG_PATH_ERLC([no])
 961
 962         if test "x$ERLC" != "xno"; then
 963             AC_ERLANG_CHECK_LIB([erl_interface], [],
 964                                 [AC_MSG_FAILURE([Erlang erl_interface library not installed.  Use --disable-erlang to disable.])])
 965             AC_ERLANG_SUBST_LIB_DIR
 966         fi
 967 fi
 968 AM_CONDITIONAL([HAVE_ERLANG], [test "x$ERLANG" != "xno" && test "x$ERLC" != "xno"])
 969
 970 dnl Check for Perl modules needed by Perl virt tools (virt-df, etc.)
 971 AS_IF([test "x$PERL" != "xno"],
 972         [
 973         missing_perl_modules=no
 974         for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper Locale::TextDomain Win::Hivex Win::Hivex::Regedit String::ShellQuote; do
 975             AC_MSG_CHECKING([for $pm])
 976             if ! $PERL -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
 977                 AC_MSG_RESULT([no])
 978                 missing_perl_modules=yes
 979             else
 980                 AC_MSG_RESULT([yes])
 981             fi
 982         done
 983         if test "x$missing_perl_modules" = "xyes"; then
 984             AC_MSG_WARN([some Perl modules required to compile the Perl virt-* tools are missing])
 985         fi
 986         ])
 987
 988 AM_CONDITIONAL([HAVE_TOOLS],
 989     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 990
 991 dnl Library versioning.
 992 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 993 AC_SUBST(MAX_PROC_NR)
 994
 995 dnl Replace libtool with a wrapper that clobbers dependency_libs in *.la files
 996 dnl http://lists.fedoraproject.org/pipermail/devel/2010-November/146343.html
 997 LIBTOOL='bash $(top_srcdir)/libtool-kill-dependency_libs.sh $(top_builddir)/libtool'
 998 AC_SUBST([LIBTOOL])
 999
1000 dnl Produce output files.
1001 AC_CONFIG_HEADERS([config.h])
1002 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
1003 AC_CONFIG_FILES([clone/virt-sysprep],
1004                 [chmod +x clone/virt-sysprep])
1005 AC_CONFIG_FILES([podwrapper.sh],
1006                 [chmod +x podwrapper.sh])
1007 AC_CONFIG_FILES([run],
1008                 [chmod +x run])
1009 AC_CONFIG_FILES([Makefile
1010                  align/Makefile
1011                  appliance/Makefile
1012                  capitests/Makefile
1013                  cat/Makefile
1014                  caution/Makefile
1015                  clone/Makefile
1016                  csharp/Makefile
1017                  daemon/Makefile
1018                  debian/changelog
1019                  df/Makefile
1020                  edit/Makefile
1021                  erlang/Makefile
1022                  erlang/examples/Makefile
1023                  examples/Makefile
1024                  fish/Makefile
1025                  fuse/Makefile
1026                  generator/Makefile
1027                  gnulib/lib/Makefile
1028                  gnulib/tests/Makefile
1029                  haskell/Makefile
1030                  images/Makefile
1031                  inspector/Makefile
1032                  java/Makefile
1033                  java/examples/Makefile
1034                  libguestfs.pc
1035                  ocaml/META
1036                  ocaml/Makefile
1037                  ocaml/examples/Makefile
1038                  perl/Makefile
1039                  perl/Makefile.PL
1040                  perl/examples/Makefile
1041                  php/Makefile
1042                  po-docs/Makefile
1043                  po-docs/ja/Makefile
1044                  po-docs/uk/Makefile
1045                  po/Makefile.in
1046                  python/Makefile
1047                  python/examples/Makefile
1048                  regressions/Makefile
1049                  rescue/Makefile
1050                  resize/Makefile
1051                  ruby/Makefile
1052                  ruby/Rakefile
1053                  ruby/examples/Makefile
1054                  sparsify/Makefile
1055                  src/Makefile
1056                  test-tool/Makefile
1057                  tools/Makefile])
1058 AC_OUTPUT
1059
1060 dnl Produce summary.
1061 echo
1062 echo
1063 echo "------------------------------------------------------------"
1064 echo "Thank you for downloading $PACKAGE_STRING"
1065 echo
1066 echo "This is how we have configured the optional components for you today:"
1067 echo
1068 echo    "Daemon .............................. $enable_daemon"
1069 echo    "Appliance ........................... $enable_appliance"
1070 echo    "QEMU ................................ $QEMU"
1071 echo -n "OCaml bindings ...................... "
1072 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1073 echo -n "Perl bindings ....................... "
1074 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1075 echo -n "Python bindings ..................... "
1076 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1077 echo -n "Ruby bindings ....................... "
1078 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1079 echo -n "Java bindings ....................... "
1080 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1081 echo -n "Haskell bindings .................... "
1082 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1083 echo -n "PHP bindings ........................ "
1084 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1085 echo -n "Erlang bindings ..................... "
1086 if test "x$HAVE_ERLANG_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1087 echo    "guestfish and C virt tools .......... yes"
1088 echo -n "Perl virt tools ..................... "
1089 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1090 echo -n "virt-resize ......................... "
1091 if test "x$HAVE_OCAML_TRUE" = "x" && test "x$HAVE_OCAML_PCRE_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1092 echo "FUSE filesystem ..................... $enable_fuse"
1093 echo
1094 echo "If any optional component is configured 'no' when you expected 'yes'"
1095 echo "then you should check the preceeding messages."
1096 echo
1097 echo "Please report bugs back to the mailing list:"
1098 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
1099 echo
1100 echo "Next you should type 'make' to build the package,"
1101 echo "then 'make check' to run the tests."
1102 echo "------------------------------------------------------------"