configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 AC_INIT([libguestfs],[1.0.48])
  19 AM_INIT_AUTOMAKE
  20
  21 AC_CONFIG_MACRO_DIR([m4])
  22
  23 AC_PROG_LIBTOOL
  24
  25 dnl Check for basic C environment.
  26 AC_PROG_CC_STDC
  27 AC_PROG_INSTALL
  28 AC_PROG_CPP
  29
  30 AC_C_PROTOTYPES
  31 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
  32
  33 AM_PROG_CC_C_O
  34
  35 dnl Check support for 64 bit file offsets.
  36 AC_SYS_LARGEFILE
  37
  38 dnl Check sizeof long.
  39 AC_CHECK_SIZEOF([long])
  40
  41 dnl Headers.
  42 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h])
  43
  44 dnl Check for rpcgen and XDR library.  rpcgen is optional.
  45 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
  46 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
  47 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
  48         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
  49         ])
  50
  51 dnl Check for pod2man and pod2text.
  52 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
  53 test "x$POD2MAN" = "xno" &&
  54      AC_MSG_ERROR([pod2man must be installed])
  55 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
  56 test "x$POD2TEXT" = "xno" &&
  57      AC_MSG_ERROR([pod2text must be installed])
  58
  59 dnl Check for mksquashfs.
  60 AC_PATH_PROGS([MKSQUASHFS],[mksquashfs],[no],
  61         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
  62 test "x$MKSQUASHFS" = "xno" && AC_MSG_ERROR([mksquashfs must be installed])
  63
  64 dnl Check for QEMU for running binaries on this $host_cpu, fall
  65 dnl back to basic 'qemu'.  Allow the user to override it.
  66 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
  67 AC_ARG_WITH([qemu],
  68         [AS_HELP_STRING([--with-qemu],
  69           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
  70         [],
  71         [with_qemu="$default_qemu"])
  72 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
  73         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
  74 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
  75 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
  76
  77 dnl Check that the chosen qemu has vmchannel support.
  78 dnl http://lists.gnu.org/archive/html/qemu-devel/2009-02/msg01042.html
  79 if test "x$vmchannel_test" != "xno"; then
  80     AC_MSG_CHECKING([for vmchannel support in $QEMU])
  81     vmchannelout=`$QEMU -net channel /dev/zero 2>&1 ||:`
  82     echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
  83     if ! echo $vmchannelout | grep -sq "vmchannel wrong port number" ; then
  84         AC_MSG_RESULT([no])
  85         AC_MSG_FAILURE(
  86 [I did not find vmchannel support in $QEMU.
  87
  88 vmchannel support is vital for libguestfs to operate.  You need a version
  89 of qemu >= 0.10, or the following patch backported to earlier versions:
  90
  91 http://lists.gnu.org/archive/html/qemu-devel/2009-02/msg01042.html
  92
  93 You can override this test by setting the environment variable
  94 vmchannel_test=no  However if you don't have vmchannel support
  95 in your qemu, then this just delays the pain.
  96
  97 If I am using the wrong qemu or you want to compile qemu from source
  98 and install it in another location, then you should configure with
  99 the --with-qemu option.
 100 ])
 101     fi
 102     AC_MSG_RESULT([yes])
 103 fi
 104
 105 dnl Check for febootstrap etc.
 106 AC_CHECK_PROG([FEBOOTSTRAP],
 107         [febootstrap],[febootstrap],[no])
 108 test "x$FEBOOTSTRAP" = "xno" && \
 109      AC_MSG_ERROR([febootstrap must be installed])
 110 AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 111         [febootstrap-run],[febootstrap-run],[no])
 112 test "x$FEBOOTSTRAP_RUN" = "xno" && \
 113      AC_MSG_ERROR([febootstrap-run must be installed])
 114 AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 115         [febootstrap-install],[febootstrap-install],[no])
 116 test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 117      AC_MSG_ERROR([febootstrap-install must be installed])
 118 AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 119         [febootstrap-minimize],[febootstrap-minimize],[no])
 120 test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 121      AC_MSG_ERROR([febootstrap-minimize must be installed])
 122 AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 123         [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 124 test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 125      AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 126
 127 dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 128 dnl of febootstrap, but old versions will fail with yum).
 129 AC_CHECK_PROG([FAKECHROOT],
 130         [fakechroot],[fakechroot],[no])
 131 test "x$FAKECHROOT" = "xno" && \
 132     AC_MSG_ERROR([fakechroot must be installed])
 133
 134 AC_MSG_CHECKING([fakechroot version])
 135 fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 136 if test -z "$fakechroot_version"; then
 137     AC_MSG_RESULT([failed])
 138     AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 139 else
 140     AC_MSG_RESULT([$fakechroot_version])
 141     fakechroot_major=`echo $fakechroot_version | awk -F. '{print $1}'`
 142     fakechroot_minor=`echo $fakechroot_version | awk -F. '{print $2}'`
 143     if test "$fakechroot_major" -lt 2 -o \
 144             \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
 145         AC_MSG_ERROR([fakechroot version must be >= 2.9])
 146     fi
 147 fi
 148
 149 dnl --with-repo to specify a Fedora repository.
 150 AC_ARG_WITH([repo],
 151         [AS_HELP_STRING([--with-repo],
 152           [set name of Fedora repository @<:@default=fedora-11@:>@])],
 153         [],
 154         [with_repo=fedora-11])
 155 REPO="$with_repo"
 156 AC_SUBST(REPO)
 157 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 158
 159 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 160
 161 dnl --with-updates to specify a Fedora updates repository.
 162 AC_ARG_WITH([updates],
 163         [AS_HELP_STRING([--with-updates],
 164           [set name of Fedora updates repository @<:@default=updates-released-f11@:>@])],
 165         [],
 166         [with_updates=updates-released-f11])
 167 UPDATES="$with_updates"
 168 AC_SUBST(UPDATES)
 169 AC_DEFINE_UNQUOTED([UPDATES],["$UPDATES"],[Name of Fedora updates repository.])
 170
 171 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 172
 173 dnl --with-mirror to specify a local Fedora mirror.
 174 AC_ARG_WITH([mirror],
 175         [AS_HELP_STRING([--with-mirror],
 176           [set URI of a local Fedora mirror])],
 177         [],
 178         [with_mirror=])
 179 MIRROR="$with_mirror"
 180 AC_SUBST(MIRROR)
 181
 182 dnl Build the supermin appliance?  Please see README file before
 183 dnl enabling this option.
 184 AC_ARG_ENABLE([supermin],
 185         [AS_HELP_STRING([--enable-supermin],
 186           [enable supermin appliance (see README) @<:@default=no@:>@])],
 187         [],
 188         [enable_supermin=no])
 189 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 190
 191 if test "x$enable_supermin" = "xyes"; then
 192     dnl Check febootstrap-to-initramfs accepts the --files option
 193     dnl (febootstrap >= 2.2).
 194     AC_MSG_CHECKING([for --files support in $FEBOOTSTRAP_TO_INITRAMFS])
 195     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 196     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 197     if ! echo $out | grep -sq -- "--files" ; then
 198         AC_MSG_RESULT([no])
 199         AC_MSG_FAILURE(
 200 [febootstrap-to-initramfs does not support the --files option.
 201
 202 To build the supermin appliance, you need to upgrade to the latest
 203 version of febootstrap.
 204 ])
 205     fi
 206     AC_MSG_RESULT([yes])
 207
 208     dnl Check febootstrap-to-initramfs accepts the --nocompress option
 209     dnl (febootstrap >= 2.3).
 210     AC_MSG_CHECKING([for --nocompress support in $FEBOOTSTRAP_TO_INITRAMFS])
 211     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 212     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 213     if ! echo $out | grep -sq -- "--nocompress" ; then
 214         AC_MSG_RESULT([no])
 215         AC_MSG_FAILURE(
 216 [febootstrap-to-initramfs does not support the --nocompress option.
 217
 218 To build the supermin appliance, you need to upgrade to the latest
 219 version of febootstrap.
 220 ])
 221     fi
 222     AC_MSG_RESULT([yes])
 223 fi
 224
 225 dnl Readline.
 226 AC_ARG_WITH([readline],
 227     [AS_HELP_STRING([--with-readline],
 228         [support fancy command line editing @<:@default=check@:>@])],
 229     [],
 230     [with_readline=check])
 231
 232 LIBREADLINE=
 233 AS_IF([test "x$with_readline" != xno],
 234     [AC_CHECK_LIB([readline], [main],
 235         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 236          AC_DEFINE([HAVE_LIBREADLINE], [1],
 237                    [Define if you have libreadline])
 238         ],
 239         [if test "x$with_readline" != xcheck; then
 240          AC_MSG_FAILURE(
 241              [--with-readline was given, but test for readline failed])
 242          fi
 243         ], -lncurses)])
 244
 245 dnl For i18n.
 246 AM_GNU_GETTEXT([external])
 247 AM_GNU_GETTEXT_VERSION([0.14])
 248
 249 dnl Check for OCaml (optional, for OCaml bindings).
 250 AC_PROG_OCAML
 251 AC_PROG_FINDLIB
 252 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
 253
 254 dnl Check for Perl (optional, for Perl bindings).
 255 dnl XXX This isn't quite right, we should check for Perl devel library.
 256 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 257
 258 dnl Check for Perl modules that must be present to compile and
 259 dnl test the Perl bindings.
 260 missing_perl_modules=no
 261 for pm in Test::More Test::Pod Test::Pod::Coverage ExtUtils::MakeMaker; do
 262     AC_MSG_CHECKING([for $pm])
 263     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 264         AC_MSG_RESULT([no])
 265         missing_perl_modules=yes
 266     else
 267         AC_MSG_RESULT([yes])
 268     fi
 269 done
 270 if test "x$missing_perl_modules" = "xyes"; then
 271     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 272 fi
 273
 274 AM_CONDITIONAL([HAVE_PERL],
 275     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 276
 277 dnl Check for Python (optional, for Python bindings).
 278 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 279
 280 PYTHON_PREFIX=
 281 PYTHON_VERSION=
 282 PYTHON_INCLUDEDIR=
 283 PYTHON_SITE_PACKAGES=
 284
 285 if test "x$PYTHON" != "xno"; then
 286     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 287     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 288     for d in \
 289         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 290         /usr/include/python$PYTHON_VERSION \
 291         /usr/local/include/python$PYTHON_VERSION
 292     do
 293         AC_MSG_CHECKING([Python.h in $d])
 294         if test -r "$d/Python.h"; then
 295             AC_MSG_RESULT([found])
 296             PYTHON_INCLUDEDIR=$d
 297             break
 298         fi
 299         AC_MSG_RESULT([not found])
 300     done
 301     for d in \
 302         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 303         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 304         /usr/lib64/python$PYTHON_VERSION/site-packages \
 305         /usr/lib/python$PYTHON_VERSION/site-packages \
 306         /usr/local/lib/python$PYTHON_VERSION/site-packages
 307     do
 308         AC_MSG_CHECKING([for $d])
 309         if test -d "$d"; then
 310             AC_MSG_RESULT([found])
 311             PYTHON_SITE_PACKAGES=$d
 312             break
 313         fi
 314         AC_MSG_RESULT([not found])
 315     done
 316 fi
 317
 318 AC_SUBST(PYTHON_PREFIX)
 319 AC_SUBST(PYTHON_VERSION)
 320 AC_SUBST(PYTHON_INCLUDEDIR)
 321 AC_SUBST(PYTHON_SITE_PACKAGES)
 322
 323 AM_CONDITIONAL([HAVE_PYTHON],
 324     [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
 325
 326 dnl Check for Ruby and rake (optional, for Ruby bindings).
 327 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 328 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 329
 330 AM_CONDITIONAL([HAVE_RUBY],
 331     [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
 332
 333 dnl Check for Java.
 334 AC_ARG_WITH(java_home,
 335     [AS_HELP_STRING([--with-java-home],
 336         [specify path to JDK directory @<:@default=check@:>@])],
 337     [],
 338     [with_java_home=check])
 339
 340 if test "x$with_java_home" != "xno"; then
 341     if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
 342     then
 343         if test -d "$with_java_home"; then
 344             JAVA_HOME="$with_java_home"
 345         else
 346             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 347         fi
 348     fi
 349
 350     if test "x$JAVA_HOME" = "x"; then
 351         # Look for Java in some likely locations.
 352         for d in \
 353             /usr/lib/jvm/java \
 354             /usr/lib/jvm/java-6-openjdk
 355         do
 356             if test -d $d -a -f $d/bin/java; then
 357                 JAVA_HOME=$d
 358                 break
 359             fi
 360         done
 361     fi
 362
 363     if test "x$JAVA_HOME" != "x"; then
 364         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 365         if test ! -x "$JAVA_HOME/bin/java"; then
 366             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 367         else
 368             JAVA="$JAVA_HOME/bin/java"
 369         fi
 370         if test ! -x "$JAVA_HOME/bin/javac"; then
 371             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 372         else
 373             JAVAC="$JAVA_HOME/bin/javac"
 374         fi
 375         if test ! -x "$JAVA_HOME/bin/javah"; then
 376             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 377         else
 378             JAVAH="$JAVA_HOME/bin/javah"
 379         fi
 380         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 381             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 382         else
 383             JAVADOC="$JAVA_HOME/bin/javadoc"
 384         fi
 385         if test ! -x "$JAVA_HOME/bin/jar"; then
 386             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 387         else
 388             JAR="$JAVA_HOME/bin/jar"
 389         fi
 390         java_version=`$JAVA -version 2>&1 | grep "java version"`
 391         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 392
 393         dnl Find jni.h.
 394         AC_MSG_CHECKING([for jni.h])
 395         if test -f "$JAVA_HOME/include/jni.h"; then
 396             JNI_CFLAGS="-I$JAVA_HOME/include"
 397         else
 398             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 399                 head=`find $JAVA_HOME -name jni.h | tail -1`
 400                 dir=`dirname $head`
 401                 JNI_CFLAGS="-I$dir"
 402             else
 403                 AC_MSG_FAILURE([missing jni.h header file])
 404             fi
 405         fi
 406         AC_MSG_RESULT([$JNI_CFLAGS])
 407
 408         dnl Find jni_md.h.
 409         AC_MSG_CHECKING([for jni_md.h])
 410         case "$build_os" in
 411         *linux*) system="linux" ;;
 412         *SunOS*) system="solaris" ;;
 413         *cygwin*) system="win32" ;;
 414         *) system="$build_os" ;;
 415         esac
 416         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 417             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 418         else
 419             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 420                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 421                 dir=`dirname $head`
 422                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 423             else
 424                 AC_MSG_FAILURE([missing jni_md.h header file])
 425             fi
 426         fi
 427         AC_MSG_RESULT([$JNI_CFLAGS])
 428
 429         dnl Need extra version flag?
 430         AC_MSG_CHECKING([extra javac flags])
 431         JAVAC_FLAGS=
 432         javac_version=`$JAVAC -version 2>&1`
 433         case "$javac_version" in
 434         *Eclipse*)
 435             JAVAC_FLAGS="-source 1.5" ;;
 436         esac
 437         AC_MSG_RESULT([$JAVAC_FLAGS])
 438
 439         dnl Where to install jarfiles.
 440         dnl XXX How to make it configurable?
 441         JAR_INSTALL_DIR=\${prefix}/share/java
 442         JNI_INSTALL_DIR=\${libdir}
 443
 444         dnl JNI version.
 445         jni_major_version=`echo $VERSION | awk -F. '{print $1}'`
 446         jni_minor_version=`echo $VERSION | awk -F. '{print $2}'`
 447         jni_micro_version=`echo $VERSION | awk -F. '{print $3}'`
 448         JNI_VERSION_INFO=`expr $jni_major_version + $jni_minor_version`:$jni_micro_version:$jni_minor_version
 449     fi
 450 fi
 451
 452 AC_SUBST(JAVA_HOME)
 453 AC_SUBST(JAVA)
 454 AC_SUBST(JAVAC)
 455 AC_SUBST(JAVAH)
 456 AC_SUBST(JAVADOC)
 457 AC_SUBST(JAR)
 458 AC_SUBST(JNI_CFLAGS)
 459 AC_SUBST(JAVAC_FLAGS)
 460 AC_SUBST(JAR_INSTALL_DIR)
 461 AC_SUBST(JNI_INSTALL_DIR)
 462 AC_SUBST(JNI_VERSION_INFO)
 463
 464 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 465
 466 dnl Check for Haskell (GHC).
 467 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 468
 469 AM_CONDITIONAL([HAVE_HASKELL],
 470     [test "x$GHC" != "xno"])
 471
 472 dnl Check for Perl modules needed by the inspector.
 473 missing_perl_modules=no
 474 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper; do
 475     AC_MSG_CHECKING([for $pm])
 476     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 477         AC_MSG_RESULT([no])
 478         missing_perl_modules=yes
 479     else
 480         AC_MSG_RESULT([yes])
 481     fi
 482 done
 483 if test "x$missing_perl_modules" = "xyes"; then
 484     AC_MSG_WARN([some Perl modules required to compile virt-inspector are missing])
 485 fi
 486
 487 AM_CONDITIONAL([HAVE_INSPECTOR],
 488     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 489
 490 dnl Run in subdirs.
 491 AC_CONFIG_SUBDIRS([daemon])
 492
 493 dnl Produce output files.
 494 AC_CONFIG_HEADERS([config.h])
 495 AC_CONFIG_FILES([Makefile
 496                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 497                  appliance/Makefile
 498                  appliance/make.sh appliance/update.sh
 499                  appliance/supermin-split.sh appliance/supermin-make.sh
 500                  appliance/guestfs-supermin-helper
 501                  images/Makefile
 502                  capitests/Makefile
 503                  regressions/Makefile
 504                  ocaml/Makefile ocaml/examples/Makefile
 505                  perl/Makefile
 506                  python/Makefile
 507                  ruby/Makefile ruby/Rakefile
 508                  java/Makefile
 509                  haskell/Makefile
 510                  inspector/Makefile
 511                  libguestfs.pc
 512                  ocaml/META perl/Makefile.PL])
 513 AC_OUTPUT
 514
 515 dnl WTF?
 516 chmod +x appliance/*.sh appliance/guestfs-supermin-helper
 517
 518 dnl Produce summary.
 519 echo
 520 echo
 521 echo "------------------------------------------------------------"
 522 echo "Thank you for downloading $PACKAGE_STRING"
 523 echo
 524 echo "This is how we have configured the optional components for you today:"
 525 echo
 526 echo    "QEMU ................................ $QEMU"
 527 echo -n "OCaml bindings ...................... "
 528 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 529 echo -n "Perl bindings ....................... "
 530 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 531 echo -n "Python bindings ..................... "
 532 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 533 echo -n "Ruby bindings ....................... "
 534 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 535 echo -n "Java bindings ....................... "
 536 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 537 echo -n "Haskell bindings .................... "
 538 if test "x$HAVE_HASKELL" = "x"; then echo "yes"; else echo "no"; fi
 539 echo -n "virt-inspector ...................... "
 540 if test "x$HAVE_INSPECTOR" = "x"; then echo "yes"; else echo "no"; fi
 541 echo "supermin appliance .................. $enable_supermin"
 542 echo
 543 echo "If any optional component is configured 'no' when you expected 'yes'"
 544 echo "then you should check the preceeding messages."
 545 echo
 546 echo "Please report bugs back to the fedora-virt mailing list:"
 547 echo "http://www.redhat.com/mailman/listinfo/fedora-virt"
 548 echo
 549 echo "Next you should type 'make' to build the package,"
 550 echo "then 'make check' to run the tests."
 551 echo "------------------------------------------------------------"