daemon/configure.ac

   1 # libguestfs-daemon
   2 # Copyright (C) 2009-2011 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 AC_INIT([libguestfs-daemon],[1.0.0])
  19 AC_CONFIG_AUX_DIR([build-aux])
  20 AM_INIT_AUTOMAKE([foreign])
  21
  22 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  23 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  24
  25 AC_CONFIG_MACRO_DIR([m4])
  26
  27 dnl If the user specified --enable-32bit, then force the C compiler
  28 dnl to build 32 bit binaries (gcc -m32).
  29 AC_ARG_ENABLE([32bit],
  30   [AS_HELP_STRING([--enable-32bit], [build 32 bit binaries (gcc -m32)])],
  31   [export CC="gcc -m32"],
  32   [enable_32bit=no])
  33
  34 dnl Enable packet dumps when in verbose mode.  This generates lots
  35 dnl of debug info, only useful for people debugging the RPC mechanism.
  36 AC_ARG_ENABLE([packet-dump],
  37         [AS_HELP_STRING([--enable-packet-dump],
  38           [enable packet dumps in verbose mode @<:@default=no@:>@])],
  39         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
  40         [])
  41
  42 dnl For strchrnul(3), asprintf(3), futimens(2) and getline(3).
  43 AC_GNU_SOURCE
  44
  45 dnl Check for basic C environment.
  46 AC_PROG_CC
  47 AC_PROG_INSTALL
  48 AC_PROG_CPP
  49
  50 gl_EARLY
  51 gl_INIT
  52
  53 AC_ARG_ENABLE([gcc-warnings],
  54   [AS_HELP_STRING([--enable-gcc-warnings],
  55                   [turn on lots of GCC warnings (for developers)])],
  56   [case $enableval in
  57      yes|no) ;;
  58      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  59    esac
  60    gl_gcc_warnings=$enableval],
  61   [gl_gcc_warnings=no]
  62 )
  63
  64 if test "$gl_gcc_warnings" = yes; then
  65   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  66   AC_SUBST([WERROR_CFLAGS])
  67
  68   nw=
  69   # This, $nw, is the list of warnings we disable.
  70   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  71   nw="$nw -Waggregate-return"       # anachronistic
  72   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  73   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  74   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  75   nw="$nw -Wcast-qual"              # Too many warnings for now
  76   nw="$nw -Wconversion"             # Too many warnings for now
  77   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  78   nw="$nw -Wsign-conversion"        # Too many warnings for now
  79   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  80   nw="$nw -Wunreachable-code"       # Too many warnings for now
  81   nw="$nw -Wpadded"                 # Our structs are not padded
  82   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  83   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  84   nw="$nw -Wvla"                    # two warnings in mount.c
  85   # things I might fix soon:
  86   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
  87   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
  88   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
  89   # ?? -Wstrict-overflow
  90   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
  91                                     # was not possible, safe to ignore
  92   nw="$nw -Wlong-long"              # Allow long long since it's required
  93                                     # by Python, Ruby and xstrtoll.
  94   nw="$nw -Wstack-protector"        # Don't warn about stack-protector
  95                                     # failures (seen on Ubuntu).
  96
  97   gl_MANYWARN_ALL_GCC([ws])
  98   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
  99   for w in $ws; do
 100     gl_WARN_ADD([$w])
 101   done
 102   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 103   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 104   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 105
 106   # In spite of excluding -Wlogical-op above, it is enabled, as of
 107   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 108   gl_WARN_ADD([-Wno-logical-op])
 109
 110   gl_WARN_ADD([-fdiagnostics-show-option])
 111
 112   AC_SUBST([WARN_CFLAGS])
 113
 114   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 115   AC_DEFINE([_FORTIFY_SOURCE], [2],
 116     [enable compile-time and run-time bounds-checking, and some warnings])
 117   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 118 fi
 119
 120 AC_C_PROTOTYPES
 121 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 122
 123 AM_PROG_CC_C_O
 124
 125 dnl If the host is Windows, define _WIN32_WINNT to a suitable value.
 126 AC_CANONICAL_HOST
 127 case $host in
 128      *mingw*|*cygwin*|*win32*) CFLAGS="$CFLAGS -D_WIN32_WINNT=0x0500" ;;
 129 esac
 130
 131 dnl Check support for 64 bit file offsets.
 132 AC_SYS_LARGEFILE
 133
 134 dnl Check if dirent (readdir) supports d_type member.
 135 AC_STRUCT_DIRENT_D_TYPE
 136
 137 dnl Check if stat has the required fields.
 138 AC_STRUCT_ST_BLOCKS
 139 AC_CHECK_MEMBER([struct stat.st_blksize],[
 140         AC_DEFINE([HAVE_STRUCT_STAT_ST_BLKSIZE],[1],[Define to 1 if 'st_blksize' is a member of 'struct stat'])])
 141
 142 dnl Check for gperf.
 143 AC_CHECK_PROG([GPERF],[gperf],[gperf],[no])
 144 test "x$GPERF" = "xno" &&
 145      AC_MSG_ERROR([gperf must be installed])
 146
 147 dnl Check for Augeas (now optional).
 148 AC_CHECK_LIB([augeas],[aug_match],[
 149         LIBS="-laugeas $LIBS"
 150         have_augeas=yes
 151         dnl Check for functions not available in earlier versions of Augeas.
 152         AC_CHECK_FUNCS([aug_load aug_defvar aug_defnode])
 153         ],[have_augeas=no])
 154 if test "x$have_augeas" = "xyes"; then
 155         AC_DEFINE([HAVE_AUGEAS],[1],[Define to 1 if you have Augeas])
 156 fi
 157
 158 dnl Check for libselinux (optional).
 159 AC_CHECK_HEADERS([selinux/selinux.h])
 160 AC_CHECK_LIB([selinux],[setexeccon],[
 161         LIBS="-lselinux $LIBS"
 162         have_libselinux="$ac_cv_header_selinux_selinux_h"
 163         AC_CHECK_FUNCS([setcon getcon])
 164         ],[have_libselinux=no])
 165 if test "x$have_libselinux" = "xyes"; then
 166         AC_DEFINE([HAVE_LIBSELINUX],[1],[Define to 1 if you have libselinux])
 167 fi
 168
 169 dnl Check for XDR library.
 170 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 171         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 172         ])
 173
 174 dnl Functions which may not be available in older distributions.
 175 AC_CHECK_FUNCS([\
 176         getxattr \
 177         htonl \
 178         htons \
 179         inotify_init1 \
 180         lgetxattr \
 181         listxattr \
 182         llistxattr \
 183         lsetxattr \
 184         lremovexattr \
 185         mknod \
 186         ntohl \
 187         ntohs \
 188         posix_fallocate \
 189         realpath \
 190         removexattr \
 191         setitimer \
 192         setxattr \
 193         sigaction \
 194         statvfs \
 195         sync])
 196
 197 dnl Headers.
 198 AC_CHECK_HEADERS([\
 199         attr/xattr.h \
 200         printf.h \
 201         sys/inotify.h \
 202         sys/statvfs.h \
 203         sys/xattr.h \
 204         windows.h])
 205
 206 dnl For modified printf, we need glibc either (old-style)
 207 dnl register_printf_function or (new-style) register_printf_specifier.
 208 AC_CHECK_FUNC([register_printf_specifier],[
 209         AC_DEFINE([HAVE_REGISTER_PRINTF_SPECIFIER],[1],
 210                 [Define to 1 if you have new-style register_printf_specifier])
 211         ],[
 212         AC_CHECK_FUNC([register_printf_function],[
 213                 AC_DEFINE([HAVE_REGISTER_PRINTF_FUNCTION],[1],
 214                         [Define to 1 if you have old-style register_printf_function])
 215                 ],[
 216                 AC_MSG_FAILURE(
 217 [No support for glibc-style extended printf formatters.
 218
 219 This means you either have a very old glibc (pre-2.0) or you
 220 are using some other libc where this is not supported.])])])
 221
 222 dnl Produce output files.
 223 AC_CONFIG_HEADERS([config.h])
 224 AC_CONFIG_FILES([Makefile lib/Makefile tests/Makefile])
 225 AC_OUTPUT