+If I am using the wrong qemu or you want to compile qemu from source
+and install it in another location, then you should configure with
+the --with-qemu option.
+])
+ fi
+fi
+
+dnl Set default drive interface used by the guestfs_add_drive_opts call
+dnl ('-drive ...,if=...' option to qemu).
+dnl
+dnl If you encounter performance problems with virtio (RHBZ#509383)
+dnl then try '--with-drive-if=ide'.
+AC_ARG_WITH([drive-if],
+ [AS_HELP_STRING([--with-drive-if],
+ [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
+ [],
+ [with_drive_if=virtio])
+AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
+
+dnl Set interface used by the network. Normally you should
+dnl leave this at the default (virtio-net-pci) but you can use the
+dnl alternative (ne2k_pci) because of bugs in virtio networking
+dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
+AC_ARG_WITH([net-if],
+ [AS_HELP_STRING([--with-net-if],
+ [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
+ [],
+ [with_net_if=virtio-net-pci])
+AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
+
+dnl Check for febootstrap etc.
+if test "x$enable_appliance" = "xyes"; then
+ AC_CHECK_PROG([FEBOOTSTRAP],
+ [febootstrap],[febootstrap],[no])
+ if test "x$FEBOOTSTRAP" != "xno"; then
+ AC_CHECK_PROG([FEBOOTSTRAP_RUN],
+ [febootstrap-run],[febootstrap-run],[no])
+ test "x$FEBOOTSTRAP_RUN" = "xno" && \
+ AC_MSG_ERROR([febootstrap-run must be installed])
+ AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
+ [febootstrap-install],[febootstrap-install],[no])
+ test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
+ AC_MSG_ERROR([febootstrap-install must be installed])
+ AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
+ [febootstrap-minimize],[febootstrap-minimize],[no])
+ test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
+ AC_MSG_ERROR([febootstrap-minimize must be installed])
+ AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
+ [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
+ test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
+ AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
+ AC_CHECK_PROG([FEBOOTSTRAP_TO_SUPERMIN],
+ [febootstrap-to-supermin],[febootstrap-to-supermin],[no])
+ test "x$FEBOOTSTRAP_TO_SUPERMIN" = "xno" && \
+ AC_MSG_ERROR([febootstrap-to-supermin must be installed])
+
+ dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
+ dnl of febootstrap, but old versions will fail with yum).
+ AC_CHECK_PROG([FAKECHROOT],
+ [fakechroot],[fakechroot],[no])
+ test "x$FAKECHROOT" = "xno" && \
+ AC_MSG_ERROR([fakechroot must be installed])
+
+ AC_MSG_CHECKING([fakechroot version])
+ fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
+ if test -z "$fakechroot_version"; then
+ AC_MSG_RESULT([failed])
+ AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
+ else
+ AC_MSG_RESULT([$fakechroot_version])
+ fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
+ fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
+ if test "$fakechroot_major" -lt 2 || \
+ ( test "$fakechroot_major" -eq 2 && test "$fakechroot_minor" -lt 9 ); then
+ AC_MSG_ERROR([fakechroot version must be >= 2.9])
+ fi
+ fi
+ DIST="REDHAT"
+ else
+ # check for debootstrap and debirf
+ AC_CHECK_PROG([DEBOOTSTRAP],
+ [debootstrap],[debootstrap],[no])
+ test "x$DEBOOTSTRAP" = "xno" && \
+ AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
+ AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
+ test "x$DEBIRF" = "xno" &&
+ AC_MSG_ERROR([debirf must be installed])
+ DIST="DEBIAN"
+ case "$host_cpu" in
+ *86)
+ DEBIAN_KERNEL_ARCH=486
+ ;;
+ x86_64)
+ DEBIAN_KERNEL_ARCH=amd64
+ ;;
+ *)
+ DEBIAN_KERNEL_ARCH=$host_cpu
+ ;;
+ esac
+ AC_SUBST(DEBIAN_KERNEL_ARCH)
+ fi
+ AC_SUBST(DIST)
+
+ dnl --with-updates to specify a Fedora updates repository.
+ AC_ARG_WITH([updates],
+ [AS_HELP_STRING([--with-updates],
+ [set name of Fedora updates repository @<:@default=updates-released-f12@:>@])],
+ [],
+ [with_updates=updates-released-f12])
+ UPDATES="$with_updates"
+ AC_SUBST(UPDATES)
+
+ dnl --with-mirror to specify a local Fedora mirror.
+ AC_ARG_WITH([mirror],
+ [AS_HELP_STRING([--with-mirror],
+ [set URI of a local Fedora mirror])],
+ [],
+ [with_mirror=])
+ MIRROR="$with_mirror"
+ AC_SUBST(MIRROR)
+fi
+
+dnl --with-repo to specify a repository.
+AC_ARG_WITH([repo],
+ [AS_HELP_STRING([--with-repo],
+ [set name of Fedora repository @<:@default=fedora-13@:>@])],
+ [],
+ [with_repo=fedora-13])
+REPO="$with_repo"
+AC_SUBST(REPO)
+AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of software repository.])
+
+dnl Build the supermin appliance? Please see README file before
+dnl enabling this option.
+AC_ARG_ENABLE([supermin],
+ [AS_HELP_STRING([--enable-supermin],
+ [enable supermin appliance (see README) @<:@default=no@:>@])],
+ [AC_DEFINE([ENABLE_SUPERMIN],[1],[Supermin appliance enabled.])],
+ [enable_supermin=no])
+AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
+
+dnl Enable packet dumps when in verbose mode. This generates lots
+dnl of debug info, only useful for people debugging the RPC mechanism.
+AC_ARG_ENABLE([packet-dump],
+ [AS_HELP_STRING([--enable-packet-dump],
+ [enable packet dumps in verbose mode @<:@default=no@:>@])],
+ [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
+ [])