configure.ac

   1 # virt-p2v
   2 # Copyright (C) 2007-2008 Red Hat Inc., Richard W.M. Jones
   3 #
   4 # This library is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU Lesser General Public
   6 # License as published by the Free Software Foundation; either
   7 # version 2 of the License, or (at your option) any later version.
   8 #
   9 # This library is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Lesser General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Lesser General Public
  15 # License along with this library; if not, write to the Free Software
  16 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  17
  18 dnl Process this file with autoconf to produce a configure script.
  19 AC_INIT(virt-p2v,0.9.7)
  20
  21 AC_PROG_INSTALL
  22
  23 dnl Override CD properties.
  24 AC_ARG_ENABLE([cd-arch],
  25         [AS_HELP_STRING([--enable-cd-arch],
  26                 [set CD architecture @<:@default=i386@:>@])],
  27         [CD_ARCH=$enableval],
  28         [CD_ARCH=i386])
  29 AC_ARG_ENABLE([cd-lang],
  30         [AS_HELP_STRING([--enable-cd-lang],
  31                 [set CD language @<:@default=en_US.UTF-8@:>@])],
  32         [CD_LANG=$enableval],
  33         [CD_LANG=en_US.UTF-8])
  34 AC_ARG_ENABLE([cd-keyboard],
  35         [AS_HELP_STRING([--enable-cd-keyboard],
  36                 [set CD keyboard @<:@default=us@:>@])],
  37         [CD_KEYBOARD=$enableval],
  38         [CD_KEYBOARD=us])
  39 AC_ARG_ENABLE([cd-timezone],
  40         [AS_HELP_STRING([--enable-cd-timezone],
  41                 [set CD timezone @<:@default=US/Eastern@:>@])],
  42         [CD_TIMEZONE=$enableval],
  43         [CD_TIMEZONE=US/Eastern])
  44 AC_ARG_ENABLE([cd-base],
  45         [AS_HELP_STRING([--enable-cd-base],
  46                 [set base Fedora for CD @<:@default=8@:>@])],
  47         [CD_BASE=$enableval],
  48         [CD_BASE=8])
  49 AC_ARG_ENABLE([cd-base-url],
  50         [AS_HELP_STRING([--enable-cd-base-url],
  51                 [set download URL for packages])],
  52         [CD_BASE_URL=$enableval],
  53         [CD_BASE_URL=http://download.fedora.redhat.com/pub/fedora/linux/releases/$CD_BASE/Everything/$CD_ARCH/os/])
  54
  55 AC_SUBST(CD_ARCH)
  56 AC_SUBST(CD_BASE)
  57 AC_SUBST(CD_BASE_URL)
  58 AC_SUBST(CD_LANG)
  59 AC_SUBST(CD_KEYBOARD)
  60 AC_SUBST(CD_TIMEZONE)
  61
  62 dnl Allow a local repository.
  63 AC_ARG_ENABLE([localrepo],
  64         [AS_HELP_STRING([--enable-localrepo],
  65                 [set path to local repository with additional packages])],
  66         [LOCALREPO=$enableval],
  67         [LOCALREPO=no])
  68
  69 if test "x$LOCALREPO" != "xno"; then
  70     if test -d "$LOCALREPO"; then
  71         # Turn a pathname into a file URL.
  72         LOCALREPO=`cd $LOCALREPO && pwd`
  73         LOCALREPO=file://$LOCALREPO
  74     fi
  75     LOCALREPO="repo --name=local --baseurl=$LOCALREPO"
  76 else
  77     LOCALREPO=""
  78 fi
  79 AC_SUBST(LOCALREPO)
  80
  81 dnl Check for basic OCaml script interpreter.
  82 AC_PROG_OCAML
  83
  84 dnl Check for required OCaml modules.
  85 AC_CHECK_OCAML_MODULE(unix,pkg_unix,Unix,[.])
  86 if test "x$pkg_unix" = "xno"; then
  87     AC_MSG_ERROR([Cannot find required OCaml package 'unix'])
  88 fi
  89
  90 AC_CHECK_OCAML_MODULE(extlib,pkg_extlib,ExtString,[+extlib])
  91 if test "x$pkg_extlib" = "xno"; then
  92     AC_MSG_ERROR([Cannot find required OCaml package 'extlib'])
  93 fi
  94
  95 AC_CHECK_OCAML_MODULE(xml-light,pkg_xml_light,Xml,[+xml-light])
  96 if test "x$pkg_xml_light" = "xno"; then
  97     AC_MSG_ERROR([Cannot find required OCaml package 'xml-light'])
  98 fi
  99
 100 AC_CHECK_OCAML_MODULE(newt,pkg_newt,Newt,[+newt])
 101 if test "x$pkg_newt" = "xno"; then
 102     AC_MSG_ERROR([Cannot find required OCaml package 'ocaml-newt'])
 103 fi
 104
 105 AC_CHECK_OCAML_MODULE(pcre,pkg_pcre,Pcre,[+pcre])
 106 if test "x$pkg_pcre" = "xno"; then
 107     AC_MSG_ERROR([Cannot find required OCaml package 'ocaml-pcre'])
 108 fi
 109
 110 AC_CHECK_OCAML_MODULE(libvirt,pkg_libvirt,Libvirt_version,[+libvirt])
 111 if test "x$pkg_libvirt" = "xno"; then
 112     AC_MSG_ERROR([Cannot find required OCaml package 'ocaml-libvirt'])
 113 fi
 114
 115 dnl Check for recommended livecd-creator (for building ISOs).
 116 AC_CHECK_PROG(HAVE_LIVECD_CREATOR,livecd-creator,livecd-creator)
 117
 118 dnl Check for optional livecd-iso-to-pxeboot.
 119 AC_CHECK_PROG(HAVE_LIVECD_ISO_TO_PXEBOOT,livecd-iso-to-pxeboot,livecd-iso-to-pxeboot)
 120
 121 dnl Check for optional perldoc (for building manual pages).
 122 AC_CHECK_PROG(HAVE_PERLDOC,perldoc,perldoc)
 123
 124 dnl Check for optional qemu or qemu-kvm (for test-booting).
 125 AC_CHECK_PROG(HAVE_QEMU,qemu,qemu)
 126 AC_CHECK_PROG(HAVE_QEMU_KVM,qemu-kvm,qemu-kvm)
 127
 128 dnl Summary.
 129 echo "------------------------------------------------------------"
 130 echo "Thanks for downloading" $PACKAGE_STRING
 131 echo "------------------------------------------------------------"
 132
 133 dnl Produce output files.
 134 AC_CONFIG_FILES([Makefile p2v.ks])
 135 AC_OUTPUT