configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2011 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [11])
  21 m4_define([libguestfs_release], [20])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 dnl Stable or unstable version?
  41 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  42 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  43             AC_MSG_RESULT([stable])
  44        ],[
  45             AC_MSG_RESULT([unstable])
  46             AC_MSG_NOTICE([
  47 ***
  48 This is a development version of libguestfs. Some APIs may be unstable
  49 until they appear in a stable release of libguestfs (at which point
  50 the C API and ABI is guaranteed to remain stable forever).  For
  51 more information about stable and development branches of libguestfs
  52 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  53 ***])
  54        ])
  55
  56 dnl Early gnulib initialization.
  57 gl_EARLY
  58 gl_INIT
  59
  60 AC_PROG_LIBTOOL
  61
  62 dnl Check for basic C environment.
  63 AC_PROG_CC_STDC
  64 AC_PROG_INSTALL
  65 AC_PROG_CPP
  66
  67 AC_ARG_ENABLE([gcc-warnings],
  68   [AS_HELP_STRING([--enable-gcc-warnings],
  69                   [turn on lots of GCC warnings (for developers)])],
  70   [case $enableval in
  71      yes|no) ;;
  72      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  73    esac
  74    gl_gcc_warnings=$enableval],
  75   [gl_gcc_warnings=no]
  76 )
  77
  78 if test "$gl_gcc_warnings" = yes; then
  79   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  80   AC_SUBST([WERROR_CFLAGS])
  81
  82   nw=
  83   # This, $nw, is the list of warnings we disable.
  84   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  85   nw="$nw -Waggregate-return"       # anachronistic
  86   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  87   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  88   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  89   nw="$nw -Wcast-qual"              # Too many warnings for now
  90   nw="$nw -Wconversion"             # Too many warnings for now
  91   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  92   nw="$nw -Wsign-conversion"        # Too many warnings for now
  93   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  94   nw="$nw -Wunreachable-code"       # Too many warnings for now
  95   nw="$nw -Wpadded"                 # Our structs are not padded
  96   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  97   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  98   nw="$nw -Wvla"                    # two warnings in mount.c
  99   # things I might fix soon:
 100   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 101   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 102   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 103   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 104                                     # was not possible, safe to ignore
 105   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 106   nw="$nw -Wlong-long"              # Allow long long since it's required
 107                                     # by Python, Ruby and xstrtoll.
 108   nw="$nw -Wstack-protector"        # Don't warn about stack-protector
 109                                     # failures (seen on Ubuntu).
 110   nw="$nw -Wmissing-noreturn"       # Don't warn about missed noreturn funcs
 111                                     # (seen on Ubuntu).
 112
 113   gl_MANYWARN_ALL_GCC([ws])
 114   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 115   for w in $ws; do
 116     gl_WARN_ADD([$w])
 117   done
 118   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 119   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 120   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 121
 122   # In spite of excluding -Wlogical-op above, it is enabled, as of
 123   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 124   gl_WARN_ADD([-Wno-logical-op])
 125
 126   # Work around warning in src/inspect.c.  This seems to be a bug in gcc 4.5.1.
 127   gl_WARN_ADD([-Wno-strict-overflow])
 128
 129   gl_WARN_ADD([-fdiagnostics-show-option])
 130
 131   AC_SUBST([WARN_CFLAGS])
 132
 133   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 134   AC_DEFINE([_FORTIFY_SOURCE], [2],
 135     [enable compile-time and run-time bounds-checking, and some warnings])
 136   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 137 fi
 138
 139 AC_C_PROTOTYPES
 140 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 141
 142 AM_PROG_CC_C_O
 143
 144 dnl Work out how to specify the linker script to the linker.
 145 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 146 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 147     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 148 AC_SUBST(VERSION_SCRIPT_FLAGS)
 149
 150 dnl Check support for 64 bit file offsets.
 151 AC_SYS_LARGEFILE
 152
 153 dnl Check sizeof long.
 154 AC_CHECK_SIZEOF([long])
 155
 156 dnl Define a C symbol for the host CPU architecture.
 157 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 158
 159 dnl Headers.
 160 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 161
 162 dnl Functions.
 163 AC_CHECK_FUNCS([futimens posix_fallocate])
 164
 165 dnl Build the daemon?
 166 AC_MSG_CHECKING([if we should build the daemon])
 167 AC_ARG_ENABLE([daemon],
 168         [AS_HELP_STRING([--enable-daemon],
 169           [enable building the daemon @<:@default=yes@:>@])],
 170         [],
 171         [enable_daemon=yes])
 172 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 173 AC_MSG_RESULT([$enable_daemon])
 174
 175 dnl Build the appliance?
 176 AC_MSG_CHECKING([if we should build the appliance])
 177 AC_ARG_ENABLE([appliance],
 178         [AS_HELP_STRING([--enable-appliance],
 179           [enable building the appliance @<:@default=yes@:>@])],
 180         [],
 181         [enable_appliance=yes])
 182 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 183 AC_MSG_RESULT([$enable_appliance])
 184
 185 if test "x$enable_appliance" = "xyes"; then
 186     dnl Check for febootstrap >= 3.0
 187     AC_CHECK_PROG([FEBOOTSTRAP],
 188                   [febootstrap],[febootstrap],[no])
 189     test "x$FEBOOTSTRAP" = "xno" &&
 190         AC_MSG_ERROR([febootstrap must be installed])
 191     dnl febootstrap 2.x did not support the --version parameter
 192     $FEBOOTSTRAP --version >/dev/null 2>&1 ||
 193         AC_MSG_ERROR([febootstrap >= 3.0 must be installed, your version is too old])
 194
 195     dnl Pass a febootstrap --yum-config option.
 196     AC_MSG_CHECKING([if user requested febootstrap --yum-config option])
 197     AC_ARG_WITH([febootstrap-yum-config],
 198         [AS_HELP_STRING([--with-febootstrap-yum-config=FILE],
 199           [pass febootstrap --yum-config option @<:@default=no@:>@])],
 200         [FEBOOTSTRAP_YUM_CONFIG="$withval"],
 201         [FEBOOTSTRAP_YUM_CONFIG=no])
 202     AC_MSG_RESULT([$FEBOOTSTRAP_YUM_CONFIG])
 203     AC_SUBST([FEBOOTSTRAP_YUM_CONFIG])
 204
 205     dnl Which distro?
 206     dnl
 207     dnl This used to be Very Important but is now just used to select
 208     dnl which packages to install in the appliance, since the package
 209     dnl names vary slightly across distros.  (See
 210     dnl appliance/packagelist.in and appliance/excludelist.in)
 211     AC_MSG_CHECKING([which Linux distro for package names])
 212     DISTRO=REDHAT
 213     if test -f /etc/debian_version; then
 214         DISTRO=DEBIAN
 215         if grep -q 'DISTRIB_ID=Ubuntu' /etc/lsb-release 2>/dev/null; then
 216             DISTRO=UBUNTU
 217         fi
 218     fi
 219     if test -f /etc/arch-release; then
 220         DISTRO=ARCHLINUX
 221     fi
 222     AC_MSG_RESULT([$DISTRO])
 223     AC_SUBST([DISTRO])
 224 fi
 225
 226 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 227 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 228 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 229 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 230         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 231         ])
 232
 233 dnl Check for cpio which isn't in the default Pardus install amazingly.
 234 AC_CHECK_PROG([CPIO],[cpio],[cpio],[no])
 235 test "x$CPIO" = "xno" &&
 236      AC_MSG_ERROR([cpio must be installed])
 237
 238 dnl Check for gperf.
 239 AC_CHECK_PROG([GPERF],[gperf],[gperf],[no])
 240 test "x$GPERF" = "xno" &&
 241      AC_MSG_ERROR([gperf must be installed])
 242
 243 dnl Check for pod2man, pod2text, pod2html.
 244 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 245 test "x$POD2MAN" = "xno" &&
 246      AC_MSG_ERROR([pod2man must be installed])
 247 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 248 test "x$POD2TEXT" = "xno" &&
 249      AC_MSG_ERROR([pod2text must be installed])
 250 AC_CHECK_PROG([POD2HTML],[pod2html],[pod2html],[no])
 251 test "x$POD2HTML" = "xno" &&
 252      AC_MSG_ERROR([pod2html must be installed])
 253
 254 dnl Check if pod2man, pod2text take --stderr and -u options (not in RHEL 5).
 255 AC_MSG_CHECKING([if pod2man takes --stderr option])
 256 if "$POD2MAN" --stderr >/dev/null 2>&1; then
 257     AC_MSG_RESULT([yes])
 258     POD2_STDERR_OPTION="--stderr"
 259 else
 260     AC_MSG_RESULT([no])
 261     POD2_STDERR_OPTION=""
 262 fi
 263 AC_SUBST([POD2_STDERR_OPTION])
 264
 265 AC_MSG_CHECKING([if pod2man takes -u option])
 266 if "$POD2MAN" -u >/dev/null 2>&1; then
 267     AC_MSG_RESULT([yes])
 268     POD2_UTF8_OPTION="-u"
 269 else
 270     AC_MSG_RESULT([no])
 271     POD2_UTF8_OPTION=""
 272 fi
 273 AC_SUBST([POD2_UTF8_OPTION])
 274
 275 dnl Check for genisoimage.
 276 AC_PATH_PROGS([GENISOIMAGE],[genisoimage],[no],
 277         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 278 test "x$GENISOIMAGE" = "xno" && AC_MSG_ERROR([genisoimage must be installed])
 279
 280 dnl Check for optional xmllint.
 281 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 282 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 283
 284 dnl po4a for translating man pages and POD files (optional).
 285 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
 286 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
 287
 288 dnl Check for db_dump, db_load (optional).
 289 AC_CHECK_PROGS([DB_DUMP],
 290                [db_dump db4_dump db4.8_dump db4.7_dump db4.6_dump],[no])
 291 AC_CHECK_PROGS([DB_LOAD],
 292                [db_load db4_load db4.8_load db4.7_load db4.6_load],[no])
 293 if test "x$DB_DUMP" != "xno"; then
 294     AC_DEFINE_UNQUOTED([DB_DUMP],["$DB_DUMP"],[Name of db_dump program.])
 295 fi
 296 if test "x$DB_LOAD" != "xno"; then
 297     AC_DEFINE_UNQUOTED([DB_LOAD],["$DB_LOAD"],[Name of db_load program.])
 298 fi
 299
 300 dnl Check for QEMU for running binaries on this $host_cpu, fall
 301 dnl back to basic 'qemu'.  Allow the user to override it.
 302 default_qemu="qemu-kvm kvm qemu-system-$host_cpu qemu"
 303 AC_ARG_WITH([qemu],
 304         [AS_HELP_STRING([--with-qemu],
 305           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 306         [],
 307         [with_qemu="$default_qemu"])
 308 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 309         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 310 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 311 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 312
 313 dnl Check that the chosen qemu has virtio-serial support.
 314 if test "x$vmchannel_test" != "xno"; then
 315     AC_MSG_CHECKING([that $QEMU -help works])
 316     if $QEMU -help > /dev/null 2>&1; then
 317         AC_MSG_RESULT([yes])
 318     else
 319         AC_MSG_RESULT([no])
 320         AC_MSG_FAILURE(
 321 [$QEMU -help: command failed.
 322
 323 This could be a very old version of qemu, or qemu might not be
 324 working.
 325 ])
 326     fi
 327
 328     AC_MSG_CHECKING([for virtio-serial support in $QEMU])
 329     if $QEMU -nographic -device \? 2>&1 | grep -sq virtio-serial; then
 330         AC_MSG_RESULT([yes])
 331     else
 332         AC_MSG_RESULT([no])
 333         AC_MSG_FAILURE(
 334 [I did not find virtio-serial support in
 335 $QEMU.
 336
 337 virtio-serial support in qemu or KVM is essential for libguestfs
 338 to operate.
 339
 340 Usually this means that you have to install a newer version of qemu
 341 and/or KVM.  Please read the relevant section in the README file for
 342 more information about this.
 343
 344 You can override this test by setting the environment variable
 345 vmchannel_test=no  However if you don't have the right support
 346 in your qemu, then this just delays the pain.
 347
 348 If I am using the wrong qemu or you want to compile qemu from source
 349 and install it in another location, then you should configure with
 350 the --with-qemu option.
 351 ])
 352     fi
 353 fi
 354
 355 dnl Set default drive interface used by the guestfs_add_drive_opts call
 356 dnl ('-drive ...,if=...' option to qemu).
 357 dnl
 358 dnl If you encounter performance problems with virtio (RHBZ#509383)
 359 dnl then try '--with-drive-if=ide'.
 360 AC_ARG_WITH([drive-if],
 361         [AS_HELP_STRING([--with-drive-if],
 362           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 363         [],
 364         [with_drive_if=virtio])
 365 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 366
 367 dnl Set interface used by the network.  Normally you should
 368 dnl leave this at the default (virtio-net-pci) but you can use the
 369 dnl alternative (ne2k_pci) because of bugs in virtio networking
 370 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 371 AC_ARG_WITH([net-if],
 372         [AS_HELP_STRING([--with-net-if],
 373           [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
 374         [],
 375         [with_net_if=virtio-net-pci])
 376 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 377
 378 dnl Enable packet dumps when in verbose mode.  This generates lots
 379 dnl of debug info, only useful for people debugging the RPC mechanism.
 380 AC_ARG_ENABLE([packet-dump],
 381         [AS_HELP_STRING([--enable-packet-dump],
 382           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 383         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 384         [])
 385
 386 dnl Readline.
 387 AC_ARG_WITH([readline],
 388     [AS_HELP_STRING([--with-readline],
 389         [support fancy command line editing @<:@default=check@:>@])],
 390     [],
 391     [with_readline=check])
 392
 393 LIBREADLINE=
 394 AS_IF([test "x$with_readline" != xno],
 395     [AC_CHECK_LIB([readline], [main],
 396         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 397          AC_DEFINE([HAVE_LIBREADLINE], [1],
 398                    [Define if you have libreadline])
 399         ],
 400         [if test "x$with_readline" != xcheck; then
 401          AC_MSG_FAILURE(
 402              [--with-readline was given, but test for readline failed])
 403          fi
 404         ], -lncurses)
 405      old_LIBS="$LIBS"
 406      LIBS="$LIBS $LIBREADLINE"
 407      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 408      LIBS="$old_LIBS"
 409     ])
 410
 411 dnl For i18n.
 412 AM_GNU_GETTEXT([external])
 413
 414 dnl libmagic (highly recommended)
 415 AC_CHECK_LIB([magic],[magic_file],
 416         [AC_CHECK_HEADER([magic.h],
 417                 [AC_SUBST([MAGIC_LIBS], ["-lmagic"])
 418                  AC_DEFINE([HAVE_LIBMAGIC],[1],[libmagic found at compile time.])
 419                 ], [])
 420         ],
 421         [AC_MSG_WARN([libmagic not found, some core features will be disabled])])
 422
 423 dnl Check for PCRE (highly recommended)
 424 PKG_CHECK_MODULES([PCRE], [libpcre],
 425         [AC_SUBST([PCRE_CFLAGS])
 426          AC_SUBST([PCRE_LIBS])
 427          AC_DEFINE([HAVE_PCRE],[1],[PCRE found at compile time.])
 428         ],
 429         [AC_MSG_WARN([PCRE not found, some core features will be disabled])])
 430
 431 dnl libvirt (highly recommended)
 432 PKG_CHECK_MODULES([LIBVIRT], [libvirt],
 433         [AC_SUBST([LIBVIRT_CFLAGS])
 434          AC_SUBST([LIBVIRT_LIBS])
 435          AC_DEFINE([HAVE_LIBVIRT],[1],[libvirt found at compile time.])
 436         ],
 437         [AC_MSG_WARN([libvirt not found, some core features will be disabled])])
 438 AM_CONDITIONAL([HAVE_LIBVIRT],[test "x$LIBVIRT_LIBS" != "x"])
 439
 440 dnl libxml2 (highly recommended)
 441 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0],
 442         [AC_SUBST([LIBXML2_CFLAGS])
 443          AC_SUBST([LIBXML2_LIBS])
 444          AC_DEFINE([HAVE_LIBXML2],[1],[libxml2 found at compile time.])
 445         ],
 446         [AC_MSG_WARN([libxml2 not found, some core features will be disabled])])
 447 AM_CONDITIONAL([HAVE_LIBXML2],[test "x$LIBXML2_LIBS" != "x"])
 448
 449 dnl libconfig (highly recommended)
 450 PKG_CHECK_MODULES([LIBCONFIG], [libconfig],
 451         [AC_SUBST([LIBCONFIG_CFLAGS])
 452          AC_SUBST([LIBCONFIG_LIBS])
 453          AC_DEFINE([HAVE_LIBCONFIG],[1],[libconfig found at compile time.])
 454         ],
 455         [AC_MSG_WARN([libconfig not found, some features will be disabled])])
 456 AM_CONDITIONAL([HAVE_LIBCONFIG],[test "x$LIBCONFIG_LIBS" != "x"])
 457
 458 dnl hivex library (highly recommended)
 459 dnl This used to be a part of libguestfs, but was spun off into its
 460 dnl own separate upstream project in libguestfs 1.0.85.
 461 PKG_CHECK_MODULES([HIVEX], [hivex],
 462         [AC_SUBST([HIVEX_CFLAGS])
 463          AC_SUBST([HIVEX_LIBS])
 464          AC_DEFINE([HAVE_HIVEX],[1],[hivex library found at compile time.])
 465         ],
 466         [AC_MSG_WARN([hivex not found, some core features will be disabled])])
 467 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HIVEX_LIBS" != "x"])
 468
 469 dnl FUSE is optional to build the FUSE module.
 470 AC_ARG_ENABLE([fuse],
 471         AS_HELP_STRING([--disable-fuse], [Disable FUSE (guestmount) support]),
 472         [],
 473         [enable_fuse=yes])
 474 AS_IF([test "x$enable_fuse" != "xno"],
 475         [PKG_CHECK_MODULES([FUSE],[fuse],,[
 476                 enable_fuse=no
 477                 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])])
 478 AM_CONDITIONAL([HAVE_FUSE],[test "x$enable_fuse" != "xno"])
 479
 480 dnl Check for OCaml (optional, for OCaml bindings).
 481 OCAMLC=no
 482 OCAMLFIND=no
 483 AC_ARG_ENABLE([ocaml],
 484         AS_HELP_STRING([--disable-ocaml], [Disable OCaml language bindings]),
 485         [],
 486         [enable_ocaml=yes])
 487 AS_IF([test "x$enable_ocaml" != "xno"],
 488         [dnl OCAMLC and OCAMLFIND have to be unset first, otherwise
 489          dnl AC_CHECK_TOOL (inside AC_PROG_OCAML) will not look.
 490          OCAMLC=
 491          OCAMLFIND=
 492          AC_PROG_OCAML
 493          AC_PROG_FINDLIB
 494
 495          AS_IF([test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"],
 496                 [AC_CHECK_OCAML_PKG([pcre])])
 497         ])
 498 AM_CONDITIONAL([HAVE_OCAML],
 499                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
 500 AM_CONDITIONAL([HAVE_OCAML_PCRE],
 501                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno" && test "x$OCAML_PKG_pcre" != "xno"])
 502 AM_CONDITIONAL([HAVE_OCAMLDOC],
 503                [test "x$OCAMLDOC" != "xno"])
 504
 505 dnl Check for Perl (optional, for Perl bindings).
 506 PERL=no
 507 AC_ARG_ENABLE([perl],
 508         AS_HELP_STRING([--disable-perl], [Disable Perl language bindings]),
 509         [],
 510         [enable_perl=yes])
 511 AS_IF([test "x$enable_perl" != "xno"],
 512         [
 513         PERL=
 514         AC_CHECK_PROG([PERL],[perl],[perl],[no])
 515
 516         dnl Check for Perl modules that must be present to compile and
 517         dnl test the Perl bindings.
 518         missing_perl_modules=no
 519         for pm in Test::More ExtUtils::MakeMaker; do
 520             AC_MSG_CHECKING([for $pm])
 521             if ! perl -M$pm -e1 >/dev/null 2>&1; then
 522                 AC_MSG_RESULT([no])
 523                 missing_perl_modules=yes
 524             else
 525                 AC_MSG_RESULT([yes])
 526             fi
 527         done
 528         if test "x$missing_perl_modules" = "xyes"; then
 529             AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 530         fi
 531         ])
 532 AM_CONDITIONAL([HAVE_PERL],
 533     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 534
 535 dnl Check for Python (optional, for Python bindings).
 536 PYTHON_PREFIX=
 537 PYTHON_VERSION=
 538 PYTHON_INCLUDEDIR=
 539 PYTHON_INSTALLDIR=
 540
 541 AC_ARG_ENABLE([python],
 542         AS_HELP_STRING([--disable-python], [Disable Python language bindings]),
 543         [],
 544         [enable_python=yes])
 545 AS_IF([test "x$enable_python" != "xno"],
 546         [
 547         AC_CHECK_PROG([PYTHON],[python],[python],[no])
 548
 549         if test "x$PYTHON" != "xno"; then
 550             AC_MSG_CHECKING([Python prefix])
 551             PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 552             AC_MSG_RESULT([$PYTHON_PREFIX])
 553
 554             AC_MSG_CHECKING([Python version])
 555             PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 556             AC_MSG_RESULT([$PYTHON_VERSION])
 557
 558             AC_MSG_CHECKING([for Python include path])
 559             if test -z "$PYTHON_INCLUDEDIR"; then
 560                 python_path=`$PYTHON -c "import distutils.sysconfig; \
 561                                          print (distutils.sysconfig.get_python_inc ());"`
 562                 PYTHON_INCLUDEDIR=$python_path
 563             fi
 564             AC_MSG_RESULT([$PYTHON_INCLUDEDIR])
 565
 566             AC_ARG_WITH([python-installdir],
 567                         [AS_HELP_STRING([--with-python-installdir],
 568                                         [directory to install python modules @<:@default=check@:>@])],
 569                         [PYTHON_INSTALLDIR="$withval"
 570                         AC_MSG_NOTICE([Python install dir $PYTHON_INSTALLDIR])],
 571                         [PYTHON_INSTALLDIR=check])
 572
 573             if test "x$PYTHON_INSTALLDIR" = "xcheck"; then
 574                 PYTHON_INSTALLDIR=
 575                 AC_MSG_CHECKING([for Python site-packages path])
 576                 if test -z "$PYTHON_INSTALLDIR"; then
 577                     PYTHON_INSTALLDIR=`$PYTHON -c "import distutils.sysconfig; \
 578                                                    print (distutils.sysconfig.get_python_lib(1,0));"`
 579                 fi
 580                 AC_MSG_RESULT([$PYTHON_INSTALLDIR])
 581             fi
 582
 583             old_LIBS="$LIBS"
 584             LIBS="$LIBS -lpython$PYTHON_VERSION"
 585             AC_CHECK_FUNCS([PyCapsule_New])
 586             LIBS="$old_LIBS"
 587         fi
 588
 589         AC_SUBST(PYTHON_PREFIX)
 590         AC_SUBST(PYTHON_VERSION)
 591         AC_SUBST(PYTHON_INCLUDEDIR)
 592         AC_SUBST(PYTHON_INSTALLDIR)
 593         ])
 594 AM_CONDITIONAL([HAVE_PYTHON],
 595     [test "x$PYTHON" != "xno" && test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_INSTALLDIR" != "x"])
 596
 597 dnl Check for Ruby and rake (optional, for Ruby bindings).
 598 AC_ARG_ENABLE([ruby],
 599         AS_HELP_STRING([--disable-ruby], [Disable Ruby language bindings]),
 600         [],
 601         [enable_ruby=yes])
 602 AS_IF([test "x$enable_ruby" != "xno"],
 603         [
 604         AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 605         AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 606         ])
 607 AM_CONDITIONAL([HAVE_RUBY],
 608     [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
 609
 610 dnl Check for Java.
 611 AC_ARG_WITH(java_home,
 612     [AS_HELP_STRING([--with-java-home],
 613         [specify path to JDK directory @<:@default=check@:>@])],
 614     [],
 615     [with_java_home=check])
 616
 617 if test "x$with_java_home" != "xno"; then
 618     if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
 619     then
 620         # Reject unsafe characters in $JAVA_HOME
 621         jh_lf='
 622 '
 623         case $JAVA_HOME in
 624           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 625             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 626         esac
 627         if test -d "$with_java_home"; then
 628             JAVA_HOME="$with_java_home"
 629         else
 630             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 631         fi
 632     fi
 633
 634     if test "x$JAVA_HOME" = "x"; then
 635         # Look for Java in some likely locations.
 636         for d in \
 637             /usr/lib/jvm/java \
 638             /usr/lib/jvm/java-6-openjdk
 639         do
 640             if test -d $d && test -f $d/bin/java; then
 641                 JAVA_HOME=$d
 642                 break
 643             fi
 644         done
 645     fi
 646
 647     if test "x$JAVA_HOME" != "x"; then
 648         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 649         if test ! -x "$JAVA_HOME/bin/java"; then
 650             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 651         else
 652             JAVA="$JAVA_HOME/bin/java"
 653         fi
 654         if test ! -x "$JAVA_HOME/bin/javac"; then
 655             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 656         else
 657             JAVAC="$JAVA_HOME/bin/javac"
 658         fi
 659         if test ! -x "$JAVA_HOME/bin/javah"; then
 660             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 661         else
 662             JAVAH="$JAVA_HOME/bin/javah"
 663         fi
 664         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 665             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 666         else
 667             JAVADOC="$JAVA_HOME/bin/javadoc"
 668         fi
 669         if test ! -x "$JAVA_HOME/bin/jar"; then
 670             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 671         else
 672             JAR="$JAVA_HOME/bin/jar"
 673         fi
 674         java_version=`$JAVA -version 2>&1 | grep "java version"`
 675         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 676
 677         dnl Find jni.h.
 678         AC_MSG_CHECKING([for jni.h])
 679         if test -f "$JAVA_HOME/include/jni.h"; then
 680             JNI_CFLAGS="-I$JAVA_HOME/include"
 681         else
 682             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 683                 head=`find $JAVA_HOME -name jni.h | tail -1`
 684                 dir=`dirname "$head"`
 685                 JNI_CFLAGS="-I$dir"
 686             else
 687                 AC_MSG_FAILURE([missing jni.h header file])
 688             fi
 689         fi
 690         AC_MSG_RESULT([$JNI_CFLAGS])
 691
 692         dnl Find jni_md.h.
 693         AC_MSG_CHECKING([for jni_md.h])
 694         case "$build_os" in
 695         *linux*) system="linux" ;;
 696         *SunOS*) system="solaris" ;;
 697         *cygwin*) system="win32" ;;
 698         *) system="$build_os" ;;
 699         esac
 700         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 701             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 702         else
 703             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 704                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 705                 dir=`dirname "$head"`
 706                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 707             else
 708                 AC_MSG_FAILURE([missing jni_md.h header file])
 709             fi
 710         fi
 711         AC_MSG_RESULT([$JNI_CFLAGS])
 712
 713         dnl Need extra version flag?
 714         AC_MSG_CHECKING([extra javac flags])
 715         JAVAC_FLAGS=
 716         javac_version=`$JAVAC -version 2>&1`
 717         case "$javac_version" in
 718         *Eclipse*)
 719             JAVAC_FLAGS="-source 1.5" ;;
 720         esac
 721         AC_MSG_RESULT([$JAVAC_FLAGS])
 722
 723         dnl Where to install jarfiles.
 724         dnl XXX How to make it configurable?
 725         JAR_INSTALL_DIR=\${prefix}/share/java
 726         JNI_INSTALL_DIR=\${libdir}
 727
 728         dnl JNI version.
 729         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 730         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 731         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 732         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 733     fi
 734 fi
 735
 736 AC_SUBST(JAVA_HOME)
 737 AC_SUBST(JAVA)
 738 AC_SUBST(JAVAC)
 739 AC_SUBST(JAVAH)
 740 AC_SUBST(JAVADOC)
 741 AC_SUBST(JAR)
 742 AC_SUBST(JNI_CFLAGS)
 743 AC_SUBST(JAVAC_FLAGS)
 744 AC_SUBST(JAR_INSTALL_DIR)
 745 AC_SUBST(JNI_INSTALL_DIR)
 746 AC_SUBST(JNI_VERSION_INFO)
 747
 748 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 749
 750 dnl Check for Haskell (GHC).
 751 GHC=no
 752 AC_ARG_ENABLE([haskell],
 753         AS_HELP_STRING([--disable-haskell], [Disable Haskell language bindings]),
 754         [],
 755         [enable_haskell=yes])
 756 AS_IF([test "x$enable_haskell" != "xno"],
 757         [
 758         GHC=
 759         AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 760         ])
 761 AM_CONDITIONAL([HAVE_HASKELL],
 762     [test "x$GHC" != "xno"])
 763
 764 dnl PHP
 765 PHP=no
 766 AC_ARG_ENABLE([php],
 767         AS_HELP_STRING([--disable-php], [Disable PHP language bindings]),
 768         [],
 769         [enable_php=yes])
 770 AS_IF([test "x$enable_php" != "xno"],
 771         [
 772         PHP=
 773         AC_CHECK_PROG([PHP],[php],[php],[no])
 774         AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
 775         ])
 776 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
 777
 778 dnl Check for Perl modules needed by Perl virt tools (virt-df, etc.)
 779 AS_IF([test "x$PERL" != "xno"],
 780         [
 781         missing_perl_modules=no
 782         for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper Locale::TextDomain Win::Hivex Win::Hivex::Regedit String::ShellQuote; do
 783             AC_MSG_CHECKING([for $pm])
 784             if ! $PERL -M$pm -e1 >/dev/null 2>&1; then
 785                 AC_MSG_RESULT([no])
 786                 missing_perl_modules=yes
 787             else
 788                 AC_MSG_RESULT([yes])
 789             fi
 790         done
 791         if test "x$missing_perl_modules" = "xyes"; then
 792             AC_MSG_WARN([some Perl modules required to compile the Perl virt-* tools are missing])
 793         fi
 794         ])
 795
 796 AM_CONDITIONAL([HAVE_TOOLS],
 797     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 798
 799 dnl Library versioning.
 800 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 801 AC_SUBST(MAX_PROC_NR)
 802
 803 dnl Replace libtool with a wrapper that clobbers dependency_libs in *.la files
 804 dnl http://lists.fedoraproject.org/pipermail/devel/2010-November/146343.html
 805 LIBTOOL='$(SHELL) $(top_srcdir)/libtool-kill-dependency_libs.sh $(top_builddir)/libtool'
 806 AC_SUBST([LIBTOOL])
 807
 808 dnl Run in subdirs.
 809 if test "x$enable_daemon" = "xyes"; then
 810     AC_CONFIG_SUBDIRS([daemon])
 811 fi
 812
 813 dnl Produce output files.
 814 AC_CONFIG_HEADERS([config.h])
 815 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 816 AC_CONFIG_FILES([podwrapper.sh],
 817                 [chmod +x podwrapper.sh])
 818 AC_CONFIG_FILES([Makefile
 819                  appliance/Makefile
 820                  capitests/Makefile
 821                  cat/Makefile
 822                  caution/Makefile
 823                  csharp/Makefile
 824                  debian/changelog
 825                  df/Makefile
 826                  edit/Makefile
 827                  examples/Makefile
 828                  fish/Makefile
 829                  fuse/Makefile
 830                  generator/Makefile
 831                  gnulib/lib/Makefile
 832                  gnulib/tests/Makefile
 833                  haskell/Makefile
 834                  images/Makefile
 835                  inspector/Makefile
 836                  java/Makefile
 837                  java/examples/Makefile
 838                  libguestfs.pc
 839                  ocaml/META
 840                  ocaml/Makefile
 841                  ocaml/examples/Makefile
 842                  perl/Makefile
 843                  perl/Makefile.PL
 844                  perl/examples/Makefile
 845                  php/Makefile
 846                  po-docs/Makefile
 847                  po-docs/ja/Makefile
 848                  po-docs/uk/Makefile
 849                  po/Makefile.in
 850                  python/Makefile
 851                  python/examples/Makefile
 852                  regressions/Makefile
 853                  rescue/Makefile
 854                  resize/Makefile
 855                  ruby/Makefile
 856                  ruby/Rakefile
 857                  ruby/examples/Makefile
 858                  src/Makefile
 859                  test-tool/Makefile
 860                  tools/Makefile])
 861 AC_OUTPUT
 862
 863 dnl Produce summary.
 864 echo
 865 echo
 866 echo "------------------------------------------------------------"
 867 echo "Thank you for downloading $PACKAGE_STRING"
 868 echo
 869 echo "This is how we have configured the optional components for you today:"
 870 echo
 871 echo    "Daemon .............................. $enable_daemon"
 872 echo    "Appliance ........................... $enable_appliance"
 873 echo    "QEMU ................................ $QEMU"
 874 echo -n "OCaml bindings ...................... "
 875 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 876 echo -n "Perl bindings ....................... "
 877 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 878 echo -n "Python bindings ..................... "
 879 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 880 echo -n "Ruby bindings ....................... "
 881 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 882 echo -n "Java bindings ....................... "
 883 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 884 echo -n "Haskell bindings .................... "
 885 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 886 echo -n "PHP bindings ........................ "
 887 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 888 echo    "guestfish and C virt tools .......... yes"
 889 echo -n "Perl virt tools ..................... "
 890 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 891 echo -n "virt-resize ......................... "
 892 if test "x$HAVE_OCAML" = "x" && test "x$HAVE_OCAML_PCRE" = "x"; then echo "yes"; else echo "no"; fi
 893 echo "FUSE filesystem ..................... $enable_fuse"
 894 echo
 895 echo "If any optional component is configured 'no' when you expected 'yes'"
 896 echo "then you should check the preceeding messages."
 897 echo
 898 echo "Please report bugs back to the mailing list:"
 899 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 900 echo
 901 echo "Next you should type 'make' to build the package,"
 902 echo "then 'make check' to run the tests."
 903 echo "------------------------------------------------------------"