jonesforth.S

   1 /*      A sometimes minimal FORTH compiler and tutorial for Linux / i386 systems. -*- asm -*-
   2         By Richard W.M. Jones <rich@annexia.org> http://annexia.org/forth
   3         This is PUBLIC DOMAIN (see public domain release statement below).
   4         $Id: jonesforth.S,v 1.41 2007-09-29 23:11:27 rich Exp $
   5
   6         gcc -m32 -nostdlib -static -Wl,-Ttext,0 -o jonesforth jonesforth.S
   7 */
   8         .set JONES_VERSION,39
   9 /*
  10         INTRODUCTION ----------------------------------------------------------------------
  11
  12         FORTH is one of those alien languages which most working programmers regard in the same
  13         way as Haskell, LISP, and so on.  Something so strange that they'd rather any thoughts
  14         of it just go away so they can get on with writing this paying code.  But that's wrong
  15         and if you care at all about programming then you should at least understand all these
  16         languages, even if you will never use them.
  17
  18         LISP is the ultimate high-level language, and features from LISP are being added every
  19         decade to the more common languages.  But FORTH is in some ways the ultimate in low level
  20         programming.  Out of the box it lacks features like dynamic memory management and even
  21         strings.  In fact, at its primitive level it lacks even basic concepts like IF-statements
  22         and loops.
  23
  24         Why then would you want to learn FORTH?  There are several very good reasons.  First
  25         and foremost, FORTH is minimal.  You really can write a complete FORTH in, say, 2000
  26         lines of code.  I don't just mean a FORTH program, I mean a complete FORTH operating
  27         system, environment and language.  You could boot such a FORTH on a bare PC and it would
  28         come up with a prompt where you could start doing useful work.  The FORTH you have here
  29         isn't minimal and uses a Linux process as its 'base PC' (both for the purposes of making
  30         it a good tutorial). It's possible to completely understand the system.  Who can say they
  31         completely understand how Linux works, or gcc?
  32
  33         Secondly FORTH has a peculiar bootstrapping property.  By that I mean that after writing
  34         a little bit of assembly to talk to the hardware and implement a few primitives, all the
  35         rest of the language and compiler is written in FORTH itself.  Remember I said before
  36         that FORTH lacked IF-statements and loops?  Well of course it doesn't really because
  37         such a lanuage would be useless, but my point was rather that IF-statements and loops are
  38         written in FORTH itself.
  39
  40         Now of course this is common in other languages as well, and in those languages we call
  41         them 'libraries'.  For example in C, 'printf' is a library function written in C.  But
  42         in FORTH this goes way beyond mere libraries.  Can you imagine writing C's 'if' in C?
  43         And that brings me to my third reason: If you can write 'if' in FORTH, then why restrict
  44         yourself to the usual if/while/for/switch constructs?  You want a construct that iterates
  45         over every other element in a list of numbers?  You can add it to the language.  What
  46         about an operator which pulls in variables directly from a configuration file and makes
  47         them available as FORTH variables?  Or how about adding Makefile-like dependencies to
  48         the language?  No problem in FORTH.  How about modifying the FORTH compiler to allow
  49         complex inlining strategies -- simple.  This concept isn't common in programming languages,
  50         but it has a name (in fact two names): "macros" (by which I mean LISP-style macros, not
  51         the lame C preprocessor) and "domain specific languages" (DSLs).
  52
  53         This tutorial isn't about learning FORTH as the language.  I'll point you to some references
  54         you should read if you're not familiar with using FORTH.  This tutorial is about how to
  55         write FORTH.  In fact, until you understand how FORTH is written, you'll have only a very
  56         superficial understanding of how to use it.
  57
  58         So if you're not familiar with FORTH or want to refresh your memory here are some online
  59         references to read:
  60
  61         http://en.wikipedia.org/wiki/Forth_%28programming_language%29
  62
  63         http://galileo.phys.virginia.edu/classes/551.jvn.fall01/primer.htm
  64
  65         http://wiki.laptop.org/go/Forth_Lessons
  66
  67         http://www.albany.net/~hello/simple.htm
  68
  69         Here is another "Why FORTH?" essay: http://www.jwdt.com/~paysan/why-forth.html
  70
  71         Discussion and criticism of this FORTH here: http://lambda-the-ultimate.org/node/2452
  72
  73         ACKNOWLEDGEMENTS ----------------------------------------------------------------------
  74
  75         This code draws heavily on the design of LINA FORTH (http://home.hccnet.nl/a.w.m.van.der.horst/lina.html)
  76         by Albert van der Horst.  Any similarities in the code are probably not accidental.
  77
  78         Some parts of this FORTH are also based on this IOCCC entry from 1992:
  79         http://ftp.funet.fi/pub/doc/IOCCC/1992/buzzard.2.design.
  80         I was very proud when Sean Barrett, the original author of the IOCCC entry, commented in the LtU thread
  81         http://lambda-the-ultimate.org/node/2452#comment-36818 about this FORTH.
  82
  83         And finally I'd like to acknowledge the (possibly forgotten?) authors of ARTIC FORTH because their
  84         original program which I still have on original cassette tape kept nagging away at me all these years.
  85         http://en.wikipedia.org/wiki/Artic_Software
  86
  87         PUBLIC DOMAIN ----------------------------------------------------------------------
  88
  89         I, the copyright holder of this work, hereby release it into the public domain. This applies worldwide.
  90
  91         In case this is not legally possible, I grant any entity the right to use this work for any purpose,
  92         without any conditions, unless such conditions are required by law.
  93
  94         SETTING UP ----------------------------------------------------------------------
  95
  96         Let's get a few housekeeping things out of the way.  Firstly because I need to draw lots of
  97         ASCII-art diagrams to explain concepts, the best way to look at this is using a window which
  98         uses a fixed width font and is at least this wide:
  99
 100  <------------------------------------------------------------------------------------------------------------------------>
 101
 102         Secondly make sure TABS are set to 8 characters.  The following should be a vertical
 103         line.  If not, sort out your tabs.
 104
 105         |
 106         |
 107         |
 108
 109         Thirdly I assume that your screen is at least 50 characters high.
 110
 111         ASSEMBLING ----------------------------------------------------------------------
 112
 113         If you want to actually run this FORTH, rather than just read it, you will need Linux on an
 114         i386.  Linux because instead of programming directly to the hardware on a bare PC which I
 115         could have done, I went for a simpler tutorial by assuming that the 'hardware' is a Linux
 116         process with a few basic system calls (read, write and exit and that's about all).  i386
 117         is needed because I had to write the assembly for a processor, and i386 is by far the most
 118         common.  (Of course when I say 'i386', any 32- or 64-bit x86 processor will do.  I'm compiling
 119         this on a 64 bit AMD Opteron).
 120
 121         Again, to assemble this you will need gcc and gas (the GNU assembler).  The commands to
 122         assemble and run the code (save this file as 'jonesforth.S') are:
 123
 124         gcc -m32 -nostdlib -static -Wl,-Ttext,0 -o jonesforth jonesforth.S
 125         cat jonesforth.f - | ./jonesforth
 126
 127         If you want to run your own FORTH programs you can do:
 128
 129         cat jonesforth.f myprog.f | ./jonesforth
 130
 131         If you want to load your own FORTH code and then continue reading user commands, you can do:
 132
 133         cat jonesforth.f myfunctions.f - | ./jonesforth
 134
 135         ASSEMBLER ----------------------------------------------------------------------
 136
 137         (You can just skip to the next section -- you don't need to be able to read assembler to
 138         follow this tutorial).
 139
 140         However if you do want to read the assembly code here are a few notes about gas (the GNU assembler):
 141
 142         (1) Register names are prefixed with '%', so %eax is the 32 bit i386 accumulator.  The registers
 143             available on i386 are: %eax, %ebx, %ecx, %edx, %esi, %edi, %ebp and %esp, and most of them
 144             have special purposes.
 145
 146         (2) Add, mov, etc. take arguments in the form SRC,DEST.  So mov %eax,%ecx moves %eax -> %ecx
 147
 148         (3) Constants are prefixed with '$', and you mustn't forget it!  If you forget it then it
 149             causes a read from memory instead, so:
 150             mov $2,%eax         moves number 2 into %eax
 151             mov 2,%eax          reads the 32 bit word from address 2 into %eax (ie. most likely a mistake)
 152
 153         (4) gas has a funky syntax for local labels, where '1f' (etc.) means label '1:' "forwards"
 154             and '1b' (etc.) means label '1:' "backwards".
 155
 156         (5) 'ja' is "jump if above", 'jb' for "jump if below", 'je' "jump if equal" etc.
 157
 158         (6) gas has a reasonably nice .macro syntax, and I use them a lot to make the code shorter and
 159             less repetitive.
 160
 161         For more help reading the assembler, do "info gas" at the Linux prompt.
 162
 163         Now the tutorial starts in earnest.
 164
 165         THE DICTIONARY ----------------------------------------------------------------------
 166
 167         In FORTH as you will know, functions are called "words", and just as in other languages they
 168         have a name and a definition.  Here are two FORTH words:
 169
 170         : DOUBLE DUP + ;                \ name is "DOUBLE", definition is "DUP +"
 171         : QUADRUPLE DOUBLE DOUBLE ;     \ name is "QUADRUPLE", definition is "DOUBLE DOUBLE"
 172
 173         Words, both built-in ones and ones which the programmer defines later, are stored in a dictionary
 174         which is just a linked list of dictionary entries.
 175
 176         <--- DICTIONARY ENTRY (HEADER) ----------------------->
 177         +------------------------+--------+---------- - - - - +----------- - - - -
 178         | LINK POINTER           | LENGTH/| NAME              | DEFINITION
 179         |                        | FLAGS  |                   |
 180         +--- (4 bytes) ----------+- byte -+- n bytes  - - - - +----------- - - - -
 181
 182         I'll come to the definition of the word later.  For now just look at the header.  The first
 183         4 bytes are the link pointer.  This points back to the previous word in the dictionary, or, for
 184         the first word in the dictionary it is just a NULL pointer.  Then comes a length/flags byte.
 185         The length of the word can be up to 31 characters (5 bits used) and the top three bits are used
 186         for various flags which I'll come to later.  This is followed by the name itself, and in this
 187         implementation the name is rounded up to a multiple of 4 bytes by padding it with zero bytes.
 188         That's just to ensure that the definition starts on a 32 bit boundary.
 189
 190         A FORTH variable called LATEST contains a pointer to the most recently defined word, in
 191         other words, the head of this linked list.
 192
 193         DOUBLE and QUADRUPLE might look like this:
 194
 195           pointer to previous word
 196            ^
 197            |
 198         +--|------+---+---+---+---+---+---+---+---+------------- - - - -
 199         | LINK    | 6 | D | O | U | B | L | E | 0 | (definition ...)
 200         +---------+---+---+---+---+---+---+---+---+------------- - - - -
 201            ^       len                         padding
 202            |
 203         +--|------+---+---+---+---+---+---+---+---+---+---+---+---+------------- - - - -
 204         | LINK    | 9 | Q | U | A | D | R | U | P | L | E | 0 | 0 | (definition ...)
 205         +---------+---+---+---+---+---+---+---+---+---+---+---+---+------------- - - - -
 206            ^       len                                     padding
 207            |
 208            |
 209           LATEST
 210
 211         You should be able to see from this how you might implement functions to find a word in
 212         the dictionary (just walk along the dictionary entries starting at LATEST and matching
 213         the names until you either find a match or hit the NULL pointer at the end of the dictionary);
 214         and add a word to the dictionary (create a new definition, set its LINK to LATEST, and set
 215         LATEST to point to the new word).  We'll see precisely these functions implemented in
 216         assembly code later on.
 217
 218         One interesting consequence of using a linked list is that you can redefine words, and
 219         a newer definition of a word overrides an older one.  This is an important concept in
 220         FORTH because it means that any word (even "built-in" or "standard" words) can be
 221         overridden with a new definition, either to enhance it, to make it faster or even to
 222         disable it.  However because of the way that FORTH words get compiled, which you'll
 223         understand below, words defined using the old definition of a word continue to use
 224         the old definition.  Only words defined after the new definition use the new definition.
 225
 226         DIRECT THREADED CODE ----------------------------------------------------------------------
 227
 228         Now we'll get to the really crucial bit in understanding FORTH, so go and get a cup of tea
 229         or coffee and settle down.  It's fair to say that if you don't understand this section, then you
 230         won't "get" how FORTH works, and that would be a failure on my part for not explaining it well.
 231         So if after reading this section a few times you don't understand it, please email me
 232         (rich@annexia.org).
 233
 234         Let's talk first about what "threaded code" means.  Imagine a peculiar version of C where
 235         you are only allowed to call functions without arguments.  (Don't worry for now that such a
 236         language would be completely useless!)  So in our peculiar C, code would look like this:
 237
 238         f ()
 239         {
 240           a ();
 241           b ();
 242           c ();
 243         }
 244
 245         and so on.  How would a function, say 'f' above, be compiled by a standard C compiler?
 246         Probably into assembly code like this.  On the right hand side I've written the actual
 247         i386 machine code.
 248
 249         f:
 250           CALL a                        E8 08 00 00 00
 251           CALL b                        E8 1C 00 00 00
 252           CALL c                        E8 2C 00 00 00
 253           ; ignore the return from the function for now
 254
 255         "E8" is the x86 machine code to "CALL" a function.  In the first 20 years of computing
 256         memory was hideously expensive and we might have worried about the wasted space being used
 257         by the repeated "E8" bytes.  We can save 20% in code size (and therefore, in expensive memory)
 258         by compressing this into just:
 259
 260         08 00 00 00             Just the function addresses, without
 261         1C 00 00 00             the CALL prefix.
 262         2C 00 00 00
 263
 264         On a 16-bit machine like the ones which originally ran FORTH the savings are even greater - 33%.
 265
 266         [Historical note: If the execution model that FORTH uses looks strange from the following
 267         paragraphs, then it was motivated entirely by the need to save memory on early computers.
 268         This code compression isn't so important now when our machines have more memory in their L1
 269         caches than those early computers had in total, but the execution model still has some
 270         useful properties].
 271
 272         Of course this code won't run directly any more.  Instead we need to write an interpreter
 273         which takes each pair of bytes and calls it.
 274
 275         On an i386 machine it turns out that we can write this interpreter rather easily, in just
 276         two assembly instructions which turn into just 3 bytes of machine code.  Let's store the
 277         pointer to the next word to execute in the %esi register:
 278
 279                 08 00 00 00     <- We're executing this one now.  %esi is the _next_ one to execute.
 280         %esi -> 1C 00 00 00
 281                 2C 00 00 00
 282
 283         The all-important i386 instruction is called LODSL (or in Intel manuals, LODSW).  It does
 284         two things.  Firstly it reads the memory at %esi into the accumulator (%eax).  Secondly it
 285         increments %esi by 4 bytes.  So after LODSL, the situation now looks like this:
 286
 287                 08 00 00 00     <- We're still executing this one
 288                 1C 00 00 00     <- %eax now contains this address (0x0000001C)
 289         %esi -> 2C 00 00 00
 290
 291         Now we just need to jump to the address in %eax.  This is again just a single x86 instruction
 292         written JMP *(%eax).  And after doing the jump, the situation looks like:
 293
 294                 08 00 00 00
 295                 1C 00 00 00     <- Now we're executing this subroutine.
 296         %esi -> 2C 00 00 00
 297
 298         To make this work, each subroutine is followed by the two instructions 'LODSL; JMP *(%eax)'
 299         which literally make the jump to the next subroutine.
 300
 301         And that brings us to our first piece of actual code!  Well, it's a macro.
 302 */
 303
 304 /* NEXT macro. */
 305         .macro NEXT
 306         lodsl
 307         jmp *(%eax)
 308         .endm
 309
 310 /*      The macro is called NEXT.  That's a FORTH-ism.  It expands to those two instructions.
 311
 312         Every FORTH primitive that we write has to be ended by NEXT.  Think of it kind of like
 313         a return.
 314
 315         The above describes what is known as direct threaded code.
 316
 317         To sum up: We compress our function calls down to a list of addresses and use a somewhat
 318         magical macro to act as a "jump to next function in the list".  We also use one register (%esi)
 319         to act as a kind of instruction pointer, pointing to the next function in the list.
 320
 321         I'll just give you a hint of what is to come by saying that a FORTH definition such as:
 322
 323         : QUADRUPLE DOUBLE DOUBLE ;
 324
 325         actually compiles (almost, not precisely but we'll see why in a moment) to a list of
 326         function addresses for DOUBLE, DOUBLE and a special function called EXIT to finish off.
 327
 328         At this point, REALLY EAGLE-EYED ASSEMBLY EXPERTS are saying "JONES, YOU'VE MADE A MISTAKE!".
 329
 330         I lied about JMP *(%eax).
 331
 332         INDIRECT THREADED CODE ----------------------------------------------------------------------
 333
 334         It turns out that direct threaded code is interesting but only if you want to just execute
 335         a list of functions written in assembly language.  So QUADRUPLE would work only if DOUBLE
 336         was an assembly language function.  In the direct threaded code, QUADRUPLE would look like:
 337
 338                 +------------------+
 339                 | addr of DOUBLE  --------------------> (assembly code to do the double)
 340                 +------------------+                    NEXT
 341         %esi -> | addr of DOUBLE   |
 342                 +------------------+
 343
 344         We can add an extra indirection to allow us to run both words written in assembly language
 345         (primitives written for speed) and words written in FORTH themselves as lists of addresses.
 346
 347         The extra indirection is the reason for the brackets in JMP *(%eax).
 348
 349         Let's have a look at how QUADRUPLE and DOUBLE really look in FORTH:
 350
 351                 : QUADRUPLE DOUBLE DOUBLE ;
 352
 353                 +------------------+
 354                 | codeword         |               : DOUBLE DUP + ;
 355                 +------------------+
 356                 | addr of DOUBLE  ---------------> +------------------+
 357                 +------------------+               | codeword         |
 358                 | addr of DOUBLE   |               +------------------+
 359                 +------------------+               | addr of DUP   --------------> +------------------+
 360                 | addr of EXIT     |               +------------------+            | codeword      -------+
 361                 +------------------+       %esi -> | addr of +     --------+       +------------------+   |
 362                                                    +------------------+    |       | assembly to    <-----+
 363                                                    | addr of EXIT     |    |       | implement DUP    |
 364                                                    +------------------+    |       |    ..            |
 365                                                                            |       |    ..            |
 366                                                                            |       | NEXT             |
 367                                                                            |       +------------------+
 368                                                                            |
 369                                                                            +-----> +------------------+
 370                                                                                    | codeword      -------+
 371                                                                                    +------------------+   |
 372                                                                                    | assembly to   <------+
 373                                                                                    | implement +      |
 374                                                                                    |    ..            |
 375                                                                                    |    ..            |
 376                                                                                    | NEXT             |
 377                                                                                    +------------------+
 378
 379         This is the part where you may need an extra cup of tea/coffee/favourite caffeinated
 380         beverage.  What has changed is that I've added an extra pointer to the beginning of
 381         the definitions.  In FORTH this is sometimes called the "codeword".  The codeword is
 382         a pointer to the interpreter to run the function.  For primitives written in
 383         assembly language, the "interpreter" just points to the actual assembly code itself.
 384         They don't need interpreting, they just run.
 385
 386         In words written in FORTH (like QUADRUPLE and DOUBLE), the codeword points to an interpreter
 387         function.
 388
 389         I'll show you the interpreter function shortly, but let's recall our indirect
 390         JMP *(%eax) with the "extra" brackets.  Take the case where we're executing DOUBLE
 391         as shown, and DUP has been called.  Note that %esi is pointing to the address of +
 392
 393         The assembly code for DUP eventually does a NEXT.  That:
 394
 395         (1) reads the address of + into %eax            %eax points to the codeword of +
 396         (2) increments %esi by 4
 397         (3) jumps to the indirect %eax                  jumps to the address in the codeword of +,
 398                                                         ie. the assembly code to implement +
 399
 400                 +------------------+
 401                 | codeword         |
 402                 +------------------+
 403                 | addr of DOUBLE  ---------------> +------------------+
 404                 +------------------+               | codeword         |
 405                 | addr of DOUBLE   |               +------------------+
 406                 +------------------+               | addr of DUP   --------------> +------------------+
 407                 | addr of EXIT     |               +------------------+            | codeword      -------+
 408                 +------------------+               | addr of +     --------+       +------------------+   |
 409                                                    +------------------+    |       | assembly to    <-----+
 410                                            %esi -> | addr of EXIT     |    |       | implement DUP    |
 411                                                    +------------------+    |       |    ..            |
 412                                                                            |       |    ..            |
 413                                                                            |       | NEXT             |
 414                                                                            |       +------------------+
 415                                                                            |
 416                                                                            +-----> +------------------+
 417                                                                                    | codeword      -------+
 418                                                                                    +------------------+   |
 419                                                                         now we're  | assembly to    <-----+
 420                                                                         executing  | implement +      |
 421                                                                         this       |    ..            |
 422                                                                         function   |    ..            |
 423                                                                                    | NEXT             |
 424                                                                                    +------------------+
 425
 426         So I hope that I've convinced you that NEXT does roughly what you'd expect.  This is
 427         indirect threaded code.
 428
 429         I've glossed over four things.  I wonder if you can guess without reading on what they are?
 430
 431         .
 432         .
 433         .
 434
 435         My list of four things are: (1) What does "EXIT" do?  (2) which is related to (1) is how do
 436         you call into a function, ie. how does %esi start off pointing at part of QUADRUPLE, but
 437         then point at part of DOUBLE.  (3) What goes in the codeword for the words which are written
 438         in FORTH?  (4) How do you compile a function which does anything except call other functions
 439         ie. a function which contains a number like : DOUBLE 2 * ; ?
 440
 441         THE INTERPRETER AND RETURN STACK ------------------------------------------------------------
 442
 443         Going at these in no particular order, let's talk about issues (3) and (2), the interpreter
 444         and the return stack.
 445
 446         Words which are defined in FORTH need a codeword which points to a little bit of code to
 447         give them a "helping hand" in life.  They don't need much, but they do need what is known
 448         as an "interpreter", although it doesn't really "interpret" in the same way that, say,
 449         Java bytecode used to be interpreted (ie. slowly).  This interpreter just sets up a few
 450         machine registers so that the word can then execute at full speed using the indirect
 451         threaded model above.
 452
 453         One of the things that needs to happen when QUADRUPLE calls DOUBLE is that we save the old
 454         %esi ("instruction pointer") and create a new one pointing to the first word in DOUBLE.
 455         Because we will need to restore the old %esi at the end of DOUBLE (this is, after all, like
 456         a function call), we will need a stack to store these "return addresses" (old values of %esi).
 457
 458         As you will have read, when reading the background documentation, FORTH has two stacks,
 459         an ordinary stack for parameters, and a return stack which is a bit more mysterious.  But
 460         our return stack is just the stack I talked about in the previous paragraph, used to save
 461         %esi when calling from a FORTH word into another FORTH word.
 462
 463         In this FORTH, we are using the normal stack pointer (%esp) for the parameter stack.
 464         We will use the i386's "other" stack pointer (%ebp, usually called the "frame pointer")
 465         for our return stack.
 466
 467         I've got two macros which just wrap up the details of using %ebp for the return stack.
 468         You use them as for example "PUSHRSP %eax" (push %eax on the return stack) or "POPRSP %ebx"
 469         (pop top of return stack into %ebx).
 470 */
 471
 472 /* Macros to deal with the return stack. */
 473         .macro PUSHRSP reg
 474         lea -4(%ebp),%ebp       // push reg on to return stack
 475         movl \reg,(%ebp)
 476         .endm
 477
 478         .macro POPRSP reg
 479         mov (%ebp),\reg         // pop top of return stack to reg
 480         lea 4(%ebp),%ebp
 481         .endm
 482
 483 /*
 484         And with that we can now talk about the interpreter.
 485
 486         In FORTH the interpreter function is often called DOCOL (I think it means "DO COLON" because
 487         all FORTH definitions start with a colon, as in : DOUBLE DUP + ;
 488
 489         The "interpreter" (it's not really "interpreting") just needs to push the old %esi on the
 490         stack and set %esi to the first word in the definition.  Remember that we jumped to the
 491         function using JMP *(%eax)?  Well a consequence of that is that conveniently %eax contains
 492         the address of this codeword, so just by adding 4 to it we get the address of the first
 493         data word.  Finally after setting up %esi, it just does NEXT which causes that first word
 494         to run.
 495 */
 496
 497 /* DOCOL - the interpreter! */
 498         .text
 499         .align 4
 500 DOCOL:
 501         PUSHRSP %esi            // push %esi on to the return stack
 502         addl $4,%eax            // %eax points to codeword, so make
 503         movl %eax,%esi          // %esi point to first data word
 504         NEXT
 505
 506 /*
 507         Just to make this absolutely clear, let's see how DOCOL works when jumping from QUADRUPLE
 508         into DOUBLE:
 509
 510                 QUADRUPLE:
 511                 +------------------+
 512                 | codeword         |
 513                 +------------------+               DOUBLE:
 514                 | addr of DOUBLE  ---------------> +------------------+
 515                 +------------------+       %eax -> | addr of DOCOL    |
 516         %esi -> | addr of DOUBLE   |               +------------------+
 517                 +------------------+               | addr of DUP      |
 518                 | addr of EXIT     |               +------------------+
 519                 +------------------+               | etc.             |
 520
 521         First, the call to DOUBLE calls DOCOL (the codeword of DOUBLE).  DOCOL does this:  It
 522         pushes the old %esi on the return stack.  %eax points to the codeword of DOUBLE, so we
 523         just add 4 on to it to get our new %esi:
 524
 525                 QUADRUPLE:
 526                 +------------------+
 527                 | codeword         |
 528                 +------------------+               DOUBLE:
 529                 | addr of DOUBLE  ---------------> +------------------+
 530 top of return   +------------------+       %eax -> | addr of DOCOL    |
 531 stack points -> | addr of DOUBLE   |       + 4 =   +------------------+
 532                 +------------------+       %esi -> | addr of DUP      |
 533                 | addr of EXIT     |               +------------------+
 534                 +------------------+               | etc.             |
 535
 536         Then we do NEXT, and because of the magic of threaded code that increments %esi again
 537         and calls DUP.
 538
 539         Well, it seems to work.
 540
 541         One minor point here.  Because DOCOL is the first bit of assembly actually to be defined
 542         in this file (the others were just macros), and because I usually compile this code with the
 543         text segment starting at address 0, DOCOL has address 0.  So if you are disassembling the
 544         code and see a word with a codeword of 0, you will immediately know that the word is
 545         written in FORTH (it's not an assembler primitive) and so uses DOCOL as the interpreter.
 546
 547         STARTING UP ----------------------------------------------------------------------
 548
 549         Now let's get down to nuts and bolts.  When we start the program we need to set up
 550         a few things like the return stack.  But as soon as we can, we want to jump into FORTH
 551         code (albeit much of the "early" FORTH code will still need to be written as
 552         assembly language primitives).
 553
 554         This is what the set up code does.  Does a tiny bit of house-keeping, sets up the
 555         separate return stack (NB: Linux gives us the ordinary parameter stack already), then
 556         immediately jumps to a FORTH word called COLD.  COLD stands for cold-start.  In ISO
 557         FORTH (but not in this FORTH), COLD can be called at any time to completely reset
 558         the state of FORTH, and there is another word called WARM which does a partial reset.
 559 */
 560
 561 /* ELF entry point. */
 562         .text
 563         .globl _start
 564 _start:
 565         cld
 566         mov %esp,var_S0         // Store the initial data stack pointer.
 567         mov $return_stack,%ebp  // Initialise the return stack.
 568
 569         mov $cold_start,%esi    // Initialise interpreter.
 570         NEXT                    // Run interpreter!
 571
 572         .section .rodata
 573 cold_start:                     // High-level code without a codeword.
 574         .int COLD
 575
 576 /*
 577         We also allocate some space for the return stack and some space to store user
 578         definitions.  These are static memory allocations using fixed-size buffers, but it
 579         wouldn't be a great deal of work to make them dynamic.
 580 */
 581
 582         .bss
 583 /* FORTH return stack. */
 584         .set RETURN_STACK_SIZE,8192
 585         .align 4096
 586         .space RETURN_STACK_SIZE
 587 return_stack:                   // Initial top of return stack.
 588
 589 /* The user definitions area: space for user-defined words and general memory allocations. */
 590         .set USER_DEFS_SIZE,65536
 591         .align 4096
 592 user_defs_start:
 593         .space USER_DEFS_SIZE
 594
 595 /* This is used as a temporary input buffer when reading from files or the terminal. */
 596         .set BUFFER_SIZE,4096
 597         .align 4096
 598 buffer:
 599 _initbufftop:
 600         .space BUFFER_SIZE
 601 buffend:
 602 currkey:
 603         .int buffer
 604 bufftop:
 605         .int _initbufftop
 606
 607 /*
 608         BUILT-IN WORDS ----------------------------------------------------------------------
 609
 610         Remember our dictionary entries (headers)?  Let's bring those together with the codeword
 611         and data words to see how : DOUBLE DUP + ; really looks in memory.
 612
 613           pointer to previous word
 614            ^
 615            |
 616         +--|------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
 617         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          | EXIT       |
 618         +---------+---+---+---+---+---+---+---+---+------------+--|---------+------------+------------+
 619            ^       len                         pad  codeword      |
 620            |                                                      V
 621           LINK in next word                             points to codeword of DUP
 622
 623         Initially we can't just write ": DOUBLE DUP + ;" (ie. that literal string) here because we
 624         don't yet have anything to read the string, break it up at spaces, parse each word, etc. etc.
 625         So instead we will have to define built-in words using the GNU assembler data constructors
 626         (like .int, .byte, .string, .ascii and so on -- look them up in the gas info page if you are
 627         unsure of them).
 628
 629         The long way would be:
 630         .int <link to previous word>
 631         .byte 6                 // len
 632         .ascii "DOUBLE"         // string
 633         .byte 0                 // padding
 634 DOUBLE: .int DOCOL              // codeword
 635         .int DUP                // pointer to codeword of DUP
 636         .int PLUS               // pointer to codeword of +
 637         .int EXIT               // pointer to codeword of EXIT
 638
 639         That's going to get quite tedious rather quickly, so here I define an assembler macro
 640         so that I can just write:
 641
 642         defword "DOUBLE",6,,DOUBLE
 643         .int DUP,PLUS,EXIT
 644
 645         and I'll get exactly the same effect.
 646
 647         Don't worry too much about the exact implementation details of this macro - it's complicated!
 648 */
 649
 650 /* Flags - these are discussed later. */
 651         .set F_IMMED,0x80
 652         .set F_HIDDEN,0x20
 653         .set F_LENMASK,0x1f     // length mask
 654
 655         // Store the chain of links.
 656         .set link,0
 657
 658         .macro defword name, namelen, flags=0, label
 659         .section .rodata
 660         .align 4
 661         .globl name_\label
 662 name_\label :
 663         .int link               // link
 664         .set link,name_\label
 665         .byte \flags+\namelen   // flags + length byte
 666         .ascii "\name"          // the name
 667         .align 4
 668         .globl \label
 669 \label :
 670         .int DOCOL              // codeword - the interpreter
 671         // list of word pointers follow
 672         .endm
 673
 674 /*
 675         Similarly I want a way to write words written in assembly language.  There will quite a few
 676         of these to start with because, well, everything has to start in assembly before there's
 677         enough "infrastructure" to be able to start writing FORTH words, but also I want to define
 678         some common FORTH words in assembly language for speed, even though I could write them in FORTH.
 679
 680         This is what DUP looks like in memory:
 681
 682           pointer to previous word
 683            ^
 684            |
 685         +--|------+---+---+---+---+------------+
 686         | LINK    | 3 | D | U | P | code_DUP ---------------------> points to the assembly
 687         +---------+---+---+---+---+------------+                    code used to write DUP,
 688            ^       len              codeword                        which ends with NEXT.
 689            |
 690           LINK in next word
 691
 692         Again, for brevity in writing the header I'm going to write an assembler macro called defcode.
 693 */
 694
 695         .macro defcode name, namelen, flags=0, label
 696         .section .rodata
 697         .align 4
 698         .globl name_\label
 699 name_\label :
 700         .int link               // link
 701         .set link,name_\label
 702         .byte \flags+\namelen   // flags + length byte
 703         .ascii "\name"          // the name
 704         .align 4
 705         .globl \label
 706 \label :
 707         .int code_\label        // codeword
 708         .text
 709         .align 4
 710         .globl code_\label
 711 code_\label :                   // assembler code follows
 712         .endm
 713
 714 /*
 715         Now some easy FORTH primitives.  These are written in assembly for speed.  If you understand
 716         i386 assembly language then it is worth reading these.  However if you don't understand assembly
 717         you can skip the details.
 718 */
 719
 720         defcode "DUP",3,,DUP
 721         pop %eax                // duplicate top of stack
 722         push %eax
 723         push %eax
 724         NEXT
 725
 726         defcode "DROP",4,,DROP
 727         pop %eax                // drop top of stack
 728         NEXT
 729
 730         defcode "SWAP",4,,SWAP
 731         pop %eax                // swap top of stack
 732         pop %ebx
 733         push %eax
 734         push %ebx
 735         NEXT
 736
 737         defcode "OVER",4,,OVER
 738         mov 4(%esp),%eax        // get the second element of stack
 739         push %eax               // and push it on top
 740         NEXT
 741
 742         defcode "ROT",3,,ROT
 743         pop %eax
 744         pop %ebx
 745         pop %ecx
 746         push %eax
 747         push %ecx
 748         push %ebx
 749         NEXT
 750
 751         defcode "-ROT",4,,NROT
 752         pop %eax
 753         pop %ebx
 754         pop %ecx
 755         push %ebx
 756         push %eax
 757         push %ecx
 758         NEXT
 759
 760         defcode "?DUP",4,,QDUP  // duplicate top of stack if non-zero
 761         pop %eax
 762         test %eax,%eax
 763         jz 1f
 764         push %eax
 765 1:      push %eax
 766         NEXT
 767
 768         defcode "1+",2,,INCR
 769         incl (%esp)             // increment top of stack
 770         NEXT
 771
 772         defcode "1-",2,,DECR
 773         decl (%esp)             // decrement top of stack
 774         NEXT
 775
 776         defcode "4+",2,,INCR4
 777         addl $4,(%esp)          // add 4 to top of stack
 778         NEXT
 779
 780         defcode "4-",2,,DECR4
 781         subl $4,(%esp)          // subtract 4 from top of stack
 782         NEXT
 783
 784         defcode "+",1,,ADD
 785         pop %eax                // get top of stack
 786         addl %eax,(%esp)        // and add it to next word on stack
 787         NEXT
 788
 789         defcode "-",1,,SUB
 790         pop %eax                // get top of stack
 791         subl %eax,(%esp)        // and subtract it from next word on stack
 792         NEXT
 793
 794         defcode "*",1,,MUL
 795         pop %eax
 796         pop %ebx
 797         imull %ebx,%eax
 798         push %eax               // ignore overflow
 799         NEXT
 800
 801 /*
 802         In this FORTH, only /MOD is primitive.  Later we will define the / and MOD words in
 803         terms of the primitive /MOD.  The design of the i386 assembly instruction idiv which
 804         leaves both quotient and remainder makes this obvious choice.
 805 */
 806
 807         defcode "/MOD",4,,DIVMOD
 808         xor %edx,%edx
 809         pop %ebx
 810         pop %eax
 811         idivl %ebx
 812         push %edx               // push remainder
 813         push %eax               // push quotient
 814         NEXT
 815
 816         defcode "=",1,,EQU      // top two words are equal?
 817         pop %eax
 818         pop %ebx
 819         cmp %ebx,%eax
 820         je 1f
 821         pushl $0
 822         NEXT
 823 1:      pushl $1
 824         NEXT
 825
 826         defcode "<>",2,,NEQU    // top two words are not equal?
 827         pop %eax
 828         pop %ebx
 829         cmp %ebx,%eax
 830         je 1f
 831         pushl $1
 832         NEXT
 833 1:      pushl $0
 834         NEXT
 835
 836         defcode "<",1,,LT
 837         pop %eax
 838         pop %ebx
 839         cmp %eax,%ebx
 840         jl 1f
 841         pushl $0
 842         NEXT
 843 1:      pushl $1
 844         NEXT
 845
 846         defcode ">",1,,GT
 847         pop %eax
 848         pop %ebx
 849         cmp %eax,%ebx
 850         jg 1f
 851         pushl $0
 852         NEXT
 853 1:      pushl $1
 854         NEXT
 855
 856         defcode "<=",2,,LE
 857         pop %eax
 858         pop %ebx
 859         cmp %eax,%ebx
 860         jle 1f
 861         pushl $0
 862         NEXT
 863 1:      pushl $1
 864         NEXT
 865
 866         defcode ">=",2,,GE
 867         pop %eax
 868         pop %ebx
 869         cmp %eax,%ebx
 870         jge 1f
 871         pushl $0
 872         NEXT
 873 1:      pushl $1
 874         NEXT
 875
 876         defcode "0=",2,,ZEQU    // top of stack equals 0?
 877         pop %eax
 878         test %eax,%eax
 879         jz 1f
 880         pushl $0
 881         NEXT
 882 1:      pushl $1
 883         NEXT
 884
 885         defcode "0<>",3,,ZNEQU  // top of stack not 0?
 886         pop %eax
 887         test %eax,%eax
 888         jnz 1f
 889         pushl $0
 890         NEXT
 891 1:      pushl $1
 892         NEXT
 893
 894         defcode "0<",2,,ZLT     // comparisons with 0
 895         pop %eax
 896         test %eax,%eax
 897         jl 1f
 898         pushl $0
 899         NEXT
 900 1:      pushl $1
 901         NEXT
 902
 903         defcode "0>",2,,ZGT
 904         pop %eax
 905         test %eax,%eax
 906         jg 1f
 907         pushl $0
 908         NEXT
 909 1:      pushl $1
 910         NEXT
 911
 912         defcode "0<=",3,,ZLE
 913         pop %eax
 914         test %eax,%eax
 915         jle 1f
 916         pushl $0
 917         NEXT
 918 1:      pushl $1
 919         NEXT
 920
 921         defcode "0>=",3,,ZGE
 922         pop %eax
 923         test %eax,%eax
 924         jge 1f
 925         pushl $0
 926         NEXT
 927 1:      pushl $1
 928         NEXT
 929
 930         defcode "AND",3,,AND    // bitwise AND
 931         pop %eax
 932         andl %eax,(%esp)
 933         NEXT
 934
 935         defcode "OR",2,,OR      // bitwise OR
 936         pop %eax
 937         orl %eax,(%esp)
 938         NEXT
 939
 940         defcode "XOR",3,,XOR    // bitwise XOR
 941         pop %eax
 942         xorl %eax,(%esp)
 943         NEXT
 944
 945         defcode "INVERT",6,,INVERT // this is the FORTH bitwise "NOT" function (cf. NEGATE)
 946         notl (%esp)
 947         NEXT
 948
 949 /*
 950         RETURNING FROM FORTH WORDS ----------------------------------------------------------------------
 951
 952         Time to talk about what happens when we EXIT a function.  In this diagram QUADRUPLE has called
 953         DOUBLE, and DOUBLE is about to exit (look at where %esi is pointing):
 954
 955                 QUADRUPLE
 956                 +------------------+
 957                 | codeword         |
 958                 +------------------+               DOUBLE
 959                 | addr of DOUBLE  ---------------> +------------------+
 960                 +------------------+               | codeword         |
 961                 | addr of DOUBLE   |               +------------------+
 962                 +------------------+               | addr of DUP      |
 963                 | addr of EXIT     |               +------------------+
 964                 +------------------+               | addr of +        |
 965                                                    +------------------+
 966                                            %esi -> | addr of EXIT     |
 967                                                    +------------------+
 968
 969         What happens when the + function does NEXT?  Well, the following code is executed.
 970 */
 971
 972         defcode "EXIT",4,,EXIT
 973         POPRSP %esi             // pop return stack into %esi
 974         NEXT
 975
 976 /*
 977         EXIT gets the old %esi which we saved from before on the return stack, and puts it in %esi.
 978         So after this (but just before NEXT) we get:
 979
 980                 QUADRUPLE
 981                 +------------------+
 982                 | codeword         |
 983                 +------------------+               DOUBLE
 984                 | addr of DOUBLE  ---------------> +------------------+
 985                 +------------------+               | codeword         |
 986         %esi -> | addr of DOUBLE   |               +------------------+
 987                 +------------------+               | addr of DUP      |
 988                 | addr of EXIT     |               +------------------+
 989                 +------------------+               | addr of +        |
 990                                                    +------------------+
 991                                                    | addr of EXIT     |
 992                                                    +------------------+
 993
 994         And NEXT just completes the job by, well, in this case just by calling DOUBLE again :-)
 995
 996         LITERALS ----------------------------------------------------------------------
 997
 998         The final point I "glossed over" before was how to deal with functions that do anything
 999         apart from calling other functions.  For example, suppose that DOUBLE was defined like this:
1000
1001         : DOUBLE 2 * ;
1002
1003         It does the same thing, but how do we compile it since it contains the literal 2?  One way
1004         would be to have a function called "2" (which you'd have to write in assembler), but you'd need
1005         a function for every single literal that you wanted to use.
1006
1007         FORTH solves this by compiling the function using a special word called LIT:
1008
1009         +---------------------------+-------+-------+-------+-------+-------+
1010         | (usual header of DOUBLE)  | DOCOL | LIT   | 2     | *     | EXIT  |
1011         +---------------------------+-------+-------+-------+-------+-------+
1012
1013         LIT is executed in the normal way, but what it does next is definitely not normal.  It
1014         looks at %esi (which now points to the literal 2), grabs it, pushes it on the stack, then
1015         manipulates %esi in order to skip the literal as if it had never been there.
1016
1017         What's neat is that the whole grab/manipulate can be done using a single byte single
1018         i386 instruction, our old friend LODSL.  Rather than me drawing more ASCII-art diagrams,
1019         see if you can find out how LIT works:
1020 */
1021
1022         defcode "LIT",3,,LIT
1023         // %esi points to the next command, but in this case it points to the next
1024         // literal 32 bit integer.  Get that literal into %eax and increment %esi.
1025         // On x86, it's a convenient single byte instruction!  (cf. NEXT macro)
1026         lodsl
1027         push %eax               // push the literal number on to stack
1028         NEXT
1029
1030 /*
1031         MEMORY ----------------------------------------------------------------------
1032
1033         As important point about FORTH is that it gives you direct access to the lowest levels
1034         of the machine.  Manipulating memory directly is done frequently in FORTH, and these are
1035         the primitive words for doing it.
1036 */
1037
1038         defcode "!",1,,STORE
1039         pop %ebx                // address to store at
1040         pop %eax                // data to store there
1041         mov %eax,(%ebx)         // store it
1042         NEXT
1043
1044         defcode "@",1,,FETCH
1045         pop %ebx                // address to fetch
1046         mov (%ebx),%eax         // fetch it
1047         push %eax               // push value onto stack
1048         NEXT
1049
1050         defcode "+!",2,,ADDSTORE
1051         pop %ebx                // address
1052         pop %eax                // the amount to add
1053         addl %eax,(%ebx)        // add it
1054         NEXT
1055
1056         defcode "-!",2,,SUBSTORE
1057         pop %ebx                // address
1058         pop %eax                // the amount to subtract
1059         subl %eax,(%ebx)        // add it
1060         NEXT
1061
1062 /*
1063         ! and @ (STORE and FETCH) store 32-bit words.  It's also useful to be able to read and write bytes
1064         so we also define standard words C@ and C!.
1065
1066         Byte-oriented operations only work on architectures which permit them (i386 is one of those).
1067  */
1068
1069         defcode "C!",2,,STOREBYTE
1070         pop %ebx                // address to store at
1071         pop %eax                // data to store there
1072         movb %al,(%ebx)         // store it
1073         NEXT
1074
1075         defcode "C@",2,,FETCHBYTE
1076         pop %ebx                // address to fetch
1077         xor %eax,%eax
1078         movb (%ebx),%al         // fetch it
1079         push %eax               // push value onto stack
1080         NEXT
1081
1082 /*
1083         BUILT-IN VARIABLES ----------------------------------------------------------------------
1084
1085         These are some built-in variables and related standard FORTH words.  Of these, the only one that we
1086         have discussed so far was LATEST, which points to the last (most recently defined) word in the
1087         FORTH dictionary.  LATEST is also a FORTH word which pushes the address of LATEST (the variable)
1088         on to the stack, so you can read or write it using @ and ! operators.  For example, to print
1089         the current value of LATEST (and this can apply to any FORTH variable) you would do:
1090
1091         LATEST @ . CR
1092
1093         To make defining variables shorter, I'm using a macro called defvar, similar to defword and
1094         defcode above.  (In fact the defvar macro uses defcode to do the dictionary header).
1095 */
1096
1097         .macro defvar name, namelen, flags=0, label, initial=0
1098         defcode \name,\namelen,\flags,\label
1099         push $var_\name
1100         NEXT
1101         .data
1102         .align 4
1103 var_\name :
1104         .int \initial
1105         .endm
1106
1107 /*
1108         The built-in variables are:
1109
1110         STATE           Is the interpreter executing code (0) or compiling a word (non-zero)?
1111         LATEST          Points to the latest (most recently defined) word in the dictionary.
1112         HERE            Points to the next free byte of memory.  When compiling, compiled words go here.
1113         _X              These are three scratch variables, used by some standard dictionary words.
1114         _Y
1115         _Z
1116         S0              Stores the address of the top of the parameter stack.
1117         BASE            The current base for printing and reading numbers.
1118
1119 */
1120         defvar "STATE",5,,STATE
1121         defvar "HERE",4,,HERE,user_defs_start
1122         defvar "LATEST",6,,LATEST,name_SYSCALL3 // SYSCALL3 must be last in built-in dictionary
1123         defvar "_X",2,,TX
1124         defvar "_Y",2,,TY
1125         defvar "_Z",2,,TZ
1126         defvar "S0",2,,SZ
1127         defvar "BASE",4,,BASE,10
1128
1129 /*
1130         BUILT-IN CONSTANTS ----------------------------------------------------------------------
1131
1132         It's also useful to expose a few constants to FORTH.  When the word is executed it pushes a
1133         constant value on the stack.
1134
1135         The built-in constants are:
1136
1137         VERSION         Is the current version of this FORTH.
1138         R0              The address of the top of the return stack.
1139         DOCOL           Pointer to DOCOL.
1140         F_IMMED         The IMMEDIATE flag's actual value.
1141         F_HIDDEN        The HIDDEN flag's actual value.
1142         F_LENMASK       The length mask in the flags/len byte.
1143
1144         SYS_*           and the numeric codes of various Linux syscalls (from <asm/unistd.h>)
1145 */
1146
1147 //#include <asm-i386/unistd.h>  // you might need this instead
1148 #include <asm/unistd.h>
1149
1150         .macro defconst name, namelen, flags=0, label, value
1151         defcode \name,\namelen,\flags,\label
1152         push $\value
1153         NEXT
1154         .endm
1155
1156         defconst "VERSION",7,,VERSION,JONES_VERSION
1157         defconst "R0",2,,RZ,return_stack
1158         defconst "DOCOL",5,,__DOCOL,DOCOL
1159         defconst "F_IMMED",7,,__F_IMMED,F_IMMED
1160         defconst "F_HIDDEN",8,,__F_HIDDEN,F_HIDDEN
1161         defconst "F_LENMASK",9,,__F_LENMASK,F_LENMASK
1162
1163         defconst "SYS_EXIT",8,,SYS_EXIT,__NR_exit
1164         defconst "SYS_OPEN",8,,SYS_OPEN,__NR_open
1165         defconst "SYS_CLOSE",9,,SYS_CLOSE,__NR_close
1166         defconst "SYS_READ",8,,SYS_READ,__NR_read
1167         defconst "SYS_WRITE",9,,SYS_WRITE,__NR_write
1168         defconst "SYS_CREAT",9,,SYS_CREAT,__NR_creat
1169
1170         defconst "O_RDONLY",8,,__O_RDONLY,0
1171         defconst "O_WRONLY",8,,__O_WRONLY,1
1172         defconst "O_RDWR",6,,__O_RDWR,2
1173         defconst "O_CREAT",7,,__O_CREAT,0100
1174         defconst "O_EXCL",6,,__O_EXCL,0200
1175         defconst "O_TRUNC",7,,__O_TRUNC,01000
1176         defconst "O_APPEND",8,,__O_APPEND,02000
1177         defconst "O_NONBLOCK",10,,__O_NONBLOCK,04000
1178
1179 /*
1180         RETURN STACK ----------------------------------------------------------------------
1181
1182         These words allow you to access the return stack.  Recall that the register %ebp always points to
1183         the top of the return stack.
1184 */
1185
1186         defcode ">R",2,,TOR
1187         pop %eax                // pop parameter stack into %eax
1188         PUSHRSP %eax            // push it on to the return stack
1189         NEXT
1190
1191         defcode "R>",2,,FROMR
1192         POPRSP %eax             // pop return stack on to %eax
1193         push %eax               // and push on to parameter stack
1194         NEXT
1195
1196         defcode "RSP@",4,,RSPFETCH
1197         push %ebp
1198         NEXT
1199
1200         defcode "RSP!",4,,RSPSTORE
1201         pop %ebp
1202         NEXT
1203
1204         defcode "RDROP",5,,RDROP
1205         lea 4(%ebp),%ebp        // pop return stack and throw away
1206         NEXT
1207
1208 /*
1209         PARAMETER (DATA) STACK ----------------------------------------------------------------------
1210
1211         These functions allow you to manipulate the parameter stack.  Recall that Linux sets up the parameter
1212         stack for us, and it is accessed through %esp.
1213 */
1214
1215         defcode "DSP@",4,,DSPFETCH
1216         mov %esp,%eax
1217         push %eax
1218         NEXT
1219
1220         defcode "DSP!",4,,DSPSTORE
1221         pop %esp
1222         NEXT
1223
1224 /*
1225         INPUT AND OUTPUT ----------------------------------------------------------------------
1226
1227         These are our first really meaty/complicated FORTH primitives.  I have chosen to write them in
1228         assembler, but surprisingly in "real" FORTH implementations these are often written in terms
1229         of more fundamental FORTH primitives.  I chose to avoid that because I think that just obscures
1230         the implementation.  After all, you may not understand assembler but you can just think of it
1231         as an opaque block of code that does what it says.
1232
1233         Let's discuss input first.
1234
1235         The FORTH word KEY reads the next byte from stdin (and pushes it on the parameter stack).
1236         So if KEY is called and someone hits the space key, then the number 32 (ASCII code of space)
1237         is pushed on the stack.
1238
1239         In FORTH there is no distinction between reading code and reading input.  We might be reading
1240         and compiling code, we might be reading words to execute, we might be asking for the user
1241         to type their name -- ultimately it all comes in through KEY.
1242
1243         The implementation of KEY uses an input buffer of a certain size (defined at the end of the
1244         program).  It calls the Linux read(2) system call to fill this buffer and tracks its position
1245         in the buffer using a couple of variables, and if it runs out of input buffer then it refills
1246         it automatically.  The other thing that KEY does is if it detects that stdin has closed, it
1247         exits the program, which is why when you hit ^D the FORTH system cleanly exits.
1248 */
1249
1250         defcode "KEY",3,,KEY
1251         call _KEY
1252         push %eax               // push return value on stack
1253         NEXT
1254 _KEY:
1255         mov (currkey),%ebx
1256         cmp (bufftop),%ebx
1257         jge 1f
1258         xor %eax,%eax
1259         mov (%ebx),%al
1260         inc %ebx
1261         mov %ebx,(currkey)
1262         ret
1263
1264 1:      // out of input; use read(2) to fetch more input from stdin
1265         xor %ebx,%ebx           // 1st param: stdin
1266         mov $buffer,%ecx        // 2nd param: buffer
1267         mov %ecx,currkey
1268         mov $buffend-buffer,%edx // 3rd param: max length
1269         mov $__NR_read,%eax     // syscall: read
1270         int $0x80
1271         test %eax,%eax          // If %eax <= 0, then exit.
1272         jbe 2f
1273         addl %eax,%ecx          // buffer+%eax = bufftop
1274         mov %ecx,bufftop
1275         jmp _KEY
1276
1277 2:      // error or out of input: exit
1278         xor %ebx,%ebx
1279         mov $__NR_exit,%eax     // syscall: exit
1280         int $0x80
1281
1282 /*
1283         By contrast, output is much simpler.  The FORTH word EMIT writes out a single byte to stdout.
1284         This implementation just uses the write system call.  No attempt is made to buffer output, but
1285         it would be a good exercise to add it.
1286 */
1287
1288         defcode "EMIT",4,,EMIT
1289         pop %eax
1290         call _EMIT
1291         NEXT
1292 _EMIT:
1293         mov $1,%ebx             // 1st param: stdout
1294
1295         // write needs the address of the byte to write
1296         mov %al,(2f)
1297         mov $2f,%ecx            // 2nd param: address
1298
1299         mov $1,%edx             // 3rd param: nbytes = 1
1300
1301         mov $__NR_write,%eax    // write syscall
1302         int $0x80
1303         ret
1304
1305         .bss
1306 2:      .space 1                // scratch used by EMIT
1307
1308 /*
1309         Back to input, WORD is a FORTH word which reads the next full word of input.
1310
1311         What it does in detail is that it first skips any blanks (spaces, tabs, newlines and so on).
1312         Then it calls KEY to read characters into an internal buffer until it hits a blank.  Then it
1313         calculates the length of the word it read and returns the address and the length as
1314         two words on the stack (with the length at the top of stack).
1315
1316         Notice that WORD has a single internal buffer which it overwrites each time (rather like
1317         a static C string).  Also notice that WORD's internal buffer is just 32 bytes long and
1318         there is NO checking for overflow.  31 bytes happens to be the maximum length of a
1319         FORTH word that we support, and that is what WORD is used for: to read FORTH words when
1320         we are compiling and executing code.  The returned strings are not NUL-terminated, so
1321         in some crazy-world you could define FORTH words containing ASCII NULs, although why
1322         you'd want to is a bit beyond me.
1323
1324         WORD is not suitable for just reading strings (eg. user input) because of all the above
1325         peculiarities and limitations.
1326
1327         Note that when executing, you'll see:
1328         WORD FOO
1329         which puts "FOO" and length 3 on the stack, but when compiling:
1330         : BAR WORD FOO ;
1331         is an error (or at least it doesn't do what you might expect).  Later we'll talk about compiling
1332         and immediate mode, and you'll understand why.
1333 */
1334
1335         defcode "WORD",4,,WORD
1336         call _WORD
1337         push %edi               // push base address
1338         push %ecx               // push length
1339         NEXT
1340
1341 _WORD:
1342         /* Search for first non-blank character.  Also skip \ comments. */
1343 1:
1344         call _KEY               // get next key, returned in %eax
1345         cmpb $'\\',%al          // start of a comment?
1346         je 3f                   // if so, skip the comment
1347         cmpb $' ',%al
1348         jbe 1b                  // if so, keep looking
1349
1350         /* Search for the end of the word, storing chars as we go. */
1351         mov $5f,%edi            // pointer to return buffer
1352 2:
1353         stosb                   // add character to return buffer
1354         call _KEY               // get next key, returned in %al
1355         cmpb $' ',%al           // is blank?
1356         ja 2b                   // if not, keep looping
1357
1358         /* Return the word (well, the static buffer) and length. */
1359         sub $5f,%edi
1360         mov %edi,%ecx           // return length of the word
1361         mov $5f,%edi            // return address of the word
1362         ret
1363
1364         /* Code to skip \ comments to end of the current line. */
1365 3:
1366         call _KEY
1367         cmpb $'\n',%al          // end of line yet?
1368         jne 3b
1369         jmp 1b
1370
1371         .bss
1372         // A static buffer where WORD returns.  Subsequent calls
1373         // overwrite this buffer.  Maximum word length is 32 chars.
1374 5:      .space 32
1375
1376 /*
1377         As well as reading in words we'll need to read in numbers and for that we are using a function
1378         called SNUMBER.  This parses a numeric string such as one returned by WORD and pushes the
1379         number on the parameter stack.
1380
1381         This function does absolutely no error checking, and in particular the length of the string
1382         must be >= 1 bytes, and should contain only digits 0-9.  If it doesn't you'll get random results.
1383
1384         This function is only used when reading literal numbers in code, and shouldn't really be used
1385         in user code at all.
1386 */
1387         defcode "SNUMBER",7,,SNUMBER
1388         pop %edi
1389         pop %ecx
1390         call _SNUMBER
1391         push %eax
1392         NEXT
1393 _SNUMBER:
1394         xor %eax,%eax
1395         xor %ebx,%ebx
1396 1:
1397         imull $10,%eax          // %eax *= 10
1398         movb (%edi),%bl
1399         inc %edi
1400         subb $'0',%bl           // ASCII -> digit
1401         add %ebx,%eax
1402         dec %ecx
1403         jnz 1b
1404         ret
1405
1406 /*
1407         DICTIONARY LOOK UPS ----------------------------------------------------------------------
1408
1409         We're building up to our prelude on how FORTH code is compiled, but first we need yet more infrastructure.
1410
1411         The FORTH word FIND takes a string (a word as parsed by WORD -- see above) and looks it up in the
1412         dictionary.  What it actually returns is the address of the dictionary header, if it finds it,
1413         or 0 if it didn't.
1414
1415         So if DOUBLE is defined in the dictionary, then WORD DOUBLE FIND returns the following pointer:
1416
1417     pointer to this
1418         |
1419         |
1420         V
1421         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1422         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          | EXIT       |
1423         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1424
1425         See also >CFA and >DFA.
1426
1427         FIND doesn't find dictionary entries which are flagged as HIDDEN.  See below for why.
1428 */
1429
1430         defcode "FIND",4,,FIND
1431         pop %ecx                // %ecx = length
1432         pop %edi                // %edi = address
1433         call _FIND
1434         push %eax               // %eax = address of dictionary entry (or NULL)
1435         NEXT
1436
1437 _FIND:
1438         push %esi               // Save %esi so we can use it in string comparison.
1439
1440         // Now we start searching backwards through the dictionary for this word.
1441         mov var_LATEST,%edx     // LATEST points to name header of the latest word in the dictionary
1442 1:
1443         test %edx,%edx          // NULL pointer?  (end of the linked list)
1444         je 4f
1445
1446         // Compare the length expected and the length of the word.
1447         // Note that if the F_HIDDEN flag is set on the word, then by a bit of trickery
1448         // this won't pick the word (the length will appear to be wrong).
1449         xor %eax,%eax
1450         movb 4(%edx),%al        // %al = flags+length field
1451         andb $(F_HIDDEN|F_LENMASK),%al // %al = name length
1452         cmpb %cl,%al            // Length is the same?
1453         jne 2f
1454
1455         // Compare the strings in detail.
1456         push %ecx               // Save the length
1457         push %edi               // Save the address (repe cmpsb will move this pointer)
1458         lea 5(%edx),%esi        // Dictionary string we are checking against.
1459         repe cmpsb              // Compare the strings.
1460         pop %edi
1461         pop %ecx
1462         jne 2f                  // Not the same.
1463
1464         // The strings are the same - return the header pointer in %eax
1465         pop %esi
1466         mov %edx,%eax
1467         ret
1468
1469 2:
1470         mov (%edx),%edx         // Move back through the link field to the previous word
1471         jmp 1b                  // .. and loop.
1472
1473 4:      // Not found.
1474         pop %esi
1475         xor %eax,%eax           // Return zero to indicate not found.
1476         ret
1477
1478 /*
1479         FIND returns the dictionary pointer, but when compiling we need the codeword pointer (recall
1480         that FORTH definitions are compiled into lists of codeword pointers).  The standard FORTH
1481         word >CFA turns a dictionary pointer into a codeword pointer.
1482
1483         The example below shows the result of:
1484
1485                 WORD DOUBLE FIND >CFA
1486
1487         FIND returns a pointer to this
1488         |                               >CFA converts it to a pointer to this
1489         |                                          |
1490         V                                          V
1491         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1492         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          | EXIT       |
1493         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1494
1495         Notes:
1496
1497         Because names vary in length, this isn't just a simple increment.
1498
1499         In this FORTH you cannot easily turn a codeword pointer back into a dictionary entry pointer, but
1500         that is not true in most FORTH implementations where they store a back pointer in the definition
1501         (with an obvious memory/complexity cost).  The reason they do this is that it is useful to be
1502         able to go backwards (codeword -> dictionary entry) in order to decompile FORTH definitions.
1503
1504         What does CFA stand for?  My best guess is "Code Field Address".
1505 */
1506
1507         defcode ">CFA",4,,TCFA
1508         pop %edi
1509         call _TCFA
1510         push %edi
1511         NEXT
1512 _TCFA:
1513         xor %eax,%eax
1514         add $4,%edi             // Skip link pointer.
1515         movb (%edi),%al         // Load flags+len into %al.
1516         inc %edi                // Skip flags+len byte.
1517         andb $F_LENMASK,%al     // Just the length, not the flags.
1518         add %eax,%edi           // Skip the name.
1519         addl $3,%edi            // The codeword is 4-byte aligned.
1520         andl $~3,%edi
1521         ret
1522
1523 /*
1524         Related to >CFA is >DFA which takes a dictionary entry address as returned by FIND and
1525         returns a pointer to the first data field.
1526
1527         FIND returns a pointer to this
1528         |                               >CFA converts it to a pointer to this
1529         |                                          |
1530         |                                          |    >DFA converts it to a pointer to this
1531         |                                          |             |
1532         V                                          V             V
1533         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1534         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          | EXIT       |
1535         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1536
1537         (Note to those following the source of FIG-FORTH / ciforth: My >DFA definition is
1538         different from theirs, because they have an extra indirection).
1539
1540         You can see that >DFA is easily defined in FORTH just by adding 4 to the result of >CFA.
1541 */
1542
1543         defword ">DFA",4,,TDFA
1544         .int TCFA               // >CFA         (get code field address)
1545         .int INCR4              // 4+           (add 4 to it to get to next word)
1546         .int EXIT               // EXIT         (return from FORTH word)
1547
1548 /*
1549         COMPILING ----------------------------------------------------------------------
1550
1551         Now we'll talk about how FORTH compiles words.  Recall that a word definition looks like this:
1552
1553                 : DOUBLE DUP + ;
1554
1555         and we have to turn this into:
1556
1557           pointer to previous word
1558            ^
1559            |
1560         +--|------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1561         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          | EXIT       |
1562         +---------+---+---+---+---+---+---+---+---+------------+--|---------+------------+------------+
1563            ^       len                         pad  codeword      |
1564            |                                                      V
1565           LATEST points here                            points to codeword of DUP
1566
1567         There are several problems to solve.  Where to put the new word?  How do we read words?  How
1568         do we define the words : (COLON) and ; (SEMICOLON)?
1569
1570         FORTH solves this rather elegantly and as you might expect in a very low-level way which
1571         allows you to change how the compiler works on your own code.
1572
1573         FORTH has an INTERPRETER function (a true interpreter this time, not DOCOL) which runs in a
1574         loop, reading words (using WORD), looking them up (using FIND), turning them into codeword
1575         pointers (using >CFA) and deciding what to do with them.
1576
1577         What it does depends on the mode of the interpreter (in variable STATE).
1578
1579         When STATE is zero, the interpreter just runs each word as it looks them up.  This is known as
1580         immediate mode.
1581
1582         The interesting stuff happens when STATE is non-zero -- compiling mode.  In this mode the
1583         interpreter appends the codeword pointer to user memory (the HERE variable points to the next
1584         free byte of user memory).
1585
1586         So you may be able to see how we could define : (COLON).  The general plan is:
1587
1588         (1) Use WORD to read the name of the function being defined.
1589
1590         (2) Construct the dictionary entry -- just the header part -- in user memory:
1591
1592     pointer to previous word (from LATEST)                      +-- Afterwards, HERE points here, where
1593            ^                                                    |   the interpreter will start appending
1594            |                                                    V   codewords.
1595         +--|------+---+---+---+---+---+---+---+---+------------+
1596         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      |
1597         +---------+---+---+---+---+---+---+---+---+------------+
1598                    len                         pad  codeword
1599
1600         (3) Set LATEST to point to the newly defined word, ...
1601
1602         (4) .. and most importantly leave HERE pointing just after the new codeword.  This is where
1603             the interpreter will append codewords.
1604
1605         (5) Set STATE to 1.  This goes into compile mode so the interpreter starts appending codewords to
1606             our partially-formed header.
1607
1608         After : has run, our input is here:
1609
1610         : DOUBLE DUP + ;
1611                  ^
1612                  |
1613                 Next byte returned by KEY will be the 'D' character of DUP
1614
1615         so the interpreter (now it's in compile mode, so I guess it's really the compiler) reads "DUP",
1616         looks it up in the dictionary, gets its codeword pointer, and appends it:
1617
1618                                                                              +-- HERE updated to point here.
1619                                                                              |
1620                                                                              V
1621         +---------+---+---+---+---+---+---+---+---+------------+------------+
1622         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        |
1623         +---------+---+---+---+---+---+---+---+---+------------+------------+
1624                    len                         pad  codeword
1625
1626         Next we read +, get the codeword pointer, and append it:
1627
1628                                                                                           +-- HERE updated to point here.
1629                                                                                           |
1630                                                                                           V
1631         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+
1632         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          |
1633         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+
1634                    len                         pad  codeword
1635
1636         The issue is what happens next.  Obviously what we _don't_ want to happen is that we
1637         read ";" and compile it and go on compiling everything afterwards.
1638
1639         At this point, FORTH uses a trick.  Remember the length byte in the dictionary definition
1640         isn't just a plain length byte, but can also contain flags.  One flag is called the
1641         IMMEDIATE flag (F_IMMED in this code).  If a word in the dictionary is flagged as
1642         IMMEDIATE then the interpreter runs it immediately _even if it's in compile mode_.
1643
1644         This is how the word ; (SEMICOLON) works -- as a word flagged in the dictionary as IMMEDIATE.
1645         And all it does is append the codeword for EXIT on to the current definition and switch
1646         back to immediate mode (set STATE back to 0).  Shortly we'll see the actual definition
1647         of ; and we'll see that it's really a very simple definition, declared IMMEDIATE.
1648
1649         After the interpreter reads ; and executes it 'immediately', we get this:
1650
1651         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1652         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          | EXIT       |
1653         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1654                    len                         pad  codeword                                           ^
1655                                                                                                        |
1656                                                                                                       HERE
1657
1658         STATE is set to 0.
1659
1660         And that's it, job done, our new definition is compiled, and we're back in immediate mode
1661         just reading and executing words, perhaps including a call to test our new word DOUBLE.
1662
1663         The only last wrinkle in this is that while our word was being compiled, it was in a
1664         half-finished state.  We certainly wouldn't want DOUBLE to be called somehow during
1665         this time.  There are several ways to stop this from happening, but in FORTH what we
1666         do is flag the word with the HIDDEN flag (F_HIDDEN in this code) just while it is
1667         being compiled.  This prevents FIND from finding it, and thus in theory stops any
1668         chance of it being called.
1669
1670         The above explains how compiling, : (COLON) and ; (SEMICOLON) works and in a moment I'm
1671         going to define them.  The : (COLON) function can be made a little bit more general by writing
1672         it in two parts.  The first part, called CREATE, makes just the header:
1673
1674                                                    +-- Afterwards, HERE points here.
1675                                                    |
1676                                                    V
1677         +---------+---+---+---+---+---+---+---+---+
1678         | LINK    | 6 | D | O | U | B | L | E | 0 |
1679         +---------+---+---+---+---+---+---+---+---+
1680                    len                         pad
1681
1682         and the second part, the actual definition of : (COLON), calls CREATE and appends the
1683         DOCOL codeword, so leaving:
1684
1685                                                                 +-- Afterwards, HERE points here.
1686                                                                 |
1687                                                                 V
1688         +---------+---+---+---+---+---+---+---+---+------------+
1689         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      |
1690         +---------+---+---+---+---+---+---+---+---+------------+
1691                    len                         pad  codeword
1692
1693         CREATE is a standard FORTH word and the advantage of this split is that we can reuse it to
1694         create other types of words (not just ones which contain code, but words which contain variables,
1695         constants and other data).
1696 */
1697
1698         defcode "CREATE",6,,CREATE
1699
1700         // Get the word.
1701         call _WORD              // Returns %ecx = length, %edi = pointer to word.
1702         mov %edi,%ebx           // %ebx = address of the word
1703
1704         // Link pointer.
1705         movl var_HERE,%edi      // %edi is the address of the header
1706         movl var_LATEST,%eax    // Get link pointer
1707         stosl                   // and store it in the header.
1708
1709         // Length byte and the word itself.
1710         mov %cl,%al             // Get the length.
1711         stosb                   // Store the length/flags byte.
1712         push %esi
1713         mov %ebx,%esi           // %esi = word
1714         rep movsb               // Copy the word
1715         pop %esi
1716         addl $3,%edi            // Align to next 4 byte boundary.
1717         andl $~3,%edi
1718
1719         // Update LATEST and HERE.
1720         movl var_HERE,%eax
1721         movl %eax,var_LATEST
1722         movl %edi,var_HERE
1723         NEXT
1724
1725 /*
1726         Because I want to define : (COLON) in FORTH, not assembler, we need a few more FORTH words
1727         to use.
1728
1729         The first is , (COMMA) which is a standard FORTH word which appends a 32 bit integer to the user
1730         data area pointed to by HERE, and adds 4 to HERE.  So the action of , (COMMA) is:
1731
1732                                                         previous value of HERE
1733                                                                  |
1734                                                                  V
1735         +---------+---+---+---+---+---+---+---+---+-- - - - - --+------------+
1736         | LINK    | 6 | D | O | U | B | L | E | 0 |             |  <data>    |
1737         +---------+---+---+---+---+---+---+---+---+-- - - - - --+------------+
1738                    len                         pad                            ^
1739                                                                               |
1740                                                                         new value of HERE
1741
1742         and <data> is whatever 32 bit integer was at the top of the stack.
1743
1744         , (COMMA) is quite a fundamental operation when compiling.  It is used to append codewords
1745         to the current word that is being compiled.
1746 */
1747
1748         defcode ",",1,,COMMA
1749         pop %eax                // Code pointer to store.
1750         call _COMMA
1751         NEXT
1752 _COMMA:
1753         movl var_HERE,%edi      // HERE
1754         stosl                   // Store it.
1755         movl %edi,var_HERE      // Update HERE (incremented)
1756         ret
1757
1758 /*
1759         Our definitions of : (COLON) and ; (SEMICOLON) will need to switch to and from compile mode.
1760
1761         Immediate mode vs. compile mode is stored in the global variable STATE, and by updating this
1762         variable we can switch between the two modes.
1763
1764         For various reasons which may become apparent later, FORTH defines two standard words called
1765         [ and ] (LBRAC and RBRAC) which switch between modes:
1766
1767         Word    Assembler       Action          Effect
1768         [       LBRAC           STATE := 0      Switch to immediate mode.
1769         ]       RBRAC           STATE := 1      Switch to compile mode.
1770
1771         [ (LBRAC) is an IMMEDIATE word.  The reason is as follows: If we are in compile mode and the
1772         interpreter saw [ then it would compile it rather than running it.  We would never be able to
1773         switch back to immediate mode!  So we flag the word as IMMEDIATE so that even in compile mode
1774         the word runs immediately, switching us back to immediate mode.
1775 */
1776
1777         defcode "[",1,F_IMMED,LBRAC
1778         xor %eax,%eax
1779         movl %eax,var_STATE     // Set STATE to 0.
1780         NEXT
1781
1782         defcode "]",1,,RBRAC
1783         movl $1,var_STATE       // Set STATE to 1.
1784         NEXT
1785
1786 /*
1787         Now we can define : (COLON) using CREATE.  It just calls CREATE, appends DOCOL (the codeword), sets
1788         the word HIDDEN and goes into compile mode.
1789 */
1790
1791         defword ":",1,,COLON
1792         .int CREATE             // CREATE the dictionary entry / header
1793         .int LIT, DOCOL, COMMA  // Append DOCOL  (the codeword).
1794         .int LATEST, FETCH, HIDDEN // Make the word hidden (see below for definition).
1795         .int RBRAC              // Go into compile mode.
1796         .int EXIT               // Return from the function.
1797
1798 /*
1799         ; (SEMICOLON) is also elegantly simple.  Notice the F_IMMED flag.
1800 */
1801
1802         defword ";",1,F_IMMED,SEMICOLON
1803         .int LIT, EXIT, COMMA   // Append EXIT (so the word will return).
1804         .int LATEST, FETCH, HIDDEN // Toggle hidden flag -- unhide the word (see below for definition).
1805         .int LBRAC              // Go back to IMMEDIATE mode.
1806         .int EXIT               // Return from the function.
1807
1808 /*
1809         EXTENDING THE COMPILER ----------------------------------------------------------------------
1810
1811         Words flagged with IMMEDIATE (F_IMMED) aren't just for the FORTH compiler to use.  You can define
1812         your own IMMEDIATE words too, and this is a crucial aspect when extending basic FORTH, because
1813         it allows you in effect to extend the compiler itself.  Does gcc let you do that?
1814
1815         Standard FORTH words like IF, WHILE, ." and so on are all written as extensions to the basic
1816         compiler, and are all IMMEDIATE words.
1817
1818         The IMMEDIATE word toggles the F_IMMED (IMMEDIATE flag) on the most recently defined word,
1819         or on the current word if you call it in the middle of a definition.
1820
1821         Typical usage is:
1822
1823         : MYIMMEDWORD IMMEDIATE
1824                 ...definition...
1825         ;
1826
1827         but some FORTH programmers write this instead:
1828
1829         : MYIMMEDWORD
1830                 ...definition...
1831         ; IMMEDIATE
1832
1833         The two usages are equivalent, to a first approximation.
1834 */
1835
1836         defcode "IMMEDIATE",9,F_IMMED,IMMEDIATE
1837         movl var_LATEST,%edi    // LATEST word.
1838         addl $4,%edi            // Point to name/flags byte.
1839         xorb $F_IMMED,(%edi)    // Toggle the IMMED bit.
1840         NEXT
1841
1842 /*
1843         'addr HIDDEN' toggles the hidden flag (F_HIDDEN) of the word defined at addr.  To hide the
1844         most recently defined word (used above in : and ; definitions) you would do:
1845
1846                 LATEST @ HIDDEN
1847
1848         Setting this flag stops the word from being found by FIND, and so can be used to make 'private'
1849         words.  For example, to break up a large word into smaller parts you might do:
1850
1851                 : SUB1 ... subword ... ;
1852                 : SUB2 ... subword ... ;
1853                 : SUB3 ... subword ... ;
1854                 : MAIN ... defined in terms of SUB1, SUB2, SUB3 ... ;
1855                 WORD SUB1 FIND HIDDEN           \ Hide SUB1
1856                 WORD SUB2 FIND HIDDEN           \ Hide SUB2
1857                 WORD SUB3 FIND HIDDEN           \ Hide SUB3
1858
1859         After this, only MAIN is 'exported' or seen by the rest of the program.
1860 */
1861
1862         defcode "HIDDEN",6,,HIDDEN
1863         pop %edi                // Dictionary entry.
1864         addl $4,%edi            // Point to name/flags byte.
1865         xorb $F_HIDDEN,(%edi)   // Toggle the HIDDEN bit.
1866         NEXT
1867
1868 /*
1869         ' (TICK) is a standard FORTH word which returns the codeword pointer of the next word.
1870
1871         The common usage is:
1872
1873         ' FOO ,
1874
1875         which appends the codeword of FOO to the current word we are defining (this only works in compiled code).
1876
1877         You tend to use ' in IMMEDIATE words.  For example an alternate (and rather useless) way to define
1878         a literal 2 might be:
1879
1880         : LIT2 IMMEDIATE
1881                 ' LIT ,         \ Appends LIT to the currently-being-defined word
1882                 2 ,             \ Appends the number 2 to the currently-being-defined word
1883         ;
1884
1885         So you could do:
1886
1887         : DOUBLE LIT2 * ;
1888
1889         (If you don't understand how LIT2 works, then you should review the material about compiling words
1890         and immediate mode).
1891
1892         This definition of ' uses a cheat which I copied from buzzard92.  As a result it only works in
1893         compiled code.  It is possible to write a version of ' based on WORD, FIND, >CFA which works in
1894         immediate mode too.
1895 */
1896         defcode "'",1,,TICK
1897         lodsl                   // Get the address of the next word and skip it.
1898         pushl %eax              // Push it on the stack.
1899         NEXT
1900
1901 /*
1902         BRANCHING ----------------------------------------------------------------------
1903
1904         It turns out that all you need in order to define looping constructs, IF-statements, etc.
1905         are two primitives.
1906
1907         BRANCH is an unconditional branch. 0BRANCH is a conditional branch (it only branches if the
1908         top of stack is zero).
1909
1910         The diagram below shows how BRANCH works in some imaginary compiled word.  When BRANCH executes,
1911         %esi starts by pointing to the offset field (compare to LIT above):
1912
1913         +---------------------+-------+---- - - ---+------------+------------+---- - - - ----+------------+
1914         | (Dictionary header) | DOCOL |            | BRANCH     | offset     | (skipped)     | word       |
1915         +---------------------+-------+---- - - ---+------------+-----|------+---- - - - ----+------------+
1916                                                                    ^  |                       ^
1917                                                                    |  |                       |
1918                                                                    |  +-----------------------+
1919                                                                   %esi added to offset
1920
1921         The offset is added to %esi to make the new %esi, and the result is that when NEXT runs, execution
1922         continues at the branch target.  Negative offsets work as expected.
1923
1924         0BRANCH is the same except the branch happens conditionally.
1925
1926         Now standard FORTH words such as IF, THEN, ELSE, WHILE, REPEAT, etc. can be implemented entirely
1927         in FORTH.  They are IMMEDIATE words which append various combinations of BRANCH or 0BRANCH
1928         into the word currently being compiled.
1929
1930         As an example, code written like this:
1931
1932                 condition-code IF true-part THEN rest-code
1933
1934         compiles to:
1935
1936                 condition-code 0BRANCH OFFSET true-part rest-code
1937                                           |             ^
1938                                           |             |
1939                                           +-------------+
1940 */
1941
1942         defcode "BRANCH",6,,BRANCH
1943         add (%esi),%esi         // add the offset to the instruction pointer
1944         NEXT
1945
1946         defcode "0BRANCH",7,,ZBRANCH
1947         pop %eax
1948         test %eax,%eax          // top of stack is zero?
1949         jz code_BRANCH          // if so, jump back to the branch function above
1950         lodsl                   // otherwise we need to skip the offset
1951         NEXT
1952
1953 /*
1954         LITERAL STRINGS ----------------------------------------------------------------------
1955
1956         LITSTRING is a primitive used to implement the ." and S" operators (which are written in
1957         FORTH).  See the definition of those operators later.
1958
1959         TELL just prints a string.  It's more efficient to define this in assembly because we
1960         can make it a single Linux syscall.
1961 */
1962
1963         defcode "LITSTRING",9,,LITSTRING
1964         lodsl                   // get the length of the string
1965         push %esi               // push the address of the start of the string
1966         push %eax               // push it on the stack
1967         addl %eax,%esi          // skip past the string
1968         addl $3,%esi            // but round up to next 4 byte boundary
1969         andl $~3,%esi
1970         NEXT
1971
1972         defcode "TELL",4,,TELL
1973         mov $1,%ebx             // 1st param: stdout
1974         pop %edx                // 3rd param: length of string
1975         pop %ecx                // 2nd param: address of string
1976         mov $__NR_write,%eax    // write syscall
1977         int $0x80
1978         NEXT
1979
1980 /*
1981         COLD START AND INTERPRETER ----------------------------------------------------------------------
1982
1983         COLD is the first FORTH function called, almost immediately after the FORTH system "boots".
1984
1985         INTERPRETER is the FORTH interpreter ("toploop", "toplevel" or "REPL" might be a more accurate
1986         description -- see: http://en.wikipedia.org/wiki/REPL).
1987 */
1988
1989         // COLD must not return (ie. must not call EXIT).
1990         defword "COLD",4,,COLD
1991         .int INTERPRETER        // call the interpreter loop (never returns)
1992
1993 /* This interpreter is pretty simple, but remember that in FORTH you can always override
1994  * it later with a more powerful one!
1995  */
1996         defword "INTERPRETER",11,,INTERPRETER
1997         .int INTERPRET,RDROP,INTERPRETER
1998
1999         defcode "INTERPRET",9,,INTERPRET
2000         call _WORD              // Returns %ecx = length, %edi = pointer to word.
2001
2002         // Is it in the dictionary?
2003         xor %eax,%eax
2004         movl %eax,interpret_is_lit // Not a literal number (not yet anyway ...)
2005         call _FIND              // Returns %eax = pointer to header or 0 if not found.
2006         test %eax,%eax          // Found?
2007         jz 1f
2008
2009         // In the dictionary.  Is it an IMMEDIATE codeword?
2010         mov %eax,%edi           // %edi = dictionary entry
2011         movb 4(%edi),%al        // Get name+flags.
2012         push %ax                // Just save it for now.
2013         call _TCFA              // Convert dictionary entry (in %edi) to codeword pointer.
2014         pop %ax
2015         andb $F_IMMED,%al       // Is IMMED flag set?
2016         mov %edi,%eax
2017         jnz 4f                  // If IMMED, jump straight to executing.
2018
2019         jmp 2f
2020
2021 1:      // Not in the dictionary (not a word) so assume it's a literal number.
2022         incl interpret_is_lit
2023         call _SNUMBER           // Returns the parsed number in %eax
2024         mov %eax,%ebx
2025         mov $LIT,%eax           // The word is LIT
2026
2027 2:      // Are we compiling or executing?
2028         movl var_STATE,%edx
2029         test %edx,%edx
2030         jz 4f                   // Jump if executing.
2031
2032         // Compiling - just append the word to the current dictionary definition.
2033         call _COMMA
2034         mov interpret_is_lit,%ecx // Was it a literal?
2035         test %ecx,%ecx
2036         jz 3f
2037         mov %ebx,%eax           // Yes, so LIT is followed by a number.
2038         call _COMMA
2039 3:      NEXT
2040
2041 4:      // Executing - run it!
2042         mov interpret_is_lit,%ecx // Literal?
2043         test %ecx,%ecx          // Literal?
2044         jnz 5f
2045
2046         // Not a literal, execute it now.  This never returns, but the codeword will
2047         // eventually call NEXT which will reenter the loop in INTERPRETER.
2048         jmp *(%eax)
2049
2050 5:      // Executing a literal, which means push it on the stack.
2051         push %ebx
2052         NEXT
2053
2054         .data
2055         .align 4
2056 interpret_is_lit:
2057         .int 0                  // Flag used to record if reading a literal
2058
2059 /*
2060         ODDS AND ENDS ----------------------------------------------------------------------
2061
2062         CHAR puts the ASCII code of the first character of the following word on the stack.  For example
2063         CHAR A puts 65 on the stack.
2064
2065         SYSCALL3 makes a standard Linux system call.  (See <asm/unistd.h> for a list of system call
2066         numbers).  This is the form to use when the function takes up to three parameters.
2067
2068         In this FORTH, SYSCALL3 must be the last word in the built-in (assembler) dictionary because we
2069         initialise the LATEST variable to point to it.  This means that if you want to extend the assembler
2070         part, you must put new words before SYSCALL3, or else change how LATEST is initialised.
2071 */
2072
2073         defcode "CHAR",4,,CHAR
2074         call _WORD              // Returns %ecx = length, %edi = pointer to word.
2075         xor %eax,%eax
2076         movb (%edi),%al         // Get the first character of the word.
2077         push %eax               // Push it onto the stack.
2078         NEXT
2079
2080         defcode "SYSCALL3",8,,SYSCALL3
2081         pop %eax                // System call number (see <asm/unistd.h>)
2082         pop %ebx                // First parameter.
2083         pop %ecx                // Second parameter
2084         pop %edx                // Third parameter
2085         int $0x80
2086         push %eax               // Result (negative for -errno)
2087         NEXT
2088
2089 /*
2090         START OF FORTH CODE ----------------------------------------------------------------------
2091
2092         We've now reached the stage where the FORTH system is running and self-hosting.  All further
2093         words can be written as FORTH itself, including words like IF, THEN, .", etc which in most
2094         languages would be considered rather fundamental.
2095
2096         I used to append this here in the assembly file, but I got sick of fighting against gas's
2097         stupid (lack of) multiline string syntax.  So now that is in a separate file called jonesforth.f
2098
2099         If you don't already have that file, download it from http://annexia.org/forth in order
2100         to continue the tutorial.
2101 */
2102
2103 /* END OF jonesforth.S */