configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2011 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [8])
  21 m4_define([libguestfs_release], [10])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 dnl Stable or unstable version?
  41 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  42 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  43             AC_MSG_RESULT([stable])
  44        ],[
  45             AC_MSG_RESULT([unstable])
  46             AC_MSG_NOTICE([
  47 ***
  48 This is a development version of libguestfs. Some APIs may be unstable
  49 until they appear in a stable release of libguestfs (at which point
  50 the C API and ABI is guaranteed to remain stable forever).  For
  51 more information about stable and development branches of libguestfs
  52 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  53 ***])
  54        ])
  55
  56 dnl Early gnulib initialization.
  57 gl_EARLY
  58 gl_INIT
  59
  60 AC_PROG_LIBTOOL
  61
  62 dnl Check for basic C environment.
  63 AC_PROG_CC_STDC
  64 AC_PROG_INSTALL
  65 AC_PROG_CPP
  66
  67 AC_ARG_ENABLE([gcc-warnings],
  68   [AS_HELP_STRING([--enable-gcc-warnings],
  69                   [turn on lots of GCC warnings (for developers)])],
  70   [case $enableval in
  71      yes|no) ;;
  72      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  73    esac
  74    gl_gcc_warnings=$enableval],
  75   [gl_gcc_warnings=no]
  76 )
  77
  78 if test "$gl_gcc_warnings" = yes; then
  79   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  80   AC_SUBST([WERROR_CFLAGS])
  81
  82   nw=
  83   # This, $nw, is the list of warnings we disable.
  84   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  85   nw="$nw -Waggregate-return"       # anachronistic
  86   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  87   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  88   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  89   nw="$nw -Wcast-qual"              # Too many warnings for now
  90   nw="$nw -Wconversion"             # Too many warnings for now
  91   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  92   nw="$nw -Wsign-conversion"        # Too many warnings for now
  93   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  94   nw="$nw -Wunreachable-code"       # Too many warnings for now
  95   nw="$nw -Wpadded"                 # Our structs are not padded
  96   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  97   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  98   nw="$nw -Wvla"                    # two warnings in mount.c
  99   # things I might fix soon:
 100   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 101   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 102   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 103   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 104                                     # was not possible, safe to ignore
 105   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 106   nw="$nw -Wlong-long"              # Allow long long since it's required
 107                                     # by Python, Ruby and xstrtoll.
 108   nw="$nw -Wstack-protector"        # Don't warn about stack-protector
 109                                     # failures (seen on Ubuntu).
 110
 111   gl_MANYWARN_ALL_GCC([ws])
 112   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 113   for w in $ws; do
 114     gl_WARN_ADD([$w])
 115   done
 116   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 117   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 118   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 119
 120   # In spite of excluding -Wlogical-op above, it is enabled, as of
 121   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 122   gl_WARN_ADD([-Wno-logical-op])
 123
 124   # Work around warning in src/inspect.c.  This seems to be a bug in gcc 4.5.1.
 125   gl_WARN_ADD([-Wno-strict-overflow])
 126
 127   gl_WARN_ADD([-fdiagnostics-show-option])
 128
 129   AC_SUBST([WARN_CFLAGS])
 130
 131   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 132   AC_DEFINE([_FORTIFY_SOURCE], [2],
 133     [enable compile-time and run-time bounds-checking, and some warnings])
 134   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 135 fi
 136
 137 AC_C_PROTOTYPES
 138 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 139
 140 AM_PROG_CC_C_O
 141
 142 dnl Work out how to specify the linker script to the linker.
 143 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 144 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 145     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 146 AC_SUBST(VERSION_SCRIPT_FLAGS)
 147
 148 dnl Check support for 64 bit file offsets.
 149 AC_SYS_LARGEFILE
 150
 151 dnl Check sizeof long.
 152 AC_CHECK_SIZEOF([long])
 153
 154 dnl Define a C symbol for the host CPU architecture.
 155 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 156
 157 dnl Headers.
 158 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 159
 160 dnl Functions.
 161 AC_CHECK_FUNCS([futimens posix_fallocate])
 162
 163 dnl Build the daemon?
 164 AC_MSG_CHECKING([if we should build the daemon])
 165 AC_ARG_ENABLE([daemon],
 166         [AS_HELP_STRING([--enable-daemon],
 167           [enable building the daemon @<:@default=yes@:>@])],
 168         [],
 169         [enable_daemon=yes])
 170 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 171 AC_MSG_RESULT([$enable_daemon])
 172
 173 dnl Build the appliance?
 174 AC_MSG_CHECKING([if we should build the appliance])
 175 AC_ARG_ENABLE([appliance],
 176         [AS_HELP_STRING([--enable-appliance],
 177           [enable building the appliance @<:@default=yes@:>@])],
 178         [],
 179         [enable_appliance=yes])
 180 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 181 AC_MSG_RESULT([$enable_appliance])
 182
 183 if test "x$enable_appliance" = "xyes"; then
 184     dnl Check for febootstrap >= 3.0
 185     AC_CHECK_PROG([FEBOOTSTRAP],
 186                   [febootstrap],[febootstrap],[no])
 187     test "x$FEBOOTSTRAP" = "xno" &&
 188         AC_MSG_ERROR([febootstrap must be installed])
 189     dnl febootstrap 2.x did not support the --version parameter
 190     $FEBOOTSTRAP --version >&AS_MESSAGE_LOG_FD 2>&1 ||
 191         AC_MSG_ERROR([febootstrap >= 3.0 must be installed, your version is too old])
 192
 193     dnl Pass a febootstrap --yum-config option.
 194     AC_MSG_CHECKING([if user requested febootstrap --yum-config option])
 195     AC_ARG_WITH([febootstrap-yum-config],
 196         [AS_HELP_STRING([--with-febootstrap-yum-config=FILE],
 197           [pass febootstrap --yum-config option @<:@default=no@:>@])],
 198         [FEBOOTSTRAP_YUM_CONFIG="$withval"],
 199         [FEBOOTSTRAP_YUM_CONFIG=no])
 200     AC_MSG_RESULT([$FEBOOTSTRAP_YUM_CONFIG])
 201     AC_SUBST([FEBOOTSTRAP_YUM_CONFIG])
 202
 203     dnl Which distro?
 204     dnl
 205     dnl This used to be Very Important but is now just used to select
 206     dnl which packages to install in the appliance, since the package
 207     dnl names vary slightly across distros.  (See
 208     dnl appliance/packagelist.in and appliance/excludelist.in)
 209     AC_MSG_CHECKING([which Linux distro for package names])
 210     DISTRO=REDHAT
 211     if test -f /etc/debian_version; then
 212         DISTRO=DEBIAN
 213         if grep -q 'DISTRIB_ID=Ubuntu' /etc/lsb-release 2>&AS_MESSAGE_LOG_FD; then
 214             DISTRO=UBUNTU
 215         fi
 216     fi
 217     if test -f /etc/arch-release; then
 218         DISTRO=ARCHLINUX
 219     fi
 220     AC_MSG_RESULT([$DISTRO])
 221     AC_SUBST([DISTRO])
 222 fi
 223
 224 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 225 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 226 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 227 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 228         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 229         ])
 230
 231 dnl Check for cpio which isn't in the default Pardus install amazingly.
 232 AC_CHECK_PROG([CPIO],[cpio],[cpio],[no])
 233 test "x$CPIO" = "xno" &&
 234      AC_MSG_ERROR([cpio must be installed])
 235
 236 dnl Check for gperf.
 237 AC_CHECK_PROG([GPERF],[gperf],[gperf],[no])
 238 test "x$GPERF" = "xno" &&
 239      AC_MSG_ERROR([gperf must be installed])
 240
 241 dnl Check for pod2man, pod2text, pod2html.
 242 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 243 test "x$POD2MAN" = "xno" &&
 244      AC_MSG_ERROR([pod2man must be installed])
 245 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 246 test "x$POD2TEXT" = "xno" &&
 247      AC_MSG_ERROR([pod2text must be installed])
 248 AC_CHECK_PROG([POD2HTML],[pod2html],[pod2html],[no])
 249 test "x$POD2HTML" = "xno" &&
 250      AC_MSG_ERROR([pod2html must be installed])
 251
 252 dnl Check if pod2man, pod2text take --stderr and -u options (not in RHEL 5).
 253 AC_MSG_CHECKING([if pod2man takes --stderr option])
 254 if "$POD2MAN" --stderr >&AS_MESSAGE_LOG_FD 2>&1; then
 255     AC_MSG_RESULT([yes])
 256     POD2_STDERR_OPTION="--stderr"
 257 else
 258     AC_MSG_RESULT([no])
 259     POD2_STDERR_OPTION=""
 260 fi
 261 AC_SUBST([POD2_STDERR_OPTION])
 262
 263 AC_MSG_CHECKING([if pod2man takes -u option])
 264 if "$POD2MAN" -u >&AS_MESSAGE_LOG_FD 2>&1; then
 265     AC_MSG_RESULT([yes])
 266     POD2_UTF8_OPTION="-u"
 267 else
 268     AC_MSG_RESULT([no])
 269     POD2_UTF8_OPTION=""
 270 fi
 271 AC_SUBST([POD2_UTF8_OPTION])
 272
 273 dnl Check for mkisofs.
 274 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 275         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 276 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 277
 278 dnl Check for optional xmllint.
 279 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 280 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 281
 282 dnl po4a for translating man pages and POD files (optional).
 283 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
 284 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
 285
 286 dnl Check for db_dump, db_load (optional).
 287 AC_CHECK_PROGS([DB_DUMP],
 288                [db_dump db4_dump db4.8_dump db4.7_dump db4.6_dump],[no])
 289 AC_CHECK_PROGS([DB_LOAD],
 290                [db_load db4_load db4.8_load db4.7_load db4.6_load],[no])
 291 if test "x$DB_DUMP" != "xno"; then
 292     AC_DEFINE_UNQUOTED([DB_DUMP],["$DB_DUMP"],[Name of db_dump program.])
 293 fi
 294 if test "x$DB_LOAD" != "xno"; then
 295     AC_DEFINE_UNQUOTED([DB_LOAD],["$DB_LOAD"],[Name of db_load program.])
 296 fi
 297
 298 dnl Check for QEMU for running binaries on this $host_cpu, fall
 299 dnl back to basic 'qemu'.  Allow the user to override it.
 300 default_qemu="qemu-kvm kvm qemu-system-$host_cpu qemu"
 301 AC_ARG_WITH([qemu],
 302         [AS_HELP_STRING([--with-qemu],
 303           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 304         [],
 305         [with_qemu="$default_qemu"])
 306 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 307         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 308 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 309 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 310
 311 dnl Check that the chosen qemu has virtio-serial support.
 312 if test "x$vmchannel_test" != "xno"; then
 313     AC_MSG_CHECKING([that $QEMU -help works])
 314     if $QEMU -help >&AS_MESSAGE_LOG_FD 2>&1; then
 315         AC_MSG_RESULT([yes])
 316     else
 317         AC_MSG_RESULT([no])
 318         AC_MSG_FAILURE(
 319 [$QEMU -help: command failed.
 320
 321 This could be a very old version of qemu, or qemu might not be
 322 working.
 323 ])
 324     fi
 325
 326     AC_MSG_CHECKING([for virtio-serial support in $QEMU])
 327     if $QEMU -nographic -device \? 2>&1 | grep -sq virtio-serial; then
 328         AC_MSG_RESULT([yes])
 329     else
 330         AC_MSG_RESULT([no])
 331         AC_MSG_FAILURE(
 332 [I did not find virtio-serial support in
 333 $QEMU.
 334
 335 virtio-serial support in qemu or KVM is essential for libguestfs
 336 to operate.
 337
 338 Usually this means that you have to install a newer version of qemu
 339 and/or KVM.  Please read the relevant section in the README file for
 340 more information about this.
 341
 342 You can override this test by setting the environment variable
 343 vmchannel_test=no  However if you don't have the right support
 344 in your qemu, then this just delays the pain.
 345
 346 If I am using the wrong qemu or you want to compile qemu from source
 347 and install it in another location, then you should configure with
 348 the --with-qemu option.
 349 ])
 350     fi
 351 fi
 352
 353 dnl Set default drive interface used by the guestfs_add_drive_opts call
 354 dnl ('-drive ...,if=...' option to qemu).
 355 dnl
 356 dnl If you encounter performance problems with virtio (RHBZ#509383)
 357 dnl then try '--with-drive-if=ide'.
 358 AC_ARG_WITH([drive-if],
 359         [AS_HELP_STRING([--with-drive-if],
 360           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 361         [],
 362         [with_drive_if=virtio])
 363 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 364
 365 dnl Set interface used by the network.  Normally you should
 366 dnl leave this at the default (virtio-net-pci) but you can use the
 367 dnl alternative (ne2k_pci) because of bugs in virtio networking
 368 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 369 AC_ARG_WITH([net-if],
 370         [AS_HELP_STRING([--with-net-if],
 371           [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
 372         [],
 373         [with_net_if=virtio-net-pci])
 374 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 375
 376 dnl Enable packet dumps when in verbose mode.  This generates lots
 377 dnl of debug info, only useful for people debugging the RPC mechanism.
 378 AC_ARG_ENABLE([packet-dump],
 379         [AS_HELP_STRING([--enable-packet-dump],
 380           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 381         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 382         [])
 383
 384 dnl Readline.
 385 AC_ARG_WITH([readline],
 386     [AS_HELP_STRING([--with-readline],
 387         [support fancy command line editing @<:@default=check@:>@])],
 388     [],
 389     [with_readline=check])
 390
 391 LIBREADLINE=
 392 AS_IF([test "x$with_readline" != xno],
 393     [AC_CHECK_LIB([readline], [main],
 394         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 395          AC_DEFINE([HAVE_LIBREADLINE], [1],
 396                    [Define if you have libreadline])
 397         ],
 398         [if test "x$with_readline" != xcheck; then
 399          AC_MSG_FAILURE(
 400              [--with-readline was given, but test for readline failed])
 401          fi
 402         ], -lncurses)
 403      old_LIBS="$LIBS"
 404      LIBS="$LIBS $LIBREADLINE"
 405      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 406      LIBS="$old_LIBS"
 407     ])
 408
 409 dnl For i18n.
 410 AM_GNU_GETTEXT([external])
 411
 412 dnl libmagic (highly recommended)
 413 AC_CHECK_LIB([magic],[magic_file],
 414         [AC_CHECK_HEADER([magic.h],
 415                 [AC_SUBST([MAGIC_LIBS], ["-lmagic"])
 416                  AC_DEFINE([HAVE_LIBMAGIC],[1],[libmagic found at compile time.])
 417                 ], [])
 418         ],
 419         [AC_MSG_WARN([libmagic not found, some core features will be disabled])])
 420
 421 dnl Check for PCRE (highly recommended)
 422 PKG_CHECK_MODULES([PCRE], [libpcre],
 423         [AC_SUBST([PCRE_CFLAGS])
 424          AC_SUBST([PCRE_LIBS])
 425          AC_DEFINE([HAVE_PCRE],[1],[PCRE found at compile time.])
 426         ],
 427         [AC_MSG_WARN([PCRE not found, some core features will be disabled])])
 428
 429 dnl libvirt (highly recommended)
 430 PKG_CHECK_MODULES([LIBVIRT], [libvirt],
 431         [AC_SUBST([LIBVIRT_CFLAGS])
 432          AC_SUBST([LIBVIRT_LIBS])
 433          AC_DEFINE([HAVE_LIBVIRT],[1],[libvirt found at compile time.])
 434         ],
 435         [AC_MSG_WARN([libvirt not found, some core features will be disabled])])
 436 AM_CONDITIONAL([HAVE_LIBVIRT],[test "x$LIBVIRT_LIBS" != "x"])
 437
 438 dnl libxml2 (highly recommended)
 439 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0],
 440         [AC_SUBST([LIBXML2_CFLAGS])
 441          AC_SUBST([LIBXML2_LIBS])
 442          AC_DEFINE([HAVE_LIBXML2],[1],[libxml2 found at compile time.])
 443         ],
 444         [AC_MSG_WARN([libxml2 not found, some core features will be disabled])])
 445 AM_CONDITIONAL([HAVE_LIBXML2],[test "x$LIBXML2_LIBS" != "x"])
 446
 447 dnl hivex library (highly recommended)
 448 dnl This used to be a part of libguestfs, but was spun off into its
 449 dnl own separate upstream project in libguestfs 1.0.85.
 450 PKG_CHECK_MODULES([HIVEX], [hivex],
 451         [AC_SUBST([HIVEX_CFLAGS])
 452          AC_SUBST([HIVEX_LIBS])
 453          AC_DEFINE([HAVE_HIVEX],[1],[hivex library found at compile time.])
 454         ],
 455         [AC_MSG_WARN([hivex not found, some core features will be disabled])])
 456
 457 dnl FUSE is optional to build the FUSE module.
 458 AC_ARG_ENABLE([fuse],
 459         AS_HELP_STRING([--disable-fuse], [Disable FUSE (guestmount) support]),
 460         [],
 461         [enable_fuse=yes])
 462 AS_IF([test "x$enable_fuse" != "xno"],
 463         [PKG_CHECK_MODULES([FUSE],[fuse],,[
 464                 enable_fuse=no
 465                 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])])
 466 AM_CONDITIONAL([HAVE_FUSE],[test "x$enable_fuse" != "xno"])
 467
 468 dnl Check for OCaml (optional, for OCaml bindings).
 469 OCAMLC=no
 470 OCAMLFIND=no
 471 AC_ARG_ENABLE([ocaml],
 472         AS_HELP_STRING([--disable-ocaml], [Disable OCaml language bindings]),
 473         [],
 474         [enable_ocaml=yes])
 475 AS_IF([test "x$enable_ocaml" != "xno"],
 476         [dnl OCAMLC and OCAMLFIND have to be unset first, otherwise
 477          dnl AC_CHECK_TOOL (inside AC_PROG_OCAML) will not look.
 478          OCAMLC=
 479          OCAMLFIND=
 480          AC_PROG_OCAML
 481          AC_PROG_FINDLIB
 482         ])
 483 AM_CONDITIONAL([HAVE_OCAML],
 484                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
 485
 486 dnl Check for Perl (optional, for Perl bindings).
 487 PERL=no
 488 AC_ARG_ENABLE([perl],
 489         AS_HELP_STRING([--disable-perl], [Disable Perl language bindings]),
 490         [],
 491         [enable_perl=yes])
 492 AS_IF([test "x$enable_perl" != "xno"],
 493         [
 494         PERL=
 495         AC_CHECK_PROG([PERL],[perl],[perl],[no])
 496
 497         dnl Check for Perl modules that must be present to compile and
 498         dnl test the Perl bindings.
 499         missing_perl_modules=no
 500         for pm in Test::More ExtUtils::MakeMaker; do
 501             AC_MSG_CHECKING([for $pm])
 502             if ! perl -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
 503                 AC_MSG_RESULT([no])
 504                 missing_perl_modules=yes
 505             else
 506                 AC_MSG_RESULT([yes])
 507             fi
 508         done
 509         if test "x$missing_perl_modules" = "xyes"; then
 510             AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 511         fi
 512         ])
 513 AM_CONDITIONAL([HAVE_PERL],
 514     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 515
 516 dnl Check for Python (optional, for Python bindings).
 517 PYTHON_PREFIX=
 518 PYTHON_VERSION=
 519 PYTHON_INCLUDEDIR=
 520 PYTHON_INSTALLDIR=
 521
 522 AC_ARG_ENABLE([python],
 523         AS_HELP_STRING([--disable-python], [Disable Python language bindings]),
 524         [],
 525         [enable_python=yes])
 526 AS_IF([test "x$enable_python" != "xno"],
 527         [
 528         AC_CHECK_PROG([PYTHON],[python],[python],[no])
 529
 530         if test "x$PYTHON" != "xno"; then
 531             AC_MSG_CHECKING([Python prefix])
 532             PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 533             AC_MSG_RESULT([$PYTHON_PREFIX])
 534
 535             AC_MSG_CHECKING([Python version])
 536             PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 537             AC_MSG_RESULT([$PYTHON_VERSION])
 538
 539             for d in \
 540                 $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 541                 /usr/include/python$PYTHON_VERSION \
 542                 /usr/local/include/python$PYTHON_VERSION
 543             do
 544                 AC_MSG_CHECKING([Python.h in $d])
 545                 if test -r "$d/Python.h"; then
 546                     AC_MSG_RESULT([found])
 547                     PYTHON_INCLUDEDIR=$d
 548                     break
 549                 fi
 550                 AC_MSG_RESULT([not found])
 551             done
 552             if test "x$PYTHON_INCLUDEDIR" = "x"; then
 553                 AC_MSG_WARN([Python include directory not found])
 554             fi
 555
 556             AC_ARG_WITH([python-installdir],
 557                         [AS_HELP_STRING([--with-python-installdir],
 558                                         [directory to install python modules @<:@default=check@:>@])],
 559                         [PYTHON_INSTALLDIR="$withval"
 560                         AC_MSG_NOTICE([Python install dir $PYTHON_INSTALLDIR])],
 561                         [PYTHON_INSTALLDIR=check])
 562
 563             if test "x$PYTHON_INSTALLDIR" = "xcheck"; then
 564                 PYTHON_INSTALLDIR=
 565                 for d in \
 566                     $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 567                     $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 568                     /usr/lib64/python$PYTHON_VERSION/site-packages \
 569                     /usr/lib/python$PYTHON_VERSION/site-packages \
 570                     /usr/local/lib/python$PYTHON_VERSION/site-packages
 571                 do
 572                     AC_MSG_CHECKING([for $d])
 573                     if test -d "$d"; then
 574                         AC_MSG_RESULT([found])
 575                         PYTHON_INSTALLDIR=$d
 576                         break
 577                     fi
 578                     AC_MSG_RESULT([not found])
 579                 done
 580                 if test "x$PYTHON_INSTALLDIR" = "x"; then
 581                     AC_MSG_WARN([Python site-packages directory not found])
 582                 fi
 583             fi
 584
 585             old_LIBS="$LIBS"
 586             LIBS="$LIBS -lpython$PYTHON_VERSION"
 587             AC_CHECK_FUNCS([PyCapsule_New])
 588             LIBS="$old_LIBS"
 589         fi
 590
 591         AC_SUBST(PYTHON_PREFIX)
 592         AC_SUBST(PYTHON_VERSION)
 593         AC_SUBST(PYTHON_INCLUDEDIR)
 594         AC_SUBST(PYTHON_INSTALLDIR)
 595         ])
 596 AM_CONDITIONAL([HAVE_PYTHON],
 597     [test "x$PYTHON" != "xno" && test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_INSTALLDIR" != "x"])
 598
 599 dnl Check for Ruby and rake (optional, for Ruby bindings).
 600 AC_ARG_ENABLE([ruby],
 601         AS_HELP_STRING([--disable-ruby], [Disable Ruby language bindings]),
 602         [],
 603         [enable_ruby=yes])
 604 AS_IF([test "x$enable_ruby" != "xno"],
 605         [
 606         AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 607         AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 608         ])
 609 AM_CONDITIONAL([HAVE_RUBY],
 610     [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
 611
 612 dnl Check for Java.
 613 AC_ARG_WITH(java_home,
 614     [AS_HELP_STRING([--with-java-home],
 615         [specify path to JDK directory @<:@default=check@:>@])],
 616     [],
 617     [with_java_home=check])
 618
 619 if test "x$with_java_home" != "xno"; then
 620     if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
 621     then
 622         # Reject unsafe characters in $JAVA_HOME
 623         jh_lf='
 624 '
 625         case $JAVA_HOME in
 626           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 627             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 628         esac
 629         if test -d "$with_java_home"; then
 630             JAVA_HOME="$with_java_home"
 631         else
 632             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 633         fi
 634     fi
 635
 636     if test "x$JAVA_HOME" = "x"; then
 637         # Look for Java in some likely locations.
 638         for d in \
 639             /usr/lib/jvm/java \
 640             /usr/lib/jvm/java-6-openjdk
 641         do
 642             if test -d $d && test -f $d/bin/java; then
 643                 JAVA_HOME=$d
 644                 break
 645             fi
 646         done
 647     fi
 648
 649     if test "x$JAVA_HOME" != "x"; then
 650         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 651         if test ! -x "$JAVA_HOME/bin/java"; then
 652             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 653         else
 654             JAVA="$JAVA_HOME/bin/java"
 655         fi
 656         if test ! -x "$JAVA_HOME/bin/javac"; then
 657             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 658         else
 659             JAVAC="$JAVA_HOME/bin/javac"
 660         fi
 661         if test ! -x "$JAVA_HOME/bin/javah"; then
 662             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 663         else
 664             JAVAH="$JAVA_HOME/bin/javah"
 665         fi
 666         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 667             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 668         else
 669             JAVADOC="$JAVA_HOME/bin/javadoc"
 670         fi
 671         if test ! -x "$JAVA_HOME/bin/jar"; then
 672             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 673         else
 674             JAR="$JAVA_HOME/bin/jar"
 675         fi
 676         java_version=`$JAVA -version 2>&1 | grep "java version"`
 677         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 678
 679         dnl Find jni.h.
 680         AC_MSG_CHECKING([for jni.h])
 681         if test -f "$JAVA_HOME/include/jni.h"; then
 682             JNI_CFLAGS="-I$JAVA_HOME/include"
 683         else
 684             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 685                 head=`find $JAVA_HOME -name jni.h | tail -1`
 686                 dir=`dirname "$head"`
 687                 JNI_CFLAGS="-I$dir"
 688             else
 689                 AC_MSG_FAILURE([missing jni.h header file])
 690             fi
 691         fi
 692         AC_MSG_RESULT([$JNI_CFLAGS])
 693
 694         dnl Find jni_md.h.
 695         AC_MSG_CHECKING([for jni_md.h])
 696         case "$build_os" in
 697         *linux*) system="linux" ;;
 698         *SunOS*) system="solaris" ;;
 699         *cygwin*) system="win32" ;;
 700         *) system="$build_os" ;;
 701         esac
 702         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 703             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 704         else
 705             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 706                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 707                 dir=`dirname "$head"`
 708                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 709             else
 710                 AC_MSG_FAILURE([missing jni_md.h header file])
 711             fi
 712         fi
 713         AC_MSG_RESULT([$JNI_CFLAGS])
 714
 715         dnl Need extra version flag?
 716         AC_MSG_CHECKING([extra javac flags])
 717         JAVAC_FLAGS=
 718         javac_version=`$JAVAC -version 2>&1`
 719         case "$javac_version" in
 720         *Eclipse*)
 721             JAVAC_FLAGS="-source 1.5" ;;
 722         esac
 723         AC_MSG_RESULT([$JAVAC_FLAGS])
 724
 725         dnl Where to install jarfiles.
 726         dnl XXX How to make it configurable?
 727         JAR_INSTALL_DIR=\${prefix}/share/java
 728         JNI_INSTALL_DIR=\${libdir}
 729
 730         dnl JNI version.
 731         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 732         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 733         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 734         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 735     fi
 736 fi
 737
 738 AC_SUBST(JAVA_HOME)
 739 AC_SUBST(JAVA)
 740 AC_SUBST(JAVAC)
 741 AC_SUBST(JAVAH)
 742 AC_SUBST(JAVADOC)
 743 AC_SUBST(JAR)
 744 AC_SUBST(JNI_CFLAGS)
 745 AC_SUBST(JAVAC_FLAGS)
 746 AC_SUBST(JAR_INSTALL_DIR)
 747 AC_SUBST(JNI_INSTALL_DIR)
 748 AC_SUBST(JNI_VERSION_INFO)
 749
 750 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 751
 752 dnl Check for Haskell (GHC).
 753 GHC=no
 754 AC_ARG_ENABLE([haskell],
 755         AS_HELP_STRING([--disable-haskell], [Disable Haskell language bindings]),
 756         [],
 757         [enable_haskell=yes])
 758 AS_IF([test "x$enable_haskell" != "xno"],
 759         [
 760         GHC=
 761         AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 762         ])
 763 AM_CONDITIONAL([HAVE_HASKELL],
 764     [test "x$GHC" != "xno"])
 765
 766 dnl PHP
 767 PHP=no
 768 AC_ARG_ENABLE([php],
 769         AS_HELP_STRING([--disable-php], [Disable PHP language bindings]),
 770         [],
 771         [enable_php=yes])
 772 AS_IF([test "x$enable_php" != "xno"],
 773         [
 774         PHP=
 775         AC_CHECK_PROG([PHP],[php],[php],[no])
 776         AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
 777         ])
 778 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
 779
 780 dnl Check for Perl modules needed by Perl virt tools (virt-df, etc.)
 781 AS_IF([test "x$PERL" != "xno"],
 782         [
 783         missing_perl_modules=no
 784         for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper Locale::TextDomain Win::Hivex Win::Hivex::Regedit String::ShellQuote; do
 785             AC_MSG_CHECKING([for $pm])
 786             if ! $PERL -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
 787                 AC_MSG_RESULT([no])
 788                 missing_perl_modules=yes
 789             else
 790                 AC_MSG_RESULT([yes])
 791             fi
 792         done
 793         if test "x$missing_perl_modules" = "xyes"; then
 794             AC_MSG_WARN([some Perl modules required to compile the Perl virt-* tools are missing])
 795         fi
 796         ])
 797
 798 AM_CONDITIONAL([HAVE_TOOLS],
 799     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 800
 801 dnl Library versioning.
 802 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 803 AC_SUBST(MAX_PROC_NR)
 804
 805 dnl Replace libtool with a wrapper that clobbers dependency_libs in *.la files
 806 dnl http://lists.fedoraproject.org/pipermail/devel/2010-November/146343.html
 807 LIBTOOL='bash $(top_srcdir)/libtool-kill-dependency_libs.sh $(top_builddir)/libtool'
 808 AC_SUBST([LIBTOOL])
 809
 810 dnl Run in subdirs.
 811 if test "x$enable_daemon" = "xyes"; then
 812     AC_CONFIG_SUBDIRS([daemon])
 813 fi
 814
 815 dnl Produce output files.
 816 AC_CONFIG_HEADERS([config.h])
 817 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 818 AC_CONFIG_FILES([podwrapper.sh],
 819                 [chmod +x podwrapper.sh])
 820 AC_CONFIG_FILES([Makefile
 821                  generator/Makefile
 822                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 823                  appliance/Makefile
 824                  images/Makefile
 825                  capitests/Makefile
 826                  caution/Makefile
 827                  regressions/Makefile
 828                  test-tool/Makefile
 829                  ocaml/Makefile ocaml/examples/Makefile
 830                  perl/Makefile
 831                  python/Makefile python/examples/Makefile
 832                  ruby/Makefile ruby/Rakefile ruby/examples/Makefile
 833                  java/Makefile
 834                  haskell/Makefile
 835                  inspector/Makefile
 836                  tools/Makefile
 837                  libguestfs.pc
 838                  gnulib/lib/Makefile
 839                  gnulib/tests/Makefile
 840                  fuse/Makefile
 841                  po-docs/Makefile
 842                  po-docs/ja/Makefile
 843                  php/Makefile
 844                  csharp/Makefile
 845                  cat/Makefile
 846                  df/Makefile
 847                  rescue/Makefile
 848                  debian/changelog
 849                  ocaml/META perl/Makefile.PL])
 850 AC_OUTPUT
 851
 852 dnl Produce summary.
 853 echo
 854 echo
 855 echo "------------------------------------------------------------"
 856 echo "Thank you for downloading $PACKAGE_STRING"
 857 echo
 858 echo "This is how we have configured the optional components for you today:"
 859 echo
 860 echo    "Daemon .............................. $enable_daemon"
 861 echo    "Appliance ........................... $enable_appliance"
 862 echo    "QEMU ................................ $QEMU"
 863 echo -n "OCaml bindings ...................... "
 864 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 865 echo -n "Perl bindings ....................... "
 866 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 867 echo -n "Python bindings ..................... "
 868 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 869 echo -n "Ruby bindings ....................... "
 870 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 871 echo -n "Java bindings ....................... "
 872 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 873 echo -n "Haskell bindings .................... "
 874 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 875 echo -n "PHP bindings ........................ "
 876 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 877 echo -n "virt-* tools ........................ "
 878 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 879 echo "FUSE filesystem ..................... $enable_fuse"
 880 echo
 881 echo "If any optional component is configured 'no' when you expected 'yes'"
 882 echo "then you should check the preceeding messages."
 883 echo
 884 echo "Please report bugs back to the mailing list:"
 885 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 886 echo
 887 echo "Next you should type 'make' to build the package,"
 888 echo "then 'make check' to run the tests."
 889 echo "------------------------------------------------------------"