jonesforth.S

   1 /*      A sometimes minimal FORTH compiler and tutorial for Linux / i386 systems. -*- asm -*-
   2         By Richard W.M. Jones <rich@annexia.org> http://annexia.org/forth
   3         This is PUBLIC DOMAIN (see public domain release statement below).
   4         $Id: jonesforth.S,v 1.36 2007-09-27 23:09:39 rich Exp $
   5
   6         gcc -m32 -nostdlib -static -Wl,-Ttext,0 -o jonesforth jonesforth.S
   7 */
   8         .set JONES_VERSION,36
   9 /*
  10         INTRODUCTION ----------------------------------------------------------------------
  11
  12         FORTH is one of those alien languages which most working programmers regard in the same
  13         way as Haskell, LISP, and so on.  Something so strange that they'd rather any thoughts
  14         of it just go away so they can get on with writing this paying code.  But that's wrong
  15         and if you care at all about programming then you should at least understand all these
  16         languages, even if you will never use them.
  17
  18         LISP is the ultimate high-level language, and features from LISP are being added every
  19         decade to the more common languages.  But FORTH is in some ways the ultimate in low level
  20         programming.  Out of the box it lacks features like dynamic memory management and even
  21         strings.  In fact, at its primitive level it lacks even basic concepts like IF-statements
  22         and loops.
  23
  24         Why then would you want to learn FORTH?  There are several very good reasons.  First
  25         and foremost, FORTH is minimal.  You really can write a complete FORTH in, say, 2000
  26         lines of code.  I don't just mean a FORTH program, I mean a complete FORTH operating
  27         system, environment and language.  You could boot such a FORTH on a bare PC and it would
  28         come up with a prompt where you could start doing useful work.  The FORTH you have here
  29         isn't minimal and uses a Linux process as its 'base PC' (both for the purposes of making
  30         it a good tutorial). It's possible to completely understand the system.  Who can say they
  31         completely understand how Linux works, or gcc?
  32
  33         Secondly FORTH has a peculiar bootstrapping property.  By that I mean that after writing
  34         a little bit of assembly to talk to the hardware and implement a few primitives, all the
  35         rest of the language and compiler is written in FORTH itself.  Remember I said before
  36         that FORTH lacked IF-statements and loops?  Well of course it doesn't really because
  37         such a lanuage would be useless, but my point was rather that IF-statements and loops are
  38         written in FORTH itself.
  39
  40         Now of course this is common in other languages as well, and in those languages we call
  41         them 'libraries'.  For example in C, 'printf' is a library function written in C.  But
  42         in FORTH this goes way beyond mere libraries.  Can you imagine writing C's 'if' in C?
  43         And that brings me to my third reason: If you can write 'if' in FORTH, then why restrict
  44         yourself to the usual if/while/for/switch constructs?  You want a construct that iterates
  45         over every other element in a list of numbers?  You can add it to the language.  What
  46         about an operator which pulls in variables directly from a configuration file and makes
  47         them available as FORTH variables?  Or how about adding Makefile-like dependencies to
  48         the language?  No problem in FORTH.  How about modifying the FORTH compiler to allow
  49         complex inlining strategies -- simple.  This concept isn't common in programming languages,
  50         but it has a name (in fact two names): "macros" (by which I mean LISP-style macros, not
  51         the lame C preprocessor) and "domain specific languages" (DSLs).
  52
  53         This tutorial isn't about learning FORTH as the language.  I'll point you to some references
  54         you should read if you're not familiar with using FORTH.  This tutorial is about how to
  55         write FORTH.  In fact, until you understand how FORTH is written, you'll have only a very
  56         superficial understanding of how to use it.
  57
  58         So if you're not familiar with FORTH or want to refresh your memory here are some online
  59         references to read:
  60
  61         http://en.wikipedia.org/wiki/Forth_%28programming_language%29
  62
  63         http://galileo.phys.virginia.edu/classes/551.jvn.fall01/primer.htm
  64
  65         http://wiki.laptop.org/go/Forth_Lessons
  66
  67         http://www.albany.net/~hello/simple.htm
  68
  69         Here is another "Why FORTH?" essay: http://www.jwdt.com/~paysan/why-forth.html
  70
  71         Discussion and criticism of this FORTH here: http://lambda-the-ultimate.org/node/2452
  72
  73         ACKNOWLEDGEMENTS ----------------------------------------------------------------------
  74
  75         This code draws heavily on the design of LINA FORTH (http://home.hccnet.nl/a.w.m.van.der.horst/lina.html)
  76         by Albert van der Horst.  Any similarities in the code are probably not accidental.
  77
  78         Some parts of this FORTH are also based on this IOCCC entry from 1992:
  79         http://ftp.funet.fi/pub/doc/IOCCC/1992/buzzard.2.design.
  80         I was very proud when Sean Barrett, the original author of the IOCCC entry, commented in the LtU thread
  81         http://lambda-the-ultimate.org/node/2452#comment-36818 about this FORTH.
  82
  83         And finally I'd like to acknowledge the (possibly forgotten?) authors of ARTIC FORTH because their
  84         original program which I still have on original cassette tape kept nagging away at me all these years.
  85         http://en.wikipedia.org/wiki/Artic_Software
  86
  87         PUBLIC DOMAIN ----------------------------------------------------------------------
  88
  89         I, the copyright holder of this work, hereby release it into the public domain. This applies worldwide.
  90
  91         In case this is not legally possible, I grant any entity the right to use this work for any purpose,
  92         without any conditions, unless such conditions are required by law.
  93
  94         SETTING UP ----------------------------------------------------------------------
  95
  96         Let's get a few housekeeping things out of the way.  Firstly because I need to draw lots of
  97         ASCII-art diagrams to explain concepts, the best way to look at this is using a window which
  98         uses a fixed width font and is at least this wide:
  99
 100  <------------------------------------------------------------------------------------------------------------------------>
 101
 102         Secondly make sure TABS are set to 8 characters.  The following should be a vertical
 103         line.  If not, sort out your tabs.
 104
 105         |
 106         |
 107         |
 108
 109         Thirdly I assume that your screen is at least 50 characters high.
 110
 111         ASSEMBLING ----------------------------------------------------------------------
 112
 113         If you want to actually run this FORTH, rather than just read it, you will need Linux on an
 114         i386.  Linux because instead of programming directly to the hardware on a bare PC which I
 115         could have done, I went for a simpler tutorial by assuming that the 'hardware' is a Linux
 116         process with a few basic system calls (read, write and exit and that's about all).  i386
 117         is needed because I had to write the assembly for a processor, and i386 is by far the most
 118         common.  (Of course when I say 'i386', any 32- or 64-bit x86 processor will do.  I'm compiling
 119         this on a 64 bit AMD Opteron).
 120
 121         Again, to assemble this you will need gcc and gas (the GNU assembler).  The commands to
 122         assemble and run the code (save this file as 'jonesforth.S') are:
 123
 124         gcc -m32 -nostdlib -static -Wl,-Ttext,0 -o jonesforth jonesforth.S
 125         cat jonesforth.f - | ./jonesforth
 126
 127         If you want to run your own FORTH programs you can do:
 128
 129         cat jonesforth.f myprog.f | ./jonesforth
 130
 131         If you want to load your own FORTH code and then continue reading user commands, you can do:
 132
 133         cat jonesforth.f myfunctions.f - | ./jonesforth
 134
 135         ASSEMBLER ----------------------------------------------------------------------
 136
 137         (You can just skip to the next section -- you don't need to be able to read assembler to
 138         follow this tutorial).
 139
 140         However if you do want to read the assembly code here are a few notes about gas (the GNU assembler):
 141
 142         (1) Register names are prefixed with '%', so %eax is the 32 bit i386 accumulator.  The registers
 143             available on i386 are: %eax, %ebx, %ecx, %edx, %esi, %edi, %ebp and %esp, and most of them
 144             have special purposes.
 145
 146         (2) Add, mov, etc. take arguments in the form SRC,DEST.  So mov %eax,%ecx moves %eax -> %ecx
 147
 148         (3) Constants are prefixed with '$', and you mustn't forget it!  If you forget it then it
 149             causes a read from memory instead, so:
 150             mov $2,%eax         moves number 2 into %eax
 151             mov 2,%eax          reads the 32 bit word from address 2 into %eax (ie. most likely a mistake)
 152
 153         (4) gas has a funky syntax for local labels, where '1f' (etc.) means label '1:' "forwards"
 154             and '1b' (etc.) means label '1:' "backwards".
 155
 156         (5) 'ja' is "jump if above", 'jb' for "jump if below", 'je' "jump if equal" etc.
 157
 158         (6) gas has a reasonably nice .macro syntax, and I use them a lot to make the code shorter and
 159             less repetitive.
 160
 161         For more help reading the assembler, do "info gas" at the Linux prompt.
 162
 163         Now the tutorial starts in earnest.
 164
 165         THE DICTIONARY ----------------------------------------------------------------------
 166
 167         In FORTH as you will know, functions are called "words", and just as in other languages they
 168         have a name and a definition.  Here are two FORTH words:
 169
 170         : DOUBLE DUP + ;                \ name is "DOUBLE", definition is "DUP +"
 171         : QUADRUPLE DOUBLE DOUBLE ;     \ name is "QUADRUPLE", definition is "DOUBLE DOUBLE"
 172
 173         Words, both built-in ones and ones which the programmer defines later, are stored in a dictionary
 174         which is just a linked list of dictionary entries.
 175
 176         <--- DICTIONARY ENTRY (HEADER) ----------------------->
 177         +------------------------+--------+---------- - - - - +----------- - - - -
 178         | LINK POINTER           | LENGTH/| NAME              | DEFINITION
 179         |                        | FLAGS  |                   |
 180         +--- (4 bytes) ----------+- byte -+- n bytes  - - - - +----------- - - - -
 181
 182         I'll come to the definition of the word later.  For now just look at the header.  The first
 183         4 bytes are the link pointer.  This points back to the previous word in the dictionary, or, for
 184         the first word in the dictionary it is just a NULL pointer.  Then comes a length/flags byte.
 185         The length of the word can be up to 31 characters (5 bits used) and the top three bits are used
 186         for various flags which I'll come to later.  This is followed by the name itself, and in this
 187         implementation the name is rounded up to a multiple of 4 bytes by padding it with zero bytes.
 188         That's just to ensure that the definition starts on a 32 bit boundary.
 189
 190         A FORTH variable called LATEST contains a pointer to the most recently defined word, in
 191         other words, the head of this linked list.
 192
 193         DOUBLE and QUADRUPLE might look like this:
 194
 195           pointer to previous word
 196            ^
 197            |
 198         +--|------+---+---+---+---+---+---+---+---+------------- - - - -
 199         | LINK    | 6 | D | O | U | B | L | E | 0 | (definition ...)
 200         +---------+---+---+---+---+---+---+---+---+------------- - - - -
 201            ^       len                         padding
 202            |
 203         +--|------+---+---+---+---+---+---+---+---+---+---+---+---+------------- - - - -
 204         | LINK    | 9 | Q | U | A | D | R | U | P | L | E | 0 | 0 | (definition ...)
 205         +---------+---+---+---+---+---+---+---+---+---+---+---+---+------------- - - - -
 206            ^       len                                     padding
 207            |
 208            |
 209           LATEST
 210
 211         You should be able to see from this how you might implement functions to find a word in
 212         the dictionary (just walk along the dictionary entries starting at LATEST and matching
 213         the names until you either find a match or hit the NULL pointer at the end of the dictionary);
 214         and add a word to the dictionary (create a new definition, set its LINK to LATEST, and set
 215         LATEST to point to the new word).  We'll see precisely these functions implemented in
 216         assembly code later on.
 217
 218         One interesting consequence of using a linked list is that you can redefine words, and
 219         a newer definition of a word overrides an older one.  This is an important concept in
 220         FORTH because it means that any word (even "built-in" or "standard" words) can be
 221         overridden with a new definition, either to enhance it, to make it faster or even to
 222         disable it.  However because of the way that FORTH words get compiled, which you'll
 223         understand below, words defined using the old definition of a word continue to use
 224         the old definition.  Only words defined after the new definition use the new definition.
 225
 226         DIRECT THREADED CODE ----------------------------------------------------------------------
 227
 228         Now we'll get to the really crucial bit in understanding FORTH, so go and get a cup of tea
 229         or coffee and settle down.  It's fair to say that if you don't understand this section, then you
 230         won't "get" how FORTH works, and that would be a failure on my part for not explaining it well.
 231         So if after reading this section a few times you don't understand it, please email me
 232         (rich@annexia.org).
 233
 234         Let's talk first about what "threaded code" means.  Imagine a peculiar version of C where
 235         you are only allowed to call functions without arguments.  (Don't worry for now that such a
 236         language would be completely useless!)  So in our peculiar C, code would look like this:
 237
 238         f ()
 239         {
 240           a ();
 241           b ();
 242           c ();
 243         }
 244
 245         and so on.  How would a function, say 'f' above, be compiled by a standard C compiler?
 246         Probably into assembly code like this.  On the right hand side I've written the actual
 247         i386 machine code.
 248
 249         f:
 250           CALL a                        E8 08 00 00 00
 251           CALL b                        E8 1C 00 00 00
 252           CALL c                        E8 2C 00 00 00
 253           ; ignore the return from the function for now
 254
 255         "E8" is the x86 machine code to "CALL" a function.  In the first 20 years of computing
 256         memory was hideously expensive and we might have worried about the wasted space being used
 257         by the repeated "E8" bytes.  We can save 20% in code size (and therefore, in expensive memory)
 258         by compressing this into just:
 259
 260         08 00 00 00             Just the function addresses, without
 261         1C 00 00 00             the CALL prefix.
 262         2C 00 00 00
 263
 264         On a 16-bit machine like the ones which originally ran FORTH the savings are even greater - 33%.
 265
 266         [Historical note: If the execution model that FORTH uses looks strange from the following
 267         paragraphs, then it was motivated entirely by the need to save memory on early computers.
 268         This code compression isn't so important now when our machines have more memory in their L1
 269         caches than those early computers had in total, but the execution model still has some
 270         useful properties].
 271
 272         Of course this code won't run directly any more.  Instead we need to write an interpreter
 273         which takes each pair of bytes and calls it.
 274
 275         On an i386 machine it turns out that we can write this interpreter rather easily, in just
 276         two assembly instructions which turn into just 3 bytes of machine code.  Let's store the
 277         pointer to the next word to execute in the %esi register:
 278
 279                 08 00 00 00     <- We're executing this one now.  %esi is the _next_ one to execute.
 280         %esi -> 1C 00 00 00
 281                 2C 00 00 00
 282
 283         The all-important i386 instruction is called LODSL (or in Intel manuals, LODSW).  It does
 284         two things.  Firstly it reads the memory at %esi into the accumulator (%eax).  Secondly it
 285         increments %esi by 4 bytes.  So after LODSL, the situation now looks like this:
 286
 287                 08 00 00 00     <- We're still executing this one
 288                 1C 00 00 00     <- %eax now contains this address (0x0000001C)
 289         %esi -> 2C 00 00 00
 290
 291         Now we just need to jump to the address in %eax.  This is again just a single x86 instruction
 292         written JMP *(%eax).  And after doing the jump, the situation looks like:
 293
 294                 08 00 00 00
 295                 1C 00 00 00     <- Now we're executing this subroutine.
 296         %esi -> 2C 00 00 00
 297
 298         To make this work, each subroutine is followed by the two instructions 'LODSL; JMP *(%eax)'
 299         which literally make the jump to the next subroutine.
 300
 301         And that brings us to our first piece of actual code!  Well, it's a macro.
 302 */
 303
 304 /* NEXT macro. */
 305         .macro NEXT
 306         lodsl
 307         jmp *(%eax)
 308         .endm
 309
 310 /*      The macro is called NEXT.  That's a FORTH-ism.  It expands to those two instructions.
 311
 312         Every FORTH primitive that we write has to be ended by NEXT.  Think of it kind of like
 313         a return.
 314
 315         The above describes what is known as direct threaded code.
 316
 317         To sum up: We compress our function calls down to a list of addresses and use a somewhat
 318         magical macro to act as a "jump to next function in the list".  We also use one register (%esi)
 319         to act as a kind of instruction pointer, pointing to the next function in the list.
 320
 321         I'll just give you a hint of what is to come by saying that a FORTH definition such as:
 322
 323         : QUADRUPLE DOUBLE DOUBLE ;
 324
 325         actually compiles (almost, not precisely but we'll see why in a moment) to a list of
 326         function addresses for DOUBLE, DOUBLE and a special function called EXIT to finish off.
 327
 328         At this point, REALLY EAGLE-EYED ASSEMBLY EXPERTS are saying "JONES, YOU'VE MADE A MISTAKE!".
 329
 330         I lied about JMP *(%eax).
 331
 332         INDIRECT THREADED CODE ----------------------------------------------------------------------
 333
 334         It turns out that direct threaded code is interesting but only if you want to just execute
 335         a list of functions written in assembly language.  So QUADRUPLE would work only if DOUBLE
 336         was an assembly language function.  In the direct threaded code, QUADRUPLE would look like:
 337
 338                 +------------------+
 339                 | addr of DOUBLE  --------------------> (assembly code to do the double)
 340                 +------------------+                    NEXT
 341         %esi -> | addr of DOUBLE   |
 342                 +------------------+
 343
 344         We can add an extra indirection to allow us to run both words written in assembly language
 345         (primitives written for speed) and words written in FORTH themselves as lists of addresses.
 346
 347         The extra indirection is the reason for the brackets in JMP *(%eax).
 348
 349         Let's have a look at how QUADRUPLE and DOUBLE really look in FORTH:
 350
 351                 : QUADRUPLE DOUBLE DOUBLE ;
 352
 353                 +------------------+
 354                 | codeword         |               : DOUBLE DUP + ;
 355                 +------------------+
 356                 | addr of DOUBLE  ---------------> +------------------+
 357                 +------------------+               | codeword         |
 358                 | addr of DOUBLE   |               +------------------+
 359                 +------------------+               | addr of DUP   --------------> +------------------+
 360                 | addr of EXIT     |               +------------------+            | codeword      -------+
 361                 +------------------+       %esi -> | addr of +     --------+       +------------------+   |
 362                                                    +------------------+    |       | assembly to    <-----+
 363                                                    | addr of EXIT     |    |       | implement DUP    |
 364                                                    +------------------+    |       |    ..            |
 365                                                                            |       |    ..            |
 366                                                                            |       | NEXT             |
 367                                                                            |       +------------------+
 368                                                                            |
 369                                                                            +-----> +------------------+
 370                                                                                    | codeword      -------+
 371                                                                                    +------------------+   |
 372                                                                                    | assembly to   <------+
 373                                                                                    | implement +      |
 374                                                                                    |    ..            |
 375                                                                                    |    ..            |
 376                                                                                    | NEXT             |
 377                                                                                    +------------------+
 378
 379         This is the part where you may need an extra cup of tea/coffee/favourite caffeinated
 380         beverage.  What has changed is that I've added an extra pointer to the beginning of
 381         the definitions.  In FORTH this is sometimes called the "codeword".  The codeword is
 382         a pointer to the interpreter to run the function.  For primitives written in
 383         assembly language, the "interpreter" just points to the actual assembly code itself.
 384         They don't need interpreting, they just run.
 385
 386         In words written in FORTH (like QUADRUPLE and DOUBLE), the codeword points to an interpreter
 387         function.
 388
 389         I'll show you the interpreter function shortly, but let's recall our indirect
 390         JMP *(%eax) with the "extra" brackets.  Take the case where we're executing DOUBLE
 391         as shown, and DUP has been called.  Note that %esi is pointing to the address of +
 392
 393         The assembly code for DUP eventually does a NEXT.  That:
 394
 395         (1) reads the address of + into %eax            %eax points to the codeword of +
 396         (2) increments %esi by 4
 397         (3) jumps to the indirect %eax                  jumps to the address in the codeword of +,
 398                                                         ie. the assembly code to implement +
 399
 400                 +------------------+
 401                 | codeword         |
 402                 +------------------+
 403                 | addr of DOUBLE  ---------------> +------------------+
 404                 +------------------+               | codeword         |
 405                 | addr of DOUBLE   |               +------------------+
 406                 +------------------+               | addr of DUP   --------------> +------------------+
 407                 | addr of EXIT     |               +------------------+            | codeword      -------+
 408                 +------------------+               | addr of +     --------+       +------------------+   |
 409                                                    +------------------+    |       | assembly to    <-----+
 410                                            %esi -> | addr of EXIT     |    |       | implement DUP    |
 411                                                    +------------------+    |       |    ..            |
 412                                                                            |       |    ..            |
 413                                                                            |       | NEXT             |
 414                                                                            |       +------------------+
 415                                                                            |
 416                                                                            +-----> +------------------+
 417                                                                                    | codeword      -------+
 418                                                                                    +------------------+   |
 419                                                                         now we're  | assembly to    <-----+
 420                                                                         executing  | implement +      |
 421                                                                         this       |    ..            |
 422                                                                         function   |    ..            |
 423                                                                                    | NEXT             |
 424                                                                                    +------------------+
 425
 426         So I hope that I've convinced you that NEXT does roughly what you'd expect.  This is
 427         indirect threaded code.
 428
 429         I've glossed over four things.  I wonder if you can guess without reading on what they are?
 430
 431         .
 432         .
 433         .
 434
 435         My list of four things are: (1) What does "EXIT" do?  (2) which is related to (1) is how do
 436         you call into a function, ie. how does %esi start off pointing at part of QUADRUPLE, but
 437         then point at part of DOUBLE.  (3) What goes in the codeword for the words which are written
 438         in FORTH?  (4) How do you compile a function which does anything except call other functions
 439         ie. a function which contains a number like : DOUBLE 2 * ; ?
 440
 441         THE INTERPRETER AND RETURN STACK ------------------------------------------------------------
 442
 443         Going at these in no particular order, let's talk about issues (3) and (2), the interpreter
 444         and the return stack.
 445
 446         Words which are defined in FORTH need a codeword which points to a little bit of code to
 447         give them a "helping hand" in life.  They don't need much, but they do need what is known
 448         as an "interpreter", although it doesn't really "interpret" in the same way that, say,
 449         Java bytecode used to be interpreted (ie. slowly).  This interpreter just sets up a few
 450         machine registers so that the word can then execute at full speed using the indirect
 451         threaded model above.
 452
 453         One of the things that needs to happen when QUADRUPLE calls DOUBLE is that we save the old
 454         %esi ("instruction pointer") and create a new one pointing to the first word in DOUBLE.
 455         Because we will need to restore the old %esi at the end of DOUBLE (this is, after all, like
 456         a function call), we will need a stack to store these "return addresses" (old values of %esi).
 457
 458         As you will have read, when reading the background documentation, FORTH has two stacks,
 459         an ordinary stack for parameters, and a return stack which is a bit more mysterious.  But
 460         our return stack is just the stack I talked about in the previous paragraph, used to save
 461         %esi when calling from a FORTH word into another FORTH word.
 462
 463         In this FORTH, we are using the normal stack pointer (%esp) for the parameter stack.
 464         We will use the i386's "other" stack pointer (%ebp, usually called the "frame pointer")
 465         for our return stack.
 466
 467         I've got two macros which just wrap up the details of using %ebp for the return stack.
 468         You use them as for example "PUSHRSP %eax" (push %eax on the return stack) or "POPRSP %ebx"
 469         (pop top of return stack into %ebx).
 470 */
 471
 472 /* Macros to deal with the return stack. */
 473         .macro PUSHRSP reg
 474         lea -4(%ebp),%ebp       // push reg on to return stack
 475         movl \reg,(%ebp)
 476         .endm
 477
 478         .macro POPRSP reg
 479         mov (%ebp),\reg         // pop top of return stack to reg
 480         lea 4(%ebp),%ebp
 481         .endm
 482
 483 /*
 484         And with that we can now talk about the interpreter.
 485
 486         In FORTH the interpreter function is often called DOCOL (I think it means "DO COLON" because
 487         all FORTH definitions start with a colon, as in : DOUBLE DUP + ;
 488
 489         The "interpreter" (it's not really "interpreting") just needs to push the old %esi on the
 490         stack and set %esi to the first word in the definition.  Remember that we jumped to the
 491         function using JMP *(%eax)?  Well a consequence of that is that conveniently %eax contains
 492         the address of this codeword, so just by adding 4 to it we get the address of the first
 493         data word.  Finally after setting up %esi, it just does NEXT which causes that first word
 494         to run.
 495 */
 496
 497 /* DOCOL - the interpreter! */
 498         .text
 499         .align 4
 500 DOCOL:
 501         PUSHRSP %esi            // push %esi on to the return stack
 502         addl $4,%eax            // %eax points to codeword, so make
 503         movl %eax,%esi          // %esi point to first data word
 504         NEXT
 505
 506 /*
 507         Just to make this absolutely clear, let's see how DOCOL works when jumping from QUADRUPLE
 508         into DOUBLE:
 509
 510                 QUADRUPLE:
 511                 +------------------+
 512                 | codeword         |
 513                 +------------------+               DOUBLE:
 514                 | addr of DOUBLE  ---------------> +------------------+
 515                 +------------------+       %eax -> | addr of DOCOL    |
 516         %esi -> | addr of DOUBLE   |               +------------------+
 517                 +------------------+               | addr of DUP      |
 518                 | addr of EXIT     |               +------------------+
 519                 +------------------+               | etc.             |
 520
 521         First, the call to DOUBLE calls DOCOL (the codeword of DOUBLE).  DOCOL does this:  It
 522         pushes the old %esi on the return stack.  %eax points to the codeword of DOUBLE, so we
 523         just add 4 on to it to get our new %esi:
 524
 525                 QUADRUPLE:
 526                 +------------------+
 527                 | codeword         |
 528                 +------------------+               DOUBLE:
 529                 | addr of DOUBLE  ---------------> +------------------+
 530 top of return   +------------------+       %eax -> | addr of DOCOL    |
 531 stack points -> | addr of DOUBLE   |       + 4 =   +------------------+
 532                 +------------------+       %esi -> | addr of DUP      |
 533                 | addr of EXIT     |               +------------------+
 534                 +------------------+               | etc.             |
 535
 536         Then we do NEXT, and because of the magic of threaded code that increments %esi again
 537         and calls DUP.
 538
 539         Well, it seems to work.
 540
 541         One minor point here.  Because DOCOL is the first bit of assembly actually to be defined
 542         in this file (the others were just macros), and because I usually compile this code with the
 543         text segment starting at address 0, DOCOL has address 0.  So if you are disassembling the
 544         code and see a word with a codeword of 0, you will immediately know that the word is
 545         written in FORTH (it's not an assembler primitive) and so uses DOCOL as the interpreter.
 546
 547         STARTING UP ----------------------------------------------------------------------
 548
 549         Now let's get down to nuts and bolts.  When we start the program we need to set up
 550         a few things like the return stack.  But as soon as we can, we want to jump into FORTH
 551         code (albeit much of the "early" FORTH code will still need to be written as
 552         assembly language primitives).
 553
 554         This is what the set up code does.  Does a tiny bit of house-keeping, sets up the
 555         separate return stack (NB: Linux gives us the ordinary parameter stack already), then
 556         immediately jumps to a FORTH word called COLD.  COLD stands for cold-start.  In ISO
 557         FORTH (but not in this FORTH), COLD can be called at any time to completely reset
 558         the state of FORTH, and there is another word called WARM which does a partial reset.
 559 */
 560
 561 /* ELF entry point. */
 562         .text
 563         .globl _start
 564 _start:
 565         cld
 566         mov %esp,var_S0         // Store the initial data stack pointer.
 567         mov $return_stack,%ebp  // Initialise the return stack.
 568
 569         mov $cold_start,%esi    // Initialise interpreter.
 570         NEXT                    // Run interpreter!
 571
 572         .section .rodata
 573 cold_start:                     // High-level code without a codeword.
 574         .int COLD
 575
 576 /*
 577         We also allocate some space for the return stack and some space to store user
 578         definitions.  These are static memory allocations using fixed-size buffers, but it
 579         wouldn't be a great deal of work to make them dynamic.
 580 */
 581
 582         .bss
 583 /* FORTH return stack. */
 584         .set RETURN_STACK_SIZE,8192
 585         .align 4096
 586         .space RETURN_STACK_SIZE
 587 return_stack:                   // Initial top of return stack.
 588
 589 /* The user definitions area: space for user-defined words and general memory allocations. */
 590         .set USER_DEFS_SIZE,65536
 591         .align 4096
 592 user_defs_start:
 593         .space USER_DEFS_SIZE
 594
 595 /* This is used as a temporary input buffer when reading from files or the terminal. */
 596         .set BUFFER_SIZE,4096
 597         .align 4096
 598 buffer:
 599 _initbufftop:
 600         .space BUFFER_SIZE
 601 buffend:
 602 currkey:
 603         .int buffer
 604 bufftop:
 605         .int _initbufftop
 606
 607 /*
 608         BUILT-IN WORDS ----------------------------------------------------------------------
 609
 610         Remember our dictionary entries (headers)?  Let's bring those together with the codeword
 611         and data words to see how : DOUBLE DUP + ; really looks in memory.
 612
 613           pointer to previous word
 614            ^
 615            |
 616         +--|------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
 617         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          | EXIT       |
 618         +---------+---+---+---+---+---+---+---+---+------------+--|---------+------------+------------+
 619            ^       len                         pad  codeword      |
 620            |                                                      V
 621           LINK in next word                             points to codeword of DUP
 622
 623         Initially we can't just write ": DOUBLE DUP + ;" (ie. that literal string) here because we
 624         don't yet have anything to read the string, break it up at spaces, parse each word, etc. etc.
 625         So instead we will have to define built-in words using the GNU assembler data constructors
 626         (like .int, .byte, .string, .ascii and so on -- look them up in the gas info page if you are
 627         unsure of them).
 628
 629         The long way would be:
 630         .int <link to previous word>
 631         .byte 6                 // len
 632         .ascii "DOUBLE"         // string
 633         .byte 0                 // padding
 634 DOUBLE: .int DOCOL              // codeword
 635         .int DUP                // pointer to codeword of DUP
 636         .int PLUS               // pointer to codeword of +
 637         .int EXIT               // pointer to codeword of EXIT
 638
 639         That's going to get quite tedious rather quickly, so here I define an assembler macro
 640         so that I can just write:
 641
 642         defword "DOUBLE",6,,DOUBLE
 643         .int DUP,PLUS,EXIT
 644
 645         and I'll get exactly the same effect.
 646
 647         Don't worry too much about the exact implementation details of this macro - it's complicated!
 648 */
 649
 650 /* Flags - these are discussed later. */
 651         .set F_IMMED,0x80
 652         .set F_HIDDEN,0x20
 653         .set F_LENMASK,0x1f     // length mask
 654
 655         // Store the chain of links.
 656         .set link,0
 657
 658         .macro defword name, namelen, flags=0, label
 659         .section .rodata
 660         .align 4
 661         .globl name_\label
 662 name_\label :
 663         .int link               // link
 664         .set link,name_\label
 665         .byte \flags+\namelen   // flags + length byte
 666         .ascii "\name"          // the name
 667         .align 4
 668         .globl \label
 669 \label :
 670         .int DOCOL              // codeword - the interpreter
 671         // list of word pointers follow
 672         .endm
 673
 674 /*
 675         Similarly I want a way to write words written in assembly language.  There will quite a few
 676         of these to start with because, well, everything has to start in assembly before there's
 677         enough "infrastructure" to be able to start writing FORTH words, but also I want to define
 678         some common FORTH words in assembly language for speed, even though I could write them in FORTH.
 679
 680         This is what DUP looks like in memory:
 681
 682           pointer to previous word
 683            ^
 684            |
 685         +--|------+---+---+---+---+------------+
 686         | LINK    | 3 | D | U | P | code_DUP ---------------------> points to the assembly
 687         +---------+---+---+---+---+------------+                    code used to write DUP,
 688            ^       len              codeword                        which ends with NEXT.
 689            |
 690           LINK in next word
 691
 692         Again, for brevity in writing the header I'm going to write an assembler macro called defcode.
 693 */
 694
 695         .macro defcode name, namelen, flags=0, label
 696         .section .rodata
 697         .align 4
 698         .globl name_\label
 699 name_\label :
 700         .int link               // link
 701         .set link,name_\label
 702         .byte \flags+\namelen   // flags + length byte
 703         .ascii "\name"          // the name
 704         .align 4
 705         .globl \label
 706 \label :
 707         .int code_\label        // codeword
 708         .text
 709         .align 4
 710         .globl code_\label
 711 code_\label :                   // assembler code follows
 712         .endm
 713
 714 /*
 715         Now some easy FORTH primitives.  These are written in assembly for speed.  If you understand
 716         i386 assembly language then it is worth reading these.  However if you don't understand assembly
 717         you can skip the details.
 718 */
 719
 720         defcode "DUP",3,,DUP
 721         pop %eax                // duplicate top of stack
 722         push %eax
 723         push %eax
 724         NEXT
 725
 726         defcode "DROP",4,,DROP
 727         pop %eax                // drop top of stack
 728         NEXT
 729
 730         defcode "SWAP",4,,SWAP
 731         pop %eax                // swap top of stack
 732         pop %ebx
 733         push %eax
 734         push %ebx
 735         NEXT
 736
 737         defcode "OVER",4,,OVER
 738         mov 4(%esp),%eax        // get the second element of stack
 739         push %eax               // and push it on top
 740         NEXT
 741
 742         defcode "ROT",3,,ROT
 743         pop %eax
 744         pop %ebx
 745         pop %ecx
 746         push %eax
 747         push %ecx
 748         push %ebx
 749         NEXT
 750
 751         defcode "-ROT",4,,NROT
 752         pop %eax
 753         pop %ebx
 754         pop %ecx
 755         push %ebx
 756         push %eax
 757         push %ecx
 758         NEXT
 759
 760         defcode "1+",2,,INCR
 761         incl (%esp)             // increment top of stack
 762         NEXT
 763
 764         defcode "1-",2,,DECR
 765         decl (%esp)             // decrement top of stack
 766         NEXT
 767
 768         defcode "4+",2,,INCR4
 769         addl $4,(%esp)          // add 4 to top of stack
 770         NEXT
 771
 772         defcode "4-",2,,DECR4
 773         subl $4,(%esp)          // subtract 4 from top of stack
 774         NEXT
 775
 776         defcode "+",1,,ADD
 777         pop %eax                // get top of stack
 778         addl %eax,(%esp)        // and add it to next word on stack
 779         NEXT
 780
 781         defcode "-",1,,SUB
 782         pop %eax                // get top of stack
 783         subl %eax,(%esp)        // and subtract it from next word on stack
 784         NEXT
 785
 786         defcode "*",1,,MUL
 787         pop %eax
 788         pop %ebx
 789         imull %ebx,%eax
 790         push %eax               // ignore overflow
 791         NEXT
 792
 793 /*
 794         In this FORTH, only /MOD is primitive.  Later we will define the / and MOD words in
 795         terms of the primitive /MOD.  The design of the i386 assembly instruction idiv which
 796         leaves both quotient and remainder makes this obvious choice.
 797 */
 798
 799         defcode "/MOD",4,,DIVMOD
 800         xor %edx,%edx
 801         pop %ebx
 802         pop %eax
 803         idivl %ebx
 804         push %edx               // push remainder
 805         push %eax               // push quotient
 806         NEXT
 807
 808         defcode "=",1,,EQU      // top two words are equal?
 809         pop %eax
 810         pop %ebx
 811         cmp %ebx,%eax
 812         je 1f
 813         pushl $0
 814         NEXT
 815 1:      pushl $1
 816         NEXT
 817
 818         defcode "<>",2,,NEQU    // top two words are not equal?
 819         pop %eax
 820         pop %ebx
 821         cmp %ebx,%eax
 822         je 1f
 823         pushl $1
 824         NEXT
 825 1:      pushl $0
 826         NEXT
 827
 828         defcode "<",1,,LT
 829         pop %eax
 830         pop %ebx
 831         cmp %eax,%ebx
 832         jl 1f
 833         pushl $0
 834         NEXT
 835 1:      pushl $1
 836         NEXT
 837
 838         defcode ">",1,,GT
 839         pop %eax
 840         pop %ebx
 841         cmp %eax,%ebx
 842         jg 1f
 843         pushl $0
 844         NEXT
 845 1:      pushl $1
 846         NEXT
 847
 848         defcode "<=",2,,LE
 849         pop %eax
 850         pop %ebx
 851         cmp %eax,%ebx
 852         jle 1f
 853         pushl $0
 854         NEXT
 855 1:      pushl $1
 856         NEXT
 857
 858         defcode ">=",2,,GE
 859         pop %eax
 860         pop %ebx
 861         cmp %eax,%ebx
 862         jge 1f
 863         pushl $0
 864         NEXT
 865 1:      pushl $1
 866         NEXT
 867
 868         defcode "0=",2,,ZEQU    // top of stack equals 0?
 869         pop %eax
 870         test %eax,%eax
 871         jz 1f
 872         pushl $0
 873         NEXT
 874 1:      pushl $1
 875         NEXT
 876
 877         defcode "0<>",3,,ZNEQU  // top of stack not 0?
 878         pop %eax
 879         test %eax,%eax
 880         jnz 1f
 881         pushl $0
 882         NEXT
 883 1:      pushl $1
 884         NEXT
 885
 886         defcode "0<",2,,ZLT     // comparisons with 0
 887         pop %eax
 888         test %eax,%eax
 889         jl 1f
 890         pushl $0
 891         NEXT
 892 1:      pushl $1
 893         NEXT
 894
 895         defcode "0>",2,,ZGT
 896         pop %eax
 897         test %eax,%eax
 898         jg 1f
 899         pushl $0
 900         NEXT
 901 1:      pushl $1
 902         NEXT
 903
 904         defcode "0<=",3,,ZLE
 905         pop %eax
 906         test %eax,%eax
 907         jle 1f
 908         pushl $0
 909         NEXT
 910 1:      pushl $1
 911         NEXT
 912
 913         defcode "0>=",3,,ZGE
 914         pop %eax
 915         test %eax,%eax
 916         jge 1f
 917         pushl $0
 918         NEXT
 919 1:      pushl $1
 920         NEXT
 921
 922         defcode "AND",3,,AND    // bitwise AND
 923         pop %eax
 924         andl %eax,(%esp)
 925         NEXT
 926
 927         defcode "OR",2,,OR      // bitwise OR
 928         pop %eax
 929         orl %eax,(%esp)
 930         NEXT
 931
 932         defcode "XOR",3,,XOR    // bitwise XOR
 933         pop %eax
 934         xorl %eax,(%esp)
 935         NEXT
 936
 937         defcode "INVERT",6,,INVERT // this is the FORTH bitwise "NOT" function (cf. NEGATE)
 938         notl (%esp)
 939         NEXT
 940
 941 /*
 942         RETURNING FROM FORTH WORDS ----------------------------------------------------------------------
 943
 944         Time to talk about what happens when we EXIT a function.  In this diagram QUADRUPLE has called
 945         DOUBLE, and DOUBLE is about to exit (look at where %esi is pointing):
 946
 947                 QUADRUPLE
 948                 +------------------+
 949                 | codeword         |
 950                 +------------------+               DOUBLE
 951                 | addr of DOUBLE  ---------------> +------------------+
 952                 +------------------+               | codeword         |
 953                 | addr of DOUBLE   |               +------------------+
 954                 +------------------+               | addr of DUP      |
 955                 | addr of EXIT     |               +------------------+
 956                 +------------------+               | addr of +        |
 957                                                    +------------------+
 958                                            %esi -> | addr of EXIT     |
 959                                                    +------------------+
 960
 961         What happens when the + function does NEXT?  Well, the following code is executed.
 962 */
 963
 964         defcode "EXIT",4,,EXIT
 965         POPRSP %esi             // pop return stack into %esi
 966         NEXT
 967
 968 /*
 969         EXIT gets the old %esi which we saved from before on the return stack, and puts it in %esi.
 970         So after this (but just before NEXT) we get:
 971
 972                 QUADRUPLE
 973                 +------------------+
 974                 | codeword         |
 975                 +------------------+               DOUBLE
 976                 | addr of DOUBLE  ---------------> +------------------+
 977                 +------------------+               | codeword         |
 978         %esi -> | addr of DOUBLE   |               +------------------+
 979                 +------------------+               | addr of DUP      |
 980                 | addr of EXIT     |               +------------------+
 981                 +------------------+               | addr of +        |
 982                                                    +------------------+
 983                                                    | addr of EXIT     |
 984                                                    +------------------+
 985
 986         And NEXT just completes the job by, well, in this case just by calling DOUBLE again :-)
 987
 988         LITERALS ----------------------------------------------------------------------
 989
 990         The final point I "glossed over" before was how to deal with functions that do anything
 991         apart from calling other functions.  For example, suppose that DOUBLE was defined like this:
 992
 993         : DOUBLE 2 * ;
 994
 995         It does the same thing, but how do we compile it since it contains the literal 2?  One way
 996         would be to have a function called "2" (which you'd have to write in assembler), but you'd need
 997         a function for every single literal that you wanted to use.
 998
 999         FORTH solves this by compiling the function using a special word called LIT:
1000
1001         +---------------------------+-------+-------+-------+-------+-------+
1002         | (usual header of DOUBLE)  | DOCOL | LIT   | 2     | *     | EXIT  |
1003         +---------------------------+-------+-------+-------+-------+-------+
1004
1005         LIT is executed in the normal way, but what it does next is definitely not normal.  It
1006         looks at %esi (which now points to the literal 2), grabs it, pushes it on the stack, then
1007         manipulates %esi in order to skip the literal as if it had never been there.
1008
1009         What's neat is that the whole grab/manipulate can be done using a single byte single
1010         i386 instruction, our old friend LODSL.  Rather than me drawing more ASCII-art diagrams,
1011         see if you can find out how LIT works:
1012 */
1013
1014         defcode "LIT",3,,LIT
1015         // %esi points to the next command, but in this case it points to the next
1016         // literal 32 bit integer.  Get that literal into %eax and increment %esi.
1017         // On x86, it's a convenient single byte instruction!  (cf. NEXT macro)
1018         lodsl
1019         push %eax               // push the literal number on to stack
1020         NEXT
1021
1022 /*
1023         MEMORY ----------------------------------------------------------------------
1024
1025         As important point about FORTH is that it gives you direct access to the lowest levels
1026         of the machine.  Manipulating memory directly is done frequently in FORTH, and these are
1027         the primitive words for doing it.
1028 */
1029
1030         defcode "!",1,,STORE
1031         pop %ebx                // address to store at
1032         pop %eax                // data to store there
1033         mov %eax,(%ebx)         // store it
1034         NEXT
1035
1036         defcode "@",1,,FETCH
1037         pop %ebx                // address to fetch
1038         mov (%ebx),%eax         // fetch it
1039         push %eax               // push value onto stack
1040         NEXT
1041
1042         defcode "+!",2,,ADDSTORE
1043         pop %ebx                // address
1044         pop %eax                // the amount to add
1045         addl %eax,(%ebx)        // add it
1046         NEXT
1047
1048         defcode "-!",2,,SUBSTORE
1049         pop %ebx                // address
1050         pop %eax                // the amount to subtract
1051         subl %eax,(%ebx)        // add it
1052         NEXT
1053
1054 /*
1055         ! and @ (STORE and FETCH) store 32-bit words.  It's also useful to be able to read and write bytes
1056         so we also define standard words C@ and C!.
1057
1058         Byte-oriented operations only work on architectures which permit them (i386 is one of those).
1059  */
1060
1061         defcode "C!",2,,STOREBYTE
1062         pop %ebx                // address to store at
1063         pop %eax                // data to store there
1064         movb %al,(%ebx)         // store it
1065         NEXT
1066
1067         defcode "C@",2,,FETCHBYTE
1068         pop %ebx                // address to fetch
1069         xor %eax,%eax
1070         movb (%ebx),%al         // fetch it
1071         push %eax               // push value onto stack
1072         NEXT
1073
1074 /*
1075         BUILT-IN VARIABLES ----------------------------------------------------------------------
1076
1077         These are some built-in variables and related standard FORTH words.  Of these, the only one that we
1078         have discussed so far was LATEST, which points to the last (most recently defined) word in the
1079         FORTH dictionary.  LATEST is also a FORTH word which pushes the address of LATEST (the variable)
1080         on to the stack, so you can read or write it using @ and ! operators.  For example, to print
1081         the current value of LATEST (and this can apply to any FORTH variable) you would do:
1082
1083         LATEST @ . CR
1084
1085         To make defining variables shorter, I'm using a macro called defvar, similar to defword and
1086         defcode above.  (In fact the defvar macro uses defcode to do the dictionary header).
1087 */
1088
1089         .macro defvar name, namelen, flags=0, label, initial=0
1090         defcode \name,\namelen,\flags,\label
1091         push $var_\name
1092         NEXT
1093         .data
1094         .align 4
1095 var_\name :
1096         .int \initial
1097         .endm
1098
1099 /*
1100         The built-in variables are:
1101
1102         STATE           Is the interpreter executing code (0) or compiling a word (non-zero)?
1103         LATEST          Points to the latest (most recently defined) word in the dictionary.
1104         HERE            Points to the next free byte of memory.  When compiling, compiled words go here.
1105         _X              These are three scratch variables, used by some standard dictionary words.
1106         _Y
1107         _Z
1108         S0              Stores the address of the top of the parameter stack.
1109         BASE            The current base for printing and reading numbers.
1110
1111 */
1112         defvar "STATE",5,,STATE
1113         defvar "HERE",4,,HERE,user_defs_start
1114         defvar "LATEST",6,,LATEST,name_SYSEXIT // SYSEXIT must be last in built-in dictionary
1115         defvar "_X",2,,TX
1116         defvar "_Y",2,,TY
1117         defvar "_Z",2,,TZ
1118         defvar "S0",2,,SZ
1119         defvar "BASE",4,,BASE,10
1120
1121 /*
1122         BUILT-IN CONSTANTS ----------------------------------------------------------------------
1123
1124         It's also useful to expose a few constants to FORTH.  When the word is executed it pushes a
1125         constant value on the stack.
1126
1127         The built-in constants are:
1128
1129         VERSION         Is the current version of this FORTH.
1130         R0              The address of the top of the return stack.
1131         DOCOL           Pointer to DOCOL.
1132         F_IMMED         The IMMEDIATE flag's actual value.
1133         F_HIDDEN        The HIDDEN flag's actual value.
1134         F_LENMASK       The length mask in the flags/len byte.
1135 */
1136
1137         .macro defconst name, namelen, flags=0, label, value
1138         defcode \name,\namelen,\flags,\label
1139         push $\value
1140         NEXT
1141         .endm
1142
1143         defconst "VERSION",7,,VERSION,JONES_VERSION
1144         defconst "R0",2,,RZ,return_stack
1145         defconst "DOCOL",5,,__DOCOL,DOCOL
1146         defconst "F_IMMED",7,,__F_IMMED,F_IMMED
1147         defconst "F_HIDDEN",8,,__F_HIDDEN,F_HIDDEN
1148         defconst "F_LENMASK",9,,__F_LENMASK,F_LENMASK
1149
1150 /*
1151         RETURN STACK ----------------------------------------------------------------------
1152
1153         These words allow you to access the return stack.  Recall that the register %ebp always points to
1154         the top of the return stack.
1155 */
1156
1157         defcode ">R",2,,TOR
1158         pop %eax                // pop parameter stack into %eax
1159         PUSHRSP %eax            // push it on to the return stack
1160         NEXT
1161
1162         defcode "R>",2,,FROMR
1163         POPRSP %eax             // pop return stack on to %eax
1164         push %eax               // and push on to parameter stack
1165         NEXT
1166
1167         defcode "RSP@",4,,RSPFETCH
1168         push %ebp
1169         NEXT
1170
1171         defcode "RSP!",4,,RSPSTORE
1172         pop %ebp
1173         NEXT
1174
1175         defcode "RDROP",5,,RDROP
1176         lea 4(%ebp),%ebp        // pop return stack and throw away
1177         NEXT
1178
1179 /*
1180         PARAMETER (DATA) STACK ----------------------------------------------------------------------
1181
1182         These functions allow you to manipulate the parameter stack.  Recall that Linux sets up the parameter
1183         stack for us, and it is accessed through %esp.
1184 */
1185
1186         defcode "DSP@",4,,DSPFETCH
1187         mov %esp,%eax
1188         push %eax
1189         NEXT
1190
1191         defcode "DSP!",4,,DSPSTORE
1192         pop %esp
1193         NEXT
1194
1195 /*
1196         INPUT AND OUTPUT ----------------------------------------------------------------------
1197
1198         These are our first really meaty/complicated FORTH primitives.  I have chosen to write them in
1199         assembler, but surprisingly in "real" FORTH implementations these are often written in terms
1200         of more fundamental FORTH primitives.  I chose to avoid that because I think that just obscures
1201         the implementation.  After all, you may not understand assembler but you can just think of it
1202         as an opaque block of code that does what it says.
1203
1204         Let's discuss input first.
1205
1206         The FORTH word KEY reads the next byte from stdin (and pushes it on the parameter stack).
1207         So if KEY is called and someone hits the space key, then the number 32 (ASCII code of space)
1208         is pushed on the stack.
1209
1210         In FORTH there is no distinction between reading code and reading input.  We might be reading
1211         and compiling code, we might be reading words to execute, we might be asking for the user
1212         to type their name -- ultimately it all comes in through KEY.
1213
1214         The implementation of KEY uses an input buffer of a certain size (defined at the end of the
1215         program).  It calls the Linux read(2) system call to fill this buffer and tracks its position
1216         in the buffer using a couple of variables, and if it runs out of input buffer then it refills
1217         it automatically.  The other thing that KEY does is if it detects that stdin has closed, it
1218         exits the program, which is why when you hit ^D the FORTH system cleanly exits.
1219 */
1220
1221 #include <asm-i386/unistd.h>
1222
1223         defcode "KEY",3,,KEY
1224         call _KEY
1225         push %eax               // push return value on stack
1226         NEXT
1227 _KEY:
1228         mov (currkey),%ebx
1229         cmp (bufftop),%ebx
1230         jge 1f
1231         xor %eax,%eax
1232         mov (%ebx),%al
1233         inc %ebx
1234         mov %ebx,(currkey)
1235         ret
1236
1237 1:      // out of input; use read(2) to fetch more input from stdin
1238         xor %ebx,%ebx           // 1st param: stdin
1239         mov $buffer,%ecx        // 2nd param: buffer
1240         mov %ecx,currkey
1241         mov $buffend-buffer,%edx // 3rd param: max length
1242         mov $__NR_read,%eax     // syscall: read
1243         int $0x80
1244         test %eax,%eax          // If %eax <= 0, then exit.
1245         jbe 2f
1246         addl %eax,%ecx          // buffer+%eax = bufftop
1247         mov %ecx,bufftop
1248         jmp _KEY
1249
1250 2:      // error or out of input: exit
1251         xor %ebx,%ebx
1252         mov $__NR_exit,%eax     // syscall: exit
1253         int $0x80
1254
1255 /*
1256         By contrast, output is much simpler.  The FORTH word EMIT writes out a single byte to stdout.
1257         This implementation just uses the write system call.  No attempt is made to buffer output, but
1258         it would be a good exercise to add it.
1259 */
1260
1261         defcode "EMIT",4,,EMIT
1262         pop %eax
1263         call _EMIT
1264         NEXT
1265 _EMIT:
1266         mov $1,%ebx             // 1st param: stdout
1267
1268         // write needs the address of the byte to write
1269         mov %al,(2f)
1270         mov $2f,%ecx            // 2nd param: address
1271
1272         mov $1,%edx             // 3rd param: nbytes = 1
1273
1274         mov $__NR_write,%eax    // write syscall
1275         int $0x80
1276         ret
1277
1278         .bss
1279 2:      .space 1                // scratch used by EMIT
1280
1281 /*
1282         Back to input, WORD is a FORTH word which reads the next full word of input.
1283
1284         What it does in detail is that it first skips any blanks (spaces, tabs, newlines and so on).
1285         Then it calls KEY to read characters into an internal buffer until it hits a blank.  Then it
1286         calculates the length of the word it read and returns the address and the length as
1287         two words on the stack (with the length at the top of stack).
1288
1289         Notice that WORD has a single internal buffer which it overwrites each time (rather like
1290         a static C string).  Also notice that WORD's internal buffer is just 32 bytes long and
1291         there is NO checking for overflow.  31 bytes happens to be the maximum length of a
1292         FORTH word that we support, and that is what WORD is used for: to read FORTH words when
1293         we are compiling and executing code.  The returned strings are not NUL-terminated, so
1294         in some crazy-world you could define FORTH words containing ASCII NULs, although why
1295         you'd want to is a bit beyond me.
1296
1297         WORD is not suitable for just reading strings (eg. user input) because of all the above
1298         peculiarities and limitations.
1299
1300         Note that when executing, you'll see:
1301         WORD FOO
1302         which puts "FOO" and length 3 on the stack, but when compiling:
1303         : BAR WORD FOO ;
1304         is an error (or at least it doesn't do what you might expect).  Later we'll talk about compiling
1305         and immediate mode, and you'll understand why.
1306 */
1307
1308         defcode "WORD",4,,WORD
1309         call _WORD
1310         push %edi               // push base address
1311         push %ecx               // push length
1312         NEXT
1313
1314 _WORD:
1315         /* Search for first non-blank character.  Also skip \ comments. */
1316 1:
1317         call _KEY               // get next key, returned in %eax
1318         cmpb $'\\',%al          // start of a comment?
1319         je 3f                   // if so, skip the comment
1320         cmpb $' ',%al
1321         jbe 1b                  // if so, keep looking
1322
1323         /* Search for the end of the word, storing chars as we go. */
1324         mov $5f,%edi            // pointer to return buffer
1325 2:
1326         stosb                   // add character to return buffer
1327         call _KEY               // get next key, returned in %al
1328         cmpb $' ',%al           // is blank?
1329         ja 2b                   // if not, keep looping
1330
1331         /* Return the word (well, the static buffer) and length. */
1332         sub $5f,%edi
1333         mov %edi,%ecx           // return length of the word
1334         mov $5f,%edi            // return address of the word
1335         ret
1336
1337         /* Code to skip \ comments to end of the current line. */
1338 3:
1339         call _KEY
1340         cmpb $'\n',%al          // end of line yet?
1341         jne 3b
1342         jmp 1b
1343
1344         .bss
1345         // A static buffer where WORD returns.  Subsequent calls
1346         // overwrite this buffer.  Maximum word length is 32 chars.
1347 5:      .space 32
1348
1349 /*
1350         As well as reading in words we'll need to read in numbers and for that we are using a function
1351         called SNUMBER.  This parses a numeric string such as one returned by WORD and pushes the
1352         number on the parameter stack.
1353
1354         This function does absolutely no error checking, and in particular the length of the string
1355         must be >= 1 bytes, and should contain only digits 0-9.  If it doesn't you'll get random results.
1356
1357         This function is only used when reading literal numbers in code, and shouldn't really be used
1358         in user code at all.
1359 */
1360         defcode "SNUMBER",7,,SNUMBER
1361         pop %edi
1362         pop %ecx
1363         call _SNUMBER
1364         push %eax
1365         NEXT
1366 _SNUMBER:
1367         xor %eax,%eax
1368         xor %ebx,%ebx
1369 1:
1370         imull $10,%eax          // %eax *= 10
1371         movb (%edi),%bl
1372         inc %edi
1373         subb $'0',%bl           // ASCII -> digit
1374         add %ebx,%eax
1375         dec %ecx
1376         jnz 1b
1377         ret
1378
1379 /*
1380         DICTIONARY LOOK UPS ----------------------------------------------------------------------
1381
1382         We're building up to our prelude on how FORTH code is compiled, but first we need yet more infrastructure.
1383
1384         The FORTH word FIND takes a string (a word as parsed by WORD -- see above) and looks it up in the
1385         dictionary.  What it actually returns is the address of the dictionary header, if it finds it,
1386         or 0 if it didn't.
1387
1388         So if DOUBLE is defined in the dictionary, then WORD DOUBLE FIND returns the following pointer:
1389
1390     pointer to this
1391         |
1392         |
1393         V
1394         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1395         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          | EXIT       |
1396         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1397
1398         See also >CFA and >DFA.
1399
1400         FIND doesn't find dictionary entries which are flagged as HIDDEN.  See below for why.
1401 */
1402
1403         defcode "FIND",4,,FIND
1404         pop %ecx                // %ecx = length
1405         pop %edi                // %edi = address
1406         call _FIND
1407         push %eax               // %eax = address of dictionary entry (or NULL)
1408         NEXT
1409
1410 _FIND:
1411         push %esi               // Save %esi so we can use it in string comparison.
1412
1413         // Now we start searching backwards through the dictionary for this word.
1414         mov var_LATEST,%edx     // LATEST points to name header of the latest word in the dictionary
1415 1:
1416         test %edx,%edx          // NULL pointer?  (end of the linked list)
1417         je 4f
1418
1419         // Compare the length expected and the length of the word.
1420         // Note that if the F_HIDDEN flag is set on the word, then by a bit of trickery
1421         // this won't pick the word (the length will appear to be wrong).
1422         xor %eax,%eax
1423         movb 4(%edx),%al        // %al = flags+length field
1424         andb $(F_HIDDEN|F_LENMASK),%al // %al = name length
1425         cmpb %cl,%al            // Length is the same?
1426         jne 2f
1427
1428         // Compare the strings in detail.
1429         push %ecx               // Save the length
1430         push %edi               // Save the address (repe cmpsb will move this pointer)
1431         lea 5(%edx),%esi        // Dictionary string we are checking against.
1432         repe cmpsb              // Compare the strings.
1433         pop %edi
1434         pop %ecx
1435         jne 2f                  // Not the same.
1436
1437         // The strings are the same - return the header pointer in %eax
1438         pop %esi
1439         mov %edx,%eax
1440         ret
1441
1442 2:
1443         mov (%edx),%edx         // Move back through the link field to the previous word
1444         jmp 1b                  // .. and loop.
1445
1446 4:      // Not found.
1447         pop %esi
1448         xor %eax,%eax           // Return zero to indicate not found.
1449         ret
1450
1451 /*
1452         FIND returns the dictionary pointer, but when compiling we need the codeword pointer (recall
1453         that FORTH definitions are compiled into lists of codeword pointers).  The standard FORTH
1454         word >CFA turns a dictionary pointer into a codeword pointer.
1455
1456         The example below shows the result of:
1457
1458                 WORD DOUBLE FIND >CFA
1459
1460         FIND returns a pointer to this
1461         |                               >CFA converts it to a pointer to this
1462         |                                          |
1463         V                                          V
1464         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1465         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          | EXIT       |
1466         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1467
1468         Notes:
1469
1470         Because names vary in length, this isn't just a simple increment.
1471
1472         In this FORTH you cannot easily turn a codeword pointer back into a dictionary entry pointer, but
1473         that is not true in most FORTH implementations where they store a back pointer in the definition
1474         (with an obvious memory/complexity cost).  The reason they do this is that it is useful to be
1475         able to go backwards (codeword -> dictionary entry) in order to decompile FORTH definitions.
1476
1477         What does CFA stand for?  My best guess is "Code Field Address".
1478 */
1479
1480         defcode ">CFA",4,,TCFA
1481         pop %edi
1482         call _TCFA
1483         push %edi
1484         NEXT
1485 _TCFA:
1486         xor %eax,%eax
1487         add $4,%edi             // Skip link pointer.
1488         movb (%edi),%al         // Load flags+len into %al.
1489         inc %edi                // Skip flags+len byte.
1490         andb $F_LENMASK,%al     // Just the length, not the flags.
1491         add %eax,%edi           // Skip the name.
1492         addl $3,%edi            // The codeword is 4-byte aligned.
1493         andl $~3,%edi
1494         ret
1495
1496 /*
1497         Related to >CFA is >DFA which takes a dictionary entry address as returned by FIND and
1498         returns a pointer to the first data field.
1499
1500         FIND returns a pointer to this
1501         |                               >CFA converts it to a pointer to this
1502         |                                          |
1503         |                                          |    >DFA converts it to a pointer to this
1504         |                                          |             |
1505         V                                          V             V
1506         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1507         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          | EXIT       |
1508         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1509
1510         (Note to those following the source of FIG-FORTH / ciforth: My >DFA definition is
1511         different from theirs, because they have an extra indirection).
1512
1513         You can see that >DFA is easily defined in FORTH just by adding 4 to the result of >CFA.
1514 */
1515
1516         defword ">DFA",4,,TDFA
1517         .int TCFA               // >CFA         (get code field address)
1518         .int INCR4              // 4+           (add 4 to it to get to next word)
1519         .int EXIT               // EXIT         (return from FORTH word)
1520
1521 /*
1522         COMPILING ----------------------------------------------------------------------
1523
1524         Now we'll talk about how FORTH compiles words.  Recall that a word definition looks like this:
1525
1526                 : DOUBLE DUP + ;
1527
1528         and we have to turn this into:
1529
1530           pointer to previous word
1531            ^
1532            |
1533         +--|------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1534         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          | EXIT       |
1535         +---------+---+---+---+---+---+---+---+---+------------+--|---------+------------+------------+
1536            ^       len                         pad  codeword      |
1537            |                                                      V
1538           LATEST points here                            points to codeword of DUP
1539
1540         There are several problems to solve.  Where to put the new word?  How do we read words?  How
1541         do we define the words : (COLON) and ; (SEMICOLON)?
1542
1543         FORTH solves this rather elegantly and as you might expect in a very low-level way which
1544         allows you to change how the compiler works on your own code.
1545
1546         FORTH has an INTERPRETER function (a true interpreter this time, not DOCOL) which runs in a
1547         loop, reading words (using WORD), looking them up (using FIND), turning them into codeword
1548         pointers (using >CFA) and deciding what to do with them.
1549
1550         What it does depends on the mode of the interpreter (in variable STATE).
1551
1552         When STATE is zero, the interpreter just runs each word as it looks them up.  This is known as
1553         immediate mode.
1554
1555         The interesting stuff happens when STATE is non-zero -- compiling mode.  In this mode the
1556         interpreter appends the codeword pointer to user memory (the HERE variable points to the next
1557         free byte of user memory).
1558
1559         So you may be able to see how we could define : (COLON).  The general plan is:
1560
1561         (1) Use WORD to read the name of the function being defined.
1562
1563         (2) Construct the dictionary entry -- just the header part -- in user memory:
1564
1565     pointer to previous word (from LATEST)                      +-- Afterwards, HERE points here, where
1566            ^                                                    |   the interpreter will start appending
1567            |                                                    V   codewords.
1568         +--|------+---+---+---+---+---+---+---+---+------------+
1569         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      |
1570         +---------+---+---+---+---+---+---+---+---+------------+
1571                    len                         pad  codeword
1572
1573         (3) Set LATEST to point to the newly defined word, ...
1574
1575         (4) .. and most importantly leave HERE pointing just after the new codeword.  This is where
1576             the interpreter will append codewords.
1577
1578         (5) Set STATE to 1.  This goes into compile mode so the interpreter starts appending codewords to
1579             our partially-formed header.
1580
1581         After : has run, our input is here:
1582
1583         : DOUBLE DUP + ;
1584                  ^
1585                  |
1586                 Next byte returned by KEY will be the 'D' character of DUP
1587
1588         so the interpreter (now it's in compile mode, so I guess it's really the compiler) reads "DUP",
1589         looks it up in the dictionary, gets its codeword pointer, and appends it:
1590
1591                                                                              +-- HERE updated to point here.
1592                                                                              |
1593                                                                              V
1594         +---------+---+---+---+---+---+---+---+---+------------+------------+
1595         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        |
1596         +---------+---+---+---+---+---+---+---+---+------------+------------+
1597                    len                         pad  codeword
1598
1599         Next we read +, get the codeword pointer, and append it:
1600
1601                                                                                           +-- HERE updated to point here.
1602                                                                                           |
1603                                                                                           V
1604         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+
1605         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          |
1606         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+
1607                    len                         pad  codeword
1608
1609         The issue is what happens next.  Obviously what we _don't_ want to happen is that we
1610         read ";" and compile it and go on compiling everything afterwards.
1611
1612         At this point, FORTH uses a trick.  Remember the length byte in the dictionary definition
1613         isn't just a plain length byte, but can also contain flags.  One flag is called the
1614         IMMEDIATE flag (F_IMMED in this code).  If a word in the dictionary is flagged as
1615         IMMEDIATE then the interpreter runs it immediately _even if it's in compile mode_.
1616
1617         This is how the word ; (SEMICOLON) works -- as a word flagged in the dictionary as IMMEDIATE.
1618         And all it does is append the codeword for EXIT on to the current definition and switch
1619         back to immediate mode (set STATE back to 0).  Shortly we'll see the actual definition
1620         of ; and we'll see that it's really a very simple definition, declared IMMEDIATE.
1621
1622         After the interpreter reads ; and executes it 'immediately', we get this:
1623
1624         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1625         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          | EXIT       |
1626         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1627                    len                         pad  codeword                                           ^
1628                                                                                                        |
1629                                                                                                       HERE
1630
1631         STATE is set to 0.
1632
1633         And that's it, job done, our new definition is compiled, and we're back in immediate mode
1634         just reading and executing words, perhaps including a call to test our new word DOUBLE.
1635
1636         The only last wrinkle in this is that while our word was being compiled, it was in a
1637         half-finished state.  We certainly wouldn't want DOUBLE to be called somehow during
1638         this time.  There are several ways to stop this from happening, but in FORTH what we
1639         do is flag the word with the HIDDEN flag (F_HIDDEN in this code) just while it is
1640         being compiled.  This prevents FIND from finding it, and thus in theory stops any
1641         chance of it being called.
1642
1643         The above explains how compiling, : (COLON) and ; (SEMICOLON) works and in a moment I'm
1644         going to define them.  The : (COLON) function can be made a little bit more general by writing
1645         it in two parts.  The first part, called CREATE, makes just the header:
1646
1647                                                    +-- Afterwards, HERE points here.
1648                                                    |
1649                                                    V
1650         +---------+---+---+---+---+---+---+---+---+
1651         | LINK    | 6 | D | O | U | B | L | E | 0 |
1652         +---------+---+---+---+---+---+---+---+---+
1653                    len                         pad
1654
1655         and the second part, the actual definition of : (COLON), calls CREATE and appends the
1656         DOCOL codeword, so leaving:
1657
1658                                                                 +-- Afterwards, HERE points here.
1659                                                                 |
1660                                                                 V
1661         +---------+---+---+---+---+---+---+---+---+------------+
1662         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      |
1663         +---------+---+---+---+---+---+---+---+---+------------+
1664                    len                         pad  codeword
1665
1666         CREATE is a standard FORTH word and the advantage of this split is that we can reuse it to
1667         create other types of words (not just ones which contain code, but words which contain variables,
1668         constants and other data).
1669 */
1670
1671         defcode "CREATE",6,,CREATE
1672
1673         // Get the word.
1674         call _WORD              // Returns %ecx = length, %edi = pointer to word.
1675         mov %edi,%ebx           // %ebx = address of the word
1676
1677         // Link pointer.
1678         movl var_HERE,%edi      // %edi is the address of the header
1679         movl var_LATEST,%eax    // Get link pointer
1680         stosl                   // and store it in the header.
1681
1682         // Length byte and the word itself.
1683         mov %cl,%al             // Get the length.
1684         stosb                   // Store the length/flags byte.
1685         push %esi
1686         mov %ebx,%esi           // %esi = word
1687         rep movsb               // Copy the word
1688         pop %esi
1689         addl $3,%edi            // Align to next 4 byte boundary.
1690         andl $~3,%edi
1691
1692         // Update LATEST and HERE.
1693         movl var_HERE,%eax
1694         movl %eax,var_LATEST
1695         movl %edi,var_HERE
1696         NEXT
1697
1698 /*
1699         Because I want to define : (COLON) in FORTH, not assembler, we need a few more FORTH words
1700         to use.
1701
1702         The first is , (COMMA) which is a standard FORTH word which appends a 32 bit integer to the user
1703         data area pointed to by HERE, and adds 4 to HERE.  So the action of , (COMMA) is:
1704
1705                                                         previous value of HERE
1706                                                                  |
1707                                                                  V
1708         +---------+---+---+---+---+---+---+---+---+-- - - - - --+------------+
1709         | LINK    | 6 | D | O | U | B | L | E | 0 |             |  <data>    |
1710         +---------+---+---+---+---+---+---+---+---+-- - - - - --+------------+
1711                    len                         pad                            ^
1712                                                                               |
1713                                                                         new value of HERE
1714
1715         and <data> is whatever 32 bit integer was at the top of the stack.
1716
1717         , (COMMA) is quite a fundamental operation when compiling.  It is used to append codewords
1718         to the current word that is being compiled.
1719 */
1720
1721         defcode ",",1,,COMMA
1722         pop %eax                // Code pointer to store.
1723         call _COMMA
1724         NEXT
1725 _COMMA:
1726         movl var_HERE,%edi      // HERE
1727         stosl                   // Store it.
1728         movl %edi,var_HERE      // Update HERE (incremented)
1729         ret
1730
1731 /*
1732         Our definitions of : (COLON) and ; (SEMICOLON) will need to switch to and from compile mode.
1733
1734         Immediate mode vs. compile mode is stored in the global variable STATE, and by updating this
1735         variable we can switch between the two modes.
1736
1737         For various reasons which may become apparent later, FORTH defines two standard words called
1738         [ and ] (LBRAC and RBRAC) which switch between modes:
1739
1740         Word    Assembler       Action          Effect
1741         [       LBRAC           STATE := 0      Switch to immediate mode.
1742         ]       RBRAC           STATE := 1      Switch to compile mode.
1743
1744         [ (LBRAC) is an IMMEDIATE word.  The reason is as follows: If we are in compile mode and the
1745         interpreter saw [ then it would compile it rather than running it.  We would never be able to
1746         switch back to immediate mode!  So we flag the word as IMMEDIATE so that even in compile mode
1747         the word runs immediately, switching us back to immediate mode.
1748 */
1749
1750         defcode "[",1,F_IMMED,LBRAC
1751         xor %eax,%eax
1752         movl %eax,var_STATE     // Set STATE to 0.
1753         NEXT
1754
1755         defcode "]",1,,RBRAC
1756         movl $1,var_STATE       // Set STATE to 1.
1757         NEXT
1758
1759 /*
1760         Now we can define : (COLON) using CREATE.  It just calls CREATE, appends DOCOL (the codeword), sets
1761         the word HIDDEN and goes into compile mode.
1762 */
1763
1764         defword ":",1,,COLON
1765         .int CREATE             // CREATE the dictionary entry / header
1766         .int LIT, DOCOL, COMMA  // Append DOCOL  (the codeword).
1767         .int LATEST, FETCH, HIDDEN // Make the word hidden (see below for definition).
1768         .int RBRAC              // Go into compile mode.
1769         .int EXIT               // Return from the function.
1770
1771 /*
1772         ; (SEMICOLON) is also elegantly simple.  Notice the F_IMMED flag.
1773 */
1774
1775         defword ";",1,F_IMMED,SEMICOLON
1776         .int LIT, EXIT, COMMA   // Append EXIT (so the word will return).
1777         .int LATEST, FETCH, HIDDEN // Toggle hidden flag -- unhide the word (see below for definition).
1778         .int LBRAC              // Go back to IMMEDIATE mode.
1779         .int EXIT               // Return from the function.
1780
1781 /*
1782         EXTENDING THE COMPILER ----------------------------------------------------------------------
1783
1784         Words flagged with IMMEDIATE (F_IMMED) aren't just for the FORTH compiler to use.  You can define
1785         your own IMMEDIATE words too, and this is a crucial aspect when extending basic FORTH, because
1786         it allows you in effect to extend the compiler itself.  Does gcc let you do that?
1787
1788         Standard FORTH words like IF, WHILE, ." and so on are all written as extensions to the basic
1789         compiler, and are all IMMEDIATE words.
1790
1791         The IMMEDIATE word toggles the F_IMMED (IMMEDIATE flag) on the most recently defined word,
1792         or on the current word if you call it in the middle of a definition.
1793
1794         Typical usage is:
1795
1796         : MYIMMEDWORD IMMEDIATE
1797                 ...definition...
1798         ;
1799
1800         but some FORTH programmers write this instead:
1801
1802         : MYIMMEDWORD
1803                 ...definition...
1804         ; IMMEDIATE
1805
1806         The two usages are equivalent, to a first approximation.
1807 */
1808
1809         defcode "IMMEDIATE",9,F_IMMED,IMMEDIATE
1810         movl var_LATEST,%edi    // LATEST word.
1811         addl $4,%edi            // Point to name/flags byte.
1812         xorb $F_IMMED,(%edi)    // Toggle the IMMED bit.
1813         NEXT
1814
1815 /*
1816         'addr HIDDEN' toggles the hidden flag (F_HIDDEN) of the word defined at addr.  To hide the
1817         most recently defined word (used above in : and ; definitions) you would do:
1818
1819                 LATEST @ HIDDEN
1820
1821         Setting this flag stops the word from being found by FIND, and so can be used to make 'private'
1822         words.  For example, to break up a large word into smaller parts you might do:
1823
1824                 : SUB1 ... subword ... ;
1825                 : SUB2 ... subword ... ;
1826                 : SUB3 ... subword ... ;
1827                 : MAIN ... defined in terms of SUB1, SUB2, SUB3 ... ;
1828                 WORD SUB1 FIND HIDDEN           \ Hide SUB1
1829                 WORD SUB2 FIND HIDDEN           \ Hide SUB2
1830                 WORD SUB3 FIND HIDDEN           \ Hide SUB3
1831
1832         After this, only MAIN is 'exported' or seen by the rest of the program.
1833 */
1834
1835         defcode "HIDDEN",6,,HIDDEN
1836         pop %edi                // Dictionary entry.
1837         addl $4,%edi            // Point to name/flags byte.
1838         xorb $F_HIDDEN,(%edi)   // Toggle the HIDDEN bit.
1839         NEXT
1840
1841 /*
1842         ' (TICK) is a standard FORTH word which returns the codeword pointer of the next word.
1843
1844         The common usage is:
1845
1846         ' FOO ,
1847
1848         which appends the codeword of FOO to the current word we are defining (this only works in compiled code).
1849
1850         You tend to use ' in IMMEDIATE words.  For example an alternate (and rather useless) way to define
1851         a literal 2 might be:
1852
1853         : LIT2 IMMEDIATE
1854                 ' LIT ,         \ Appends LIT to the currently-being-defined word
1855                 2 ,             \ Appends the number 2 to the currently-being-defined word
1856         ;
1857
1858         So you could do:
1859
1860         : DOUBLE LIT2 * ;
1861
1862         (If you don't understand how LIT2 works, then you should review the material about compiling words
1863         and immediate mode).
1864
1865         This definition of ' uses a cheat which I copied from buzzard92.  As a result it only works in
1866         compiled code.  It is possible to write a version of ' based on WORD, FIND, >CFA which works in
1867         immediate mode too.
1868 */
1869         defcode "'",1,,TICK
1870         lodsl                   // Get the address of the next word and skip it.
1871         pushl %eax              // Push it on the stack.
1872         NEXT
1873
1874 /*
1875         BRANCHING ----------------------------------------------------------------------
1876
1877         It turns out that all you need in order to define looping constructs, IF-statements, etc.
1878         are two primitives.
1879
1880         BRANCH is an unconditional branch. 0BRANCH is a conditional branch (it only branches if the
1881         top of stack is zero).
1882
1883         The diagram below shows how BRANCH works in some imaginary compiled word.  When BRANCH executes,
1884         %esi starts by pointing to the offset field (compare to LIT above):
1885
1886         +---------------------+-------+---- - - ---+------------+------------+---- - - - ----+------------+
1887         | (Dictionary header) | DOCOL |            | BRANCH     | offset     | (skipped)     | word       |
1888         +---------------------+-------+---- - - ---+------------+-----|------+---- - - - ----+------------+
1889                                                                    ^  |                       ^
1890                                                                    |  |                       |
1891                                                                    |  +-----------------------+
1892                                                                   %esi added to offset
1893
1894         The offset is added to %esi to make the new %esi, and the result is that when NEXT runs, execution
1895         continues at the branch target.  Negative offsets work as expected.
1896
1897         0BRANCH is the same except the branch happens conditionally.
1898
1899         Now standard FORTH words such as IF, THEN, ELSE, WHILE, REPEAT, etc. can be implemented entirely
1900         in FORTH.  They are IMMEDIATE words which append various combinations of BRANCH or 0BRANCH
1901         into the word currently being compiled.
1902
1903         As an example, code written like this:
1904
1905                 condition-code IF true-part THEN rest-code
1906
1907         compiles to:
1908
1909                 condition-code 0BRANCH OFFSET true-part rest-code
1910                                           |             ^
1911                                           |             |
1912                                           +-------------+
1913 */
1914
1915         defcode "BRANCH",6,,BRANCH
1916         add (%esi),%esi         // add the offset to the instruction pointer
1917         NEXT
1918
1919         defcode "0BRANCH",7,,ZBRANCH
1920         pop %eax
1921         test %eax,%eax          // top of stack is zero?
1922         jz code_BRANCH          // if so, jump back to the branch function above
1923         lodsl                   // otherwise we need to skip the offset
1924         NEXT
1925
1926 /*
1927         PRINTING STRINGS ----------------------------------------------------------------------
1928
1929         LITSTRING and EMITSTRING are primitives used to implement the ." and S" operators
1930         (which are written in FORTH).  See the definition of those operators below.
1931 */
1932
1933         defcode "LITSTRING",9,,LITSTRING
1934         lodsl                   // get the length of the string
1935         push %esi               // push the address of the start of the string
1936         push %eax               // push it on the stack
1937         addl %eax,%esi          // skip past the string
1938         addl $3,%esi            // but round up to next 4 byte boundary
1939         andl $~3,%esi
1940         NEXT
1941
1942         defcode "EMITSTRING",10,,EMITSTRING
1943         mov $1,%ebx             // 1st param: stdout
1944         pop %edx                // 3rd param: length of string
1945         pop %ecx                // 2nd param: address of string
1946         mov $__NR_write,%eax    // write syscall
1947         int $0x80
1948         NEXT
1949
1950 /*
1951         COLD START AND INTERPRETER ----------------------------------------------------------------------
1952
1953         COLD is the first FORTH function called, almost immediately after the FORTH system "boots".
1954
1955         INTERPRETER is the FORTH interpreter ("toploop", "toplevel" or "REPL" might be a more accurate
1956         description -- see: http://en.wikipedia.org/wiki/REPL).
1957 */
1958
1959         // COLD must not return (ie. must not call EXIT).
1960         defword "COLD",4,,COLD
1961         .int INTERPRETER        // call the interpreter loop (never returns)
1962         .int LIT,1,SYSEXIT      // hmmm, but in case it does, exit(1).
1963
1964 /* This interpreter is pretty simple, but remember that in FORTH you can always override
1965  * it later with a more powerful one!
1966  */
1967         defword "INTERPRETER",11,,INTERPRETER
1968         .int INTERPRET,RDROP,INTERPRETER
1969
1970         defcode "INTERPRET",9,,INTERPRET
1971         call _WORD              // Returns %ecx = length, %edi = pointer to word.
1972
1973         // Is it in the dictionary?
1974         xor %eax,%eax
1975         movl %eax,interpret_is_lit // Not a literal number (not yet anyway ...)
1976         call _FIND              // Returns %eax = pointer to header or 0 if not found.
1977         test %eax,%eax          // Found?
1978         jz 1f
1979
1980         // In the dictionary.  Is it an IMMEDIATE codeword?
1981         mov %eax,%edi           // %edi = dictionary entry
1982         movb 4(%edi),%al        // Get name+flags.
1983         push %ax                // Just save it for now.
1984         call _TCFA              // Convert dictionary entry (in %edi) to codeword pointer.
1985         pop %ax
1986         andb $F_IMMED,%al       // Is IMMED flag set?
1987         mov %edi,%eax
1988         jnz 4f                  // If IMMED, jump straight to executing.
1989
1990         jmp 2f
1991
1992 1:      // Not in the dictionary (not a word) so assume it's a literal number.
1993         incl interpret_is_lit
1994         call _SNUMBER           // Returns the parsed number in %eax
1995         mov %eax,%ebx
1996         mov $LIT,%eax           // The word is LIT
1997
1998 2:      // Are we compiling or executing?
1999         movl var_STATE,%edx
2000         test %edx,%edx
2001         jz 4f                   // Jump if executing.
2002
2003         // Compiling - just append the word to the current dictionary definition.
2004         call _COMMA
2005         mov interpret_is_lit,%ecx // Was it a literal?
2006         test %ecx,%ecx
2007         jz 3f
2008         mov %ebx,%eax           // Yes, so LIT is followed by a number.
2009         call _COMMA
2010 3:      NEXT
2011
2012 4:      // Executing - run it!
2013         mov interpret_is_lit,%ecx // Literal?
2014         test %ecx,%ecx          // Literal?
2015         jnz 5f
2016
2017         // Not a literal, execute it now.  This never returns, but the codeword will
2018         // eventually call NEXT which will reenter the loop in INTERPRETER.
2019         jmp *(%eax)
2020
2021 5:      // Executing a literal, which means push it on the stack.
2022         push %ebx
2023         NEXT
2024
2025         .data
2026         .align 4
2027 interpret_is_lit:
2028         .int 0                  // Flag used to record if reading a literal
2029
2030 /*
2031         ODDS AND ENDS ----------------------------------------------------------------------
2032
2033         CHAR puts the ASCII code of the first character of the following word on the stack.  For example
2034         CHAR A puts 65 on the stack.
2035
2036         SYSEXIT exits the process using Linux exit syscall.
2037
2038         In this FORTH, SYSEXIT must be the last word in the built-in (assembler) dictionary because we
2039         initialise the LATEST variable to point to it.  This means that if you want to extend the assembler
2040         part, you must put new words before SYSEXIT, or else change how LATEST is initialised.
2041 */
2042
2043         defcode "CHAR",4,,CHAR
2044         call _WORD              // Returns %ecx = length, %edi = pointer to word.
2045         xor %eax,%eax
2046         movb (%edi),%al         // Get the first character of the word.
2047         push %eax               // Push it onto the stack.
2048         NEXT
2049
2050         // NB: SYSEXIT must be the last entry in the built-in dictionary.
2051         defcode SYSEXIT,7,,SYSEXIT
2052         pop %ebx
2053         mov $__NR_exit,%eax
2054         int $0x80
2055
2056 /*
2057         START OF FORTH CODE ----------------------------------------------------------------------
2058
2059         We've now reached the stage where the FORTH system is running and self-hosting.  All further
2060         words can be written as FORTH itself, including words like IF, THEN, .", etc which in most
2061         languages would be considered rather fundamental.
2062
2063         I used to append this here in the assembly file, but I got sick of fighting against gas's
2064         stupid (lack of) multiline string syntax.  So now that is in a separate file called jonesforth.f
2065
2066         If you don't already have that file, download it from http://annexia.org/forth in order
2067         to continue the tutorial.
2068 */
2069
2070 /* END OF jonesforth.S */