configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2010 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [0])
  21 m4_define([libguestfs_release], [86])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release[]libguestfs_extra)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 gl_EARLY
  41 gl_INIT
  42
  43 AC_PROG_LIBTOOL
  44
  45 dnl Check for basic C environment.
  46 AC_PROG_CC_STDC
  47 AC_PROG_INSTALL
  48 AC_PROG_CPP
  49
  50 AC_ARG_ENABLE([gcc-warnings],
  51   [AS_HELP_STRING([--enable-gcc-warnings],
  52                   [turn on lots of GCC warnings (for developers)])],
  53   [case $enableval in
  54      yes|no) ;;
  55      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  56    esac
  57    gl_gcc_warnings=$enableval],
  58   [gl_gcc_warnings=no]
  59 )
  60
  61 if test "$gl_gcc_warnings" = yes; then
  62   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  63   AC_SUBST([WERROR_CFLAGS])
  64
  65   nw=
  66   # This, $nw, is the list of warnings we disable.
  67   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  68   nw="$nw -Waggregate-return"       # anachronistic
  69   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  70   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  71   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  72   nw="$nw -Wcast-qual"              # Too many warnings for now
  73   nw="$nw -Wconversion"             # Too many warnings for now
  74   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  75   nw="$nw -Wsign-conversion"        # Too many warnings for now
  76   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  77   nw="$nw -Wunreachable-code"       # Too many warnings for now
  78   nw="$nw -Wpadded"                 # Our structs are not padded
  79   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  80   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  81   nw="$nw -Wvla"                    # two warnings in mount.c
  82   # things I might fix soon:
  83   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
  84   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
  85   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
  86   # ?? -Wstrict-overflow
  87   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
  88                                     # was not possible, safe to ignore
  89   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
  90
  91   gl_MANYWARN_ALL_GCC([ws])
  92   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
  93   for w in $ws; do
  94     gl_WARN_ADD([$w])
  95   done
  96   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
  97   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
  98   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
  99
 100   # In spite of excluding -Wlogical-op above, it is enabled, as of
 101   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 102   gl_WARN_ADD([-Wno-logical-op])
 103
 104   gl_WARN_ADD([-fdiagnostics-show-option])
 105
 106   AC_SUBST([WARN_CFLAGS])
 107
 108   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 109   AC_DEFINE([_FORTIFY_SOURCE], [2],
 110     [enable compile-time and run-time bounds-checking, and some warnings])
 111   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 112 fi
 113
 114 AC_C_PROTOTYPES
 115 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 116
 117 AM_PROG_CC_C_O
 118
 119 dnl Work out how to specify the linker script to the linker.
 120 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 121 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 122     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 123 AC_SUBST(VERSION_SCRIPT_FLAGS)
 124
 125 dnl Check support for 64 bit file offsets.
 126 AC_SYS_LARGEFILE
 127
 128 dnl Check sizeof long.
 129 AC_CHECK_SIZEOF([long])
 130
 131 dnl Define a C symbol for the host CPU architecture.
 132 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 133
 134 dnl Headers.
 135 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 136
 137 dnl Functions.
 138 AC_CHECK_FUNCS([posix_fallocate])
 139
 140 dnl Build the daemon?
 141 AC_MSG_CHECKING([if we should build the daemon])
 142 AC_ARG_ENABLE([daemon],
 143         [AS_HELP_STRING([--enable-daemon],
 144           [enable building the daemon @<:@default=yes@:>@])],
 145         [],
 146         [enable_daemon=yes])
 147 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 148 AC_MSG_RESULT([$enable_daemon])
 149
 150 dnl Build the appliance?
 151 AC_MSG_CHECKING([if we should build the appliance])
 152 AC_ARG_ENABLE([appliance],
 153         [AS_HELP_STRING([--enable-appliance],
 154           [enable building the appliance @<:@default=yes@:>@])],
 155         [],
 156         [enable_appliance=yes])
 157 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 158 AC_MSG_RESULT([$enable_appliance])
 159
 160 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 161 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 162 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 163 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 164         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 165         ])
 166
 167 dnl Check for pod2man and pod2text.
 168 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 169 test "x$POD2MAN" = "xno" &&
 170      AC_MSG_ERROR([pod2man must be installed])
 171 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 172 test "x$POD2TEXT" = "xno" &&
 173      AC_MSG_ERROR([pod2text must be installed])
 174
 175 dnl Check for mkisofs.
 176 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 177         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 178 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 179
 180 dnl Check for optional xmllint.
 181 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 182 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 183
 184 dnl Check for QEMU for running binaries on this $host_cpu, fall
 185 dnl back to basic 'qemu'.  Allow the user to override it.
 186 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
 187 AC_ARG_WITH([qemu],
 188         [AS_HELP_STRING([--with-qemu],
 189           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 190         [],
 191         [with_qemu="$default_qemu"])
 192 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 193         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 194 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 195 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 196
 197 dnl Check that the chosen qemu has vmchannel support or we can
 198 dnl fallback to null vmchannel (still using SLIRP).  See the
 199 dnl discussion in the README file.
 200 if test "x$vmchannel_test" != "xno"; then
 201     AC_MSG_CHECKING([for guestfwd support in $QEMU])
 202     if $QEMU -nographic --help | grep -sq guestfwd; then
 203         AC_MSG_RESULT([yes])
 204         vmchannel_guestfwd=guestfwd
 205     else
 206         AC_MSG_RESULT([no])
 207         # Note that this test must be conditional on the previous
 208         # test failing.  This is because recent qemu will throw
 209         # up an SDL window and hang if we try to run this test.
 210         AC_MSG_CHECKING([for "-net channel" (old guestfwd) support in $QEMU])
 211         vmchannelout=`$QEMU -nographic -net channel /dev/zero 2>&1 ||:`
 212         echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
 213         if echo "$vmchannelout" | grep -sq "vmchannel wrong port number" ; then
 214             AC_MSG_RESULT([yes])
 215             vmchannel_guestfwd=net_channel
 216         else
 217             AC_MSG_RESULT([no])
 218             vmchannel_guestfwd=no
 219         fi
 220     fi
 221
 222     AC_MSG_CHECKING([for "-net user" (user mode network) support in $QEMU])
 223     if $QEMU -nographic --help | grep -sq -- "-net user"; then
 224         AC_MSG_RESULT([yes])
 225         vmchannel_net_user=yes
 226     else
 227         AC_MSG_RESULT([no])
 228         vmchannel_net_user=no
 229     fi
 230
 231     if test "x$vmchannel_net_user" = "xno" -a "x$vmchannel_guestfwd" = "xno"; then
 232         AC_MSG_FAILURE(
 233 [I did not find user mode network or vmchannel support in
 234 $QEMU.
 235
 236 Either user mode networking or vmchannel support is vital for
 237 libguestfs to operate.
 238
 239 Please read the relevant section in the README file for more
 240 information about this.
 241
 242 You can override this test by setting the environment variable
 243 vmchannel_test=no  However if you don't have the right support
 244 in your qemu, then this just delays the pain.
 245
 246 If I am using the wrong qemu or you want to compile qemu from source
 247 and install it in another location, then you should configure with
 248 the --with-qemu option.
 249 ])
 250     fi
 251 fi
 252
 253 dnl Set drive interface used by the guestfs_add_drive{,_ro} calls
 254 dnl ('-drive ...,if=...' option to qemu).
 255 dnl
 256 dnl If you encounter performance problems with virtio (RHBZ#509383)
 257 dnl then try '--with-drive-if=ide'.
 258 AC_ARG_WITH([drive-if],
 259         [AS_HELP_STRING([--with-drive-if],
 260           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 261         [],
 262         [with_drive_if=virtio])
 263 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 264
 265 dnl Set interface used by the network.  Normally you should
 266 dnl leave this at the default (virtio) but you can use the
 267 dnl alternative (ne2k_pci) because of bugs in virtio networking
 268 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 269 AC_ARG_WITH([net-if],
 270         [AS_HELP_STRING([--with-net-if],
 271           [set default net driver (virtio|ne2k_pci) @<:@default=virtio@:>@])],
 272         [],
 273         [with_net_if=virtio])
 274 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 275
 276 dnl Check for febootstrap etc.
 277 if test "x$enable_appliance" = "xyes"; then
 278     AC_CHECK_PROG([FEBOOTSTRAP],
 279                   [febootstrap],[febootstrap],[no])
 280     if test "x$FEBOOTSTRAP" != "xno"; then
 281       AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 282                     [febootstrap-run],[febootstrap-run],[no])
 283       test "x$FEBOOTSTRAP_RUN" = "xno" && \
 284           AC_MSG_ERROR([febootstrap-run must be installed])
 285       AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 286                     [febootstrap-install],[febootstrap-install],[no])
 287       test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 288           AC_MSG_ERROR([febootstrap-install must be installed])
 289       AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 290                     [febootstrap-minimize],[febootstrap-minimize],[no])
 291       test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 292           AC_MSG_ERROR([febootstrap-minimize must be installed])
 293       AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 294                     [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 295       test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 296           AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 297
 298       dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 299       dnl of febootstrap, but old versions will fail with yum).
 300       AC_CHECK_PROG([FAKECHROOT],
 301                     [fakechroot],[fakechroot],[no])
 302       test "x$FAKECHROOT" = "xno" && \
 303          AC_MSG_ERROR([fakechroot must be installed])
 304
 305       AC_MSG_CHECKING([fakechroot version])
 306       fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 307       if test -z "$fakechroot_version"; then
 308         AC_MSG_RESULT([failed])
 309         AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 310       else
 311         AC_MSG_RESULT([$fakechroot_version])
 312         fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 313         fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 314         if test "$fakechroot_major" -lt 2 -o \
 315             \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
 316           AC_MSG_ERROR([fakechroot version must be >= 2.9])
 317         fi
 318       fi
 319       DIST="REDHAT"
 320     else
 321       # check for debootstrap and debirf
 322       AC_CHECK_PROG([DEBOOTSTRAP],
 323                     [debootstrap],[debootstrap],[no])
 324       test "x$DEBOOTSTRAP" = "xno" && \
 325           AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 326       AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 327       test "x$DEBIRF" = "xno" &&
 328           AC_MSG_ERROR([debirf must be installed])
 329       DIST="DEBIAN"
 330       case "$host_cpu" in
 331       *86)
 332           DEBIAN_KERNEL_ARCH=486
 333           ;;
 334       x86_64)
 335           DEBIAN_KERNEL_ARCH=amd64
 336           ;;
 337       *)
 338          DEBIAN_KERNEL_ARCH=$host_cpu
 339          ;;
 340       esac
 341       AC_SUBST(DEBIAN_KERNEL_ARCH)
 342     fi
 343     AC_SUBST(DIST)
 344
 345     dnl --with-updates to specify a Fedora updates repository.
 346     AC_ARG_WITH([updates],
 347         [AS_HELP_STRING([--with-updates],
 348           [set name of Fedora updates repository @<:@default=updates-released-f11@:>@])],
 349         [],
 350         [with_updates=updates-released-f11])
 351     UPDATES="$with_updates"
 352     AC_SUBST(UPDATES)
 353
 354     dnl --with-mirror to specify a local Fedora mirror.
 355     AC_ARG_WITH([mirror],
 356         [AS_HELP_STRING([--with-mirror],
 357           [set URI of a local Fedora mirror])],
 358         [],
 359         [with_mirror=])
 360     MIRROR="$with_mirror"
 361     AC_SUBST(MIRROR)
 362 fi
 363
 364 dnl --with-repo to specify a Fedora repository.
 365 AC_ARG_WITH([repo],
 366         [AS_HELP_STRING([--with-repo],
 367           [set name of Fedora repository @<:@default=fedora-11@:>@])],
 368         [],
 369         [with_repo=fedora-11])
 370 REPO="$with_repo"
 371 AC_SUBST(REPO)
 372 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 373
 374 dnl Build the supermin appliance?  Please see README file before
 375 dnl enabling this option.
 376 AC_ARG_ENABLE([supermin],
 377         [AS_HELP_STRING([--enable-supermin],
 378           [enable supermin appliance (see README) @<:@default=no@:>@])],
 379         [],
 380         [enable_supermin=no])
 381 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 382
 383 if test "x$enable_supermin" = "xyes"; then
 384     dnl Check febootstrap-to-initramfs accepts the --files option
 385     dnl (febootstrap >= 2.2).
 386     AC_MSG_CHECKING([for --files support in $FEBOOTSTRAP_TO_INITRAMFS])
 387     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 388     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 389     if ! echo "$out" | grep -sq -e --files ; then
 390         AC_MSG_RESULT([no])
 391         AC_MSG_FAILURE(
 392 [febootstrap-to-initramfs does not support the --files option.
 393
 394 To build the supermin appliance, you need to upgrade to the latest
 395 version of febootstrap.
 396 ])
 397     fi
 398     AC_MSG_RESULT([yes])
 399
 400     dnl Check febootstrap-to-initramfs accepts the --nocompress option
 401     dnl (febootstrap >= 2.3).
 402     AC_MSG_CHECKING([for --nocompress support in $FEBOOTSTRAP_TO_INITRAMFS])
 403     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 404     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 405     if ! echo "$out" | grep -sq -e --nocompress ; then
 406         AC_MSG_RESULT([no])
 407         AC_MSG_FAILURE(
 408 [febootstrap-to-initramfs does not support the --nocompress option.
 409
 410 To build the supermin appliance, you need to upgrade to the latest
 411 version of febootstrap.
 412 ])
 413     fi
 414     AC_MSG_RESULT([yes])
 415 fi
 416
 417 dnl Enable packet dumps when in verbose mode.  This generates lots
 418 dnl of debug info, only useful for people debugging the RPC mechanism.
 419 AC_ARG_ENABLE([packet-dump],
 420         [AS_HELP_STRING([--enable-packet-dump],
 421           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 422         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 423         [])
 424
 425 dnl Readline.
 426 AC_ARG_WITH([readline],
 427     [AS_HELP_STRING([--with-readline],
 428         [support fancy command line editing @<:@default=check@:>@])],
 429     [],
 430     [with_readline=check])
 431
 432 LIBREADLINE=
 433 AS_IF([test "x$with_readline" != xno],
 434     [AC_CHECK_LIB([readline], [main],
 435         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 436          AC_DEFINE([HAVE_LIBREADLINE], [1],
 437                    [Define if you have libreadline])
 438         ],
 439         [if test "x$with_readline" != xcheck; then
 440          AC_MSG_FAILURE(
 441              [--with-readline was given, but test for readline failed])
 442          fi
 443         ], -lncurses)])
 444
 445 dnl For i18n.
 446 AM_GNU_GETTEXT([external])
 447 AM_GNU_GETTEXT_VERSION([0.17])
 448
 449 dnl hivex library (highly recommended).
 450 dnl This used to be a part of libguestfs, but was spun off into its
 451 dnl own separate upstream project in libguestfs 1.0.85.
 452 HAVE_HIVEX=yes
 453 PKG_CHECK_MODULES([HIVEX], [hivex],,[
 454         HAVE_HIVEX=no
 455         AC_MSG_WARN([Hivex library and headers are missing, so optional Windows Registry tools won't be built])])
 456 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HAVE_HIVEX" = "xyes"])
 457 AC_SUBST([HIVEX_CFLAGS])
 458 AC_SUBST([HIVEX_LIBS])
 459
 460 dnl FUSE is optional to build the FUSE module.
 461 HAVE_FUSE=yes
 462 PKG_CHECK_MODULES([FUSE],[fuse],,[
 463         HAVE_FUSE=no
 464         AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])
 465 AM_CONDITIONAL([HAVE_FUSE],[test "x$HAVE_FUSE" = "xyes"])
 466
 467 dnl Check for OCaml (optional, for OCaml bindings).
 468 AC_PROG_OCAML
 469 AC_PROG_FINDLIB
 470 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
 471
 472 dnl Optional xml-light for running the generator.
 473 OCAML_PKG_xml_light=no
 474 if test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"; then
 475     AC_CHECK_OCAML_PKG([xml-light])
 476 fi
 477 AM_CONDITIONAL([HAVE_XML_LIGHT],[test "x$OCAML_PKG_xml_light" != "xno"])
 478
 479 dnl Build the OCaml viewer example.  This has a lengthy list of
 480 dnl dependencies and we don't attempt to detect them all.  Read
 481 dnl the top of ocaml/examples/viewer.ml before enabling this.
 482 AC_ARG_ENABLE([ocaml-viewer],
 483         [AS_HELP_STRING([--enable-ocaml-viewer],
 484           [enable OCaml viewer (see ocaml/examples) @<:@default=no@:>@])],
 485         [],
 486         [enable_ocaml_viewer=no])
 487 AM_CONDITIONAL([BUILD_OCAML_VIEWER],[test "x$enable_ocaml_viewer" = "xyes"])
 488
 489 dnl Check for Perl (optional, for Perl bindings).
 490 dnl XXX This isn't quite right, we should check for Perl devel library.
 491 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 492
 493 dnl Check for Perl modules that must be present to compile and
 494 dnl test the Perl bindings.
 495 missing_perl_modules=no
 496 for pm in Test::More Test::Pod Test::Pod::Coverage ExtUtils::MakeMaker; do
 497     AC_MSG_CHECKING([for $pm])
 498     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 499         AC_MSG_RESULT([no])
 500         missing_perl_modules=yes
 501     else
 502         AC_MSG_RESULT([yes])
 503     fi
 504 done
 505 if test "x$missing_perl_modules" = "xyes"; then
 506     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 507 fi
 508
 509 AM_CONDITIONAL([HAVE_PERL],
 510     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 511
 512 dnl Check for Python (optional, for Python bindings).
 513 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 514
 515 PYTHON_PREFIX=
 516 PYTHON_VERSION=
 517 PYTHON_INCLUDEDIR=
 518 PYTHON_SITE_PACKAGES=
 519
 520 if test "x$PYTHON" != "xno"; then
 521     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 522     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 523     for d in \
 524         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 525         /usr/include/python$PYTHON_VERSION \
 526         /usr/local/include/python$PYTHON_VERSION
 527     do
 528         AC_MSG_CHECKING([Python.h in $d])
 529         if test -r "$d/Python.h"; then
 530             AC_MSG_RESULT([found])
 531             PYTHON_INCLUDEDIR=$d
 532             break
 533         fi
 534         AC_MSG_RESULT([not found])
 535     done
 536     for d in \
 537         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 538         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 539         /usr/lib64/python$PYTHON_VERSION/site-packages \
 540         /usr/lib/python$PYTHON_VERSION/site-packages \
 541         /usr/local/lib/python$PYTHON_VERSION/site-packages
 542     do
 543         AC_MSG_CHECKING([for $d])
 544         if test -d "$d"; then
 545             AC_MSG_RESULT([found])
 546             PYTHON_SITE_PACKAGES=$d
 547             break
 548         fi
 549         AC_MSG_RESULT([not found])
 550     done
 551 fi
 552
 553 AC_SUBST(PYTHON_PREFIX)
 554 AC_SUBST(PYTHON_VERSION)
 555 AC_SUBST(PYTHON_INCLUDEDIR)
 556 AC_SUBST(PYTHON_SITE_PACKAGES)
 557
 558 AM_CONDITIONAL([HAVE_PYTHON],
 559     [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
 560
 561 dnl Check for Ruby and rake (optional, for Ruby bindings).
 562 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 563 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 564
 565 AM_CONDITIONAL([HAVE_RUBY],
 566     [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
 567
 568 dnl Check for Java.
 569 AC_ARG_WITH(java_home,
 570     [AS_HELP_STRING([--with-java-home],
 571         [specify path to JDK directory @<:@default=check@:>@])],
 572     [],
 573     [with_java_home=check])
 574
 575 if test "x$with_java_home" != "xno"; then
 576     if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
 577     then
 578         # Reject unsafe characters in $JAVA_HOME
 579         jh_lf='
 580 '
 581         case $JAVA_HOME in
 582           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 583             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 584         esac
 585         if test -d "$with_java_home"; then
 586             JAVA_HOME="$with_java_home"
 587         else
 588             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 589         fi
 590     fi
 591
 592     if test "x$JAVA_HOME" = "x"; then
 593         # Look for Java in some likely locations.
 594         for d in \
 595             /usr/lib/jvm/java \
 596             /usr/lib/jvm/java-6-openjdk
 597         do
 598             if test -d $d -a -f $d/bin/java; then
 599                 JAVA_HOME=$d
 600                 break
 601             fi
 602         done
 603     fi
 604
 605     if test "x$JAVA_HOME" != "x"; then
 606         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 607         if test ! -x "$JAVA_HOME/bin/java"; then
 608             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 609         else
 610             JAVA="$JAVA_HOME/bin/java"
 611         fi
 612         if test ! -x "$JAVA_HOME/bin/javac"; then
 613             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 614         else
 615             JAVAC="$JAVA_HOME/bin/javac"
 616         fi
 617         if test ! -x "$JAVA_HOME/bin/javah"; then
 618             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 619         else
 620             JAVAH="$JAVA_HOME/bin/javah"
 621         fi
 622         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 623             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 624         else
 625             JAVADOC="$JAVA_HOME/bin/javadoc"
 626         fi
 627         if test ! -x "$JAVA_HOME/bin/jar"; then
 628             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 629         else
 630             JAR="$JAVA_HOME/bin/jar"
 631         fi
 632         java_version=`$JAVA -version 2>&1 | grep "java version"`
 633         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 634
 635         dnl Find jni.h.
 636         AC_MSG_CHECKING([for jni.h])
 637         if test -f "$JAVA_HOME/include/jni.h"; then
 638             JNI_CFLAGS="-I$JAVA_HOME/include"
 639         else
 640             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 641                 head=`find $JAVA_HOME -name jni.h | tail -1`
 642                 dir=`dirname "$head"`
 643                 JNI_CFLAGS="-I$dir"
 644             else
 645                 AC_MSG_FAILURE([missing jni.h header file])
 646             fi
 647         fi
 648         AC_MSG_RESULT([$JNI_CFLAGS])
 649
 650         dnl Find jni_md.h.
 651         AC_MSG_CHECKING([for jni_md.h])
 652         case "$build_os" in
 653         *linux*) system="linux" ;;
 654         *SunOS*) system="solaris" ;;
 655         *cygwin*) system="win32" ;;
 656         *) system="$build_os" ;;
 657         esac
 658         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 659             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 660         else
 661             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 662                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 663                 dir=`dirname "$head"`
 664                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 665             else
 666                 AC_MSG_FAILURE([missing jni_md.h header file])
 667             fi
 668         fi
 669         AC_MSG_RESULT([$JNI_CFLAGS])
 670
 671         dnl Need extra version flag?
 672         AC_MSG_CHECKING([extra javac flags])
 673         JAVAC_FLAGS=
 674         javac_version=`$JAVAC -version 2>&1`
 675         case "$javac_version" in
 676         *Eclipse*)
 677             JAVAC_FLAGS="-source 1.5" ;;
 678         esac
 679         AC_MSG_RESULT([$JAVAC_FLAGS])
 680
 681         dnl Where to install jarfiles.
 682         dnl XXX How to make it configurable?
 683         JAR_INSTALL_DIR=\${prefix}/share/java
 684         JNI_INSTALL_DIR=\${libdir}
 685
 686         dnl JNI version.
 687         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 688         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 689         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 690         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 691     fi
 692 fi
 693
 694 AC_SUBST(JAVA_HOME)
 695 AC_SUBST(JAVA)
 696 AC_SUBST(JAVAC)
 697 AC_SUBST(JAVAH)
 698 AC_SUBST(JAVADOC)
 699 AC_SUBST(JAR)
 700 AC_SUBST(JNI_CFLAGS)
 701 AC_SUBST(JAVAC_FLAGS)
 702 AC_SUBST(JAR_INSTALL_DIR)
 703 AC_SUBST(JNI_INSTALL_DIR)
 704 AC_SUBST(JNI_VERSION_INFO)
 705
 706 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 707
 708 dnl Check for Haskell (GHC).
 709 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 710
 711 AM_CONDITIONAL([HAVE_HASKELL],
 712     [test "x$GHC" != "xno"])
 713
 714 dnl Check for Perl modules needed by virt-df, inspector, etc.
 715 missing_perl_modules=no
 716 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer Locale::TextDomain; do
 717     AC_MSG_CHECKING([for $pm])
 718     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 719         AC_MSG_RESULT([no])
 720         missing_perl_modules=yes
 721     else
 722         AC_MSG_RESULT([yes])
 723     fi
 724 done
 725 if test "x$missing_perl_modules" = "xyes"; then
 726     AC_MSG_WARN([some Perl modules required to compile virt-inspector and the other virt-* tools are missing])
 727 fi
 728
 729 AM_CONDITIONAL([HAVE_INSPECTOR],
 730     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 731 AM_CONDITIONAL([HAVE_TOOLS],
 732     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 733
 734 dnl Library versioning.
 735 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 736 AC_SUBST(MAX_PROC_NR)
 737
 738 dnl Run in subdirs.
 739 if test "x$enable_daemon" = "xyes"; then
 740     AC_CONFIG_SUBDIRS([daemon])
 741 fi
 742
 743 dnl Produce output files.
 744 AC_CONFIG_HEADERS([config.h])
 745 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 746 AC_CONFIG_FILES([appliance/update.sh],
 747                 [chmod +x appliance/update.sh])
 748 AC_CONFIG_FILES([appliance/supermin-split.sh],
 749                 [chmod +x appliance/supermin-split.sh])
 750 AC_CONFIG_FILES([appliance/supermin-make.sh],
 751                 [chmod +x appliance/supermin-make.sh])
 752 AC_CONFIG_FILES([Makefile
 753                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 754                  appliance/Makefile
 755                  appliance/debian/debirf.conf
 756                  images/Makefile
 757                  capitests/Makefile
 758                  regressions/Makefile
 759                  test-tool/Makefile
 760                  ocaml/Makefile ocaml/examples/Makefile
 761                  perl/Makefile
 762                  python/Makefile
 763                  ruby/Makefile ruby/Rakefile
 764                  java/Makefile
 765                  haskell/Makefile
 766                  inspector/Makefile
 767                  tools/Makefile
 768                  libguestfs.pc
 769                  gnulib/lib/Makefile
 770                  gnulib/tests/Makefile
 771                  fuse/Makefile
 772                  ocaml/META perl/Makefile.PL])
 773 AC_OUTPUT
 774
 775 dnl Produce summary.
 776 echo
 777 echo
 778 echo "------------------------------------------------------------"
 779 echo "Thank you for downloading $PACKAGE_STRING"
 780 echo
 781 echo "This is how we have configured the optional components for you today:"
 782 echo
 783 echo    "Daemon .............................. $enable_daemon"
 784 echo    "Appliance ........................... $enable_appliance"
 785 echo    "QEMU ................................ $QEMU"
 786 echo -n "OCaml bindings ...................... "
 787 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 788 echo -n "Perl bindings ....................... "
 789 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 790 echo -n "Python bindings ..................... "
 791 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 792 echo -n "Ruby bindings ....................... "
 793 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 794 echo -n "Java bindings ....................... "
 795 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 796 echo -n "Haskell bindings .................... "
 797 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 798 echo -n "virt-inspector ...................... "
 799 if test "x$HAVE_INSPECTOR_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 800 echo -n "virt-* tools ........................ "
 801 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 802 echo "supermin appliance .................. $enable_supermin"
 803 echo "FUSE filesystem ..................... $HAVE_FUSE"
 804 echo
 805 echo "If any optional component is configured 'no' when you expected 'yes'"
 806 echo "then you should check the preceeding messages."
 807 echo
 808 echo "Please report bugs back to the mailing list:"
 809 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 810 echo
 811 echo "Next you should type 'make' to build the package,"
 812 echo "then 'make check' to run the tests."
 813 echo "------------------------------------------------------------"