configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2010 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [2])
  21 m4_define([libguestfs_release], [13])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 dnl Stable or unstable version?
  41 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  42 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  43             AC_MSG_RESULT([stable])
  44        ],[
  45             AC_MSG_RESULT([unstable])
  46             AC_MSG_NOTICE([
  47 ***
  48 This is a development version of libguestfs. Some APIs may be unstable
  49 until they appear in a stable release of libguestfs (at which point
  50 the C API and ABI is guaranteed to remain stable forever).  For
  51 more information about stable and development branches of libguestfs
  52 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  53 ***])
  54        ])
  55
  56 dnl Die if the user tries to configure as root, see:
  57 dnl https://www.redhat.com/archives/libguestfs/2010-April/msg00098.html
  58 AC_MSG_CHECKING([if you are trying to configure as root])
  59 AS_IF([test "`id -u`" = 0 ],[
  60             AC_MSG_RESULT([yes])
  61             AC_MSG_FAILURE([Don't run './configure' or 'make' as root.])
  62       ],[
  63             AC_MSG_RESULT([no])
  64       ])
  65
  66 dnl Early gnulib initialization.
  67 gl_EARLY
  68 gl_INIT
  69
  70 AC_PROG_LIBTOOL
  71
  72 dnl Check for basic C environment.
  73 AC_PROG_CC_STDC
  74 AC_PROG_INSTALL
  75 AC_PROG_CPP
  76
  77 AC_ARG_ENABLE([gcc-warnings],
  78   [AS_HELP_STRING([--enable-gcc-warnings],
  79                   [turn on lots of GCC warnings (for developers)])],
  80   [case $enableval in
  81      yes|no) ;;
  82      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  83    esac
  84    gl_gcc_warnings=$enableval],
  85   [gl_gcc_warnings=no]
  86 )
  87
  88 if test "$gl_gcc_warnings" = yes; then
  89   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  90   AC_SUBST([WERROR_CFLAGS])
  91
  92   nw=
  93   # This, $nw, is the list of warnings we disable.
  94   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  95   nw="$nw -Waggregate-return"       # anachronistic
  96   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  97   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  98   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  99   nw="$nw -Wcast-qual"              # Too many warnings for now
 100   nw="$nw -Wconversion"             # Too many warnings for now
 101   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 102   nw="$nw -Wsign-conversion"        # Too many warnings for now
 103   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 104   nw="$nw -Wunreachable-code"       # Too many warnings for now
 105   nw="$nw -Wpadded"                 # Our structs are not padded
 106   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 107   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 108   nw="$nw -Wvla"                    # two warnings in mount.c
 109   # things I might fix soon:
 110   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 111   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 112   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 113   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 114                                     # was not possible, safe to ignore
 115   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 116   nw="$nw -Wlong-long"              # Allow long long since it's required
 117                                     # by Python, Ruby and xstrtoll.
 118
 119   gl_MANYWARN_ALL_GCC([ws])
 120   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 121   for w in $ws; do
 122     gl_WARN_ADD([$w])
 123   done
 124   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 125   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 126   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 127
 128   # In spite of excluding -Wlogical-op above, it is enabled, as of
 129   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 130   gl_WARN_ADD([-Wno-logical-op])
 131
 132   gl_WARN_ADD([-fdiagnostics-show-option])
 133
 134   AC_SUBST([WARN_CFLAGS])
 135
 136   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 137   AC_DEFINE([_FORTIFY_SOURCE], [2],
 138     [enable compile-time and run-time bounds-checking, and some warnings])
 139   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 140 fi
 141
 142 AC_C_PROTOTYPES
 143 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 144
 145 AM_PROG_CC_C_O
 146
 147 dnl Work out how to specify the linker script to the linker.
 148 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 149 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 150     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 151 AC_SUBST(VERSION_SCRIPT_FLAGS)
 152
 153 dnl Check support for 64 bit file offsets.
 154 AC_SYS_LARGEFILE
 155
 156 dnl Check sizeof long.
 157 AC_CHECK_SIZEOF([long])
 158
 159 dnl Define a C symbol for the host CPU architecture.
 160 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 161
 162 dnl Headers.
 163 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 164
 165 dnl Functions.
 166 AC_CHECK_FUNCS([posix_fallocate])
 167
 168 dnl Build the daemon?
 169 AC_MSG_CHECKING([if we should build the daemon])
 170 AC_ARG_ENABLE([daemon],
 171         [AS_HELP_STRING([--enable-daemon],
 172           [enable building the daemon @<:@default=yes@:>@])],
 173         [],
 174         [enable_daemon=yes])
 175 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 176 AC_MSG_RESULT([$enable_daemon])
 177
 178 dnl Build the appliance?
 179 AC_MSG_CHECKING([if we should build the appliance])
 180 AC_ARG_ENABLE([appliance],
 181         [AS_HELP_STRING([--enable-appliance],
 182           [enable building the appliance @<:@default=yes@:>@])],
 183         [],
 184         [enable_appliance=yes])
 185 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 186 AC_MSG_RESULT([$enable_appliance])
 187
 188 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 189 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 190 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 191 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 192         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 193         ])
 194
 195 dnl Check for pod2man and pod2text.
 196 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 197 test "x$POD2MAN" = "xno" &&
 198      AC_MSG_ERROR([pod2man must be installed])
 199 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 200 test "x$POD2TEXT" = "xno" &&
 201      AC_MSG_ERROR([pod2text must be installed])
 202
 203 dnl Check for mkisofs.
 204 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 205         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 206 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 207
 208 dnl Check for optional xmllint.
 209 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 210 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 211
 212 dnl Check for QEMU for running binaries on this $host_cpu, fall
 213 dnl back to basic 'qemu'.  Allow the user to override it.
 214 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
 215 AC_ARG_WITH([qemu],
 216         [AS_HELP_STRING([--with-qemu],
 217           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 218         [],
 219         [with_qemu="$default_qemu"])
 220 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 221         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 222 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 223 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 224
 225 dnl Check that the chosen qemu has vmchannel support or we can
 226 dnl fallback to null vmchannel (still using SLIRP).  See the
 227 dnl discussion in the README file.
 228 if test "x$vmchannel_test" != "xno"; then
 229     AC_MSG_CHECKING([for guestfwd support in $QEMU])
 230     if $QEMU -nographic --help | grep -sq guestfwd; then
 231         AC_MSG_RESULT([yes])
 232         vmchannel_guestfwd=guestfwd
 233     else
 234         AC_MSG_RESULT([no])
 235         # Note that this test must be conditional on the previous
 236         # test failing.  This is because recent qemu will throw
 237         # up an SDL window and hang if we try to run this test.
 238         AC_MSG_CHECKING([for "-net channel" (old guestfwd) support in $QEMU])
 239         vmchannelout=`$QEMU -nographic -net channel /dev/zero 2>&1 ||:`
 240         echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
 241         if echo "$vmchannelout" | grep -sq "vmchannel wrong port number" ; then
 242             AC_MSG_RESULT([yes])
 243             vmchannel_guestfwd=net_channel
 244         else
 245             AC_MSG_RESULT([no])
 246             vmchannel_guestfwd=no
 247         fi
 248     fi
 249
 250     AC_MSG_CHECKING([for "-net user" (user mode network) support in $QEMU])
 251     if $QEMU -nographic --help | grep -sq -- "-net user"; then
 252         AC_MSG_RESULT([yes])
 253         vmchannel_net_user=yes
 254     else
 255         AC_MSG_RESULT([no])
 256         vmchannel_net_user=no
 257     fi
 258
 259     if test "x$vmchannel_net_user" = "xno" -a "x$vmchannel_guestfwd" = "xno"; then
 260         AC_MSG_FAILURE(
 261 [I did not find user mode network or vmchannel support in
 262 $QEMU.
 263
 264 Either user mode networking or vmchannel support is vital for
 265 libguestfs to operate.
 266
 267 Please read the relevant section in the README file for more
 268 information about this.
 269
 270 You can override this test by setting the environment variable
 271 vmchannel_test=no  However if you don't have the right support
 272 in your qemu, then this just delays the pain.
 273
 274 If I am using the wrong qemu or you want to compile qemu from source
 275 and install it in another location, then you should configure with
 276 the --with-qemu option.
 277 ])
 278     fi
 279 fi
 280
 281 dnl Set drive interface used by the guestfs_add_drive{,_ro} calls
 282 dnl ('-drive ...,if=...' option to qemu).
 283 dnl
 284 dnl If you encounter performance problems with virtio (RHBZ#509383)
 285 dnl then try '--with-drive-if=ide'.
 286 AC_ARG_WITH([drive-if],
 287         [AS_HELP_STRING([--with-drive-if],
 288           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 289         [],
 290         [with_drive_if=virtio])
 291 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 292
 293 dnl Set interface used by the network.  Normally you should
 294 dnl leave this at the default (virtio) but you can use the
 295 dnl alternative (ne2k_pci) because of bugs in virtio networking
 296 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 297 AC_ARG_WITH([net-if],
 298         [AS_HELP_STRING([--with-net-if],
 299           [set default net driver (virtio|ne2k_pci) @<:@default=virtio@:>@])],
 300         [],
 301         [with_net_if=virtio])
 302 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 303
 304 dnl Check for febootstrap etc.
 305 if test "x$enable_appliance" = "xyes"; then
 306     AC_CHECK_PROG([FEBOOTSTRAP],
 307                   [febootstrap],[febootstrap],[no])
 308     if test "x$FEBOOTSTRAP" != "xno"; then
 309       AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 310                     [febootstrap-run],[febootstrap-run],[no])
 311       test "x$FEBOOTSTRAP_RUN" = "xno" && \
 312           AC_MSG_ERROR([febootstrap-run must be installed])
 313       AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 314                     [febootstrap-install],[febootstrap-install],[no])
 315       test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 316           AC_MSG_ERROR([febootstrap-install must be installed])
 317       AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 318                     [febootstrap-minimize],[febootstrap-minimize],[no])
 319       test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 320           AC_MSG_ERROR([febootstrap-minimize must be installed])
 321       AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 322                     [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 323       test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 324           AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 325
 326       dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 327       dnl of febootstrap, but old versions will fail with yum).
 328       AC_CHECK_PROG([FAKECHROOT],
 329                     [fakechroot],[fakechroot],[no])
 330       test "x$FAKECHROOT" = "xno" && \
 331          AC_MSG_ERROR([fakechroot must be installed])
 332
 333       AC_MSG_CHECKING([fakechroot version])
 334       fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 335       if test -z "$fakechroot_version"; then
 336         AC_MSG_RESULT([failed])
 337         AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 338       else
 339         AC_MSG_RESULT([$fakechroot_version])
 340         fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 341         fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 342         if test "$fakechroot_major" -lt 2 -o \
 343             \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
 344           AC_MSG_ERROR([fakechroot version must be >= 2.9])
 345         fi
 346       fi
 347       DIST="REDHAT"
 348     else
 349       # check for debootstrap and debirf
 350       AC_CHECK_PROG([DEBOOTSTRAP],
 351                     [debootstrap],[debootstrap],[no])
 352       test "x$DEBOOTSTRAP" = "xno" && \
 353           AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 354       AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 355       test "x$DEBIRF" = "xno" &&
 356           AC_MSG_ERROR([debirf must be installed])
 357       DIST="DEBIAN"
 358       case "$host_cpu" in
 359       *86)
 360           DEBIAN_KERNEL_ARCH=486
 361           ;;
 362       x86_64)
 363           DEBIAN_KERNEL_ARCH=amd64
 364           ;;
 365       *)
 366          DEBIAN_KERNEL_ARCH=$host_cpu
 367          ;;
 368       esac
 369       AC_SUBST(DEBIAN_KERNEL_ARCH)
 370     fi
 371     AC_SUBST(DIST)
 372
 373     dnl --with-updates to specify a Fedora updates repository.
 374     AC_ARG_WITH([updates],
 375         [AS_HELP_STRING([--with-updates],
 376           [set name of Fedora updates repository @<:@default=updates-released-f12@:>@])],
 377         [],
 378         [with_updates=updates-released-f12])
 379     UPDATES="$with_updates"
 380     AC_SUBST(UPDATES)
 381
 382     dnl --with-mirror to specify a local Fedora mirror.
 383     AC_ARG_WITH([mirror],
 384         [AS_HELP_STRING([--with-mirror],
 385           [set URI of a local Fedora mirror])],
 386         [],
 387         [with_mirror=])
 388     MIRROR="$with_mirror"
 389     AC_SUBST(MIRROR)
 390 fi
 391
 392 dnl --with-repo to specify a Fedora repository.
 393 AC_ARG_WITH([repo],
 394         [AS_HELP_STRING([--with-repo],
 395           [set name of Fedora repository @<:@default=fedora-13@:>@])],
 396         [],
 397         [with_repo=fedora-13])
 398 REPO="$with_repo"
 399 AC_SUBST(REPO)
 400 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 401
 402 dnl Build the supermin appliance?  Please see README file before
 403 dnl enabling this option.
 404 AC_ARG_ENABLE([supermin],
 405         [AS_HELP_STRING([--enable-supermin],
 406           [enable supermin appliance (see README) @<:@default=no@:>@])],
 407         [],
 408         [enable_supermin=no])
 409 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 410
 411 if test "x$enable_supermin" = "xyes"; then
 412     dnl Check febootstrap-to-initramfs accepts the --files option
 413     dnl (febootstrap >= 2.2).
 414     AC_MSG_CHECKING([for --files support in $FEBOOTSTRAP_TO_INITRAMFS])
 415     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 416     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 417     if ! echo "$out" | grep -sq -e --files ; then
 418         AC_MSG_RESULT([no])
 419         AC_MSG_FAILURE(
 420 [febootstrap-to-initramfs does not support the --files option.
 421
 422 To build the supermin appliance, you need to upgrade to the latest
 423 version of febootstrap.
 424 ])
 425     fi
 426     AC_MSG_RESULT([yes])
 427
 428     dnl Check febootstrap-to-initramfs accepts the --nocompress option
 429     dnl (febootstrap >= 2.3).
 430     AC_MSG_CHECKING([for --nocompress support in $FEBOOTSTRAP_TO_INITRAMFS])
 431     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 432     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 433     if ! echo "$out" | grep -sq -e --nocompress ; then
 434         AC_MSG_RESULT([no])
 435         AC_MSG_FAILURE(
 436 [febootstrap-to-initramfs does not support the --nocompress option.
 437
 438 To build the supermin appliance, you need to upgrade to the latest
 439 version of febootstrap.
 440 ])
 441     fi
 442     AC_MSG_RESULT([yes])
 443 fi
 444
 445 dnl Enable packet dumps when in verbose mode.  This generates lots
 446 dnl of debug info, only useful for people debugging the RPC mechanism.
 447 AC_ARG_ENABLE([packet-dump],
 448         [AS_HELP_STRING([--enable-packet-dump],
 449           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 450         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 451         [])
 452
 453 dnl Readline.
 454 AC_ARG_WITH([readline],
 455     [AS_HELP_STRING([--with-readline],
 456         [support fancy command line editing @<:@default=check@:>@])],
 457     [],
 458     [with_readline=check])
 459
 460 LIBREADLINE=
 461 AS_IF([test "x$with_readline" != xno],
 462     [AC_CHECK_LIB([readline], [main],
 463         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 464          AC_DEFINE([HAVE_LIBREADLINE], [1],
 465                    [Define if you have libreadline])
 466         ],
 467         [if test "x$with_readline" != xcheck; then
 468          AC_MSG_FAILURE(
 469              [--with-readline was given, but test for readline failed])
 470          fi
 471         ], -lncurses)
 472      old_LIBS="$LIBS"
 473      LIBS="$LIBS $LIBREADLINE"
 474      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 475      LIBS="$old_LIBS"
 476     ])
 477
 478 dnl For i18n.
 479 AM_GNU_GETTEXT([external])
 480 AM_GNU_GETTEXT_VERSION([0.17])
 481
 482 dnl hivex library (highly recommended).
 483 dnl This used to be a part of libguestfs, but was spun off into its
 484 dnl own separate upstream project in libguestfs 1.0.85.
 485 HAVE_HIVEX=yes
 486 PKG_CHECK_MODULES([HIVEX], [hivex],,[
 487         HAVE_HIVEX=no
 488         AC_MSG_WARN([Hivex library and headers are missing, so optional Windows Registry tools won't be built])])
 489 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HAVE_HIVEX" = "xyes"])
 490 AC_SUBST([HIVEX_CFLAGS])
 491 AC_SUBST([HIVEX_LIBS])
 492
 493 dnl FUSE is optional to build the FUSE module.
 494 HAVE_FUSE=yes
 495 PKG_CHECK_MODULES([FUSE],[fuse],,[
 496         HAVE_FUSE=no
 497         AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])
 498 AM_CONDITIONAL([HAVE_FUSE],[test "x$HAVE_FUSE" = "xyes"])
 499
 500 dnl Check for OCaml (optional, for OCaml bindings).
 501 AC_PROG_OCAML
 502 AC_PROG_FINDLIB
 503 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
 504
 505 dnl Optional xml-light for running the generator.
 506 OCAML_PKG_xml_light=no
 507 if test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"; then
 508     AC_CHECK_OCAML_PKG([xml-light])
 509 fi
 510 AM_CONDITIONAL([HAVE_XML_LIGHT],[test "x$OCAML_PKG_xml_light" != "xno"])
 511
 512 dnl Build the OCaml viewer example.  This has a lengthy list of
 513 dnl dependencies and we don't attempt to detect them all.  Read
 514 dnl the top of ocaml/examples/viewer.ml before enabling this.
 515 AC_ARG_ENABLE([ocaml-viewer],
 516         [AS_HELP_STRING([--enable-ocaml-viewer],
 517           [enable OCaml viewer (see ocaml/examples) @<:@default=no@:>@])],
 518         [],
 519         [enable_ocaml_viewer=no])
 520 AM_CONDITIONAL([BUILD_OCAML_VIEWER],[test "x$enable_ocaml_viewer" = "xyes"])
 521
 522 dnl Check for Perl (optional, for Perl bindings).
 523 dnl XXX This isn't quite right, we should check for Perl devel library.
 524 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 525
 526 dnl Check for Perl modules that must be present to compile and
 527 dnl test the Perl bindings.
 528 missing_perl_modules=no
 529 for pm in Test::More ExtUtils::MakeMaker; do
 530     AC_MSG_CHECKING([for $pm])
 531     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 532         AC_MSG_RESULT([no])
 533         missing_perl_modules=yes
 534     else
 535         AC_MSG_RESULT([yes])
 536     fi
 537 done
 538 if test "x$missing_perl_modules" = "xyes"; then
 539     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 540 fi
 541
 542 AM_CONDITIONAL([HAVE_PERL],
 543     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 544
 545 dnl Check for Python (optional, for Python bindings).
 546 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 547
 548 PYTHON_PREFIX=
 549 PYTHON_VERSION=
 550 PYTHON_INCLUDEDIR=
 551 PYTHON_SITE_PACKAGES=
 552
 553 if test "x$PYTHON" != "xno"; then
 554     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 555     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 556     for d in \
 557         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 558         /usr/include/python$PYTHON_VERSION \
 559         /usr/local/include/python$PYTHON_VERSION
 560     do
 561         AC_MSG_CHECKING([Python.h in $d])
 562         if test -r "$d/Python.h"; then
 563             AC_MSG_RESULT([found])
 564             PYTHON_INCLUDEDIR=$d
 565             break
 566         fi
 567         AC_MSG_RESULT([not found])
 568     done
 569     for d in \
 570         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 571         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 572         /usr/lib64/python$PYTHON_VERSION/site-packages \
 573         /usr/lib/python$PYTHON_VERSION/site-packages \
 574         /usr/local/lib/python$PYTHON_VERSION/site-packages
 575     do
 576         AC_MSG_CHECKING([for $d])
 577         if test -d "$d"; then
 578             AC_MSG_RESULT([found])
 579             PYTHON_SITE_PACKAGES=$d
 580             break
 581         fi
 582         AC_MSG_RESULT([not found])
 583     done
 584 fi
 585
 586 AC_SUBST(PYTHON_PREFIX)
 587 AC_SUBST(PYTHON_VERSION)
 588 AC_SUBST(PYTHON_INCLUDEDIR)
 589 AC_SUBST(PYTHON_SITE_PACKAGES)
 590
 591 AM_CONDITIONAL([HAVE_PYTHON],
 592     [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
 593
 594 dnl Check for Ruby and rake (optional, for Ruby bindings).
 595 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 596 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 597
 598 AM_CONDITIONAL([HAVE_RUBY],
 599     [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
 600
 601 dnl Check for Java.
 602 AC_ARG_WITH(java_home,
 603     [AS_HELP_STRING([--with-java-home],
 604         [specify path to JDK directory @<:@default=check@:>@])],
 605     [],
 606     [with_java_home=check])
 607
 608 if test "x$with_java_home" != "xno"; then
 609     if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
 610     then
 611         # Reject unsafe characters in $JAVA_HOME
 612         jh_lf='
 613 '
 614         case $JAVA_HOME in
 615           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 616             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 617         esac
 618         if test -d "$with_java_home"; then
 619             JAVA_HOME="$with_java_home"
 620         else
 621             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 622         fi
 623     fi
 624
 625     if test "x$JAVA_HOME" = "x"; then
 626         # Look for Java in some likely locations.
 627         for d in \
 628             /usr/lib/jvm/java \
 629             /usr/lib/jvm/java-6-openjdk
 630         do
 631             if test -d $d -a -f $d/bin/java; then
 632                 JAVA_HOME=$d
 633                 break
 634             fi
 635         done
 636     fi
 637
 638     if test "x$JAVA_HOME" != "x"; then
 639         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 640         if test ! -x "$JAVA_HOME/bin/java"; then
 641             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 642         else
 643             JAVA="$JAVA_HOME/bin/java"
 644         fi
 645         if test ! -x "$JAVA_HOME/bin/javac"; then
 646             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 647         else
 648             JAVAC="$JAVA_HOME/bin/javac"
 649         fi
 650         if test ! -x "$JAVA_HOME/bin/javah"; then
 651             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 652         else
 653             JAVAH="$JAVA_HOME/bin/javah"
 654         fi
 655         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 656             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 657         else
 658             JAVADOC="$JAVA_HOME/bin/javadoc"
 659         fi
 660         if test ! -x "$JAVA_HOME/bin/jar"; then
 661             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 662         else
 663             JAR="$JAVA_HOME/bin/jar"
 664         fi
 665         java_version=`$JAVA -version 2>&1 | grep "java version"`
 666         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 667
 668         dnl Find jni.h.
 669         AC_MSG_CHECKING([for jni.h])
 670         if test -f "$JAVA_HOME/include/jni.h"; then
 671             JNI_CFLAGS="-I$JAVA_HOME/include"
 672         else
 673             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 674                 head=`find $JAVA_HOME -name jni.h | tail -1`
 675                 dir=`dirname "$head"`
 676                 JNI_CFLAGS="-I$dir"
 677             else
 678                 AC_MSG_FAILURE([missing jni.h header file])
 679             fi
 680         fi
 681         AC_MSG_RESULT([$JNI_CFLAGS])
 682
 683         dnl Find jni_md.h.
 684         AC_MSG_CHECKING([for jni_md.h])
 685         case "$build_os" in
 686         *linux*) system="linux" ;;
 687         *SunOS*) system="solaris" ;;
 688         *cygwin*) system="win32" ;;
 689         *) system="$build_os" ;;
 690         esac
 691         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 692             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 693         else
 694             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 695                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 696                 dir=`dirname "$head"`
 697                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 698             else
 699                 AC_MSG_FAILURE([missing jni_md.h header file])
 700             fi
 701         fi
 702         AC_MSG_RESULT([$JNI_CFLAGS])
 703
 704         dnl Need extra version flag?
 705         AC_MSG_CHECKING([extra javac flags])
 706         JAVAC_FLAGS=
 707         javac_version=`$JAVAC -version 2>&1`
 708         case "$javac_version" in
 709         *Eclipse*)
 710             JAVAC_FLAGS="-source 1.5" ;;
 711         esac
 712         AC_MSG_RESULT([$JAVAC_FLAGS])
 713
 714         dnl Where to install jarfiles.
 715         dnl XXX How to make it configurable?
 716         JAR_INSTALL_DIR=\${prefix}/share/java
 717         JNI_INSTALL_DIR=\${libdir}
 718
 719         dnl JNI version.
 720         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 721         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 722         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 723         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 724     fi
 725 fi
 726
 727 AC_SUBST(JAVA_HOME)
 728 AC_SUBST(JAVA)
 729 AC_SUBST(JAVAC)
 730 AC_SUBST(JAVAH)
 731 AC_SUBST(JAVADOC)
 732 AC_SUBST(JAR)
 733 AC_SUBST(JNI_CFLAGS)
 734 AC_SUBST(JAVAC_FLAGS)
 735 AC_SUBST(JAR_INSTALL_DIR)
 736 AC_SUBST(JNI_INSTALL_DIR)
 737 AC_SUBST(JNI_VERSION_INFO)
 738
 739 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 740
 741 dnl Check for Haskell (GHC).
 742 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 743
 744 AM_CONDITIONAL([HAVE_HASKELL],
 745     [test "x$GHC" != "xno"])
 746
 747 dnl Check for Perl modules needed by virt-df, inspector, etc.
 748 missing_perl_modules=no
 749 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer Locale::TextDomain Win::Hivex Win::Hivex::Regedit; do
 750     AC_MSG_CHECKING([for $pm])
 751     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 752         AC_MSG_RESULT([no])
 753         missing_perl_modules=yes
 754     else
 755         AC_MSG_RESULT([yes])
 756     fi
 757 done
 758 if test "x$missing_perl_modules" = "xyes"; then
 759     AC_MSG_WARN([some Perl modules required to compile virt-inspector and the other virt-* tools are missing])
 760 fi
 761
 762 AM_CONDITIONAL([HAVE_INSPECTOR],
 763     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 764 AM_CONDITIONAL([HAVE_TOOLS],
 765     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 766
 767 dnl Library versioning.
 768 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 769 AC_SUBST(MAX_PROC_NR)
 770
 771 dnl Run in subdirs.
 772 if test "x$enable_daemon" = "xyes"; then
 773     AC_CONFIG_SUBDIRS([daemon])
 774 fi
 775
 776 dnl Produce output files.
 777 AC_CONFIG_HEADERS([config.h])
 778 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 779 AC_CONFIG_FILES([appliance/update.sh],
 780                 [chmod +x appliance/update.sh])
 781 AC_CONFIG_FILES([appliance/supermin-split.sh],
 782                 [chmod +x appliance/supermin-split.sh])
 783 AC_CONFIG_FILES([appliance/supermin-make.sh],
 784                 [chmod +x appliance/supermin-make.sh])
 785 AC_CONFIG_FILES([Makefile
 786                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 787                  appliance/Makefile
 788                  appliance/debian/debirf.conf
 789                  images/Makefile
 790                  capitests/Makefile
 791                  regressions/Makefile
 792                  test-tool/Makefile
 793                  ocaml/Makefile ocaml/examples/Makefile
 794                  perl/Makefile
 795                  python/Makefile
 796                  ruby/Makefile ruby/Rakefile
 797                  java/Makefile
 798                  haskell/Makefile
 799                  inspector/Makefile
 800                  tools/Makefile
 801                  libguestfs.pc
 802                  gnulib/lib/Makefile
 803                  gnulib/tests/Makefile
 804                  fuse/Makefile
 805                  ocaml/META perl/Makefile.PL])
 806 AC_OUTPUT
 807
 808 dnl Produce summary.
 809 echo
 810 echo
 811 echo "------------------------------------------------------------"
 812 echo "Thank you for downloading $PACKAGE_STRING"
 813 echo
 814 echo "This is how we have configured the optional components for you today:"
 815 echo
 816 echo    "Daemon .............................. $enable_daemon"
 817 echo    "Appliance ........................... $enable_appliance"
 818 echo    "QEMU ................................ $QEMU"
 819 echo -n "OCaml bindings ...................... "
 820 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 821 echo -n "Perl bindings ....................... "
 822 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 823 echo -n "Python bindings ..................... "
 824 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 825 echo -n "Ruby bindings ....................... "
 826 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 827 echo -n "Java bindings ....................... "
 828 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 829 echo -n "Haskell bindings .................... "
 830 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 831 echo -n "virt-inspector ...................... "
 832 if test "x$HAVE_INSPECTOR_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 833 echo -n "virt-* tools ........................ "
 834 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 835 echo "supermin appliance .................. $enable_supermin"
 836 echo "FUSE filesystem ..................... $HAVE_FUSE"
 837 echo
 838 echo "If any optional component is configured 'no' when you expected 'yes'"
 839 echo "then you should check the preceeding messages."
 840 echo
 841 echo "Please report bugs back to the mailing list:"
 842 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 843 echo
 844 echo "Next you should type 'make' to build the package,"
 845 echo "then 'make check' to run the tests."
 846 echo "------------------------------------------------------------"