configure.ac

   1 dnl febootstrap configure.ac
   2 dnl (C) Copyright 2009-2011 Red Hat Inc.
   3 dnl
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8 dnl
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13 dnl
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17 dnl
  18 dnl Written by Richard W.M. Jones <rjones@redhat.com>
  19
  20 AC_INIT(febootstrap,3.5)
  21 AM_INIT_AUTOMAKE
  22
  23 dnl Check for basic C environment.
  24 AC_PROG_CC_STDC
  25 gl_EARLY
  26
  27 AC_PROG_INSTALL
  28 AC_PROG_CPP
  29
  30 AC_C_PROTOTYPES
  31 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
  32
  33 AM_PROG_CC_C_O
  34
  35 dnl Check support for 64 bit file offsets.
  36 AC_SYS_LARGEFILE
  37
  38 gl_INIT
  39
  40 # OCaml and ocamlfind are required to compile.
  41 AC_PROG_OCAML
  42 if test "$OCAMLC" = "no"; then
  43     AC_MSG_ERROR([You must install the OCaml compiler])
  44 fi
  45 AM_CONDITIONAL([HAVE_OCAMLOPT],[test "$OCAMLBEST" = "opt"])
  46 AC_PROG_FINDLIB
  47 if test "$OCAMLFIND" = "no"; then
  48     AC_MSG_ERROR([You must install OCaml findlib (the ocamlfind command)])
  49 fi
  50
  51 dnl Optional programs.
  52 AC_CHECK_PROG(PERLDOC,[perldoc],[perldoc],[no])
  53 if test "x$PERLDOC" = "xno" ; then
  54   AC_MSG_WARN([perldoc not found - install perl to make man pages])
  55 fi
  56 AM_CONDITIONAL(HAVE_PERLDOC,[test "$perldoc" != "no"])
  57
  58 dnl For yum-rpm handler.
  59 AC_CHECK_PROG(YUM,[yum],[yum],[no])
  60 AC_CHECK_PROG(RPM,[rpm],[rpm],[no])
  61 AC_CHECK_PROG(YUMDOWNLOADER,[yumdownloader],[yumdownloader],[no])
  62
  63 dnl For Debian handler.
  64 AC_CHECK_PROG(APTITUDE,[aptitude],[aptitude],[no])
  65 AC_CHECK_PROG(DPKG,[dpkg],[dpkg],[no])
  66
  67 dnl For ArchLinux handler.
  68 AC_CHECK_PROG(PACMAN,[pacman],[pacman],[no])
  69
  70 dnl Required programs, libraries.
  71 AC_PATH_PROG([INSMODSTATIC],[insmod.static],[no])
  72 if test "x$INSMODSTATIC" = "xno" ; then
  73   AC_MSG_FAILURE([insmod.static program not found
  74
  75 Is /sbin in your current path?
  76
  77 Note that Debian/Ubuntu do not package this file from module-init-tools.
  78 Sorry, please fix your distribution.  In the meantime you can copy
  79 /sbin/insmod.static from a Fedora machine.
  80 ])
  81 fi
  82 AC_DEFINE_UNQUOTED([INSMODSTATIC],["$INSMODSTATIC"],
  83   [Full path to the insmod.static program.])
  84
  85 AC_PATH_PROG([MKE2FS],[mke2fs],[no])
  86 if test "x$MKE2FS" = "xno" ; then
  87   AC_MSG_FAILURE([mke2fs program not found (is /sbin in your current path?)])
  88 fi
  89 AC_DEFINE_UNQUOTED([MKE2FS],["$MKE2FS"],
  90   [Full path to the mke2fs program.])
  91
  92 old_LIBS="$LIBS"
  93 AC_CHECK_LIB([com_err],[error_message],[],[
  94   AC_MSG_FAILURE([com_err library not found (part of e2fsprogs)])
  95 ])
  96 LIBS="$old_LIBS"
  97
  98 old_LIBS="$LIBS"
  99 AC_CHECK_LIB([ext2fs],[ext2fs_file_open2],[],[
 100   AC_MSG_FAILURE([libext2fs library not found (part of e2fsprogs)])
 101 ])
 102 LIBS="$old_LIBS"
 103
 104 AC_CHECK_HEADER([ext2fs/ext2fs.h],[],[
 105   AC_MSG_FAILURE([Header <ext2fs/ext2fs.h> not found (part of e2fsprogs)])
 106 ])
 107
 108 AC_CONFIG_HEADERS([config.h])
 109 AC_CONFIG_FILES([config.ml
 110         debian/changelog
 111         Makefile
 112         lib/Makefile
 113         helper/Makefile])
 114 AC_OUTPUT