configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [0])
  21 m4_define([libguestfs_release], [72])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release[]libguestfs_extra)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 gl_EARLY
  41 gl_INIT
  42
  43 AC_PROG_LIBTOOL
  44
  45 dnl Check for basic C environment.
  46 AC_PROG_CC_STDC
  47 AC_PROG_INSTALL
  48 AC_PROG_CPP
  49
  50 AC_ARG_ENABLE([gcc-warnings],
  51   [AS_HELP_STRING([--enable-gcc-warnings],
  52                   [turn on lots of GCC warnings (for developers)])],
  53   [case $enableval in
  54      yes|no) ;;
  55      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  56    esac
  57    gl_gcc_warnings=$enableval],
  58   [gl_gcc_warnings=no]
  59 )
  60
  61 if test "$gl_gcc_warnings" = yes; then
  62   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  63   AC_SUBST([WERROR_CFLAGS])
  64
  65   nw=
  66   # This, $nw, is the list of warnings we disable.
  67   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  68   nw="$nw -Waggregate-return"       # anachronistic
  69   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  70   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  71   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  72   nw="$nw -Wcast-qual"              # Too many warnings for now
  73   nw="$nw -Wconversion"             # Too many warnings for now
  74   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  75   nw="$nw -Wsign-conversion"        # Too many warnings for now
  76   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  77   nw="$nw -Wunreachable-code"       # Too many warnings for now
  78   nw="$nw -Wpadded"                 # Our structs are not padded
  79   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  80   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  81   nw="$nw -Wvla"                    # two warnings in mount.c
  82   # things I might fix soon:
  83   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
  84   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
  85   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
  86   # ?? -Wstrict-overflow
  87   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
  88                                     # was not possible, safe to ignore
  89
  90   gl_MANYWARN_ALL_GCC([ws])
  91   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
  92   for w in $ws; do
  93     gl_WARN_ADD([$w])
  94   done
  95   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
  96   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
  97   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
  98
  99   # In spite of excluding -Wlogical-op above, it is enabled, as of
 100   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 101   gl_WARN_ADD([-Wno-logical-op])
 102
 103   gl_WARN_ADD([-fdiagnostics-show-option])
 104
 105   AC_SUBST([WARN_CFLAGS])
 106
 107   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 108   AC_DEFINE([_FORTIFY_SOURCE], [2],
 109     [enable compile-time and run-time bounds-checking, and some warnings])
 110   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 111 fi
 112
 113 AC_C_PROTOTYPES
 114 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 115
 116 AM_PROG_CC_C_O
 117
 118 dnl Check support for 64 bit file offsets.
 119 AC_SYS_LARGEFILE
 120
 121 dnl Check sizeof long.
 122 AC_CHECK_SIZEOF([long])
 123
 124 dnl Headers.
 125 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h])
 126
 127 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 128 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 129 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 130 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 131         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 132         ])
 133
 134 dnl Check for pod2man and pod2text.
 135 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 136 test "x$POD2MAN" = "xno" &&
 137      AC_MSG_ERROR([pod2man must be installed])
 138 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 139 test "x$POD2TEXT" = "xno" &&
 140      AC_MSG_ERROR([pod2text must be installed])
 141
 142 dnl Check for mkisofs.
 143 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 144         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 145 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 146
 147 dnl Check for optional xmllint.
 148 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 149 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 150
 151 dnl Check for QEMU for running binaries on this $host_cpu, fall
 152 dnl back to basic 'qemu'.  Allow the user to override it.
 153 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
 154 AC_ARG_WITH([qemu],
 155         [AS_HELP_STRING([--with-qemu],
 156           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 157         [],
 158         [with_qemu="$default_qemu"])
 159 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 160         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 161 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 162 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 163
 164 dnl Check that the chosen qemu has vmchannel support or we can
 165 dnl fallback to null vmchannel (still using SLIRP).  See the
 166 dnl discussion in the README file.
 167 if test "x$vmchannel_test" != "xno"; then
 168     AC_MSG_CHECKING([for guestfwd support in $QEMU])
 169     if $QEMU --help | grep -sq guestfwd; then
 170         AC_MSG_RESULT([yes])
 171         vmchannel_guestfwd=guestfwd
 172     else
 173         AC_MSG_RESULT([no])
 174         # Note that this test must be conditional on the previous
 175         # test failing.  This is because recent qemu will throw
 176         # up an SDL window and hang if we try to run this test.
 177         AC_MSG_CHECKING([for "-net channel" (old guestfwd) support in $QEMU])
 178         vmchannelout=`$QEMU -net channel /dev/zero 2>&1 ||:`
 179         echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
 180         if echo "$vmchannelout" | grep -sq "vmchannel wrong port number" ; then
 181             AC_MSG_RESULT([yes])
 182             vmchannel_guestfwd=net_channel
 183         else
 184             AC_MSG_RESULT([no])
 185             vmchannel_guestfwd=no
 186         fi
 187     fi
 188
 189     AC_MSG_CHECKING([for "-net user" (user mode network) support in $QEMU])
 190     if $QEMU --help | grep -sq -- "-net user"; then
 191         AC_MSG_RESULT([yes])
 192         vmchannel_net_user=yes
 193     else
 194         AC_MSG_RESULT([no])
 195         vmchannel_net_user=no
 196     fi
 197
 198     if test "x$vmchannel_net_user" = "xno" -a "x$vmchannel_guestfwd" = "xno"; then
 199         AC_MSG_FAILURE(
 200 [I did not find user mode network or vmchannel support in
 201 $QEMU.
 202
 203 Either user mode networking or vmchannel support is vital for
 204 libguestfs to operate.
 205
 206 Please read the relevant section in the README file for more
 207 information about this.
 208
 209 You can override this test by setting the environment variable
 210 vmchannel_test=no  However if you don't have the right support
 211 in your qemu, then this just delays the pain.
 212
 213 If I am using the wrong qemu or you want to compile qemu from source
 214 and install it in another location, then you should configure with
 215 the --with-qemu option.
 216 ])
 217     fi
 218 fi
 219
 220 dnl Set drive interface used by the guestfs_add_drive{,_ro} calls
 221 dnl ('-drive ...,if=...' option to qemu).
 222 dnl
 223 dnl NB. We will change the default in future to virtio, but at the
 224 dnl moment this causes a performance problem, RHBZ#509383.
 225 AC_ARG_WITH([drive-if],
 226         [AS_HELP_STRING([--with-drive-if],
 227           [set default driver (ide|scsi|virtio) @<:@default=ide@:>@])],
 228         [],
 229         [with_drive_if=ide])
 230 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 231
 232 dnl Set interface used by the network.  Normally you should
 233 dnl leave this at the default (virtio) but you can use the
 234 dnl alternative (ne2k_pci) because of bugs in virtio networking
 235 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 236 AC_ARG_WITH([net-if],
 237         [AS_HELP_STRING([--with-net-if],
 238           [set default net driver (virtio|ne2k_pci) @<:@default=virtio@:>@])],
 239         [],
 240         [with_net_if=virtio])
 241 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 242
 243 dnl Check for febootstrap etc.
 244 AC_CHECK_PROG([FEBOOTSTRAP],
 245         [febootstrap],[febootstrap],[no])
 246 if test "x$FEBOOTSTRAP" != "xno"; then
 247   AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 248         [febootstrap-run],[febootstrap-run],[no])
 249   test "x$FEBOOTSTRAP_RUN" = "xno" && \
 250      AC_MSG_ERROR([febootstrap-run must be installed])
 251   AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 252         [febootstrap-install],[febootstrap-install],[no])
 253   test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 254      AC_MSG_ERROR([febootstrap-install must be installed])
 255   AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 256         [febootstrap-minimize],[febootstrap-minimize],[no])
 257   test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 258      AC_MSG_ERROR([febootstrap-minimize must be installed])
 259   AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 260         [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 261   test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 262      AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 263
 264   dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 265   dnl of febootstrap, but old versions will fail with yum).
 266   AC_CHECK_PROG([FAKECHROOT],
 267         [fakechroot],[fakechroot],[no])
 268   test "x$FAKECHROOT" = "xno" && \
 269     AC_MSG_ERROR([fakechroot must be installed])
 270
 271   AC_MSG_CHECKING([fakechroot version])
 272   fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 273   if test -z "$fakechroot_version"; then
 274     AC_MSG_RESULT([failed])
 275     AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 276   else
 277     AC_MSG_RESULT([$fakechroot_version])
 278     fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 279     fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 280     if test "$fakechroot_major" -lt 2 -o \
 281             \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
 282         AC_MSG_ERROR([fakechroot version must be >= 2.9])
 283     fi
 284   fi
 285   DIST="REDHAT"
 286 else
 287   # check for debootstrap and debirf
 288   AC_CHECK_PROG([DEBOOTSTRAP],
 289         [debootstrap],[debootstrap],[no])
 290   test "x$DEBOOTSTRAP" = "xno" && \
 291         AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 292   AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 293   test "x$DEBIRF" = "xno" &&
 294         AC_MSG_ERROR([debirf must be installed])
 295   DIST="DEBIAN"
 296   case "$host_cpu" in
 297       *86)
 298           DEBIAN_KERNEL_ARCH=486
 299           ;;
 300       x86_64)
 301           DEBIAN_KERNEL_ARCH=amd64
 302           ;;
 303       *)
 304          DEBIAN_KERNEL_ARCH=$host_cpu
 305          ;;
 306    esac
 307    AC_SUBST(DEBIAN_KERNEL_ARCH)
 308 fi
 309 AC_SUBST(DIST)
 310
 311
 312 dnl --with-repo to specify a Fedora repository.
 313 AC_ARG_WITH([repo],
 314         [AS_HELP_STRING([--with-repo],
 315           [set name of Fedora repository @<:@default=fedora-11@:>@])],
 316         [],
 317         [with_repo=fedora-11])
 318 REPO="$with_repo"
 319 AC_SUBST(REPO)
 320 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 321
 322 dnl --with-updates to specify a Fedora updates repository.
 323 AC_ARG_WITH([updates],
 324         [AS_HELP_STRING([--with-updates],
 325           [set name of Fedora updates repository @<:@default=updates-released-f11@:>@])],
 326         [],
 327         [with_updates=updates-released-f11])
 328 UPDATES="$with_updates"
 329 AC_SUBST(UPDATES)
 330
 331 dnl Define a symbol for the host CPU architecture.
 332 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 333
 334 dnl --with-mirror to specify a local Fedora mirror.
 335 AC_ARG_WITH([mirror],
 336         [AS_HELP_STRING([--with-mirror],
 337           [set URI of a local Fedora mirror])],
 338         [],
 339         [with_mirror=])
 340 MIRROR="$with_mirror"
 341 AC_SUBST(MIRROR)
 342
 343 dnl Build the supermin appliance?  Please see README file before
 344 dnl enabling this option.
 345 AC_ARG_ENABLE([supermin],
 346         [AS_HELP_STRING([--enable-supermin],
 347           [enable supermin appliance (see README) @<:@default=no@:>@])],
 348         [],
 349         [enable_supermin=no])
 350 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 351
 352 if test "x$enable_supermin" = "xyes"; then
 353     dnl Check febootstrap-to-initramfs accepts the --files option
 354     dnl (febootstrap >= 2.2).
 355     AC_MSG_CHECKING([for --files support in $FEBOOTSTRAP_TO_INITRAMFS])
 356     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 357     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 358     if ! echo "$out" | grep -sq -e --files ; then
 359         AC_MSG_RESULT([no])
 360         AC_MSG_FAILURE(
 361 [febootstrap-to-initramfs does not support the --files option.
 362
 363 To build the supermin appliance, you need to upgrade to the latest
 364 version of febootstrap.
 365 ])
 366     fi
 367     AC_MSG_RESULT([yes])
 368
 369     dnl Check febootstrap-to-initramfs accepts the --nocompress option
 370     dnl (febootstrap >= 2.3).
 371     AC_MSG_CHECKING([for --nocompress support in $FEBOOTSTRAP_TO_INITRAMFS])
 372     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 373     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 374     if ! echo "$out" | grep -sq -e --nocompress ; then
 375         AC_MSG_RESULT([no])
 376         AC_MSG_FAILURE(
 377 [febootstrap-to-initramfs does not support the --nocompress option.
 378
 379 To build the supermin appliance, you need to upgrade to the latest
 380 version of febootstrap.
 381 ])
 382     fi
 383     AC_MSG_RESULT([yes])
 384 fi
 385
 386 dnl Enable packet dumps when in verbose mode.  This generates lots
 387 dnl of debug info, only useful for people debugging the RPC mechanism.
 388 AC_ARG_ENABLE([packet-dump],
 389         [AS_HELP_STRING([--enable-packet-dump],
 390           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 391         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 392         [])
 393
 394 dnl Readline.
 395 AC_ARG_WITH([readline],
 396     [AS_HELP_STRING([--with-readline],
 397         [support fancy command line editing @<:@default=check@:>@])],
 398     [],
 399     [with_readline=check])
 400
 401 LIBREADLINE=
 402 AS_IF([test "x$with_readline" != xno],
 403     [AC_CHECK_LIB([readline], [main],
 404         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 405          AC_DEFINE([HAVE_LIBREADLINE], [1],
 406                    [Define if you have libreadline])
 407         ],
 408         [if test "x$with_readline" != xcheck; then
 409          AC_MSG_FAILURE(
 410              [--with-readline was given, but test for readline failed])
 411          fi
 412         ], -lncurses)])
 413
 414 dnl For i18n.
 415 AM_GNU_GETTEXT([external])
 416 AM_GNU_GETTEXT_VERSION([0.17])
 417
 418 dnl Check for OCaml (optional, for OCaml bindings).
 419 AC_PROG_OCAML
 420 AC_PROG_FINDLIB
 421 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
 422
 423 dnl Build the OCaml viewer example.  This has a lengthy list of
 424 dnl dependencies and we don't attempt to detect them all.  Read
 425 dnl the top of ocaml/examples/viewer.ml before enabling this.
 426 AC_ARG_ENABLE([ocaml-viewer],
 427         [AS_HELP_STRING([--enable-ocaml-viewer],
 428           [enable OCaml viewer (see ocaml/examples) @<:@default=no@:>@])],
 429         [],
 430         [enable_ocaml_viewer=no])
 431 AM_CONDITIONAL([BUILD_OCAML_VIEWER],[test "x$enable_ocaml_viewer" = "xyes"])
 432
 433 dnl Check for Perl (optional, for Perl bindings).
 434 dnl XXX This isn't quite right, we should check for Perl devel library.
 435 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 436
 437 dnl Check for Perl modules that must be present to compile and
 438 dnl test the Perl bindings.
 439 missing_perl_modules=no
 440 for pm in Test::More Test::Pod Test::Pod::Coverage ExtUtils::MakeMaker; do
 441     AC_MSG_CHECKING([for $pm])
 442     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 443         AC_MSG_RESULT([no])
 444         missing_perl_modules=yes
 445     else
 446         AC_MSG_RESULT([yes])
 447     fi
 448 done
 449 if test "x$missing_perl_modules" = "xyes"; then
 450     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 451 fi
 452
 453 AM_CONDITIONAL([HAVE_PERL],
 454     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 455
 456 dnl Check for Python (optional, for Python bindings).
 457 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 458
 459 PYTHON_PREFIX=
 460 PYTHON_VERSION=
 461 PYTHON_INCLUDEDIR=
 462 PYTHON_SITE_PACKAGES=
 463
 464 if test "x$PYTHON" != "xno"; then
 465     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 466     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 467     for d in \
 468         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 469         /usr/include/python$PYTHON_VERSION \
 470         /usr/local/include/python$PYTHON_VERSION
 471     do
 472         AC_MSG_CHECKING([Python.h in $d])
 473         if test -r "$d/Python.h"; then
 474             AC_MSG_RESULT([found])
 475             PYTHON_INCLUDEDIR=$d
 476             break
 477         fi
 478         AC_MSG_RESULT([not found])
 479     done
 480     for d in \
 481         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 482         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 483         /usr/lib64/python$PYTHON_VERSION/site-packages \
 484         /usr/lib/python$PYTHON_VERSION/site-packages \
 485         /usr/local/lib/python$PYTHON_VERSION/site-packages
 486     do
 487         AC_MSG_CHECKING([for $d])
 488         if test -d "$d"; then
 489             AC_MSG_RESULT([found])
 490             PYTHON_SITE_PACKAGES=$d
 491             break
 492         fi
 493         AC_MSG_RESULT([not found])
 494     done
 495 fi
 496
 497 AC_SUBST(PYTHON_PREFIX)
 498 AC_SUBST(PYTHON_VERSION)
 499 AC_SUBST(PYTHON_INCLUDEDIR)
 500 AC_SUBST(PYTHON_SITE_PACKAGES)
 501
 502 AM_CONDITIONAL([HAVE_PYTHON],
 503     [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
 504
 505 dnl Check for Ruby and rake (optional, for Ruby bindings).
 506 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 507 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 508
 509 AM_CONDITIONAL([HAVE_RUBY],
 510     [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
 511
 512 dnl Check for Java.
 513 AC_ARG_WITH(java_home,
 514     [AS_HELP_STRING([--with-java-home],
 515         [specify path to JDK directory @<:@default=check@:>@])],
 516     [],
 517     [with_java_home=check])
 518
 519 if test "x$with_java_home" != "xno"; then
 520     if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
 521     then
 522         # Reject unsafe characters in $JAVA_HOME
 523         jh_lf='
 524 '
 525         case $JAVA_HOME in
 526           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 527             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 528         esac
 529         if test -d "$with_java_home"; then
 530             JAVA_HOME="$with_java_home"
 531         else
 532             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 533         fi
 534     fi
 535
 536     if test "x$JAVA_HOME" = "x"; then
 537         # Look for Java in some likely locations.
 538         for d in \
 539             /usr/lib/jvm/java \
 540             /usr/lib/jvm/java-6-openjdk
 541         do
 542             if test -d $d -a -f $d/bin/java; then
 543                 JAVA_HOME=$d
 544                 break
 545             fi
 546         done
 547     fi
 548
 549     if test "x$JAVA_HOME" != "x"; then
 550         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 551         if test ! -x "$JAVA_HOME/bin/java"; then
 552             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 553         else
 554             JAVA="$JAVA_HOME/bin/java"
 555         fi
 556         if test ! -x "$JAVA_HOME/bin/javac"; then
 557             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 558         else
 559             JAVAC="$JAVA_HOME/bin/javac"
 560         fi
 561         if test ! -x "$JAVA_HOME/bin/javah"; then
 562             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 563         else
 564             JAVAH="$JAVA_HOME/bin/javah"
 565         fi
 566         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 567             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 568         else
 569             JAVADOC="$JAVA_HOME/bin/javadoc"
 570         fi
 571         if test ! -x "$JAVA_HOME/bin/jar"; then
 572             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 573         else
 574             JAR="$JAVA_HOME/bin/jar"
 575         fi
 576         java_version=`$JAVA -version 2>&1 | grep "java version"`
 577         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 578
 579         dnl Find jni.h.
 580         AC_MSG_CHECKING([for jni.h])
 581         if test -f "$JAVA_HOME/include/jni.h"; then
 582             JNI_CFLAGS="-I$JAVA_HOME/include"
 583         else
 584             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 585                 head=`find $JAVA_HOME -name jni.h | tail -1`
 586                 dir=`dirname "$head"`
 587                 JNI_CFLAGS="-I$dir"
 588             else
 589                 AC_MSG_FAILURE([missing jni.h header file])
 590             fi
 591         fi
 592         AC_MSG_RESULT([$JNI_CFLAGS])
 593
 594         dnl Find jni_md.h.
 595         AC_MSG_CHECKING([for jni_md.h])
 596         case "$build_os" in
 597         *linux*) system="linux" ;;
 598         *SunOS*) system="solaris" ;;
 599         *cygwin*) system="win32" ;;
 600         *) system="$build_os" ;;
 601         esac
 602         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 603             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 604         else
 605             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 606                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 607                 dir=`dirname "$head"`
 608                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 609             else
 610                 AC_MSG_FAILURE([missing jni_md.h header file])
 611             fi
 612         fi
 613         AC_MSG_RESULT([$JNI_CFLAGS])
 614
 615         dnl Need extra version flag?
 616         AC_MSG_CHECKING([extra javac flags])
 617         JAVAC_FLAGS=
 618         javac_version=`$JAVAC -version 2>&1`
 619         case "$javac_version" in
 620         *Eclipse*)
 621             JAVAC_FLAGS="-source 1.5" ;;
 622         esac
 623         AC_MSG_RESULT([$JAVAC_FLAGS])
 624
 625         dnl Where to install jarfiles.
 626         dnl XXX How to make it configurable?
 627         JAR_INSTALL_DIR=\${prefix}/share/java
 628         JNI_INSTALL_DIR=\${libdir}
 629
 630         dnl JNI version.
 631         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 632         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 633         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 634         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 635     fi
 636 fi
 637
 638 AC_SUBST(JAVA_HOME)
 639 AC_SUBST(JAVA)
 640 AC_SUBST(JAVAC)
 641 AC_SUBST(JAVAH)
 642 AC_SUBST(JAVADOC)
 643 AC_SUBST(JAR)
 644 AC_SUBST(JNI_CFLAGS)
 645 AC_SUBST(JAVAC_FLAGS)
 646 AC_SUBST(JAR_INSTALL_DIR)
 647 AC_SUBST(JNI_INSTALL_DIR)
 648 AC_SUBST(JNI_VERSION_INFO)
 649
 650 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 651
 652 dnl Check for Haskell (GHC).
 653 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 654
 655 AM_CONDITIONAL([HAVE_HASKELL],
 656     [test "x$GHC" != "xno"])
 657
 658 dnl Check for Perl modules needed by virt-df, inspector, etc.
 659 missing_perl_modules=no
 660 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer Locale::TextDomain; do
 661     AC_MSG_CHECKING([for $pm])
 662     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 663         AC_MSG_RESULT([no])
 664         missing_perl_modules=yes
 665     else
 666         AC_MSG_RESULT([yes])
 667     fi
 668 done
 669 if test "x$missing_perl_modules" = "xyes"; then
 670     AC_MSG_WARN([some Perl modules required to compile virt-cat, virt-df, virt-edit, virt-inspector and virt-rescue are missing])
 671 fi
 672
 673 AM_CONDITIONAL([HAVE_CAT],
 674     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 675 AM_CONDITIONAL([HAVE_DF],
 676     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 677 AM_CONDITIONAL([HAVE_EDIT],
 678     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 679 AM_CONDITIONAL([HAVE_INSPECTOR],
 680     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 681 AM_CONDITIONAL([HAVE_RESCUE],
 682     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 683
 684 dnl Library versioning.
 685 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 686 AC_SUBST(MAX_PROC_NR)
 687
 688 dnl Run in subdirs.
 689 AC_CONFIG_SUBDIRS([daemon])
 690
 691 dnl Produce output files.
 692 AC_CONFIG_HEADERS([config.h])
 693 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 694 AC_CONFIG_FILES([appliance/make.sh],
 695                 [chmod +x appliance/make.sh])
 696 AC_CONFIG_FILES([appliance/update.sh],
 697                 [chmod +x appliance/update.sh])
 698 AC_CONFIG_FILES([appliance/supermin-split.sh],
 699                 [chmod +x appliance/supermin-split.sh])
 700 AC_CONFIG_FILES([appliance/supermin-make.sh],
 701                 [chmod +x appliance/supermin-make.sh])
 702 AC_CONFIG_FILES([appliance/libguestfs-supermin-helper],
 703                 [chmod +x appliance/libguestfs-supermin-helper])
 704 AC_CONFIG_FILES([Makefile
 705                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 706                  appliance/Makefile
 707                  appliance/debian/debirf.conf
 708                  images/Makefile
 709                  capitests/Makefile
 710                  regressions/Makefile
 711                  test-tool/Makefile
 712                  ocaml/Makefile ocaml/examples/Makefile
 713                  perl/Makefile
 714                  python/Makefile
 715                  ruby/Makefile ruby/Rakefile
 716                  java/Makefile
 717                  haskell/Makefile
 718                  cat/Makefile
 719                  df/Makefile
 720                  edit/Makefile
 721                  inspector/Makefile
 722                  rescue/Makefile
 723                  libguestfs.pc
 724                  gnulib/lib/Makefile
 725                  gnulib/tests/Makefile
 726                  ocaml/META perl/Makefile.PL])
 727 AC_OUTPUT
 728
 729 dnl Produce summary.
 730 echo
 731 echo
 732 echo "------------------------------------------------------------"
 733 echo "Thank you for downloading $PACKAGE_STRING"
 734 echo
 735 echo "This is how we have configured the optional components for you today:"
 736 echo
 737 echo    "QEMU ................................ $QEMU"
 738 echo -n "OCaml bindings ...................... "
 739 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 740 echo -n "Perl bindings ....................... "
 741 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 742 echo -n "Python bindings ..................... "
 743 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 744 echo -n "Ruby bindings ....................... "
 745 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 746 echo -n "Java bindings ....................... "
 747 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 748 echo -n "Haskell bindings .................... "
 749 if test "x$HAVE_HASKELL" = "x"; then echo "yes"; else echo "no"; fi
 750 echo -n "virt-cat ............................ "
 751 if test "x$HAVE_CAT" = "x"; then echo "yes"; else echo "no"; fi
 752 echo -n "virt-df ............................. "
 753 if test "x$HAVE_DF" = "x"; then echo "yes"; else echo "no"; fi
 754 echo -n "virt-edit ........................... "
 755 if test "x$HAVE_EDIT" = "x"; then echo "yes"; else echo "no"; fi
 756 echo -n "virt-inspector ...................... "
 757 if test "x$HAVE_INSPECTOR" = "x"; then echo "yes"; else echo "no"; fi
 758 echo -n "virt-rescue ......................... "
 759 if test "x$HAVE_RESCUE" = "x"; then echo "yes"; else echo "no"; fi
 760 echo "supermin appliance .................. $enable_supermin"
 761 echo
 762 echo "If any optional component is configured 'no' when you expected 'yes'"
 763 echo "then you should check the preceeding messages."
 764 echo
 765 echo "Please report bugs back to the mailing list:"
 766 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 767 echo
 768 echo "Next you should type 'make' to build the package,"
 769 echo "then 'make check' to run the tests."
 770 echo "------------------------------------------------------------"