configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 AC_INIT([libguestfs],[1.0.27])
  19 AM_INIT_AUTOMAKE
  20
  21 AC_CONFIG_MACRO_DIR([m4])
  22
  23 AC_PROG_LIBTOOL
  24
  25 dnl Check for basic C environment.
  26 AC_PROG_CC_STDC
  27 AC_PROG_INSTALL
  28 AC_PROG_CPP
  29
  30 AC_C_PROTOTYPES
  31 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
  32
  33 AM_PROG_CC_C_O
  34
  35 dnl Check support for 64 bit file offsets.
  36 AC_SYS_LARGEFILE
  37
  38 dnl Check sizeof long.
  39 AC_CHECK_SIZEOF([long])
  40
  41 dnl Headers.
  42 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h])
  43
  44 dnl Check for rpcgen and XDR library.  rpcgen is optional.
  45 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
  46 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
  47 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
  48         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
  49         ])
  50
  51 dnl Check for pod2man and pod2text.
  52 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
  53 test "x$POD2MAN" = "xno" &&
  54      AC_MSG_ERROR([pod2man must be installed])
  55 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
  56 test "x$POD2TEXT" = "xno" &&
  57      AC_MSG_ERROR([pod2text must be installed])
  58
  59 dnl Check for QEMU for running binaries on this $host_cpu, fall
  60 dnl back to basic 'qemu'.  Allow the user to override it.
  61 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
  62 AC_ARG_WITH([qemu],
  63         [AS_HELP_STRING([--with-qemu],
  64           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
  65         [],
  66         [with_qemu="$default_qemu"])
  67 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
  68         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
  69 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
  70 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
  71
  72 dnl Check that the chosen qemu has vmchannel support.
  73 dnl http://lists.gnu.org/archive/html/qemu-devel/2009-02/msg01042.html
  74 if test "x$vmchannel_test" != "xno"; then
  75     AC_MSG_CHECKING([for vmchannel support in $QEMU])
  76     vmchannelout=`$QEMU -net channel /dev/zero 2>&1 ||:`
  77     echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
  78     if ! echo $vmchannelout | grep -sq "vmchannel wrong port number" ; then
  79         AC_MSG_RESULT([no])
  80         AC_MSG_FAILURE(
  81 [I did not find vmchannel support in $QEMU.
  82
  83 vmchannel support is vital for libguestfs to operate.  You need a version
  84 of qemu >= 0.10, or the following patch backported to earlier versions:
  85
  86 http://lists.gnu.org/archive/html/qemu-devel/2009-02/msg01042.html
  87
  88 You can override this test by setting the environment variable
  89 vmchannel_test=no  However if you don't have vmchannel support
  90 in your qemu, then this just delays the pain.
  91
  92 If I am using the wrong qemu or you want to compile qemu from source
  93 and install it in another location, then you should configure with
  94 the --with-qemu option.
  95 ])
  96     fi
  97     AC_MSG_RESULT([yes])
  98 fi
  99
 100 dnl Check for febootstrap etc.
 101 AC_CHECK_PROG([FEBOOTSTRAP],
 102         [febootstrap],[febootstrap],[no])
 103 test "x$FEBOOTSTRAP" = "xno" && \
 104      AC_MSG_ERROR([febootstrap must be installed])
 105 AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 106         [febootstrap-run],[febootstrap-run],[no])
 107 test "x$FEBOOTSTRAP_RUN" = "xno" && \
 108      AC_MSG_ERROR([febootstrap-run must be installed])
 109 AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 110         [febootstrap-install],[febootstrap-install],[no])
 111 test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 112      AC_MSG_ERROR([febootstrap-install must be installed])
 113 AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 114         [febootstrap-minimize],[febootstrap-minimize],[no])
 115 test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 116      AC_MSG_ERROR([febootstrap-minimize must be installed])
 117 AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 118         [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 119 test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 120      AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 121
 122 dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 123 dnl of febootstrap, but old versions will fail with yum).
 124 AC_CHECK_PROG([FAKECHROOT],
 125         [fakechroot],[fakechroot],[no])
 126 test "x$FAKECHROOT" = "xno" && \
 127     AC_MSG_ERROR([fakechroot must be installed])
 128
 129 AC_MSG_CHECKING([fakechroot version])
 130 fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 131 if test -z "$fakechroot_version"; then
 132     AC_MSG_RESULT([failed])
 133     AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 134 else
 135     AC_MSG_RESULT([$fakechroot_version])
 136     fakechroot_major=`echo $fakechroot_version | awk -F. '{print $1}'`
 137     fakechroot_minor=`echo $fakechroot_version | awk -F. '{print $2}'`
 138     if test "$fakechroot_major" -lt 2 -o \
 139             \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
 140         AC_MSG_ERROR([fakechroot version must be >= 2.9])
 141     fi
 142 fi
 143
 144 dnl --with-repo to specify a Fedora repository.
 145 AC_ARG_WITH([repo],
 146         [AS_HELP_STRING([--with-repo],
 147           [set name of Fedora repository @<:@default=fedora-11@:>@])],
 148         [],
 149         [with_repo=fedora-11])
 150 REPO="$with_repo"
 151 AC_SUBST(REPO)
 152 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 153
 154 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 155
 156 dnl --with-updates to specify a Fedora updates repository.
 157 AC_ARG_WITH([updates],
 158         [AS_HELP_STRING([--with-updates],
 159           [set name of Fedora updates repository @<:@default=updates-released-f10@:>@])],
 160         [],
 161         [with_updates=updates-released-f11])
 162 UPDATES="$with_updates"
 163 AC_SUBST(UPDATES)
 164 AC_DEFINE_UNQUOTED([UPDATES],["$UPDATES"],[Name of Fedora updates repository.])
 165
 166 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 167
 168 dnl --with-mirror to specify a local Fedora mirror.
 169 AC_ARG_WITH([mirror],
 170         [AS_HELP_STRING([--with-mirror],
 171           [set URI of a local Fedora mirror])],
 172         [],
 173         [with_mirror=])
 174 MIRROR="$with_mirror"
 175 AC_SUBST(MIRROR)
 176
 177 dnl Readline.
 178 AC_ARG_WITH([readline],
 179     [AS_HELP_STRING([--with-readline],
 180         [support fancy command line editing @<:@default=check@:>@])],
 181     [],
 182     [with_readline=check])
 183
 184 LIBREADLINE=
 185 AS_IF([test "x$with_readline" != xno],
 186     [AC_CHECK_LIB([readline], [main],
 187         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 188          AC_DEFINE([HAVE_LIBREADLINE], [1],
 189                    [Define if you have libreadline])
 190         ],
 191         [if test "x$with_readline" != xcheck; then
 192          AC_MSG_FAILURE(
 193              [--with-readline was given, but test for readline failed])
 194          fi
 195         ], -lncurses)])
 196
 197 dnl For i18n.
 198 IT_PROG_INTLTOOL
 199
 200 dnl Check for OCaml (optional, for OCaml bindings).
 201 AC_PROG_OCAML
 202 AC_PROG_FINDLIB
 203 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
 204
 205 dnl Check for Perl (optional, for Perl bindings).
 206 dnl XXX This isn't quite right, we should check for Perl devel library.
 207 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 208
 209 dnl Check for Perl modules that must be present to compile and
 210 dnl test the Perl bindings.
 211 missing_perl_modules=no
 212 for pm in Test::More Test::Pod Test::Pod::Coverage ExtUtils::MakeMaker; do
 213     AC_MSG_CHECKING([for $pm])
 214     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 215         AC_MSG_RESULT([no])
 216         missing_perl_modules=yes
 217     else
 218         AC_MSG_RESULT([yes])
 219     fi
 220 done
 221 if test "x$missing_perl_modules" = "xyes"; then
 222     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 223 fi
 224
 225 AM_CONDITIONAL([HAVE_PERL],
 226     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 227
 228 dnl Check for Python (optional, for Python bindings).
 229 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 230
 231 PYTHON_PREFIX=
 232 PYTHON_VERSION=
 233 PYTHON_INCLUDEDIR=
 234 PYTHON_SITE_PACKAGES=
 235
 236 if test "x$PYTHON" != "xno"; then
 237     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 238     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 239     for d in \
 240         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 241         /usr/include/python$PYTHON_VERSION \
 242         /usr/local/include/python$PYTHON_VERSION
 243     do
 244         AC_MSG_CHECKING([Python.h in $d])
 245         if test -r "$d/Python.h"; then
 246             AC_MSG_RESULT([found])
 247             PYTHON_INCLUDEDIR=$d
 248             break
 249         fi
 250         AC_MSG_RESULT([not found])
 251     done
 252     for d in \
 253         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 254         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 255         /usr/lib64/python$PYTHON_VERSION/site-packages \
 256         /usr/lib/python$PYTHON_VERSION/site-packages \
 257         /usr/local/lib/python$PYTHON_VERSION/site-packages
 258     do
 259         AC_MSG_CHECKING([for $d])
 260         if test -d "$d"; then
 261             AC_MSG_RESULT([found])
 262             PYTHON_SITE_PACKAGES=$d
 263             break
 264         fi
 265         AC_MSG_RESULT([not found])
 266     done
 267 fi
 268
 269 AC_SUBST(PYTHON_PREFIX)
 270 AC_SUBST(PYTHON_VERSION)
 271 AC_SUBST(PYTHON_INCLUDEDIR)
 272 AC_SUBST(PYTHON_SITE_PACKAGES)
 273
 274 AM_CONDITIONAL([HAVE_PYTHON],
 275     [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
 276
 277 dnl Check for Ruby and rake (optional, for Ruby bindings).
 278 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 279 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 280
 281 AM_CONDITIONAL([HAVE_RUBY],
 282     [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
 283
 284 dnl Check for Java.
 285 AC_ARG_WITH(java_home,
 286     [AS_HELP_STRING([--with-java-home],
 287         [specify path to JDK directory @<:@default=check@:>@])],
 288     [],
 289     [with_java_home=check])
 290
 291 if test "x$with_java_home" != "xno"; then
 292     if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
 293     then
 294         if test -d "$with_java_home"; then
 295             JAVA_HOME="$with_java_home"
 296         else
 297             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 298         fi
 299     fi
 300     if test "x$JAVA_HOME" = "x"; then
 301         JAVA_HOME=/usr/lib/jvm/java
 302     fi
 303     AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 304     if test ! -x "$JAVA_HOME/bin/java"; then
 305         AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 306     else
 307         JAVA="$JAVA_HOME/bin/java"
 308     fi
 309     if test ! -x "$JAVA_HOME/bin/javac"; then
 310         AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 311     else
 312         JAVAC="$JAVA_HOME/bin/javac"
 313     fi
 314     if test ! -x "$JAVA_HOME/bin/javah"; then
 315         AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 316     else
 317         JAVAH="$JAVA_HOME/bin/javah"
 318     fi
 319     if test ! -x "$JAVA_HOME/bin/javadoc"; then
 320         AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 321     else
 322         JAVADOC="$JAVA_HOME/bin/javadoc"
 323     fi
 324     if test ! -x "$JAVA_HOME/bin/jar"; then
 325         AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 326     else
 327         JAR="$JAVA_HOME/bin/jar"
 328     fi
 329     java_version=`$JAVA -version 2>&1 | grep "java version"`
 330     AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 331
 332     dnl Find jni.h.
 333     AC_MSG_CHECKING([for jni.h])
 334     if test -f "$JAVA_HOME/include/jni.h"; then
 335         JNI_CFLAGS="-I$JAVA_HOME/include"
 336     else
 337     if test "`find $JAVA_HOME -name jni.h`" != ""; then
 338         head=`find $JAVA_HOME -name jni.h | tail -1`
 339         dir=`dirname $head`
 340         JNI_CFLAGS="-I$dir"
 341     else
 342         AC_MSG_FAILURE([missing jni.h header file])
 343     fi
 344     fi
 345     AC_MSG_RESULT([$JNI_CFLAGS])
 346
 347     dnl Find jni_md.h.
 348     AC_MSG_CHECKING([for jni_md.h])
 349     case "$build_os" in
 350     *linux*) system="linux" ;;
 351     *SunOS*) system="solaris" ;;
 352     *cygwin*) system="win32" ;;
 353     *) system="$build_os" ;;
 354     esac
 355     if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 356         JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 357     else
 358     if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 359         head=`find $JAVA_HOME -name jni_md.h | tail -1`
 360         dir=`dirname $head`
 361         JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 362     else
 363         AC_MSG_FAILURE([missing jni_md.h header file])
 364     fi
 365     fi
 366     AC_MSG_RESULT([$JNI_CFLAGS])
 367
 368     dnl Need extra version flag?
 369     AC_MSG_CHECKING([extra javac flags])
 370     JAVAC_FLAGS=
 371     javac_version=`$JAVAC -version 2>&1`
 372     case "$javac_version" in
 373     *Eclipse*)
 374         JAVAC_FLAGS="-source 1.5" ;;
 375     esac
 376     AC_MSG_RESULT([$JAVAC_FLAGS])
 377
 378     dnl Where to install jarfiles.
 379     dnl XXX How to make it configurable?
 380     JAR_INSTALL_DIR=\${prefix}/share/java
 381     JNI_INSTALL_DIR=\${libdir}
 382
 383     dnl JNI version.
 384     jni_major_version=`echo $VERSION | awk -F. '{print $1}'`
 385     jni_minor_version=`echo $VERSION | awk -F. '{print $2}'`
 386     jni_micro_version=`echo $VERSION | awk -F. '{print $3}'`
 387     JNI_VERSION_INFO=`expr $jni_major_version + $jni_minor_version`:$jni_micro_version:$jni_minor_version
 388 fi
 389
 390 AC_SUBST(JAVA_HOME)
 391 AC_SUBST(JAVA)
 392 AC_SUBST(JAVAC)
 393 AC_SUBST(JAVAH)
 394 AC_SUBST(JAVADOC)
 395 AC_SUBST(JAR)
 396 AC_SUBST(JNI_CFLAGS)
 397 AC_SUBST(JAVAC_FLAGS)
 398 AC_SUBST(JAR_INSTALL_DIR)
 399 AC_SUBST(JNI_INSTALL_DIR)
 400 AC_SUBST(JNI_VERSION_INFO)
 401
 402 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 403
 404 dnl Check for Haskell (GHC).
 405 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 406
 407 AM_CONDITIONAL([HAVE_HASKELL],
 408     [test "x$GHC" != "xno"])
 409
 410 dnl Check for Perl modules needed by the inspector.
 411 missing_perl_modules=no
 412 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper; do
 413     AC_MSG_CHECKING([for $pm])
 414     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 415         AC_MSG_RESULT([no])
 416         missing_perl_modules=yes
 417     else
 418         AC_MSG_RESULT([yes])
 419     fi
 420 done
 421 if test "x$missing_perl_modules" = "xyes"; then
 422     AC_MSG_WARN([some Perl modules required to compile virt-inspector are missing])
 423 fi
 424
 425 AM_CONDITIONAL([HAVE_INSPECTOR],
 426     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 427
 428 dnl Run in subdirs.
 429 AC_CONFIG_SUBDIRS([daemon])
 430
 431 dnl Produce output files.
 432 AC_CONFIG_HEADERS([config.h])
 433 AC_CONFIG_FILES([Makefile
 434                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 435                  images/Makefile
 436                  ocaml/Makefile ocaml/examples/Makefile
 437                  perl/Makefile
 438                  python/Makefile
 439                  ruby/Makefile ruby/Rakefile
 440                  java/Makefile
 441                  haskell/Makefile
 442                  inspector/Makefile
 443                  make-initramfs.sh update-initramfs.sh
 444                  libguestfs.pc
 445                  ocaml/META perl/Makefile.PL])
 446 AC_OUTPUT
 447
 448 dnl WTF?
 449 chmod +x make-initramfs.sh update-initramfs.sh
 450
 451 dnl Produce summary.
 452 echo
 453 echo
 454 echo "------------------------------------------------------------"
 455 echo "Thank you for downloading $PACKAGE_STRING"
 456 echo
 457 echo "This is how we have configured the optional components for you today:"
 458 echo
 459 echo    "QEMU ................................ $QEMU"
 460 echo -n "OCaml bindings ...................... "
 461 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 462 echo -n "Perl bindings ....................... "
 463 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 464 echo -n "Python bindings ..................... "
 465 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 466 echo -n "Ruby bindings ....................... "
 467 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 468 echo -n "Java bindings ....................... "
 469 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 470 echo -n "Haskell bindings .................... "
 471 if test "x$HAVE_HASKELL" = "x"; then echo "yes"; else echo "no"; fi
 472 echo -n "virt-inspector ...................... "
 473 if test "x$HAVE_INSPECTOR" = "x"; then echo "yes"; else echo "no"; fi
 474 echo
 475 echo "If any optional component is configured 'no' when you expected 'yes'"
 476 echo "then you should check the preceeding messages."
 477 echo
 478 echo "Please report bugs back to the fedora-virt mailing list:"
 479 echo "http://www.redhat.com/mailman/listinfo/fedora-virt"
 480 echo
 481 echo "Next you should type 'make' to build the package,"
 482 echo "then 'make check' to run the tests."
 483 echo "------------------------------------------------------------"