configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2010 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [2])
  21 m4_define([libguestfs_release], [10])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release[]libguestfs_extra)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 dnl Stable or unstable version?
  41 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  42 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  43             AC_MSG_RESULT([stable])
  44        ],[
  45             AC_MSG_RESULT([unstable])
  46             AC_MSG_NOTICE([
  47 ***
  48 This is a development version of libguestfs. Some APIs may be unstable
  49 until they appear in a stable release of libguestfs (at which point
  50 the C API and ABI is guaranteed to remain stable forever).  For
  51 more information about stable and development branches of libguestfs
  52 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  53 ***])
  54        ])
  55
  56 dnl Die if the user tries to configure as root, see:
  57 dnl https://www.redhat.com/archives/libguestfs/2010-April/msg00098.html
  58 AC_MSG_CHECKING([if you are trying to configure as root])
  59 AS_IF([test "`id -u`" = 0 ],[
  60             AC_MSG_RESULT([yes])
  61             AC_MSG_FAILURE([Don't run './configure' or 'make' as root.])
  62       ],[
  63             AC_MSG_RESULT([no])
  64       ])
  65
  66 dnl Early gnulib initialization.
  67 gl_EARLY
  68 gl_INIT
  69
  70 AC_PROG_LIBTOOL
  71
  72 dnl Check for basic C environment.
  73 AC_PROG_CC_STDC
  74 AC_PROG_INSTALL
  75 AC_PROG_CPP
  76
  77 AC_ARG_ENABLE([gcc-warnings],
  78   [AS_HELP_STRING([--enable-gcc-warnings],
  79                   [turn on lots of GCC warnings (for developers)])],
  80   [case $enableval in
  81      yes|no) ;;
  82      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  83    esac
  84    gl_gcc_warnings=$enableval],
  85   [gl_gcc_warnings=no]
  86 )
  87
  88 if test "$gl_gcc_warnings" = yes; then
  89   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  90   AC_SUBST([WERROR_CFLAGS])
  91
  92   nw=
  93   # This, $nw, is the list of warnings we disable.
  94   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  95   nw="$nw -Waggregate-return"       # anachronistic
  96   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  97   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  98   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  99   nw="$nw -Wcast-qual"              # Too many warnings for now
 100   nw="$nw -Wconversion"             # Too many warnings for now
 101   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 102   nw="$nw -Wsign-conversion"        # Too many warnings for now
 103   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 104   nw="$nw -Wunreachable-code"       # Too many warnings for now
 105   nw="$nw -Wpadded"                 # Our structs are not padded
 106   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 107   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 108   nw="$nw -Wvla"                    # two warnings in mount.c
 109   # things I might fix soon:
 110   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 111   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 112   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 113   # ?? -Wstrict-overflow
 114   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 115                                     # was not possible, safe to ignore
 116   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 117   nw="$nw -Wlong-long"              # Allow long long since it's required
 118                                     # by Python, Ruby and xstrtoll.
 119
 120   gl_MANYWARN_ALL_GCC([ws])
 121   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 122   for w in $ws; do
 123     gl_WARN_ADD([$w])
 124   done
 125   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 126   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 127   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 128
 129   # In spite of excluding -Wlogical-op above, it is enabled, as of
 130   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 131   gl_WARN_ADD([-Wno-logical-op])
 132
 133   gl_WARN_ADD([-fdiagnostics-show-option])
 134
 135   AC_SUBST([WARN_CFLAGS])
 136
 137   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 138   AC_DEFINE([_FORTIFY_SOURCE], [2],
 139     [enable compile-time and run-time bounds-checking, and some warnings])
 140   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 141 fi
 142
 143 AC_C_PROTOTYPES
 144 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 145
 146 AM_PROG_CC_C_O
 147
 148 dnl Work out how to specify the linker script to the linker.
 149 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 150 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 151     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 152 AC_SUBST(VERSION_SCRIPT_FLAGS)
 153
 154 dnl Check support for 64 bit file offsets.
 155 AC_SYS_LARGEFILE
 156
 157 dnl Check sizeof long.
 158 AC_CHECK_SIZEOF([long])
 159
 160 dnl Define a C symbol for the host CPU architecture.
 161 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 162
 163 dnl Headers.
 164 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 165
 166 dnl Functions.
 167 AC_CHECK_FUNCS([posix_fallocate])
 168
 169 dnl Build the daemon?
 170 AC_MSG_CHECKING([if we should build the daemon])
 171 AC_ARG_ENABLE([daemon],
 172         [AS_HELP_STRING([--enable-daemon],
 173           [enable building the daemon @<:@default=yes@:>@])],
 174         [],
 175         [enable_daemon=yes])
 176 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 177 AC_MSG_RESULT([$enable_daemon])
 178
 179 dnl Build the appliance?
 180 AC_MSG_CHECKING([if we should build the appliance])
 181 AC_ARG_ENABLE([appliance],
 182         [AS_HELP_STRING([--enable-appliance],
 183           [enable building the appliance @<:@default=yes@:>@])],
 184         [],
 185         [enable_appliance=yes])
 186 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 187 AC_MSG_RESULT([$enable_appliance])
 188
 189 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 190 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 191 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 192 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 193         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 194         ])
 195
 196 dnl Check for pod2man and pod2text.
 197 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 198 test "x$POD2MAN" = "xno" &&
 199      AC_MSG_ERROR([pod2man must be installed])
 200 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 201 test "x$POD2TEXT" = "xno" &&
 202      AC_MSG_ERROR([pod2text must be installed])
 203
 204 dnl Check for mkisofs.
 205 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 206         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 207 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 208
 209 dnl Check for optional xmllint.
 210 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 211 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 212
 213 dnl Check for QEMU for running binaries on this $host_cpu, fall
 214 dnl back to basic 'qemu'.  Allow the user to override it.
 215 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
 216 AC_ARG_WITH([qemu],
 217         [AS_HELP_STRING([--with-qemu],
 218           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 219         [],
 220         [with_qemu="$default_qemu"])
 221 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 222         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 223 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 224 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 225
 226 dnl Check that the chosen qemu has vmchannel support or we can
 227 dnl fallback to null vmchannel (still using SLIRP).  See the
 228 dnl discussion in the README file.
 229 if test "x$vmchannel_test" != "xno"; then
 230     AC_MSG_CHECKING([for guestfwd support in $QEMU])
 231     if $QEMU -nographic --help | grep -sq guestfwd; then
 232         AC_MSG_RESULT([yes])
 233         vmchannel_guestfwd=guestfwd
 234     else
 235         AC_MSG_RESULT([no])
 236         # Note that this test must be conditional on the previous
 237         # test failing.  This is because recent qemu will throw
 238         # up an SDL window and hang if we try to run this test.
 239         AC_MSG_CHECKING([for "-net channel" (old guestfwd) support in $QEMU])
 240         vmchannelout=`$QEMU -nographic -net channel /dev/zero 2>&1 ||:`
 241         echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
 242         if echo "$vmchannelout" | grep -sq "vmchannel wrong port number" ; then
 243             AC_MSG_RESULT([yes])
 244             vmchannel_guestfwd=net_channel
 245         else
 246             AC_MSG_RESULT([no])
 247             vmchannel_guestfwd=no
 248         fi
 249     fi
 250
 251     AC_MSG_CHECKING([for "-net user" (user mode network) support in $QEMU])
 252     if $QEMU -nographic --help | grep -sq -- "-net user"; then
 253         AC_MSG_RESULT([yes])
 254         vmchannel_net_user=yes
 255     else
 256         AC_MSG_RESULT([no])
 257         vmchannel_net_user=no
 258     fi
 259
 260     if test "x$vmchannel_net_user" = "xno" -a "x$vmchannel_guestfwd" = "xno"; then
 261         AC_MSG_FAILURE(
 262 [I did not find user mode network or vmchannel support in
 263 $QEMU.
 264
 265 Either user mode networking or vmchannel support is vital for
 266 libguestfs to operate.
 267
 268 Please read the relevant section in the README file for more
 269 information about this.
 270
 271 You can override this test by setting the environment variable
 272 vmchannel_test=no  However if you don't have the right support
 273 in your qemu, then this just delays the pain.
 274
 275 If I am using the wrong qemu or you want to compile qemu from source
 276 and install it in another location, then you should configure with
 277 the --with-qemu option.
 278 ])
 279     fi
 280 fi
 281
 282 dnl Set drive interface used by the guestfs_add_drive{,_ro} calls
 283 dnl ('-drive ...,if=...' option to qemu).
 284 dnl
 285 dnl If you encounter performance problems with virtio (RHBZ#509383)
 286 dnl then try '--with-drive-if=ide'.
 287 AC_ARG_WITH([drive-if],
 288         [AS_HELP_STRING([--with-drive-if],
 289           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 290         [],
 291         [with_drive_if=virtio])
 292 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 293
 294 dnl Set interface used by the network.  Normally you should
 295 dnl leave this at the default (virtio) but you can use the
 296 dnl alternative (ne2k_pci) because of bugs in virtio networking
 297 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 298 AC_ARG_WITH([net-if],
 299         [AS_HELP_STRING([--with-net-if],
 300           [set default net driver (virtio|ne2k_pci) @<:@default=virtio@:>@])],
 301         [],
 302         [with_net_if=virtio])
 303 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 304
 305 dnl Check for febootstrap etc.
 306 if test "x$enable_appliance" = "xyes"; then
 307     AC_CHECK_PROG([FEBOOTSTRAP],
 308                   [febootstrap],[febootstrap],[no])
 309     if test "x$FEBOOTSTRAP" != "xno"; then
 310       AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 311                     [febootstrap-run],[febootstrap-run],[no])
 312       test "x$FEBOOTSTRAP_RUN" = "xno" && \
 313           AC_MSG_ERROR([febootstrap-run must be installed])
 314       AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 315                     [febootstrap-install],[febootstrap-install],[no])
 316       test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 317           AC_MSG_ERROR([febootstrap-install must be installed])
 318       AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 319                     [febootstrap-minimize],[febootstrap-minimize],[no])
 320       test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 321           AC_MSG_ERROR([febootstrap-minimize must be installed])
 322       AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 323                     [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 324       test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 325           AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 326
 327       dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 328       dnl of febootstrap, but old versions will fail with yum).
 329       AC_CHECK_PROG([FAKECHROOT],
 330                     [fakechroot],[fakechroot],[no])
 331       test "x$FAKECHROOT" = "xno" && \
 332          AC_MSG_ERROR([fakechroot must be installed])
 333
 334       AC_MSG_CHECKING([fakechroot version])
 335       fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 336       if test -z "$fakechroot_version"; then
 337         AC_MSG_RESULT([failed])
 338         AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 339       else
 340         AC_MSG_RESULT([$fakechroot_version])
 341         fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 342         fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 343         if test "$fakechroot_major" -lt 2 -o \
 344             \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
 345           AC_MSG_ERROR([fakechroot version must be >= 2.9])
 346         fi
 347       fi
 348       DIST="REDHAT"
 349     else
 350       # check for debootstrap and debirf
 351       AC_CHECK_PROG([DEBOOTSTRAP],
 352                     [debootstrap],[debootstrap],[no])
 353       test "x$DEBOOTSTRAP" = "xno" && \
 354           AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 355       AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 356       test "x$DEBIRF" = "xno" &&
 357           AC_MSG_ERROR([debirf must be installed])
 358       DIST="DEBIAN"
 359       case "$host_cpu" in
 360       *86)
 361           DEBIAN_KERNEL_ARCH=486
 362           ;;
 363       x86_64)
 364           DEBIAN_KERNEL_ARCH=amd64
 365           ;;
 366       *)
 367          DEBIAN_KERNEL_ARCH=$host_cpu
 368          ;;
 369       esac
 370       AC_SUBST(DEBIAN_KERNEL_ARCH)
 371     fi
 372     AC_SUBST(DIST)
 373
 374     dnl --with-updates to specify a Fedora updates repository.
 375     AC_ARG_WITH([updates],
 376         [AS_HELP_STRING([--with-updates],
 377           [set name of Fedora updates repository @<:@default=updates-released-f12@:>@])],
 378         [],
 379         [with_updates=updates-released-f12])
 380     UPDATES="$with_updates"
 381     AC_SUBST(UPDATES)
 382
 383     dnl --with-mirror to specify a local Fedora mirror.
 384     AC_ARG_WITH([mirror],
 385         [AS_HELP_STRING([--with-mirror],
 386           [set URI of a local Fedora mirror])],
 387         [],
 388         [with_mirror=])
 389     MIRROR="$with_mirror"
 390     AC_SUBST(MIRROR)
 391 fi
 392
 393 dnl --with-repo to specify a Fedora repository.
 394 AC_ARG_WITH([repo],
 395         [AS_HELP_STRING([--with-repo],
 396           [set name of Fedora repository @<:@default=fedora-12@:>@])],
 397         [],
 398         [with_repo=fedora-12])
 399 REPO="$with_repo"
 400 AC_SUBST(REPO)
 401 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 402
 403 dnl Build the supermin appliance?  Please see README file before
 404 dnl enabling this option.
 405 AC_ARG_ENABLE([supermin],
 406         [AS_HELP_STRING([--enable-supermin],
 407           [enable supermin appliance (see README) @<:@default=no@:>@])],
 408         [],
 409         [enable_supermin=no])
 410 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 411
 412 if test "x$enable_supermin" = "xyes"; then
 413     dnl Check febootstrap-to-initramfs accepts the --files option
 414     dnl (febootstrap >= 2.2).
 415     AC_MSG_CHECKING([for --files support in $FEBOOTSTRAP_TO_INITRAMFS])
 416     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 417     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 418     if ! echo "$out" | grep -sq -e --files ; then
 419         AC_MSG_RESULT([no])
 420         AC_MSG_FAILURE(
 421 [febootstrap-to-initramfs does not support the --files option.
 422
 423 To build the supermin appliance, you need to upgrade to the latest
 424 version of febootstrap.
 425 ])
 426     fi
 427     AC_MSG_RESULT([yes])
 428
 429     dnl Check febootstrap-to-initramfs accepts the --nocompress option
 430     dnl (febootstrap >= 2.3).
 431     AC_MSG_CHECKING([for --nocompress support in $FEBOOTSTRAP_TO_INITRAMFS])
 432     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 433     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 434     if ! echo "$out" | grep -sq -e --nocompress ; then
 435         AC_MSG_RESULT([no])
 436         AC_MSG_FAILURE(
 437 [febootstrap-to-initramfs does not support the --nocompress option.
 438
 439 To build the supermin appliance, you need to upgrade to the latest
 440 version of febootstrap.
 441 ])
 442     fi
 443     AC_MSG_RESULT([yes])
 444 fi
 445
 446 dnl Enable packet dumps when in verbose mode.  This generates lots
 447 dnl of debug info, only useful for people debugging the RPC mechanism.
 448 AC_ARG_ENABLE([packet-dump],
 449         [AS_HELP_STRING([--enable-packet-dump],
 450           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 451         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 452         [])
 453
 454 dnl Readline.
 455 AC_ARG_WITH([readline],
 456     [AS_HELP_STRING([--with-readline],
 457         [support fancy command line editing @<:@default=check@:>@])],
 458     [],
 459     [with_readline=check])
 460
 461 LIBREADLINE=
 462 AS_IF([test "x$with_readline" != xno],
 463     [AC_CHECK_LIB([readline], [main],
 464         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 465          AC_DEFINE([HAVE_LIBREADLINE], [1],
 466                    [Define if you have libreadline])
 467         ],
 468         [if test "x$with_readline" != xcheck; then
 469          AC_MSG_FAILURE(
 470              [--with-readline was given, but test for readline failed])
 471          fi
 472         ], -lncurses)
 473      old_LIBS="$LIBS"
 474      LIBS="$LIBS $LIBREADLINE"
 475      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 476      LIBS="$old_LIBS"
 477     ])
 478
 479 dnl For i18n.
 480 AM_GNU_GETTEXT([external])
 481 AM_GNU_GETTEXT_VERSION([0.17])
 482
 483 dnl hivex library (highly recommended).
 484 dnl This used to be a part of libguestfs, but was spun off into its
 485 dnl own separate upstream project in libguestfs 1.0.85.
 486 HAVE_HIVEX=yes
 487 PKG_CHECK_MODULES([HIVEX], [hivex],,[
 488         HAVE_HIVEX=no
 489         AC_MSG_WARN([Hivex library and headers are missing, so optional Windows Registry tools won't be built])])
 490 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HAVE_HIVEX" = "xyes"])
 491 AC_SUBST([HIVEX_CFLAGS])
 492 AC_SUBST([HIVEX_LIBS])
 493
 494 dnl FUSE is optional to build the FUSE module.
 495 HAVE_FUSE=yes
 496 PKG_CHECK_MODULES([FUSE],[fuse],,[
 497         HAVE_FUSE=no
 498         AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])
 499 AM_CONDITIONAL([HAVE_FUSE],[test "x$HAVE_FUSE" = "xyes"])
 500
 501 dnl Check for OCaml (optional, for OCaml bindings).
 502 AC_PROG_OCAML
 503 AC_PROG_FINDLIB
 504 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
 505
 506 dnl Optional xml-light for running the generator.
 507 OCAML_PKG_xml_light=no
 508 if test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"; then
 509     AC_CHECK_OCAML_PKG([xml-light])
 510 fi
 511 AM_CONDITIONAL([HAVE_XML_LIGHT],[test "x$OCAML_PKG_xml_light" != "xno"])
 512
 513 dnl Build the OCaml viewer example.  This has a lengthy list of
 514 dnl dependencies and we don't attempt to detect them all.  Read
 515 dnl the top of ocaml/examples/viewer.ml before enabling this.
 516 AC_ARG_ENABLE([ocaml-viewer],
 517         [AS_HELP_STRING([--enable-ocaml-viewer],
 518           [enable OCaml viewer (see ocaml/examples) @<:@default=no@:>@])],
 519         [],
 520         [enable_ocaml_viewer=no])
 521 AM_CONDITIONAL([BUILD_OCAML_VIEWER],[test "x$enable_ocaml_viewer" = "xyes"])
 522
 523 dnl Check for Perl (optional, for Perl bindings).
 524 dnl XXX This isn't quite right, we should check for Perl devel library.
 525 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 526
 527 dnl Check for Perl modules that must be present to compile and
 528 dnl test the Perl bindings.
 529 missing_perl_modules=no
 530 for pm in Test::More ExtUtils::MakeMaker; do
 531     AC_MSG_CHECKING([for $pm])
 532     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 533         AC_MSG_RESULT([no])
 534         missing_perl_modules=yes
 535     else
 536         AC_MSG_RESULT([yes])
 537     fi
 538 done
 539 if test "x$missing_perl_modules" = "xyes"; then
 540     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 541 fi
 542
 543 AM_CONDITIONAL([HAVE_PERL],
 544     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 545
 546 dnl Check for Python (optional, for Python bindings).
 547 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 548
 549 PYTHON_PREFIX=
 550 PYTHON_VERSION=
 551 PYTHON_INCLUDEDIR=
 552 PYTHON_SITE_PACKAGES=
 553
 554 if test "x$PYTHON" != "xno"; then
 555     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 556     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 557     for d in \
 558         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 559         /usr/include/python$PYTHON_VERSION \
 560         /usr/local/include/python$PYTHON_VERSION
 561     do
 562         AC_MSG_CHECKING([Python.h in $d])
 563         if test -r "$d/Python.h"; then
 564             AC_MSG_RESULT([found])
 565             PYTHON_INCLUDEDIR=$d
 566             break
 567         fi
 568         AC_MSG_RESULT([not found])
 569     done
 570     for d in \
 571         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 572         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 573         /usr/lib64/python$PYTHON_VERSION/site-packages \
 574         /usr/lib/python$PYTHON_VERSION/site-packages \
 575         /usr/local/lib/python$PYTHON_VERSION/site-packages
 576     do
 577         AC_MSG_CHECKING([for $d])
 578         if test -d "$d"; then
 579             AC_MSG_RESULT([found])
 580             PYTHON_SITE_PACKAGES=$d
 581             break
 582         fi
 583         AC_MSG_RESULT([not found])
 584     done
 585 fi
 586
 587 AC_SUBST(PYTHON_PREFIX)
 588 AC_SUBST(PYTHON_VERSION)
 589 AC_SUBST(PYTHON_INCLUDEDIR)
 590 AC_SUBST(PYTHON_SITE_PACKAGES)
 591
 592 AM_CONDITIONAL([HAVE_PYTHON],
 593     [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
 594
 595 dnl Check for Ruby and rake (optional, for Ruby bindings).
 596 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 597 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 598
 599 AM_CONDITIONAL([HAVE_RUBY],
 600     [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
 601
 602 dnl Check for Java.
 603 AC_ARG_WITH(java_home,
 604     [AS_HELP_STRING([--with-java-home],
 605         [specify path to JDK directory @<:@default=check@:>@])],
 606     [],
 607     [with_java_home=check])
 608
 609 if test "x$with_java_home" != "xno"; then
 610     if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
 611     then
 612         # Reject unsafe characters in $JAVA_HOME
 613         jh_lf='
 614 '
 615         case $JAVA_HOME in
 616           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 617             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 618         esac
 619         if test -d "$with_java_home"; then
 620             JAVA_HOME="$with_java_home"
 621         else
 622             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 623         fi
 624     fi
 625
 626     if test "x$JAVA_HOME" = "x"; then
 627         # Look for Java in some likely locations.
 628         for d in \
 629             /usr/lib/jvm/java \
 630             /usr/lib/jvm/java-6-openjdk
 631         do
 632             if test -d $d -a -f $d/bin/java; then
 633                 JAVA_HOME=$d
 634                 break
 635             fi
 636         done
 637     fi
 638
 639     if test "x$JAVA_HOME" != "x"; then
 640         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 641         if test ! -x "$JAVA_HOME/bin/java"; then
 642             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 643         else
 644             JAVA="$JAVA_HOME/bin/java"
 645         fi
 646         if test ! -x "$JAVA_HOME/bin/javac"; then
 647             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 648         else
 649             JAVAC="$JAVA_HOME/bin/javac"
 650         fi
 651         if test ! -x "$JAVA_HOME/bin/javah"; then
 652             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 653         else
 654             JAVAH="$JAVA_HOME/bin/javah"
 655         fi
 656         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 657             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 658         else
 659             JAVADOC="$JAVA_HOME/bin/javadoc"
 660         fi
 661         if test ! -x "$JAVA_HOME/bin/jar"; then
 662             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 663         else
 664             JAR="$JAVA_HOME/bin/jar"
 665         fi
 666         java_version=`$JAVA -version 2>&1 | grep "java version"`
 667         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 668
 669         dnl Find jni.h.
 670         AC_MSG_CHECKING([for jni.h])
 671         if test -f "$JAVA_HOME/include/jni.h"; then
 672             JNI_CFLAGS="-I$JAVA_HOME/include"
 673         else
 674             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 675                 head=`find $JAVA_HOME -name jni.h | tail -1`
 676                 dir=`dirname "$head"`
 677                 JNI_CFLAGS="-I$dir"
 678             else
 679                 AC_MSG_FAILURE([missing jni.h header file])
 680             fi
 681         fi
 682         AC_MSG_RESULT([$JNI_CFLAGS])
 683
 684         dnl Find jni_md.h.
 685         AC_MSG_CHECKING([for jni_md.h])
 686         case "$build_os" in
 687         *linux*) system="linux" ;;
 688         *SunOS*) system="solaris" ;;
 689         *cygwin*) system="win32" ;;
 690         *) system="$build_os" ;;
 691         esac
 692         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 693             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 694         else
 695             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 696                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 697                 dir=`dirname "$head"`
 698                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 699             else
 700                 AC_MSG_FAILURE([missing jni_md.h header file])
 701             fi
 702         fi
 703         AC_MSG_RESULT([$JNI_CFLAGS])
 704
 705         dnl Need extra version flag?
 706         AC_MSG_CHECKING([extra javac flags])
 707         JAVAC_FLAGS=
 708         javac_version=`$JAVAC -version 2>&1`
 709         case "$javac_version" in
 710         *Eclipse*)
 711             JAVAC_FLAGS="-source 1.5" ;;
 712         esac
 713         AC_MSG_RESULT([$JAVAC_FLAGS])
 714
 715         dnl Where to install jarfiles.
 716         dnl XXX How to make it configurable?
 717         JAR_INSTALL_DIR=\${prefix}/share/java
 718         JNI_INSTALL_DIR=\${libdir}
 719
 720         dnl JNI version.
 721         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 722         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 723         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 724         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 725     fi
 726 fi
 727
 728 AC_SUBST(JAVA_HOME)
 729 AC_SUBST(JAVA)
 730 AC_SUBST(JAVAC)
 731 AC_SUBST(JAVAH)
 732 AC_SUBST(JAVADOC)
 733 AC_SUBST(JAR)
 734 AC_SUBST(JNI_CFLAGS)
 735 AC_SUBST(JAVAC_FLAGS)
 736 AC_SUBST(JAR_INSTALL_DIR)
 737 AC_SUBST(JNI_INSTALL_DIR)
 738 AC_SUBST(JNI_VERSION_INFO)
 739
 740 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 741
 742 dnl Check for Haskell (GHC).
 743 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 744
 745 AM_CONDITIONAL([HAVE_HASKELL],
 746     [test "x$GHC" != "xno"])
 747
 748 dnl Check for Perl modules needed by virt-df, inspector, etc.
 749 missing_perl_modules=no
 750 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer Locale::TextDomain Win::Hivex Win::Hivex::Regedit; do
 751     AC_MSG_CHECKING([for $pm])
 752     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 753         AC_MSG_RESULT([no])
 754         missing_perl_modules=yes
 755     else
 756         AC_MSG_RESULT([yes])
 757     fi
 758 done
 759 if test "x$missing_perl_modules" = "xyes"; then
 760     AC_MSG_WARN([some Perl modules required to compile virt-inspector and the other virt-* tools are missing])
 761 fi
 762
 763 AM_CONDITIONAL([HAVE_INSPECTOR],
 764     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 765 AM_CONDITIONAL([HAVE_TOOLS],
 766     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 767
 768 dnl Library versioning.
 769 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 770 AC_SUBST(MAX_PROC_NR)
 771
 772 dnl Run in subdirs.
 773 if test "x$enable_daemon" = "xyes"; then
 774     AC_CONFIG_SUBDIRS([daemon])
 775 fi
 776
 777 dnl Produce output files.
 778 AC_CONFIG_HEADERS([config.h])
 779 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 780 AC_CONFIG_FILES([appliance/update.sh],
 781                 [chmod +x appliance/update.sh])
 782 AC_CONFIG_FILES([appliance/supermin-split.sh],
 783                 [chmod +x appliance/supermin-split.sh])
 784 AC_CONFIG_FILES([appliance/supermin-make.sh],
 785                 [chmod +x appliance/supermin-make.sh])
 786 AC_CONFIG_FILES([Makefile
 787                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 788                  appliance/Makefile
 789                  appliance/debian/debirf.conf
 790                  images/Makefile
 791                  capitests/Makefile
 792                  regressions/Makefile
 793                  test-tool/Makefile
 794                  ocaml/Makefile ocaml/examples/Makefile
 795                  perl/Makefile
 796                  python/Makefile
 797                  ruby/Makefile ruby/Rakefile
 798                  java/Makefile
 799                  haskell/Makefile
 800                  inspector/Makefile
 801                  tools/Makefile
 802                  libguestfs.pc
 803                  gnulib/lib/Makefile
 804                  gnulib/tests/Makefile
 805                  fuse/Makefile
 806                  ocaml/META perl/Makefile.PL])
 807 AC_OUTPUT
 808
 809 dnl Produce summary.
 810 echo
 811 echo
 812 echo "------------------------------------------------------------"
 813 echo "Thank you for downloading $PACKAGE_STRING"
 814 echo
 815 echo "This is how we have configured the optional components for you today:"
 816 echo
 817 echo    "Daemon .............................. $enable_daemon"
 818 echo    "Appliance ........................... $enable_appliance"
 819 echo    "QEMU ................................ $QEMU"
 820 echo -n "OCaml bindings ...................... "
 821 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 822 echo -n "Perl bindings ....................... "
 823 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 824 echo -n "Python bindings ..................... "
 825 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 826 echo -n "Ruby bindings ....................... "
 827 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 828 echo -n "Java bindings ....................... "
 829 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 830 echo -n "Haskell bindings .................... "
 831 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 832 echo -n "virt-inspector ...................... "
 833 if test "x$HAVE_INSPECTOR_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 834 echo -n "virt-* tools ........................ "
 835 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 836 echo "supermin appliance .................. $enable_supermin"
 837 echo "FUSE filesystem ..................... $HAVE_FUSE"
 838 echo
 839 echo "If any optional component is configured 'no' when you expected 'yes'"
 840 echo "then you should check the preceeding messages."
 841 echo
 842 echo "Please report bugs back to the mailing list:"
 843 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 844 echo
 845 echo "Next you should type 'make' to build the package,"
 846 echo "then 'make check' to run the tests."
 847 echo "------------------------------------------------------------"