configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2010 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [7])
  21 m4_define([libguestfs_release], [3])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 dnl Stable or unstable version?
  41 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  42 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  43             AC_MSG_RESULT([stable])
  44        ],[
  45             AC_MSG_RESULT([unstable])
  46             AC_MSG_NOTICE([
  47 ***
  48 This is a development version of libguestfs. Some APIs may be unstable
  49 until they appear in a stable release of libguestfs (at which point
  50 the C API and ABI is guaranteed to remain stable forever).  For
  51 more information about stable and development branches of libguestfs
  52 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  53 ***])
  54        ])
  55
  56 dnl Die if the user tries to configure as root, see:
  57 dnl https://www.redhat.com/archives/libguestfs/2010-April/msg00098.html
  58 AC_MSG_CHECKING([if you are trying to configure as root])
  59 AS_IF([test "`id -u`" = 0 ],[
  60             AC_MSG_RESULT([yes])
  61             AC_MSG_FAILURE([Don't run './configure' or 'make' as root.])
  62       ],[
  63             AC_MSG_RESULT([no])
  64       ])
  65
  66 dnl Early gnulib initialization.
  67 gl_EARLY
  68 gl_INIT
  69
  70 AC_PROG_LIBTOOL
  71
  72 dnl Check for basic C environment.
  73 AC_PROG_CC_STDC
  74 AC_PROG_INSTALL
  75 AC_PROG_CPP
  76
  77 AC_ARG_ENABLE([gcc-warnings],
  78   [AS_HELP_STRING([--enable-gcc-warnings],
  79                   [turn on lots of GCC warnings (for developers)])],
  80   [case $enableval in
  81      yes|no) ;;
  82      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  83    esac
  84    gl_gcc_warnings=$enableval],
  85   [gl_gcc_warnings=no]
  86 )
  87
  88 if test "$gl_gcc_warnings" = yes; then
  89   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  90   AC_SUBST([WERROR_CFLAGS])
  91
  92   nw=
  93   # This, $nw, is the list of warnings we disable.
  94   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  95   nw="$nw -Waggregate-return"       # anachronistic
  96   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  97   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  98   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  99   nw="$nw -Wcast-qual"              # Too many warnings for now
 100   nw="$nw -Wconversion"             # Too many warnings for now
 101   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 102   nw="$nw -Wsign-conversion"        # Too many warnings for now
 103   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 104   nw="$nw -Wunreachable-code"       # Too many warnings for now
 105   nw="$nw -Wpadded"                 # Our structs are not padded
 106   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 107   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 108   nw="$nw -Wvla"                    # two warnings in mount.c
 109   # things I might fix soon:
 110   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 111   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 112   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 113   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 114                                     # was not possible, safe to ignore
 115   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 116   nw="$nw -Wlong-long"              # Allow long long since it's required
 117                                     # by Python, Ruby and xstrtoll.
 118
 119   gl_MANYWARN_ALL_GCC([ws])
 120   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 121   for w in $ws; do
 122     gl_WARN_ADD([$w])
 123   done
 124   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 125   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 126   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 127
 128   # In spite of excluding -Wlogical-op above, it is enabled, as of
 129   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 130   gl_WARN_ADD([-Wno-logical-op])
 131
 132   # Work around warning in src/inspect.c.  This seems to be a bug in gcc 4.5.1.
 133   gl_WARN_ADD([-Wno-strict-overflow])
 134
 135   gl_WARN_ADD([-fdiagnostics-show-option])
 136
 137   AC_SUBST([WARN_CFLAGS])
 138
 139   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 140   AC_DEFINE([_FORTIFY_SOURCE], [2],
 141     [enable compile-time and run-time bounds-checking, and some warnings])
 142   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 143 fi
 144
 145 AC_C_PROTOTYPES
 146 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 147
 148 AM_PROG_CC_C_O
 149
 150 dnl Work out how to specify the linker script to the linker.
 151 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 152 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 153     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 154 AC_SUBST(VERSION_SCRIPT_FLAGS)
 155
 156 dnl Check support for 64 bit file offsets.
 157 AC_SYS_LARGEFILE
 158
 159 dnl Check sizeof long.
 160 AC_CHECK_SIZEOF([long])
 161
 162 dnl Define a C symbol for the host CPU architecture.
 163 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 164
 165 dnl Headers.
 166 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 167
 168 dnl Functions.
 169 AC_CHECK_FUNCS([posix_fallocate])
 170
 171 dnl Build the daemon?
 172 AC_MSG_CHECKING([if we should build the daemon])
 173 AC_ARG_ENABLE([daemon],
 174         [AS_HELP_STRING([--enable-daemon],
 175           [enable building the daemon @<:@default=yes@:>@])],
 176         [],
 177         [enable_daemon=yes])
 178 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 179 AC_MSG_RESULT([$enable_daemon])
 180
 181 dnl Build the appliance?
 182 AC_MSG_CHECKING([if we should build the appliance])
 183 AC_ARG_ENABLE([appliance],
 184         [AS_HELP_STRING([--enable-appliance],
 185           [enable building the appliance @<:@default=yes@:>@])],
 186         [],
 187         [enable_appliance=yes])
 188 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 189 AC_MSG_RESULT([$enable_appliance])
 190
 191 dnl Check for PCRE.
 192 AC_CHECK_LIB([pcre],[pcre_compile],
 193         [AC_SUBST([LIBPCRE], ["-lpcre"])],
 194         [AC_MSG_FAILURE(
 195              [Perl Compatible Regular Expressions library (PCRE) is required])])
 196 AC_CHECK_HEADER([pcre.h],[],
 197         [AC_MSG_FAILURE(
 198              [Perl Compatible Regular Expressions library (PCRE) header file pcre.h is required])])
 199
 200 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 201 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 202 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 203 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 204         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 205         ])
 206
 207 dnl Check for cpio which isn't in the default Pardus install amazingly.
 208 AC_CHECK_PROG([CPIO],[cpio],[cpio],[no])
 209 test "x$CPIO" = "xno" &&
 210      AC_MSG_ERROR([cpio must be installed])
 211
 212 dnl Check for gperf.
 213 AC_CHECK_PROG([GPERF],[gperf],[gperf],[no])
 214 test "x$GPERF" = "xno" &&
 215      AC_MSG_ERROR([gperf must be installed])
 216
 217 dnl Check for pod2man and pod2text.
 218 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 219 test "x$POD2MAN" = "xno" &&
 220      AC_MSG_ERROR([pod2man must be installed])
 221 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 222 test "x$POD2TEXT" = "xno" &&
 223      AC_MSG_ERROR([pod2text must be installed])
 224
 225 dnl Check for mkisofs.
 226 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 227         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 228 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 229
 230 dnl Check for optional xmllint.
 231 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 232 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 233
 234 dnl Check for QEMU for running binaries on this $host_cpu, fall
 235 dnl back to basic 'qemu'.  Allow the user to override it.
 236 default_qemu="qemu-kvm kvm qemu-system-$host_cpu qemu"
 237 AC_ARG_WITH([qemu],
 238         [AS_HELP_STRING([--with-qemu],
 239           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 240         [],
 241         [with_qemu="$default_qemu"])
 242 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 243         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 244 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 245 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 246
 247 dnl Check that the chosen qemu has virtio-serial support.
 248 if test "x$vmchannel_test" != "xno"; then
 249     AC_MSG_CHECKING([for virtio-serial support in $QEMU])
 250     if $QEMU -nographic -device \? 2>&1 | grep -sq virtio-serial; then
 251         AC_MSG_RESULT([yes])
 252         vmchannel_guestfwd=guestfwd
 253     else
 254         AC_MSG_RESULT([no])
 255         AC_MSG_FAILURE(
 256 [I did not find virtio-serial support in
 257 $QEMU.
 258
 259 virtio-serial support in qemu or KVM is essential for libguestfs
 260 to operate.
 261
 262 Usually this means that you have to install a newer version of qemu
 263 and/or KVM.  Please read the relevant section in the README file for
 264 more information about this.
 265
 266 You can override this test by setting the environment variable
 267 vmchannel_test=no  However if you don't have the right support
 268 in your qemu, then this just delays the pain.
 269
 270 If I am using the wrong qemu or you want to compile qemu from source
 271 and install it in another location, then you should configure with
 272 the --with-qemu option.
 273 ])
 274     fi
 275 fi
 276
 277 dnl Set default drive interface used by the guestfs_add_drive_opts call
 278 dnl ('-drive ...,if=...' option to qemu).
 279 dnl
 280 dnl If you encounter performance problems with virtio (RHBZ#509383)
 281 dnl then try '--with-drive-if=ide'.
 282 AC_ARG_WITH([drive-if],
 283         [AS_HELP_STRING([--with-drive-if],
 284           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 285         [],
 286         [with_drive_if=virtio])
 287 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 288
 289 dnl Set interface used by the network.  Normally you should
 290 dnl leave this at the default (virtio-net-pci) but you can use the
 291 dnl alternative (ne2k_pci) because of bugs in virtio networking
 292 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 293 AC_ARG_WITH([net-if],
 294         [AS_HELP_STRING([--with-net-if],
 295           [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
 296         [],
 297         [with_net_if=virtio-net-pci])
 298 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 299
 300 dnl Check for febootstrap etc.
 301 if test "x$enable_appliance" = "xyes"; then
 302     AC_CHECK_PROG([FEBOOTSTRAP],
 303                   [febootstrap],[febootstrap],[no])
 304     if test "x$FEBOOTSTRAP" != "xno"; then
 305       AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 306                     [febootstrap-run],[febootstrap-run],[no])
 307       test "x$FEBOOTSTRAP_RUN" = "xno" && \
 308           AC_MSG_ERROR([febootstrap-run must be installed])
 309       AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 310                     [febootstrap-install],[febootstrap-install],[no])
 311       test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 312           AC_MSG_ERROR([febootstrap-install must be installed])
 313       AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 314                     [febootstrap-minimize],[febootstrap-minimize],[no])
 315       test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 316           AC_MSG_ERROR([febootstrap-minimize must be installed])
 317       AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 318                     [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 319       test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 320           AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 321       AC_CHECK_PROG([FEBOOTSTRAP_TO_SUPERMIN],
 322                     [febootstrap-to-supermin],[febootstrap-to-supermin],[no])
 323       test "x$FEBOOTSTRAP_TO_SUPERMIN" = "xno" && \
 324           AC_MSG_ERROR([febootstrap-to-supermin must be installed])
 325
 326       dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 327       dnl of febootstrap, but old versions will fail with yum).
 328       AC_CHECK_PROG([FAKECHROOT],
 329                     [fakechroot],[fakechroot],[no])
 330       test "x$FAKECHROOT" = "xno" && \
 331          AC_MSG_ERROR([fakechroot must be installed])
 332
 333       AC_MSG_CHECKING([fakechroot version])
 334       fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 335       if test -z "$fakechroot_version"; then
 336         AC_MSG_RESULT([failed])
 337         AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 338       else
 339         AC_MSG_RESULT([$fakechroot_version])
 340         fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 341         fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 342         if test "$fakechroot_major" -lt 2 || \
 343           ( test "$fakechroot_major" -eq 2 && test "$fakechroot_minor" -lt 9 ); then
 344           AC_MSG_ERROR([fakechroot version must be >= 2.9])
 345         fi
 346       fi
 347       DIST="REDHAT"
 348     else
 349       # check for debootstrap and debirf
 350       AC_CHECK_PROG([DEBOOTSTRAP],
 351                     [debootstrap],[debootstrap],[no])
 352       test "x$DEBOOTSTRAP" = "xno" && \
 353           AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 354       AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 355       test "x$DEBIRF" = "xno" &&
 356           AC_MSG_ERROR([debirf must be installed])
 357       DIST="DEBIAN"
 358       case "$host_cpu" in
 359       *86)
 360           DEBIAN_KERNEL_ARCH=486
 361           ;;
 362       x86_64)
 363           DEBIAN_KERNEL_ARCH=amd64
 364           ;;
 365       *)
 366          DEBIAN_KERNEL_ARCH=$host_cpu
 367          ;;
 368       esac
 369       AC_SUBST(DEBIAN_KERNEL_ARCH)
 370     fi
 371     AC_SUBST(DIST)
 372
 373     dnl --with-updates to specify a Fedora updates repository.
 374     AC_ARG_WITH([updates],
 375         [AS_HELP_STRING([--with-updates],
 376           [set name of Fedora updates repository @<:@default=updates-released-f12@:>@])],
 377         [],
 378         [with_updates=updates-released-f12])
 379     UPDATES="$with_updates"
 380     AC_SUBST(UPDATES)
 381
 382     dnl --with-mirror to specify a local Fedora mirror.
 383     AC_ARG_WITH([mirror],
 384         [AS_HELP_STRING([--with-mirror],
 385           [set URI of a local Fedora mirror])],
 386         [],
 387         [with_mirror=])
 388     MIRROR="$with_mirror"
 389     AC_SUBST(MIRROR)
 390 fi
 391
 392 dnl --with-repo to specify a repository.
 393 AC_ARG_WITH([repo],
 394         [AS_HELP_STRING([--with-repo],
 395           [set name of Fedora repository @<:@default=fedora-13@:>@])],
 396         [],
 397         [with_repo=fedora-13])
 398 REPO="$with_repo"
 399 AC_SUBST(REPO)
 400 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of software repository.])
 401
 402 dnl Build the supermin appliance?  Please see README file before
 403 dnl enabling this option.
 404 AC_ARG_ENABLE([supermin],
 405         [AS_HELP_STRING([--enable-supermin],
 406           [enable supermin appliance (see README) @<:@default=no@:>@])],
 407         [AC_DEFINE([ENABLE_SUPERMIN],[1],[Supermin appliance enabled.])],
 408         [enable_supermin=no])
 409 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 410
 411 dnl Enable packet dumps when in verbose mode.  This generates lots
 412 dnl of debug info, only useful for people debugging the RPC mechanism.
 413 AC_ARG_ENABLE([packet-dump],
 414         [AS_HELP_STRING([--enable-packet-dump],
 415           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 416         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 417         [])
 418
 419 dnl Readline.
 420 AC_ARG_WITH([readline],
 421     [AS_HELP_STRING([--with-readline],
 422         [support fancy command line editing @<:@default=check@:>@])],
 423     [],
 424     [with_readline=check])
 425
 426 LIBREADLINE=
 427 AS_IF([test "x$with_readline" != xno],
 428     [AC_CHECK_LIB([readline], [main],
 429         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 430          AC_DEFINE([HAVE_LIBREADLINE], [1],
 431                    [Define if you have libreadline])
 432         ],
 433         [if test "x$with_readline" != xcheck; then
 434          AC_MSG_FAILURE(
 435              [--with-readline was given, but test for readline failed])
 436          fi
 437         ], -lncurses)
 438      old_LIBS="$LIBS"
 439      LIBS="$LIBS $LIBREADLINE"
 440      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 441      LIBS="$old_LIBS"
 442     ])
 443
 444 dnl For i18n.
 445 AM_GNU_GETTEXT([external])
 446 AM_GNU_GETTEXT_VERSION([0.17])
 447
 448 dnl libmagic (required)
 449 AC_CHECK_LIB([magic],[magic_file],[
 450         AC_SUBST([LIBMAGIC], ["-lmagic"])
 451     ],[
 452         AC_MSG_FAILURE([libmagic is required])
 453     ])
 454 AC_CHECK_HEADER([magic.h],[],[
 455         AC_MSG_FAILURE([magic.h header file is required])
 456     ])
 457
 458 dnl libvirt (required)
 459 PKG_CHECK_MODULES([LIBVIRT], [libvirt])
 460 AC_SUBST([LIBVIRT_CFLAGS])
 461 AC_SUBST([LIBVIRT_LIBS])
 462
 463 dnl libxml2 (required)
 464 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0])
 465 AC_SUBST([LIBXML2_CFLAGS])
 466 AC_SUBST([LIBXML2_LIBS])
 467
 468
 469 dnl hivex library (required)
 470 dnl This used to be a part of libguestfs, but was spun off into its
 471 dnl own separate upstream project in libguestfs 1.0.85.
 472 PKG_CHECK_MODULES([HIVEX], [hivex])
 473 AC_SUBST([HIVEX_CFLAGS])
 474 AC_SUBST([HIVEX_LIBS])
 475
 476 dnl FUSE is optional to build the FUSE module.
 477 AC_ARG_ENABLE([fuse],
 478         AS_HELP_STRING([--disable-fuse], [Disable FUSE (guestmount) support]),
 479         [],
 480         [enable_fuse=yes])
 481 AS_IF([test "x$enable_fuse" != "xno"],
 482         [PKG_CHECK_MODULES([FUSE],[fuse],,[
 483                 enable_fuse=no
 484                 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])])
 485 AM_CONDITIONAL([HAVE_FUSE],[test "x$enable_fuse" != "xno"])
 486
 487 dnl Check for OCaml (optional, for OCaml bindings).
 488 OCAMLC=no
 489 OCAMLFIND=no
 490 OCAML_PKG_xml_light=no
 491 AC_ARG_ENABLE([ocaml],
 492         AS_HELP_STRING([--disable-ocaml], [Disable OCaml language bindings]),
 493         [],
 494         [enable_ocaml=yes])
 495 AS_IF([test "x$enable_ocaml" != "xno"],
 496         [dnl OCAMLC and OCAMLFIND have to be unset first, otherwise
 497          dnl AC_CHECK_TOOL (inside AC_PROG_OCAML) will not look.
 498          OCAMLC=
 499          OCAMLFIND=
 500          AC_PROG_OCAML
 501          AC_PROG_FINDLIB
 502
 503          dnl Optional xml-light for running the generator.
 504          if test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"; then
 505              AC_CHECK_OCAML_PKG([xml-light])
 506          fi])
 507 AM_CONDITIONAL([HAVE_OCAML],
 508                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
 509 AM_CONDITIONAL([HAVE_XML_LIGHT],[test "x$OCAML_PKG_xml_light" != "xno"])
 510
 511 dnl Check for Perl (optional, for Perl bindings).
 512 PERL=no
 513 AC_ARG_ENABLE([perl],
 514         AS_HELP_STRING([--disable-perl], [Disable Perl language bindings]),
 515         [],
 516         [enable_perl=yes])
 517 AS_IF([test "x$enable_perl" != "xno"],
 518         [
 519         PERL=
 520         AC_CHECK_PROG([PERL],[perl],[perl],[no])
 521
 522         dnl Check for Perl modules that must be present to compile and
 523         dnl test the Perl bindings.
 524         missing_perl_modules=no
 525         for pm in Test::More ExtUtils::MakeMaker; do
 526             AC_MSG_CHECKING([for $pm])
 527             if ! perl -M$pm -e1 >/dev/null 2>&1; then
 528                 AC_MSG_RESULT([no])
 529                 missing_perl_modules=yes
 530             else
 531                 AC_MSG_RESULT([yes])
 532             fi
 533         done
 534         if test "x$missing_perl_modules" = "xyes"; then
 535             AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 536         fi
 537         ])
 538 AM_CONDITIONAL([HAVE_PERL],
 539     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 540
 541 dnl Check for Python (optional, for Python bindings).
 542 PYTHON_PREFIX=
 543 PYTHON_VERSION=
 544 PYTHON_INCLUDEDIR=
 545 PYTHON_SITE_PACKAGES=
 546
 547 AC_ARG_ENABLE([python],
 548         AS_HELP_STRING([--disable-python], [Disable Python language bindings]),
 549         [],
 550         [enable_python=yes])
 551 AS_IF([test "x$enable_python" != "xno"],
 552         [
 553         AC_CHECK_PROG([PYTHON],[python],[python],[no])
 554
 555         if test "x$PYTHON" != "xno"; then
 556             PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 557             PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 558             for d in \
 559                 $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 560                 /usr/include/python$PYTHON_VERSION \
 561                 /usr/local/include/python$PYTHON_VERSION
 562             do
 563                 AC_MSG_CHECKING([Python.h in $d])
 564                 if test -r "$d/Python.h"; then
 565                     AC_MSG_RESULT([found])
 566                     PYTHON_INCLUDEDIR=$d
 567                     break
 568                 fi
 569                 AC_MSG_RESULT([not found])
 570             done
 571             if test "x$PYTHON_INCLUDEDIR" = "x"; then
 572                 AC_MSG_WARN([Python include directory not found])
 573             fi
 574
 575             for d in \
 576                 $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 577                 $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 578                 /usr/lib64/python$PYTHON_VERSION/site-packages \
 579                 /usr/lib/python$PYTHON_VERSION/site-packages \
 580                 /usr/local/lib/python$PYTHON_VERSION/site-packages
 581             do
 582                 AC_MSG_CHECKING([for $d])
 583                 if test -d "$d"; then
 584                     AC_MSG_RESULT([found])
 585                     PYTHON_SITE_PACKAGES=$d
 586                     break
 587                 fi
 588                 AC_MSG_RESULT([not found])
 589             done
 590             if test "x$PYTHON_SITE_PACKAGES" = "x"; then
 591                 AC_MSG_WARN([Python site-packages directory not found])
 592             fi
 593
 594             old_LIBS="$LIBS"
 595             LIBS="$LIBS -lpython$PYTHON_VERSION"
 596             AC_CHECK_FUNCS([PyCapsule_New])
 597             LIBS="$old_LIBS"
 598         fi
 599
 600         AC_SUBST(PYTHON_PREFIX)
 601         AC_SUBST(PYTHON_VERSION)
 602         AC_SUBST(PYTHON_INCLUDEDIR)
 603         AC_SUBST(PYTHON_SITE_PACKAGES)
 604         ])
 605 AM_CONDITIONAL([HAVE_PYTHON],
 606     [test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_SITE_PACKAGES" != "x"])
 607
 608 dnl Check for Ruby and rake (optional, for Ruby bindings).
 609 AC_ARG_ENABLE([ruby],
 610         AS_HELP_STRING([--disable-ruby], [Disable Ruby language bindings]),
 611         [],
 612         [enable_ruby=yes])
 613 AS_IF([test "x$enable_ruby" != "xno"],
 614         [
 615         AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 616         AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 617         ])
 618 AM_CONDITIONAL([HAVE_RUBY],
 619     [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
 620
 621 dnl Check for Java.
 622 AC_ARG_WITH(java_home,
 623     [AS_HELP_STRING([--with-java-home],
 624         [specify path to JDK directory @<:@default=check@:>@])],
 625     [],
 626     [with_java_home=check])
 627
 628 if test "x$with_java_home" != "xno"; then
 629     if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
 630     then
 631         # Reject unsafe characters in $JAVA_HOME
 632         jh_lf='
 633 '
 634         case $JAVA_HOME in
 635           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 636             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 637         esac
 638         if test -d "$with_java_home"; then
 639             JAVA_HOME="$with_java_home"
 640         else
 641             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 642         fi
 643     fi
 644
 645     if test "x$JAVA_HOME" = "x"; then
 646         # Look for Java in some likely locations.
 647         for d in \
 648             /usr/lib/jvm/java \
 649             /usr/lib/jvm/java-6-openjdk
 650         do
 651             if test -d $d && test -f $d/bin/java; then
 652                 JAVA_HOME=$d
 653                 break
 654             fi
 655         done
 656     fi
 657
 658     if test "x$JAVA_HOME" != "x"; then
 659         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 660         if test ! -x "$JAVA_HOME/bin/java"; then
 661             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 662         else
 663             JAVA="$JAVA_HOME/bin/java"
 664         fi
 665         if test ! -x "$JAVA_HOME/bin/javac"; then
 666             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 667         else
 668             JAVAC="$JAVA_HOME/bin/javac"
 669         fi
 670         if test ! -x "$JAVA_HOME/bin/javah"; then
 671             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 672         else
 673             JAVAH="$JAVA_HOME/bin/javah"
 674         fi
 675         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 676             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 677         else
 678             JAVADOC="$JAVA_HOME/bin/javadoc"
 679         fi
 680         if test ! -x "$JAVA_HOME/bin/jar"; then
 681             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 682         else
 683             JAR="$JAVA_HOME/bin/jar"
 684         fi
 685         java_version=`$JAVA -version 2>&1 | grep "java version"`
 686         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 687
 688         dnl Find jni.h.
 689         AC_MSG_CHECKING([for jni.h])
 690         if test -f "$JAVA_HOME/include/jni.h"; then
 691             JNI_CFLAGS="-I$JAVA_HOME/include"
 692         else
 693             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 694                 head=`find $JAVA_HOME -name jni.h | tail -1`
 695                 dir=`dirname "$head"`
 696                 JNI_CFLAGS="-I$dir"
 697             else
 698                 AC_MSG_FAILURE([missing jni.h header file])
 699             fi
 700         fi
 701         AC_MSG_RESULT([$JNI_CFLAGS])
 702
 703         dnl Find jni_md.h.
 704         AC_MSG_CHECKING([for jni_md.h])
 705         case "$build_os" in
 706         *linux*) system="linux" ;;
 707         *SunOS*) system="solaris" ;;
 708         *cygwin*) system="win32" ;;
 709         *) system="$build_os" ;;
 710         esac
 711         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 712             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 713         else
 714             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 715                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 716                 dir=`dirname "$head"`
 717                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 718             else
 719                 AC_MSG_FAILURE([missing jni_md.h header file])
 720             fi
 721         fi
 722         AC_MSG_RESULT([$JNI_CFLAGS])
 723
 724         dnl Need extra version flag?
 725         AC_MSG_CHECKING([extra javac flags])
 726         JAVAC_FLAGS=
 727         javac_version=`$JAVAC -version 2>&1`
 728         case "$javac_version" in
 729         *Eclipse*)
 730             JAVAC_FLAGS="-source 1.5" ;;
 731         esac
 732         AC_MSG_RESULT([$JAVAC_FLAGS])
 733
 734         dnl Where to install jarfiles.
 735         dnl XXX How to make it configurable?
 736         JAR_INSTALL_DIR=\${prefix}/share/java
 737         JNI_INSTALL_DIR=\${libdir}
 738
 739         dnl JNI version.
 740         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 741         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 742         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 743         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 744     fi
 745 fi
 746
 747 AC_SUBST(JAVA_HOME)
 748 AC_SUBST(JAVA)
 749 AC_SUBST(JAVAC)
 750 AC_SUBST(JAVAH)
 751 AC_SUBST(JAVADOC)
 752 AC_SUBST(JAR)
 753 AC_SUBST(JNI_CFLAGS)
 754 AC_SUBST(JAVAC_FLAGS)
 755 AC_SUBST(JAR_INSTALL_DIR)
 756 AC_SUBST(JNI_INSTALL_DIR)
 757 AC_SUBST(JNI_VERSION_INFO)
 758
 759 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 760
 761 dnl Check for Haskell (GHC).
 762 GHC=no
 763 AC_ARG_ENABLE([haskell],
 764         AS_HELP_STRING([--disable-haskell], [Disable Haskell language bindings]),
 765         [],
 766         [enable_haskell=yes])
 767 AS_IF([test "x$enable_haskell" != "xno"],
 768         [
 769         GHC=
 770         AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 771         ])
 772 AM_CONDITIONAL([HAVE_HASKELL],
 773     [test "x$GHC" != "xno"])
 774
 775 dnl PHP
 776 PHP=no
 777 AC_ARG_ENABLE([php],
 778         AS_HELP_STRING([--disable-php], [Disable PHP language bindings]),
 779         [],
 780         [enable_php=yes])
 781 AS_IF([test "x$enable_php" != "xno"],
 782         [
 783         PHP=
 784         AC_CHECK_PROG([PHP],[php],[php],[no])
 785         AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
 786         ])
 787 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
 788
 789 dnl Check for Perl modules needed by virt-df, inspector, etc.
 790 AS_IF([test "x$PERL" != "xno"],
 791         [
 792         missing_perl_modules=no
 793         for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer Locale::TextDomain Win::Hivex Win::Hivex::Regedit; do
 794             AC_MSG_CHECKING([for $pm])
 795             if ! $PERL -M$pm -e1 >/dev/null 2>&1; then
 796                 AC_MSG_RESULT([no])
 797                 missing_perl_modules=yes
 798             else
 799                 AC_MSG_RESULT([yes])
 800             fi
 801         done
 802         if test "x$missing_perl_modules" = "xyes"; then
 803             AC_MSG_WARN([some Perl modules required to compile virt-inspector and the other virt-* tools are missing])
 804         fi
 805         ])
 806
 807 AM_CONDITIONAL([HAVE_INSPECTOR],
 808     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 809 AM_CONDITIONAL([HAVE_TOOLS],
 810     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 811
 812 dnl po4a for translating man pages and POD files (optional).
 813 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
 814 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
 815
 816 dnl Library versioning.
 817 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 818 AC_SUBST(MAX_PROC_NR)
 819
 820 dnl Run in subdirs.
 821 if test "x$enable_daemon" = "xyes"; then
 822     AC_CONFIG_SUBDIRS([daemon])
 823 fi
 824
 825 dnl Produce output files.
 826 AC_CONFIG_HEADERS([config.h])
 827 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 828 AC_CONFIG_FILES([appliance/update.sh],
 829                 [chmod +x appliance/update.sh])
 830 AC_CONFIG_FILES([Makefile
 831                  generator/Makefile
 832                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 833                  appliance/Makefile
 834                  appliance/debian/debirf.conf
 835                  images/Makefile
 836                  capitests/Makefile
 837                  regressions/Makefile
 838                  test-tool/Makefile
 839                  ocaml/Makefile ocaml/examples/Makefile
 840                  perl/Makefile
 841                  python/Makefile
 842                  ruby/Makefile ruby/Rakefile
 843                  java/Makefile
 844                  haskell/Makefile
 845                  inspector/Makefile
 846                  tools/Makefile
 847                  libguestfs.pc
 848                  gnulib/lib/Makefile
 849                  gnulib/tests/Makefile
 850                  fuse/Makefile
 851                  po-docs/Makefile
 852                  po-docs/ja/Makefile
 853                  php/Makefile
 854                  csharp/Makefile
 855                  ocaml/META perl/Makefile.PL])
 856 AC_OUTPUT
 857
 858 dnl Produce summary.
 859 echo
 860 echo
 861 echo "------------------------------------------------------------"
 862 echo "Thank you for downloading $PACKAGE_STRING"
 863 echo
 864 echo "This is how we have configured the optional components for you today:"
 865 echo
 866 echo    "Daemon .............................. $enable_daemon"
 867 echo    "Appliance ........................... $enable_appliance"
 868 echo    "QEMU ................................ $QEMU"
 869 echo -n "OCaml bindings ...................... "
 870 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 871 echo -n "Perl bindings ....................... "
 872 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 873 echo -n "Python bindings ..................... "
 874 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 875 echo -n "Ruby bindings ....................... "
 876 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 877 echo -n "Java bindings ....................... "
 878 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 879 echo -n "Haskell bindings .................... "
 880 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 881 echo -n "PHP bindings ........................ "
 882 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 883 echo -n "virt-inspector ...................... "
 884 if test "x$HAVE_INSPECTOR_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 885 echo -n "virt-* tools ........................ "
 886 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 887 echo "supermin appliance .................. $enable_supermin"
 888 echo "FUSE filesystem ..................... $enable_fuse"
 889 echo
 890 echo "If any optional component is configured 'no' when you expected 'yes'"
 891 echo "then you should check the preceeding messages."
 892 echo
 893 echo "Please report bugs back to the mailing list:"
 894 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 895 echo
 896 echo "Next you should type 'make' to build the package,"
 897 echo "then 'make check' to run the tests."
 898 echo "------------------------------------------------------------"