configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2010 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [2])
  21 m4_define([libguestfs_release], [8])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release[]libguestfs_extra)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 dnl Stable or unstable version?
  41 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  42 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  43             AC_MSG_RESULT([stable])
  44        ],[
  45             AC_MSG_RESULT([unstable])
  46             AC_MSG_NOTICE([
  47 ***
  48 This is a development version of libguestfs. Some APIs may be unstable
  49 until they appear in a stable release of libguestfs (at which point
  50 the C API and ABI is guaranteed to remain stable forever).  For
  51 more information about stable and development branches of libguestfs
  52 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  53 ***])
  54        ])
  55
  56 dnl Die if the user tries to configure as root, see:
  57 dnl https://www.redhat.com/archives/libguestfs/2010-April/msg00098.html
  58 AC_MSG_CHECKING([if you are trying to configure as root])
  59 AS_IF([test "`id -u`" = 0 ],[
  60             AC_MSG_RESULT([yes])
  61             AC_MSG_FAILURE([Don't run './configure' or 'make' as root.])
  62       ],[
  63             AC_MSG_RESULT([no])
  64       ])
  65
  66 dnl Early gnulib initialization.
  67 gl_EARLY
  68 gl_INIT
  69
  70 AC_PROG_LIBTOOL
  71
  72 dnl Check for basic C environment.
  73 AC_PROG_CC_STDC
  74 AC_PROG_INSTALL
  75 AC_PROG_CPP
  76
  77 AC_ARG_ENABLE([gcc-warnings],
  78   [AS_HELP_STRING([--enable-gcc-warnings],
  79                   [turn on lots of GCC warnings (for developers)])],
  80   [case $enableval in
  81      yes|no) ;;
  82      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  83    esac
  84    gl_gcc_warnings=$enableval],
  85   [gl_gcc_warnings=no]
  86 )
  87
  88 if test "$gl_gcc_warnings" = yes; then
  89   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  90   AC_SUBST([WERROR_CFLAGS])
  91
  92   nw=
  93   # This, $nw, is the list of warnings we disable.
  94   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  95   nw="$nw -Waggregate-return"       # anachronistic
  96   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  97   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  98   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  99   nw="$nw -Wcast-qual"              # Too many warnings for now
 100   nw="$nw -Wconversion"             # Too many warnings for now
 101   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 102   nw="$nw -Wsign-conversion"        # Too many warnings for now
 103   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 104   nw="$nw -Wunreachable-code"       # Too many warnings for now
 105   nw="$nw -Wpadded"                 # Our structs are not padded
 106   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 107   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 108   nw="$nw -Wvla"                    # two warnings in mount.c
 109   # things I might fix soon:
 110   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 111   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 112   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 113   # ?? -Wstrict-overflow
 114   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 115                                     # was not possible, safe to ignore
 116   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 117
 118   gl_MANYWARN_ALL_GCC([ws])
 119   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 120   for w in $ws; do
 121     gl_WARN_ADD([$w])
 122   done
 123   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 124   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 125   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 126
 127   # In spite of excluding -Wlogical-op above, it is enabled, as of
 128   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 129   gl_WARN_ADD([-Wno-logical-op])
 130
 131   gl_WARN_ADD([-fdiagnostics-show-option])
 132
 133   AC_SUBST([WARN_CFLAGS])
 134
 135   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 136   AC_DEFINE([_FORTIFY_SOURCE], [2],
 137     [enable compile-time and run-time bounds-checking, and some warnings])
 138   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 139 fi
 140
 141 AC_C_PROTOTYPES
 142 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 143
 144 AM_PROG_CC_C_O
 145
 146 dnl Work out how to specify the linker script to the linker.
 147 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 148 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 149     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 150 AC_SUBST(VERSION_SCRIPT_FLAGS)
 151
 152 dnl Check support for 64 bit file offsets.
 153 AC_SYS_LARGEFILE
 154
 155 dnl Check sizeof long.
 156 AC_CHECK_SIZEOF([long])
 157
 158 dnl Define a C symbol for the host CPU architecture.
 159 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 160
 161 dnl Headers.
 162 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 163
 164 dnl Functions.
 165 AC_CHECK_FUNCS([posix_fallocate])
 166
 167 dnl Build the daemon?
 168 AC_MSG_CHECKING([if we should build the daemon])
 169 AC_ARG_ENABLE([daemon],
 170         [AS_HELP_STRING([--enable-daemon],
 171           [enable building the daemon @<:@default=yes@:>@])],
 172         [],
 173         [enable_daemon=yes])
 174 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 175 AC_MSG_RESULT([$enable_daemon])
 176
 177 dnl Build the appliance?
 178 AC_MSG_CHECKING([if we should build the appliance])
 179 AC_ARG_ENABLE([appliance],
 180         [AS_HELP_STRING([--enable-appliance],
 181           [enable building the appliance @<:@default=yes@:>@])],
 182         [],
 183         [enable_appliance=yes])
 184 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 185 AC_MSG_RESULT([$enable_appliance])
 186
 187 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 188 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 189 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 190 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 191         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 192         ])
 193
 194 dnl Check for pod2man and pod2text.
 195 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 196 test "x$POD2MAN" = "xno" &&
 197      AC_MSG_ERROR([pod2man must be installed])
 198 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 199 test "x$POD2TEXT" = "xno" &&
 200      AC_MSG_ERROR([pod2text must be installed])
 201
 202 dnl Check for mkisofs.
 203 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 204         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 205 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 206
 207 dnl Check for optional xmllint.
 208 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 209 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 210
 211 dnl Check for QEMU for running binaries on this $host_cpu, fall
 212 dnl back to basic 'qemu'.  Allow the user to override it.
 213 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
 214 AC_ARG_WITH([qemu],
 215         [AS_HELP_STRING([--with-qemu],
 216           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 217         [],
 218         [with_qemu="$default_qemu"])
 219 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 220         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 221 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 222 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 223
 224 dnl Check that the chosen qemu has vmchannel support or we can
 225 dnl fallback to null vmchannel (still using SLIRP).  See the
 226 dnl discussion in the README file.
 227 if test "x$vmchannel_test" != "xno"; then
 228     AC_MSG_CHECKING([for guestfwd support in $QEMU])
 229     if $QEMU -nographic --help | grep -sq guestfwd; then
 230         AC_MSG_RESULT([yes])
 231         vmchannel_guestfwd=guestfwd
 232     else
 233         AC_MSG_RESULT([no])
 234         # Note that this test must be conditional on the previous
 235         # test failing.  This is because recent qemu will throw
 236         # up an SDL window and hang if we try to run this test.
 237         AC_MSG_CHECKING([for "-net channel" (old guestfwd) support in $QEMU])
 238         vmchannelout=`$QEMU -nographic -net channel /dev/zero 2>&1 ||:`
 239         echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
 240         if echo "$vmchannelout" | grep -sq "vmchannel wrong port number" ; then
 241             AC_MSG_RESULT([yes])
 242             vmchannel_guestfwd=net_channel
 243         else
 244             AC_MSG_RESULT([no])
 245             vmchannel_guestfwd=no
 246         fi
 247     fi
 248
 249     AC_MSG_CHECKING([for "-net user" (user mode network) support in $QEMU])
 250     if $QEMU -nographic --help | grep -sq -- "-net user"; then
 251         AC_MSG_RESULT([yes])
 252         vmchannel_net_user=yes
 253     else
 254         AC_MSG_RESULT([no])
 255         vmchannel_net_user=no
 256     fi
 257
 258     if test "x$vmchannel_net_user" = "xno" -a "x$vmchannel_guestfwd" = "xno"; then
 259         AC_MSG_FAILURE(
 260 [I did not find user mode network or vmchannel support in
 261 $QEMU.
 262
 263 Either user mode networking or vmchannel support is vital for
 264 libguestfs to operate.
 265
 266 Please read the relevant section in the README file for more
 267 information about this.
 268
 269 You can override this test by setting the environment variable
 270 vmchannel_test=no  However if you don't have the right support
 271 in your qemu, then this just delays the pain.
 272
 273 If I am using the wrong qemu or you want to compile qemu from source
 274 and install it in another location, then you should configure with
 275 the --with-qemu option.
 276 ])
 277     fi
 278 fi
 279
 280 dnl Set drive interface used by the guestfs_add_drive{,_ro} calls
 281 dnl ('-drive ...,if=...' option to qemu).
 282 dnl
 283 dnl If you encounter performance problems with virtio (RHBZ#509383)
 284 dnl then try '--with-drive-if=ide'.
 285 AC_ARG_WITH([drive-if],
 286         [AS_HELP_STRING([--with-drive-if],
 287           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 288         [],
 289         [with_drive_if=virtio])
 290 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 291
 292 dnl Set interface used by the network.  Normally you should
 293 dnl leave this at the default (virtio) but you can use the
 294 dnl alternative (ne2k_pci) because of bugs in virtio networking
 295 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 296 AC_ARG_WITH([net-if],
 297         [AS_HELP_STRING([--with-net-if],
 298           [set default net driver (virtio|ne2k_pci) @<:@default=virtio@:>@])],
 299         [],
 300         [with_net_if=virtio])
 301 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 302
 303 dnl Check for febootstrap etc.
 304 if test "x$enable_appliance" = "xyes"; then
 305     AC_CHECK_PROG([FEBOOTSTRAP],
 306                   [febootstrap],[febootstrap],[no])
 307     if test "x$FEBOOTSTRAP" != "xno"; then
 308       AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 309                     [febootstrap-run],[febootstrap-run],[no])
 310       test "x$FEBOOTSTRAP_RUN" = "xno" && \
 311           AC_MSG_ERROR([febootstrap-run must be installed])
 312       AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 313                     [febootstrap-install],[febootstrap-install],[no])
 314       test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 315           AC_MSG_ERROR([febootstrap-install must be installed])
 316       AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 317                     [febootstrap-minimize],[febootstrap-minimize],[no])
 318       test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 319           AC_MSG_ERROR([febootstrap-minimize must be installed])
 320       AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 321                     [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 322       test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 323           AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 324
 325       dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 326       dnl of febootstrap, but old versions will fail with yum).
 327       AC_CHECK_PROG([FAKECHROOT],
 328                     [fakechroot],[fakechroot],[no])
 329       test "x$FAKECHROOT" = "xno" && \
 330          AC_MSG_ERROR([fakechroot must be installed])
 331
 332       AC_MSG_CHECKING([fakechroot version])
 333       fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 334       if test -z "$fakechroot_version"; then
 335         AC_MSG_RESULT([failed])
 336         AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 337       else
 338         AC_MSG_RESULT([$fakechroot_version])
 339         fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 340         fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 341         if test "$fakechroot_major" -lt 2 -o \
 342             \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
 343           AC_MSG_ERROR([fakechroot version must be >= 2.9])
 344         fi
 345       fi
 346       DIST="REDHAT"
 347     else
 348       # check for debootstrap and debirf
 349       AC_CHECK_PROG([DEBOOTSTRAP],
 350                     [debootstrap],[debootstrap],[no])
 351       test "x$DEBOOTSTRAP" = "xno" && \
 352           AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 353       AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 354       test "x$DEBIRF" = "xno" &&
 355           AC_MSG_ERROR([debirf must be installed])
 356       DIST="DEBIAN"
 357       case "$host_cpu" in
 358       *86)
 359           DEBIAN_KERNEL_ARCH=486
 360           ;;
 361       x86_64)
 362           DEBIAN_KERNEL_ARCH=amd64
 363           ;;
 364       *)
 365          DEBIAN_KERNEL_ARCH=$host_cpu
 366          ;;
 367       esac
 368       AC_SUBST(DEBIAN_KERNEL_ARCH)
 369     fi
 370     AC_SUBST(DIST)
 371
 372     dnl --with-updates to specify a Fedora updates repository.
 373     AC_ARG_WITH([updates],
 374         [AS_HELP_STRING([--with-updates],
 375           [set name of Fedora updates repository @<:@default=updates-released-f12@:>@])],
 376         [],
 377         [with_updates=updates-released-f12])
 378     UPDATES="$with_updates"
 379     AC_SUBST(UPDATES)
 380
 381     dnl --with-mirror to specify a local Fedora mirror.
 382     AC_ARG_WITH([mirror],
 383         [AS_HELP_STRING([--with-mirror],
 384           [set URI of a local Fedora mirror])],
 385         [],
 386         [with_mirror=])
 387     MIRROR="$with_mirror"
 388     AC_SUBST(MIRROR)
 389 fi
 390
 391 dnl --with-repo to specify a Fedora repository.
 392 AC_ARG_WITH([repo],
 393         [AS_HELP_STRING([--with-repo],
 394           [set name of Fedora repository @<:@default=fedora-12@:>@])],
 395         [],
 396         [with_repo=fedora-12])
 397 REPO="$with_repo"
 398 AC_SUBST(REPO)
 399 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 400
 401 dnl Build the supermin appliance?  Please see README file before
 402 dnl enabling this option.
 403 AC_ARG_ENABLE([supermin],
 404         [AS_HELP_STRING([--enable-supermin],
 405           [enable supermin appliance (see README) @<:@default=no@:>@])],
 406         [],
 407         [enable_supermin=no])
 408 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 409
 410 if test "x$enable_supermin" = "xyes"; then
 411     dnl Check febootstrap-to-initramfs accepts the --files option
 412     dnl (febootstrap >= 2.2).
 413     AC_MSG_CHECKING([for --files support in $FEBOOTSTRAP_TO_INITRAMFS])
 414     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 415     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 416     if ! echo "$out" | grep -sq -e --files ; then
 417         AC_MSG_RESULT([no])
 418         AC_MSG_FAILURE(
 419 [febootstrap-to-initramfs does not support the --files option.
 420
 421 To build the supermin appliance, you need to upgrade to the latest
 422 version of febootstrap.
 423 ])
 424     fi
 425     AC_MSG_RESULT([yes])
 426
 427     dnl Check febootstrap-to-initramfs accepts the --nocompress option
 428     dnl (febootstrap >= 2.3).
 429     AC_MSG_CHECKING([for --nocompress support in $FEBOOTSTRAP_TO_INITRAMFS])
 430     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 431     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 432     if ! echo "$out" | grep -sq -e --nocompress ; then
 433         AC_MSG_RESULT([no])
 434         AC_MSG_FAILURE(
 435 [febootstrap-to-initramfs does not support the --nocompress option.
 436
 437 To build the supermin appliance, you need to upgrade to the latest
 438 version of febootstrap.
 439 ])
 440     fi
 441     AC_MSG_RESULT([yes])
 442 fi
 443
 444 dnl Enable packet dumps when in verbose mode.  This generates lots
 445 dnl of debug info, only useful for people debugging the RPC mechanism.
 446 AC_ARG_ENABLE([packet-dump],
 447         [AS_HELP_STRING([--enable-packet-dump],
 448           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 449         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 450         [])
 451
 452 dnl Readline.
 453 AC_ARG_WITH([readline],
 454     [AS_HELP_STRING([--with-readline],
 455         [support fancy command line editing @<:@default=check@:>@])],
 456     [],
 457     [with_readline=check])
 458
 459 LIBREADLINE=
 460 AS_IF([test "x$with_readline" != xno],
 461     [AC_CHECK_LIB([readline], [main],
 462         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 463          AC_DEFINE([HAVE_LIBREADLINE], [1],
 464                    [Define if you have libreadline])
 465         ],
 466         [if test "x$with_readline" != xcheck; then
 467          AC_MSG_FAILURE(
 468              [--with-readline was given, but test for readline failed])
 469          fi
 470         ], -lncurses)
 471      old_LIBS="$LIBS"
 472      LIBS="$LIBS $LIBREADLINE"
 473      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 474      LIBS="$old_LIBS"
 475     ])
 476
 477 dnl For i18n.
 478 AM_GNU_GETTEXT([external])
 479 AM_GNU_GETTEXT_VERSION([0.17])
 480
 481 dnl hivex library (highly recommended).
 482 dnl This used to be a part of libguestfs, but was spun off into its
 483 dnl own separate upstream project in libguestfs 1.0.85.
 484 HAVE_HIVEX=yes
 485 PKG_CHECK_MODULES([HIVEX], [hivex],,[
 486         HAVE_HIVEX=no
 487         AC_MSG_WARN([Hivex library and headers are missing, so optional Windows Registry tools won't be built])])
 488 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HAVE_HIVEX" = "xyes"])
 489 AC_SUBST([HIVEX_CFLAGS])
 490 AC_SUBST([HIVEX_LIBS])
 491
 492 dnl FUSE is optional to build the FUSE module.
 493 HAVE_FUSE=yes
 494 PKG_CHECK_MODULES([FUSE],[fuse],,[
 495         HAVE_FUSE=no
 496         AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])
 497 AM_CONDITIONAL([HAVE_FUSE],[test "x$HAVE_FUSE" = "xyes"])
 498
 499 dnl Check for OCaml (optional, for OCaml bindings).
 500 AC_PROG_OCAML
 501 AC_PROG_FINDLIB
 502 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
 503
 504 dnl Optional xml-light for running the generator.
 505 OCAML_PKG_xml_light=no
 506 if test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"; then
 507     AC_CHECK_OCAML_PKG([xml-light])
 508 fi
 509 AM_CONDITIONAL([HAVE_XML_LIGHT],[test "x$OCAML_PKG_xml_light" != "xno"])
 510
 511 dnl Build the OCaml viewer example.  This has a lengthy list of
 512 dnl dependencies and we don't attempt to detect them all.  Read
 513 dnl the top of ocaml/examples/viewer.ml before enabling this.
 514 AC_ARG_ENABLE([ocaml-viewer],
 515         [AS_HELP_STRING([--enable-ocaml-viewer],
 516           [enable OCaml viewer (see ocaml/examples) @<:@default=no@:>@])],
 517         [],
 518         [enable_ocaml_viewer=no])
 519 AM_CONDITIONAL([BUILD_OCAML_VIEWER],[test "x$enable_ocaml_viewer" = "xyes"])
 520
 521 dnl Check for Perl (optional, for Perl bindings).
 522 dnl XXX This isn't quite right, we should check for Perl devel library.
 523 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 524
 525 dnl Check for Perl modules that must be present to compile and
 526 dnl test the Perl bindings.
 527 missing_perl_modules=no
 528 for pm in Test::More ExtUtils::MakeMaker; do
 529     AC_MSG_CHECKING([for $pm])
 530     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 531         AC_MSG_RESULT([no])
 532         missing_perl_modules=yes
 533     else
 534         AC_MSG_RESULT([yes])
 535     fi
 536 done
 537 if test "x$missing_perl_modules" = "xyes"; then
 538     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 539 fi
 540
 541 AM_CONDITIONAL([HAVE_PERL],
 542     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 543
 544 dnl Check for Python (optional, for Python bindings).
 545 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 546
 547 PYTHON_PREFIX=
 548 PYTHON_VERSION=
 549 PYTHON_INCLUDEDIR=
 550 PYTHON_SITE_PACKAGES=
 551
 552 if test "x$PYTHON" != "xno"; then
 553     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 554     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 555     for d in \
 556         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 557         /usr/include/python$PYTHON_VERSION \
 558         /usr/local/include/python$PYTHON_VERSION
 559     do
 560         AC_MSG_CHECKING([Python.h in $d])
 561         if test -r "$d/Python.h"; then
 562             AC_MSG_RESULT([found])
 563             PYTHON_INCLUDEDIR=$d
 564             break
 565         fi
 566         AC_MSG_RESULT([not found])
 567     done
 568     for d in \
 569         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 570         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 571         /usr/lib64/python$PYTHON_VERSION/site-packages \
 572         /usr/lib/python$PYTHON_VERSION/site-packages \
 573         /usr/local/lib/python$PYTHON_VERSION/site-packages
 574     do
 575         AC_MSG_CHECKING([for $d])
 576         if test -d "$d"; then
 577             AC_MSG_RESULT([found])
 578             PYTHON_SITE_PACKAGES=$d
 579             break
 580         fi
 581         AC_MSG_RESULT([not found])
 582     done
 583 fi
 584
 585 AC_SUBST(PYTHON_PREFIX)
 586 AC_SUBST(PYTHON_VERSION)
 587 AC_SUBST(PYTHON_INCLUDEDIR)
 588 AC_SUBST(PYTHON_SITE_PACKAGES)
 589
 590 AM_CONDITIONAL([HAVE_PYTHON],
 591     [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
 592
 593 dnl Check for Ruby and rake (optional, for Ruby bindings).
 594 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 595 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 596
 597 AM_CONDITIONAL([HAVE_RUBY],
 598     [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
 599
 600 dnl Check for Java.
 601 AC_ARG_WITH(java_home,
 602     [AS_HELP_STRING([--with-java-home],
 603         [specify path to JDK directory @<:@default=check@:>@])],
 604     [],
 605     [with_java_home=check])
 606
 607 if test "x$with_java_home" != "xno"; then
 608     if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
 609     then
 610         # Reject unsafe characters in $JAVA_HOME
 611         jh_lf='
 612 '
 613         case $JAVA_HOME in
 614           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 615             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 616         esac
 617         if test -d "$with_java_home"; then
 618             JAVA_HOME="$with_java_home"
 619         else
 620             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 621         fi
 622     fi
 623
 624     if test "x$JAVA_HOME" = "x"; then
 625         # Look for Java in some likely locations.
 626         for d in \
 627             /usr/lib/jvm/java \
 628             /usr/lib/jvm/java-6-openjdk
 629         do
 630             if test -d $d -a -f $d/bin/java; then
 631                 JAVA_HOME=$d
 632                 break
 633             fi
 634         done
 635     fi
 636
 637     if test "x$JAVA_HOME" != "x"; then
 638         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 639         if test ! -x "$JAVA_HOME/bin/java"; then
 640             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 641         else
 642             JAVA="$JAVA_HOME/bin/java"
 643         fi
 644         if test ! -x "$JAVA_HOME/bin/javac"; then
 645             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 646         else
 647             JAVAC="$JAVA_HOME/bin/javac"
 648         fi
 649         if test ! -x "$JAVA_HOME/bin/javah"; then
 650             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 651         else
 652             JAVAH="$JAVA_HOME/bin/javah"
 653         fi
 654         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 655             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 656         else
 657             JAVADOC="$JAVA_HOME/bin/javadoc"
 658         fi
 659         if test ! -x "$JAVA_HOME/bin/jar"; then
 660             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 661         else
 662             JAR="$JAVA_HOME/bin/jar"
 663         fi
 664         java_version=`$JAVA -version 2>&1 | grep "java version"`
 665         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 666
 667         dnl Find jni.h.
 668         AC_MSG_CHECKING([for jni.h])
 669         if test -f "$JAVA_HOME/include/jni.h"; then
 670             JNI_CFLAGS="-I$JAVA_HOME/include"
 671         else
 672             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 673                 head=`find $JAVA_HOME -name jni.h | tail -1`
 674                 dir=`dirname "$head"`
 675                 JNI_CFLAGS="-I$dir"
 676             else
 677                 AC_MSG_FAILURE([missing jni.h header file])
 678             fi
 679         fi
 680         AC_MSG_RESULT([$JNI_CFLAGS])
 681
 682         dnl Find jni_md.h.
 683         AC_MSG_CHECKING([for jni_md.h])
 684         case "$build_os" in
 685         *linux*) system="linux" ;;
 686         *SunOS*) system="solaris" ;;
 687         *cygwin*) system="win32" ;;
 688         *) system="$build_os" ;;
 689         esac
 690         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 691             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 692         else
 693             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 694                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 695                 dir=`dirname "$head"`
 696                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 697             else
 698                 AC_MSG_FAILURE([missing jni_md.h header file])
 699             fi
 700         fi
 701         AC_MSG_RESULT([$JNI_CFLAGS])
 702
 703         dnl Need extra version flag?
 704         AC_MSG_CHECKING([extra javac flags])
 705         JAVAC_FLAGS=
 706         javac_version=`$JAVAC -version 2>&1`
 707         case "$javac_version" in
 708         *Eclipse*)
 709             JAVAC_FLAGS="-source 1.5" ;;
 710         esac
 711         AC_MSG_RESULT([$JAVAC_FLAGS])
 712
 713         dnl Where to install jarfiles.
 714         dnl XXX How to make it configurable?
 715         JAR_INSTALL_DIR=\${prefix}/share/java
 716         JNI_INSTALL_DIR=\${libdir}
 717
 718         dnl JNI version.
 719         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 720         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 721         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 722         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 723     fi
 724 fi
 725
 726 AC_SUBST(JAVA_HOME)
 727 AC_SUBST(JAVA)
 728 AC_SUBST(JAVAC)
 729 AC_SUBST(JAVAH)
 730 AC_SUBST(JAVADOC)
 731 AC_SUBST(JAR)
 732 AC_SUBST(JNI_CFLAGS)
 733 AC_SUBST(JAVAC_FLAGS)
 734 AC_SUBST(JAR_INSTALL_DIR)
 735 AC_SUBST(JNI_INSTALL_DIR)
 736 AC_SUBST(JNI_VERSION_INFO)
 737
 738 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 739
 740 dnl Check for Haskell (GHC).
 741 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 742
 743 AM_CONDITIONAL([HAVE_HASKELL],
 744     [test "x$GHC" != "xno"])
 745
 746 dnl Check for Perl modules needed by virt-df, inspector, etc.
 747 missing_perl_modules=no
 748 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer Locale::TextDomain Win::Hivex Win::Hivex::Regedit; do
 749     AC_MSG_CHECKING([for $pm])
 750     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 751         AC_MSG_RESULT([no])
 752         missing_perl_modules=yes
 753     else
 754         AC_MSG_RESULT([yes])
 755     fi
 756 done
 757 if test "x$missing_perl_modules" = "xyes"; then
 758     AC_MSG_WARN([some Perl modules required to compile virt-inspector and the other virt-* tools are missing])
 759 fi
 760
 761 AM_CONDITIONAL([HAVE_INSPECTOR],
 762     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 763 AM_CONDITIONAL([HAVE_TOOLS],
 764     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 765
 766 dnl Library versioning.
 767 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 768 AC_SUBST(MAX_PROC_NR)
 769
 770 dnl Run in subdirs.
 771 if test "x$enable_daemon" = "xyes"; then
 772     AC_CONFIG_SUBDIRS([daemon])
 773 fi
 774
 775 dnl Produce output files.
 776 AC_CONFIG_HEADERS([config.h])
 777 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 778 AC_CONFIG_FILES([appliance/update.sh],
 779                 [chmod +x appliance/update.sh])
 780 AC_CONFIG_FILES([appliance/supermin-split.sh],
 781                 [chmod +x appliance/supermin-split.sh])
 782 AC_CONFIG_FILES([appliance/supermin-make.sh],
 783                 [chmod +x appliance/supermin-make.sh])
 784 AC_CONFIG_FILES([Makefile
 785                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 786                  appliance/Makefile
 787                  appliance/debian/debirf.conf
 788                  images/Makefile
 789                  capitests/Makefile
 790                  regressions/Makefile
 791                  test-tool/Makefile
 792                  ocaml/Makefile ocaml/examples/Makefile
 793                  perl/Makefile
 794                  python/Makefile
 795                  ruby/Makefile ruby/Rakefile
 796                  java/Makefile
 797                  haskell/Makefile
 798                  inspector/Makefile
 799                  tools/Makefile
 800                  libguestfs.pc
 801                  gnulib/lib/Makefile
 802                  gnulib/tests/Makefile
 803                  fuse/Makefile
 804                  ocaml/META perl/Makefile.PL])
 805 AC_OUTPUT
 806
 807 dnl Produce summary.
 808 echo
 809 echo
 810 echo "------------------------------------------------------------"
 811 echo "Thank you for downloading $PACKAGE_STRING"
 812 echo
 813 echo "This is how we have configured the optional components for you today:"
 814 echo
 815 echo    "Daemon .............................. $enable_daemon"
 816 echo    "Appliance ........................... $enable_appliance"
 817 echo    "QEMU ................................ $QEMU"
 818 echo -n "OCaml bindings ...................... "
 819 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 820 echo -n "Perl bindings ....................... "
 821 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 822 echo -n "Python bindings ..................... "
 823 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 824 echo -n "Ruby bindings ....................... "
 825 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 826 echo -n "Java bindings ....................... "
 827 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 828 echo -n "Haskell bindings .................... "
 829 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 830 echo -n "virt-inspector ...................... "
 831 if test "x$HAVE_INSPECTOR_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 832 echo -n "virt-* tools ........................ "
 833 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 834 echo "supermin appliance .................. $enable_supermin"
 835 echo "FUSE filesystem ..................... $HAVE_FUSE"
 836 echo
 837 echo "If any optional component is configured 'no' when you expected 'yes'"
 838 echo "then you should check the preceeding messages."
 839 echo
 840 echo "Please report bugs back to the mailing list:"
 841 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 842 echo
 843 echo "Next you should type 'make' to build the package,"
 844 echo "then 'make check' to run the tests."
 845 echo "------------------------------------------------------------"