2 # Copyright (C) 2009-2011 Red Hat Inc.
4 # This program is free software; you can redistribute it and/or modify
5 # it under the terms of the GNU General Public License as published by
6 # the Free Software Foundation; either version 2 of the License, or
7 # (at your option) any later version.
9 # This program is distributed in the hope that it will be useful,
10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
12 # GNU General Public License for more details.
14 # You should have received a copy of the GNU General Public License
15 # along with this program; if not, write to the Free Software
16 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
18 # The major, minor, and release fields MUST be numbers. Packagers can
19 # add extra information using --with-extra="..." which may be any
21 m4_define([libguestfs_major], [1])
22 m4_define([libguestfs_minor], [14])
23 m4_define([libguestfs_release], [5])
25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
26 AC_CONFIG_AUX_DIR([build-aux])
27 AM_INIT_AUTOMAKE([foreign])
29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
32 AC_CONFIG_MACRO_DIR([m4])
34 dnl Stable or unstable version?
35 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
36 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
37 AC_MSG_RESULT([stable])
39 AC_MSG_RESULT([unstable])
42 This is a development version of libguestfs. Some APIs may be unstable
43 until they appear in a stable release of libguestfs (at which point
44 the C API and ABI is guaranteed to remain stable forever). For
45 more information about stable and development branches of libguestfs
46 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
50 dnl Extra string, a freeform string defined by packagers.
52 [AS_HELP_STRING([--with-extra],
53 [extra version string (for use by packagers)])],
54 [libguestfs_extra="$withval"],
58 AC_MSG_NOTICE([libguestfs version libguestfs_major.libguestfs_minor.libguestfs_release$libguestfs_extra])
60 dnl Split up the version string.
61 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
62 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
63 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
64 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_EXTRA],["$libguestfs_extra"],[Extra version string])
66 dnl Early gnulib initialization.
74 dnl Check for basic C environment.
79 AC_ARG_ENABLE([gcc-warnings],
80 [AS_HELP_STRING([--enable-gcc-warnings],
81 [turn on lots of GCC warnings (for developers)])],
84 *) AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
86 gl_gcc_warnings=$enableval],
90 if test "$gl_gcc_warnings" = yes; then
91 gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
92 AC_SUBST([WERROR_CFLAGS])
95 # This, $nw, is the list of warnings we disable.
96 nw="$nw -Wdeclaration-after-statement" # too useful to forbid
97 nw="$nw -Waggregate-return" # anachronistic
98 nw="$nw -Wc++-compat" # We don't care about C++ compilers
99 nw="$nw -Wundef" # Warns on '#if GNULIB_FOO' etc in gnulib
100 nw="$nw -Wtraditional" # Warns on #elif which we use often
101 nw="$nw -Wcast-qual" # Too many warnings for now
102 nw="$nw -Wconversion" # Too many warnings for now
103 nw="$nw -Wsystem-headers" # Don't let system headers trigger warnings
104 nw="$nw -Wsign-conversion" # Too many warnings for now
105 nw="$nw -Wtraditional-conversion" # Too many warnings for now
106 nw="$nw -Wunreachable-code" # Too many warnings for now
107 nw="$nw -Wpadded" # Our structs are not padded
108 nw="$nw -Wredundant-decls" # openat.h declares e.g., mkdirat
109 nw="$nw -Wlogical-op" # any use of fwrite provokes this
110 nw="$nw -Wvla" # two warnings in mount.c
111 # things I might fix soon:
112 nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
113 nw="$nw -Winline" # daemon.h's asprintf_nowarn
114 nw="$nw -Wshadow" # numerous, plus we're not unanimous
115 nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
116 # was not possible, safe to ignore
117 nw="$nw -Wpacked" # Allow attribute((packed)) on structs
118 nw="$nw -Wlong-long" # Allow long long since it's required
119 # by Python, Ruby and xstrtoll.
120 nw="$nw -Wstack-protector" # Don't warn about stack-protector
121 # failures (seen on Ubuntu).
122 nw="$nw -Wmissing-noreturn" # Don't warn about missed noreturn funcs
124 nw="$nw -Wsuggest-attribute=pure" # Don't suggest pure functions.
125 nw="$nw -Wsuggest-attribute=const" # Don't suggest const functions.
126 nw="$nw -Wunsuffixed-float-constants" # Don't care about these.
128 gl_MANYWARN_ALL_GCC([ws])
129 gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
133 gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
134 gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
135 gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
137 # In spite of excluding -Wlogical-op above, it is enabled, as of
138 # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
139 gl_WARN_ADD([-Wno-logical-op])
141 # Work around warning in src/inspect.c. This seems to be a bug in gcc 4.5.1.
142 gl_WARN_ADD([-Wno-strict-overflow])
144 gl_WARN_ADD([-fdiagnostics-show-option])
146 AC_SUBST([WARN_CFLAGS])
148 AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
149 AC_DEFINE([_FORTIFY_SOURCE], [2],
150 [enable compile-time and run-time bounds-checking, and some warnings])
151 AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
155 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
159 dnl Work out how to specify the linker script to the linker.
160 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
161 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
162 VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
163 AC_SUBST(VERSION_SCRIPT_FLAGS)
165 dnl Check support for 64 bit file offsets.
168 dnl Check sizeof long.
169 AC_CHECK_SIZEOF([long])
171 dnl Check if dirent (readdir) supports d_type member.
172 AC_STRUCT_DIRENT_D_TYPE
174 dnl Check if stat has the required fields.
176 AC_CHECK_MEMBER([struct stat.st_blksize],[
177 AC_DEFINE([HAVE_STRUCT_STAT_ST_BLKSIZE],[1],[Define to 1 if 'st_blksize' is a member of 'struct stat'])])
179 dnl Define a C symbol for the host CPU architecture.
180 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
222 dnl For modified printf in the daemon, we need glibc either (old-style)
223 dnl register_printf_function or (new-style) register_printf_specifier.
224 AC_CHECK_FUNC([register_printf_specifier],[
225 AC_DEFINE([HAVE_REGISTER_PRINTF_SPECIFIER],[1],
226 [Define to 1 if you have new-style register_printf_specifier])
228 AC_CHECK_FUNC([register_printf_function],[
229 AC_DEFINE([HAVE_REGISTER_PRINTF_FUNCTION],[1],
230 [Define to 1 if you have old-style register_printf_function])
233 [No support for glibc-style extended printf formatters.
235 This means you either have a very old glibc (pre-2.0) or you
236 are using some other libc where this is not supported.])])])
238 dnl Build the daemon?
239 AC_MSG_CHECKING([if we should build the daemon])
240 AC_ARG_ENABLE([daemon],
241 [AS_HELP_STRING([--enable-daemon],
242 [enable building the daemon @<:@default=yes@:>@])],
245 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
246 AC_MSG_RESULT([$enable_daemon])
248 if test "x$enable_daemon" = "xyes"; then
249 dnl Install the daemon (for libguestfs live service)
250 AC_MSG_CHECKING([if we should install the daemon])
251 AC_ARG_ENABLE([install-daemon],
252 [AS_HELP_STRING([--enable-install-daemon],
253 [enable installing the daemon under $sbindir @<:@default=no@:>@])],
255 [enable_install_daemon=no])
256 AM_CONDITIONAL([INSTALL_DAEMON],[test "x$enable_install_daemon" = "xyes"])
257 AC_MSG_RESULT([$enable_install_daemon])
260 dnl Build the appliance?
261 AC_MSG_CHECKING([if we should build the appliance])
262 AC_ARG_ENABLE([appliance],
263 [AS_HELP_STRING([--enable-appliance],
264 [enable building the appliance @<:@default=yes@:>@])],
266 [enable_appliance=yes])
267 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
268 AC_MSG_RESULT([$enable_appliance])
270 if test "x$enable_appliance" = "xyes"; then
271 dnl Check for febootstrap >= 3.0
272 AC_CHECK_PROG([FEBOOTSTRAP],
273 [febootstrap],[febootstrap],[no])
274 test "x$FEBOOTSTRAP" = "xno" &&
275 AC_MSG_ERROR([febootstrap must be installed])
276 dnl febootstrap 2.x did not support the --version parameter
277 $FEBOOTSTRAP --version >&AS_MESSAGE_LOG_FD 2>&1 ||
278 AC_MSG_ERROR([febootstrap >= 3.0 must be installed, your version is too old])
280 dnl Pass a febootstrap --yum-config option.
281 AC_MSG_CHECKING([if user requested febootstrap --yum-config option])
282 AC_ARG_WITH([febootstrap-yum-config],
283 [AS_HELP_STRING([--with-febootstrap-yum-config=FILE],
284 [pass febootstrap --yum-config option @<:@default=no@:>@])],
285 [FEBOOTSTRAP_YUM_CONFIG="$withval"],
286 [FEBOOTSTRAP_YUM_CONFIG=no])
287 AC_MSG_RESULT([$FEBOOTSTRAP_YUM_CONFIG])
288 AC_SUBST([FEBOOTSTRAP_YUM_CONFIG])
292 dnl This used to be Very Important but is now just used to select
293 dnl which packages to install in the appliance, since the package
294 dnl names vary slightly across distros. (See
295 dnl appliance/packagelist.in and appliance/excludelist.in)
296 AC_MSG_CHECKING([which Linux distro for package names])
298 if test -f /etc/debian_version; then
300 if grep -q 'DISTRIB_ID=Ubuntu' /etc/lsb-release 2>&AS_MESSAGE_LOG_FD; then
304 if test -f /etc/arch-release; then
307 AC_MSG_RESULT([$DISTRO])
311 dnl Check for rpcgen and XDR library. rpcgen is optional.
312 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
313 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
314 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
315 AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
318 dnl Check for Augeas (optional).
319 PKG_CHECK_MODULES([AUGEAS], [augeas],
320 [AC_SUBST([AUGEAS_CFLAGS])
321 AC_SUBST([AUGEAS_LIBS])
322 AC_DEFINE([HAVE_AUGEAS],[1],[Define to 1 if you have Augeas])
325 LIBS="$LIBS $AUGEAS_LIBS"
326 dnl Check for functions not available in earlier versions of Augeas.
327 AC_CHECK_FUNCS([aug_load aug_defvar aug_defnode])
330 [AC_MSG_WARN([augeas not found, some core features will be disabled])])
332 dnl Check for libselinux (optional).
333 AC_CHECK_HEADERS([selinux/selinux.h])
334 AC_CHECK_LIB([selinux],[setexeccon],[
335 have_libselinux="$ac_cv_header_selinux_selinux_h"
336 SELINUX_LIB="-lselinux"
339 LIBS="$LIBS $SELINUX_LIB"
340 AC_CHECK_FUNCS([setcon getcon])
343 ],[have_libselinux=no])
344 if test "x$have_libselinux" = "xyes"; then
345 AC_DEFINE([HAVE_LIBSELINUX],[1],[Define to 1 if you have libselinux])
347 AC_SUBST([SELINUX_LIB])
349 dnl Check for systemtap/DTrace userspace probes (optional).
350 dnl http://sourceware.org/systemtap/wiki/AddingUserSpaceProbingToApps
351 AC_CHECK_HEADERS([sys/sdt.h])
352 dnl AC_CHECK_PROG([DTRACE],[dtrace],[dtrace],[no])
354 dnl Check for cpio which isn't in the default Pardus install amazingly.
355 AC_CHECK_PROG([CPIO],[cpio],[cpio],[no])
356 test "x$CPIO" = "xno" &&
357 AC_MSG_ERROR([cpio must be installed])
360 AC_CHECK_PROG([GPERF],[gperf],[gperf],[no])
361 test "x$GPERF" = "xno" &&
362 AC_MSG_ERROR([gperf must be installed])
364 dnl Check for pod2man, pod2text, pod2html.
365 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
366 test "x$POD2MAN" = "xno" &&
367 AC_MSG_ERROR([pod2man must be installed])
368 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
369 test "x$POD2TEXT" = "xno" &&
370 AC_MSG_ERROR([pod2text must be installed])
371 AC_CHECK_PROG([POD2HTML],[pod2html],[pod2html],[no])
372 test "x$POD2HTML" = "xno" &&
373 AC_MSG_ERROR([pod2html must be installed])
375 dnl Check if pod2man, pod2text take --stderr and -u options (not in RHEL 5).
376 AC_MSG_CHECKING([if pod2man takes --stderr option])
377 if "$POD2MAN" --stderr >&AS_MESSAGE_LOG_FD 2>&1; then
379 POD2_STDERR_OPTION="--stderr"
382 POD2_STDERR_OPTION=""
384 AC_SUBST([POD2_STDERR_OPTION])
386 AC_MSG_CHECKING([if pod2man takes -u option])
387 if "$POD2MAN" -u >&AS_MESSAGE_LOG_FD 2>&1; then
389 POD2_UTF8_OPTION="-u"
394 AC_SUBST([POD2_UTF8_OPTION])
396 dnl Check for genisoimage.
397 AC_PATH_PROGS([GENISOIMAGE],[genisoimage],[no],
398 [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
399 test "x$GENISOIMAGE" = "xno" && AC_MSG_ERROR([genisoimage must be installed])
401 dnl Check for optional xmllint.
402 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
403 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
405 dnl po4a for translating man pages and POD files (optional).
406 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
407 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
409 dnl Check for db_dump, db_load (optional).
410 AC_CHECK_PROGS([DB_DUMP],
411 [db_dump db4_dump db4.8_dump db4.7_dump db4.6_dump],[no])
412 AC_CHECK_PROGS([DB_LOAD],
413 [db_load db4_load db4.8_load db4.7_load db4.6_load],[no])
414 if test "x$DB_DUMP" != "xno"; then
415 AC_DEFINE_UNQUOTED([DB_DUMP],["$DB_DUMP"],[Name of db_dump program.])
417 if test "x$DB_LOAD" != "xno"; then
418 AC_DEFINE_UNQUOTED([DB_LOAD],["$DB_LOAD"],[Name of db_load program.])
421 dnl Check for QEMU for running binaries on this $host_cpu, fall
422 dnl back to basic 'qemu'. Allow the user to override it.
423 default_qemu="qemu-kvm kvm qemu-system-$host_cpu qemu"
425 [AS_HELP_STRING([--with-qemu],
426 [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
428 [with_qemu="$default_qemu"])
429 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
430 [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
431 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
432 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
434 dnl Check that the chosen qemu has virtio-serial support.
435 if test "x$vmchannel_test" != "xno"; then
436 AC_MSG_CHECKING([that $QEMU -help works])
437 if $QEMU -help >&AS_MESSAGE_LOG_FD 2>&1; then
442 [$QEMU -help: command failed.
444 This could be a very old version of qemu, or qemu might not be
449 dnl qemu 0.15 was released with broken support for '-machine',
450 dnl requiring you to add the machine type: '-machine pc,[...]'.
451 dnl The problem is that 'pc' is only applicable for PC-like
452 dnl hardware, so we cannot do this as a general solution. Since
453 dnl qemu 0.15, this problem has been fixed so now the default
454 dnl machine type is chosen (qemu commit 2645c6dcaf6ea2a51a).
456 dnl We need to work out if this qemu is the broken version, so we
457 dnl can add 'pc' just for this broken version.
459 dnl Note that old qemu didn't support the '-machine' option at all.
461 dnl We use the -kernel option for testing this, because this option
462 dnl is processed very late, after qemu has set up the machine.
463 AC_MSG_CHECKING([for broken '-machine accel=tcg' option in $QEMU])
464 LC_ALL=C $QEMU -nographic -machine accel=tcg -kernel /NO_SUCH_FILE \
466 LC_ALL=C $QEMU -nographic -machine pc,accel=tcg -kernel /NO_SUCH_FILE \
468 if cmp -s config1.tmp config2.tmp; then
472 AC_DEFINE([QEMU_MACHINE_TYPE_IS_BROKEN],[1],[qemu -machine accel=tcg option is broken (in qemu 0.15 only)])
474 rm config1.tmp config2.tmp
476 dnl See if the '-machine [pc,]accel=tcg' option is required in
477 dnl order to run the virtio-serial test below. This happens when
478 dnl we run qemu-kvm inside a VM without forcing TCG:
480 dnl Could not access KVM kernel module: No such file or directory
481 dnl failed to initialize KVM: No such file or directory
482 dnl No accelerator found!
483 AC_MSG_CHECKING([if -machine @<:@pc,@:>@accel=tcg option is required to test virtio-serial feature])
484 if $QEMU -nographic -device \? >/dev/null 2>&1; then
486 elif $QEMU -machine accel=tcg -nographic -device \? >/dev/null 2>&1; then
487 QEMU_EXTRA_OPTIONS_FOR_TEST="-machine accel=tcg"
488 elif $QEMU -machine pc,accel=tcg -nographic -device \? >/dev/null 2>&1; then
489 QEMU_EXTRA_OPTIONS_FOR_TEST="-machine pc,accel=tcg"
490 # else nothing ... it'll fail below.
492 AC_MSG_RESULT([$QEMU_EXTRA_OPTIONS_FOR_TEST])
494 AC_MSG_CHECKING([for virtio-serial support in $QEMU])
495 if $QEMU $QEMU_EXTRA_OPTIONS_FOR_TEST -nographic -device \? 2>&1 | grep -sq virtio-serial; then
500 [I did not find virtio-serial support in
503 virtio-serial support in qemu or KVM is essential for libguestfs
506 Usually this means that you have to install a newer version of qemu
507 and/or KVM. Please read the relevant section in the README file for
508 more information about this.
510 You can override this test by setting the environment variable
511 vmchannel_test=no However if you don't have the right support
512 in your qemu, then this just delays the pain.
514 If I am using the wrong qemu or you want to compile qemu from source
515 and install it in another location, then you should configure with
516 the --with-qemu option.
521 dnl Set default drive interface used by the guestfs_add_drive_opts call
522 dnl ('-drive ...,if=...' option to qemu).
524 dnl If you encounter performance problems with virtio (RHBZ#509383)
525 dnl then try '--with-drive-if=ide'.
526 AC_ARG_WITH([drive-if],
527 [AS_HELP_STRING([--with-drive-if],
528 [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
530 [with_drive_if=virtio])
531 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
533 dnl Set interface used by the network. Normally you should
534 dnl leave this at the default (virtio-net-pci) but you can use the
535 dnl alternative (ne2k_pci) because of bugs in virtio networking
536 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
537 AC_ARG_WITH([net-if],
538 [AS_HELP_STRING([--with-net-if],
539 [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
541 [with_net_if=virtio-net-pci])
542 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
544 dnl Enable packet dumps when in verbose mode. This generates lots
545 dnl of debug info, only useful for people debugging the RPC mechanism.
546 AC_ARG_ENABLE([packet-dump],
547 [AS_HELP_STRING([--enable-packet-dump],
548 [enable packet dumps in verbose mode @<:@default=no@:>@])],
549 [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
553 AC_ARG_WITH([readline],
554 [AS_HELP_STRING([--with-readline],
555 [support fancy command line editing @<:@default=check@:>@])],
557 [with_readline=check])
560 AS_IF([test "x$with_readline" != xno],
561 [AC_CHECK_LIB([readline], [main],
562 [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
563 AC_DEFINE([HAVE_LIBREADLINE], [1],
564 [Define if you have libreadline])
566 [if test "x$with_readline" != xcheck; then
568 [--with-readline was given, but test for readline failed])
572 LIBS="$LIBS $LIBREADLINE"
573 AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
578 AM_GNU_GETTEXT([external])
580 dnl Check for PCRE (required)
581 PKG_CHECK_MODULES([PCRE], [libpcre])
583 dnl libmagic (highly recommended)
584 AC_CHECK_LIB([magic],[magic_file],
585 [AC_CHECK_HEADER([magic.h],
586 [AC_SUBST([MAGIC_LIBS], ["-lmagic"])
587 AC_DEFINE([HAVE_LIBMAGIC],[1],[libmagic found at compile time.])
590 [AC_MSG_WARN([libmagic not found, some core features will be disabled])])
592 dnl libvirt (highly recommended)
593 PKG_CHECK_MODULES([LIBVIRT], [libvirt],
594 [AC_SUBST([LIBVIRT_CFLAGS])
595 AC_SUBST([LIBVIRT_LIBS])
596 AC_DEFINE([HAVE_LIBVIRT],[1],[libvirt found at compile time.])
598 [AC_MSG_WARN([libvirt not found, some core features will be disabled])])
599 AM_CONDITIONAL([HAVE_LIBVIRT],[test "x$LIBVIRT_LIBS" != "x"])
601 dnl libxml2 (highly recommended)
602 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0],
603 [AC_SUBST([LIBXML2_CFLAGS])
604 AC_SUBST([LIBXML2_LIBS])
605 AC_DEFINE([HAVE_LIBXML2],[1],[libxml2 found at compile time.])
607 [AC_MSG_WARN([libxml2 not found, some core features will be disabled])])
608 AM_CONDITIONAL([HAVE_LIBXML2],[test "x$LIBXML2_LIBS" != "x"])
610 dnl libconfig (highly recommended)
611 PKG_CHECK_MODULES([LIBCONFIG], [libconfig],
612 [AC_SUBST([LIBCONFIG_CFLAGS])
613 AC_SUBST([LIBCONFIG_LIBS])
614 AC_DEFINE([HAVE_LIBCONFIG],[1],[libconfig found at compile time.])
616 [AC_MSG_WARN([libconfig not found, some features will be disabled])])
617 AM_CONDITIONAL([HAVE_LIBCONFIG],[test "x$LIBCONFIG_LIBS" != "x"])
619 dnl hivex library (highly recommended)
620 dnl This used to be a part of libguestfs, but was spun off into its
621 dnl own separate upstream project in libguestfs 1.0.85.
622 PKG_CHECK_MODULES([HIVEX], [hivex],
623 [AC_SUBST([HIVEX_CFLAGS])
624 AC_SUBST([HIVEX_LIBS])
625 AC_DEFINE([HAVE_HIVEX],[1],[hivex library found at compile time.])
627 [AC_MSG_WARN([hivex not found, some core features will be disabled])])
628 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HIVEX_LIBS" != "x"])
630 dnl FUSE is optional to build the FUSE module.
631 AC_ARG_ENABLE([fuse],
632 AS_HELP_STRING([--disable-fuse], [Disable FUSE (guestmount) support]),
635 AS_IF([test "x$enable_fuse" != "xno"],
636 [PKG_CHECK_MODULES([FUSE],[fuse],,[
638 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])])
639 AM_CONDITIONAL([HAVE_FUSE],[test "x$enable_fuse" != "xno"])
641 dnl Check for OCaml (optional, for OCaml bindings).
644 AC_ARG_ENABLE([ocaml],
645 AS_HELP_STRING([--disable-ocaml], [Disable OCaml language bindings]),
648 AS_IF([test "x$enable_ocaml" != "xno"],
649 [dnl OCAMLC and OCAMLFIND have to be unset first, otherwise
650 dnl AC_CHECK_TOOL (inside AC_PROG_OCAML) will not look.
656 AM_CONDITIONAL([HAVE_OCAML],
657 [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
658 AM_CONDITIONAL([HAVE_OCAMLDOC],
659 [test "x$OCAMLDOC" != "xno"])
661 dnl Check for Perl (optional, for Perl bindings).
663 AC_ARG_ENABLE([perl],
664 AS_HELP_STRING([--disable-perl], [Disable Perl language bindings]),
667 AS_IF([test "x$enable_perl" != "xno"],
670 AC_CHECK_PROG([PERL],[perl],[perl],[no])
672 dnl Check for Perl modules that must be present to compile and
673 dnl test the Perl bindings.
674 missing_perl_modules=no
675 for pm in Test::More ExtUtils::MakeMaker; do
676 AC_MSG_CHECKING([for $pm])
677 if ! perl -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
679 missing_perl_modules=yes
684 if test "x$missing_perl_modules" = "xyes"; then
685 AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
688 AM_CONDITIONAL([HAVE_PERL],
689 [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
691 dnl Check for Python (optional, for Python bindings).
697 AC_ARG_ENABLE([python],
698 AS_HELP_STRING([--disable-python], [Disable Python language bindings]),
701 AS_IF([test "x$enable_python" != "xno"],
703 AC_CHECK_PROG([PYTHON],[python],[python],[no])
705 if test "x$PYTHON" != "xno"; then
706 AC_MSG_CHECKING([Python prefix])
707 PYTHON_PREFIX=`$PYTHON -c "import sys; print (sys.prefix)"`
708 AC_MSG_RESULT([$PYTHON_PREFIX])
710 AC_MSG_CHECKING([Python version])
711 PYTHON_VERSION_MAJOR=`$PYTHON -c "import sys; print (sys.version_info@<:@0@:>@)"`
712 PYTHON_VERSION_MINOR=`$PYTHON -c "import sys; print (sys.version_info@<:@1@:>@)"`
713 PYTHON_VERSION="$PYTHON_VERSION_MAJOR.$PYTHON_VERSION_MINOR"
714 AC_MSG_RESULT([$PYTHON_VERSION])
716 AC_MSG_CHECKING([for Python include path])
717 if test -z "$PYTHON_INCLUDEDIR"; then
718 python_path=`$PYTHON -c "import distutils.sysconfig; \
719 print (distutils.sysconfig.get_python_inc ());"`
720 PYTHON_INCLUDEDIR=$python_path
722 AC_MSG_RESULT([$PYTHON_INCLUDEDIR])
724 AC_ARG_WITH([python-installdir],
725 [AS_HELP_STRING([--with-python-installdir],
726 [directory to install python modules @<:@default=check@:>@])],
727 [PYTHON_INSTALLDIR="$withval"
728 AC_MSG_NOTICE([Python install dir $PYTHON_INSTALLDIR])],
729 [PYTHON_INSTALLDIR=check])
731 if test "x$PYTHON_INSTALLDIR" = "xcheck"; then
733 AC_MSG_CHECKING([for Python site-packages path])
734 if test -z "$PYTHON_INSTALLDIR"; then
735 PYTHON_INSTALLDIR=`$PYTHON -c "import distutils.sysconfig; \
736 print (distutils.sysconfig.get_python_lib(1,0));"`
738 AC_MSG_RESULT([$PYTHON_INSTALLDIR])
741 dnl Look for libpython and some optional symbols in it.
743 if test "x$PYTHON_VERSION_MAJOR" = "x3"; then
744 dnl libpython3 is called "libpython3.Xmu.so"
745 LIBPYTHON="python${PYTHON_VERSION}mu"
747 LIBPYTHON="python$PYTHON_VERSION"
749 AC_CHECK_LIB([$LIBPYTHON], [PyList_Size], [],
750 [AC_MSG_FAILURE([$LIBPYTHON is not installed])])
752 AC_CHECK_FUNCS([PyCapsule_New \
757 AC_SUBST(PYTHON_PREFIX)
758 AC_SUBST(PYTHON_VERSION)
759 AC_SUBST(PYTHON_INCLUDEDIR)
760 AC_SUBST(PYTHON_INSTALLDIR)
762 AM_CONDITIONAL([HAVE_PYTHON],
763 [test "x$PYTHON" != "xno" && test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_INSTALLDIR" != "x"])
765 dnl Check for Ruby and rake (optional, for Ruby bindings).
766 AC_ARG_ENABLE([ruby],
767 AS_HELP_STRING([--disable-ruby], [Disable Ruby language bindings]),
770 AS_IF([test "x$enable_ruby" != "xno"],
772 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
773 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
775 AM_CONDITIONAL([HAVE_RUBY],
776 [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
779 AC_ARG_WITH(java_home,
780 [AS_HELP_STRING([--with-java-home],
781 [specify path to JDK directory @<:@default=check@:>@])],
783 [with_java_home=check])
785 if test "x$with_java_home" != "xno"; then
786 if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
788 # Reject unsafe characters in $JAVA_HOME
792 *[\\\"\#\$\&\'\`$jh_lf\ \ ]*)
793 AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
795 if test -d "$with_java_home"; then
796 JAVA_HOME="$with_java_home"
798 AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
802 if test "x$JAVA_HOME" = "x"; then
803 # Look for Java in some likely locations.
806 /usr/lib/jvm/java-6-openjdk
808 if test -d $d && test -f $d/bin/java; then
815 if test "x$JAVA_HOME" != "x"; then
816 AC_MSG_CHECKING(for JDK in $JAVA_HOME)
817 if test ! -x "$JAVA_HOME/bin/java"; then
818 AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
820 JAVA="$JAVA_HOME/bin/java"
822 if test ! -x "$JAVA_HOME/bin/javac"; then
823 AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
825 JAVAC="$JAVA_HOME/bin/javac"
827 if test ! -x "$JAVA_HOME/bin/javah"; then
828 AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
830 JAVAH="$JAVA_HOME/bin/javah"
832 if test ! -x "$JAVA_HOME/bin/javadoc"; then
833 AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
835 JAVADOC="$JAVA_HOME/bin/javadoc"
837 if test ! -x "$JAVA_HOME/bin/jar"; then
838 AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
840 JAR="$JAVA_HOME/bin/jar"
842 java_version=`$JAVA -version 2>&1 | grep "java version"`
843 AC_MSG_RESULT(found $java_version in $JAVA_HOME)
846 AC_MSG_CHECKING([for jni.h])
847 if test -f "$JAVA_HOME/include/jni.h"; then
848 JNI_CFLAGS="-I$JAVA_HOME/include"
850 if test "`find $JAVA_HOME -name jni.h`" != ""; then
851 head=`find $JAVA_HOME -name jni.h | tail -1`
852 dir=`dirname "$head"`
855 AC_MSG_FAILURE([missing jni.h header file])
858 AC_MSG_RESULT([$JNI_CFLAGS])
861 AC_MSG_CHECKING([for jni_md.h])
863 *linux*) system="linux" ;;
864 *SunOS*) system="solaris" ;;
865 *cygwin*) system="win32" ;;
866 *) system="$build_os" ;;
868 if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
869 JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
871 if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
872 head=`find $JAVA_HOME -name jni_md.h | tail -1`
873 dir=`dirname "$head"`
874 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
876 AC_MSG_FAILURE([missing jni_md.h header file])
879 AC_MSG_RESULT([$JNI_CFLAGS])
881 dnl Need extra version flag?
882 AC_MSG_CHECKING([extra javac flags])
884 javac_version=`$JAVAC -version 2>&1`
885 case "$javac_version" in
887 JAVAC_FLAGS="-source 1.5" ;;
889 AC_MSG_RESULT([$JAVAC_FLAGS])
891 dnl Where to install jarfiles.
892 dnl XXX How to make it configurable?
893 JAR_INSTALL_DIR=\${prefix}/share/java
894 JNI_INSTALL_DIR=\${libdir}
897 jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
898 jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
899 jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
900 JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
911 AC_SUBST(JAVAC_FLAGS)
912 AC_SUBST(JAR_INSTALL_DIR)
913 AC_SUBST(JNI_INSTALL_DIR)
914 AC_SUBST(JNI_VERSION_INFO)
916 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
918 dnl Check for Haskell (GHC).
920 AC_ARG_ENABLE([haskell],
921 AS_HELP_STRING([--disable-haskell], [Disable Haskell language bindings]),
923 [enable_haskell=yes])
924 AS_IF([test "x$enable_haskell" != "xno"],
927 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
929 AM_CONDITIONAL([HAVE_HASKELL],
930 [test "x$GHC" != "xno"])
935 AS_HELP_STRING([--disable-php], [Disable PHP language bindings]),
938 AS_IF([test "x$enable_php" != "xno"],
941 AC_CHECK_PROG([PHP],[php],[php],[no])
942 AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
944 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
948 AC_ARG_ENABLE([erlang],
949 AS_HELP_STRING([--disable-erlang], [Disable Erlang language bindings]),
952 # NB: Don't use AS_IF here: it doesn't work.
953 if test "x$enable_erlang" != "xno"; then
955 AC_ERLANG_PATH_ERLC([no])
957 if test "x$ERLC" != "xno"; then
958 AC_ERLANG_CHECK_LIB([erl_interface], [],
959 [AC_MSG_FAILURE([Erlang erl_interface library not installed. Use --disable-erlang to disable.])])
960 AC_ERLANG_SUBST_LIB_DIR
963 AM_CONDITIONAL([HAVE_ERLANG], [test "x$ERLANG" != "xno" && test "x$ERLC" != "xno"])
965 dnl Check for Perl modules needed by Perl virt tools (virt-df, etc.)
966 AS_IF([test "x$PERL" != "xno"],
968 missing_perl_modules=no
969 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper Locale::TextDomain Win::Hivex Win::Hivex::Regedit String::ShellQuote; do
970 AC_MSG_CHECKING([for $pm])
971 if ! $PERL -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
973 missing_perl_modules=yes
978 if test "x$missing_perl_modules" = "xyes"; then
979 AC_MSG_WARN([some Perl modules required to compile the Perl virt-* tools are missing])
983 AM_CONDITIONAL([HAVE_TOOLS],
984 [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
986 dnl Library versioning.
987 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
988 AC_SUBST(MAX_PROC_NR)
990 dnl Replace libtool with a wrapper that clobbers dependency_libs in *.la files
991 dnl http://lists.fedoraproject.org/pipermail/devel/2010-November/146343.html
992 LIBTOOL='bash $(top_srcdir)/libtool-kill-dependency_libs.sh $(top_builddir)/libtool'
995 dnl Produce output files.
996 AC_CONFIG_HEADERS([config.h])
997 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
998 AC_CONFIG_FILES([clone/virt-sysprep],
999 [chmod +x clone/virt-sysprep])
1000 AC_CONFIG_FILES([podwrapper.sh],
1001 [chmod +x podwrapper.sh])
1002 AC_CONFIG_FILES([run],
1004 AC_CONFIG_FILES([Makefile
1017 erlang/examples/Makefile
1024 gnulib/tests/Makefile
1029 java/examples/Makefile
1033 ocaml/examples/Makefile
1036 perl/examples/Makefile
1043 python/examples/Makefile
1044 regressions/Makefile
1049 ruby/examples/Makefile
1056 dnl Produce summary.
1059 echo "------------------------------------------------------------"
1060 echo "Thank you for downloading $PACKAGE_STRING"
1062 echo "This is how we have configured the optional components for you today:"
1064 echo "Daemon .............................. $enable_daemon"
1065 echo "Appliance ........................... $enable_appliance"
1066 echo "QEMU ................................ $QEMU"
1067 echo -n "OCaml bindings ...................... "
1068 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1069 echo -n "Perl bindings ....................... "
1070 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1071 echo -n "Python bindings ..................... "
1072 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1073 echo -n "Ruby bindings ....................... "
1074 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1075 echo -n "Java bindings ....................... "
1076 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1077 echo -n "Haskell bindings .................... "
1078 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1079 echo -n "PHP bindings ........................ "
1080 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1081 echo -n "Erlang bindings ..................... "
1082 if test "x$HAVE_ERLANG_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1083 echo "guestfish and C virt tools .......... yes"
1084 echo -n "Perl virt tools ..................... "
1085 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1086 echo -n "virt-resize ......................... "
1087 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1088 echo "FUSE filesystem ..................... $enable_fuse"
1090 echo "If any optional component is configured 'no' when you expected 'yes'"
1091 echo "then you should check the preceeding messages."
1093 echo "Please report bugs back to the mailing list:"
1094 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
1096 echo "Next you should type 'make' to build the package,"
1097 echo "then 'make check' to run the tests."
1098 echo "------------------------------------------------------------"