configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 AC_INIT([libguestfs],[0.2])
  19 AM_INIT_AUTOMAKE
  20
  21 AC_CONFIG_MACRO_DIR([m4])
  22
  23 AC_PROG_LIBTOOL
  24
  25 dnl Check for basic C environment.
  26 AC_PROG_CC
  27 AC_PROG_INSTALL
  28 AC_PROG_CPP
  29
  30 AC_C_PROTOTYPES
  31 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
  32
  33 AC_PROG_CC_C_O
  34
  35 dnl Headers.
  36 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h])
  37
  38 dnl Check for rpcgen and XDR library.  rpcgen is optional.
  39 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
  40 AM_CONDITIONAL([RPCGEN],[test "x$RPCGEN" != "xno"])
  41 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
  42         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
  43         ])
  44
  45 dnl Check for QEMU.  We only check for the basic 'qemu' program here
  46 dnl (ie. the i386 full system qemu).  But at runtime we might choose
  47 dnl a different qemu to run, eg. qemu-system-ppc.
  48 AC_PATH_PROG([QEMU],[qemu],[no],
  49         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
  50 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
  51 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
  52
  53 dnl Check for febootstrap etc.
  54 AC_CHECK_PROG([FEBOOTSTRAP],
  55         [febootstrap],[febootstrap],[no])
  56 test "x$FEBOOTSTRAP" = "xno" && \
  57      AC_MSG_ERROR([febootstrap must be installed])
  58 AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
  59         [febootstrap-minimize],[febootstrap-minimize],[no])
  60 test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
  61      AC_MSG_ERROR([febootstrap-minimize must be installed])
  62 AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
  63         [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
  64 test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
  65      AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
  66
  67 dnl --with-repo to specify a Fedora repository.
  68 AC_ARG_WITH([repo],
  69         [AS_HELP_STRING([--with-repo],
  70           [set name of Fedora repository @<:@default=fedora-10@:>@])],
  71         [],
  72         [with_repo=fedora-10])
  73 REPO="$with_repo"
  74 AC_SUBST(REPO)
  75
  76 dnl --with-mirror to specify a local Fedora mirror.
  77 AC_ARG_WITH([mirror],
  78         [AS_HELP_STRING([--with-mirror],
  79           [set URI of a local Fedora mirror])],
  80         [],
  81         [with_mirror=])
  82 MIRROR="$with_mirror"
  83 AC_SUBST(MIRROR)
  84
  85 dnl Run in subdirs.
  86 AC_CONFIG_SUBDIRS([daemon])
  87
  88 dnl Produce output files.
  89 AC_CONFIG_HEADERS([config.h])
  90 AC_CONFIG_FILES([Makefile src/Makefile examples/Makefile make-initramfs.sh])
  91 AC_OUTPUT
  92
  93 dnl WTF?
  94 chmod +x make-initramfs.sh