configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2011 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # The major, minor, and release fields MUST be numbers.  Packagers can
  19 # add extra information using --with-extra="..." which may be any
  20 # freeform string.
  21 m4_define([libguestfs_major],   [1])
  22 m4_define([libguestfs_minor],   [12])
  23 m4_define([libguestfs_release], [8])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Stable or unstable version?
  35 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  36 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  37             AC_MSG_RESULT([stable])
  38        ],[
  39             AC_MSG_RESULT([unstable])
  40             AC_MSG_NOTICE([
  41 ***
  42 This is a development version of libguestfs. Some APIs may be unstable
  43 until they appear in a stable release of libguestfs (at which point
  44 the C API and ABI is guaranteed to remain stable forever).  For
  45 more information about stable and development branches of libguestfs
  46 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  47 ***])
  48        ])
  49
  50 dnl Extra string, a freeform string defined by packagers.
  51 AC_ARG_WITH([extra],
  52   [AS_HELP_STRING([--with-extra],
  53                   [extra version string (for use by packagers)])],
  54   [libguestfs_extra="$withval"],
  55   [libguestfs_extra=]
  56 )
  57
  58 AC_MSG_NOTICE([libguestfs version libguestfs_major.libguestfs_minor.libguestfs_release$libguestfs_extra])
  59
  60 dnl Split up the version string.
  61 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  62 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  63 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  64 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_EXTRA],["$libguestfs_extra"],[Extra version string])
  65
  66 dnl Early gnulib initialization.
  67 gl_EARLY
  68 gl_INIT
  69
  70 AC_PROG_LIBTOOL
  71
  72 AC_PROG_SED
  73
  74 dnl Check for basic C environment.
  75 AC_PROG_CC_STDC
  76 AC_PROG_INSTALL
  77 AC_PROG_CPP
  78
  79 AC_ARG_ENABLE([gcc-warnings],
  80   [AS_HELP_STRING([--enable-gcc-warnings],
  81                   [turn on lots of GCC warnings (for developers)])],
  82   [case $enableval in
  83      yes|no) ;;
  84      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  85    esac
  86    gl_gcc_warnings=$enableval],
  87   [gl_gcc_warnings=no]
  88 )
  89
  90 if test "$gl_gcc_warnings" = yes; then
  91   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  92   AC_SUBST([WERROR_CFLAGS])
  93
  94   nw=
  95   # This, $nw, is the list of warnings we disable.
  96   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  97   nw="$nw -Waggregate-return"       # anachronistic
  98   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  99   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 100   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 101   nw="$nw -Wcast-qual"              # Too many warnings for now
 102   nw="$nw -Wconversion"             # Too many warnings for now
 103   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 104   nw="$nw -Wsign-conversion"        # Too many warnings for now
 105   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 106   nw="$nw -Wunreachable-code"       # Too many warnings for now
 107   nw="$nw -Wpadded"                 # Our structs are not padded
 108   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 109   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 110   nw="$nw -Wvla"                    # two warnings in mount.c
 111   # things I might fix soon:
 112   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 113   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 114   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 115   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 116                                     # was not possible, safe to ignore
 117   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 118   nw="$nw -Wlong-long"              # Allow long long since it's required
 119                                     # by Python, Ruby and xstrtoll.
 120   nw="$nw -Wstack-protector"        # Don't warn about stack-protector
 121                                     # failures (seen on Ubuntu).
 122   nw="$nw -Wmissing-noreturn"       # Don't warn about missed noreturn funcs
 123                                     # (seen on Ubuntu).
 124
 125   gl_MANYWARN_ALL_GCC([ws])
 126   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 127   for w in $ws; do
 128     gl_WARN_ADD([$w])
 129   done
 130   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 131   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 132   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 133
 134   # In spite of excluding -Wlogical-op above, it is enabled, as of
 135   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 136   gl_WARN_ADD([-Wno-logical-op])
 137
 138   # Work around warning in src/inspect.c.  This seems to be a bug in gcc 4.5.1.
 139   gl_WARN_ADD([-Wno-strict-overflow])
 140
 141   gl_WARN_ADD([-fdiagnostics-show-option])
 142
 143   AC_SUBST([WARN_CFLAGS])
 144
 145   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 146   AC_DEFINE([_FORTIFY_SOURCE], [2],
 147     [enable compile-time and run-time bounds-checking, and some warnings])
 148   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 149 fi
 150
 151 AC_C_PROTOTYPES
 152 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 153
 154 AM_PROG_CC_C_O
 155
 156 dnl Work out how to specify the linker script to the linker.
 157 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 158 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 159     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 160 AC_SUBST(VERSION_SCRIPT_FLAGS)
 161
 162 dnl Check support for 64 bit file offsets.
 163 AC_SYS_LARGEFILE
 164
 165 dnl Check sizeof long.
 166 AC_CHECK_SIZEOF([long])
 167
 168 dnl Define a C symbol for the host CPU architecture.
 169 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 170
 171 dnl Headers.
 172 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 173
 174 dnl Functions.
 175 AC_CHECK_FUNCS([futimens posix_fallocate])
 176
 177 dnl Build the daemon?
 178 AC_MSG_CHECKING([if we should build the daemon])
 179 AC_ARG_ENABLE([daemon],
 180         [AS_HELP_STRING([--enable-daemon],
 181           [enable building the daemon @<:@default=yes@:>@])],
 182         [],
 183         [enable_daemon=yes])
 184 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 185 AC_MSG_RESULT([$enable_daemon])
 186
 187 dnl Build the appliance?
 188 AC_MSG_CHECKING([if we should build the appliance])
 189 AC_ARG_ENABLE([appliance],
 190         [AS_HELP_STRING([--enable-appliance],
 191           [enable building the appliance @<:@default=yes@:>@])],
 192         [],
 193         [enable_appliance=yes])
 194 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 195 AC_MSG_RESULT([$enable_appliance])
 196
 197 if test "x$enable_appliance" = "xyes"; then
 198     dnl Check for febootstrap >= 3.0
 199     AC_CHECK_PROG([FEBOOTSTRAP],
 200                   [febootstrap],[febootstrap],[no])
 201     test "x$FEBOOTSTRAP" = "xno" &&
 202         AC_MSG_ERROR([febootstrap must be installed])
 203     dnl febootstrap 2.x did not support the --version parameter
 204     $FEBOOTSTRAP --version >&AS_MESSAGE_LOG_FD 2>&1 ||
 205         AC_MSG_ERROR([febootstrap >= 3.0 must be installed, your version is too old])
 206
 207     dnl Pass a febootstrap --yum-config option.
 208     AC_MSG_CHECKING([if user requested febootstrap --yum-config option])
 209     AC_ARG_WITH([febootstrap-yum-config],
 210         [AS_HELP_STRING([--with-febootstrap-yum-config=FILE],
 211           [pass febootstrap --yum-config option @<:@default=no@:>@])],
 212         [FEBOOTSTRAP_YUM_CONFIG="$withval"],
 213         [FEBOOTSTRAP_YUM_CONFIG=no])
 214     AC_MSG_RESULT([$FEBOOTSTRAP_YUM_CONFIG])
 215     AC_SUBST([FEBOOTSTRAP_YUM_CONFIG])
 216
 217     dnl Which distro?
 218     dnl
 219     dnl This used to be Very Important but is now just used to select
 220     dnl which packages to install in the appliance, since the package
 221     dnl names vary slightly across distros.  (See
 222     dnl appliance/packagelist.in and appliance/excludelist.in)
 223     AC_MSG_CHECKING([which Linux distro for package names])
 224     DISTRO=REDHAT
 225     if test -f /etc/debian_version; then
 226         DISTRO=DEBIAN
 227         if grep -q 'DISTRIB_ID=Ubuntu' /etc/lsb-release 2>&AS_MESSAGE_LOG_FD; then
 228             DISTRO=UBUNTU
 229         fi
 230     fi
 231     if test -f /etc/arch-release; then
 232         DISTRO=ARCHLINUX
 233     fi
 234     AC_MSG_RESULT([$DISTRO])
 235     AC_SUBST([DISTRO])
 236 fi
 237
 238 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 239 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 240 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 241 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 242         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 243         ])
 244
 245 dnl Check for cpio which isn't in the default Pardus install amazingly.
 246 AC_CHECK_PROG([CPIO],[cpio],[cpio],[no])
 247 test "x$CPIO" = "xno" &&
 248      AC_MSG_ERROR([cpio must be installed])
 249
 250 dnl Check for gperf.
 251 AC_CHECK_PROG([GPERF],[gperf],[gperf],[no])
 252 test "x$GPERF" = "xno" &&
 253      AC_MSG_ERROR([gperf must be installed])
 254
 255 dnl Check for pod2man, pod2text, pod2html.
 256 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 257 test "x$POD2MAN" = "xno" &&
 258      AC_MSG_ERROR([pod2man must be installed])
 259 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 260 test "x$POD2TEXT" = "xno" &&
 261      AC_MSG_ERROR([pod2text must be installed])
 262 AC_CHECK_PROG([POD2HTML],[pod2html],[pod2html],[no])
 263 test "x$POD2HTML" = "xno" &&
 264      AC_MSG_ERROR([pod2html must be installed])
 265
 266 dnl Check if pod2man, pod2text take --stderr and -u options (not in RHEL 5).
 267 AC_MSG_CHECKING([if pod2man takes --stderr option])
 268 if "$POD2MAN" --stderr >&AS_MESSAGE_LOG_FD 2>&1; then
 269     AC_MSG_RESULT([yes])
 270     POD2_STDERR_OPTION="--stderr"
 271 else
 272     AC_MSG_RESULT([no])
 273     POD2_STDERR_OPTION=""
 274 fi
 275 AC_SUBST([POD2_STDERR_OPTION])
 276
 277 AC_MSG_CHECKING([if pod2man takes -u option])
 278 if "$POD2MAN" -u >&AS_MESSAGE_LOG_FD 2>&1; then
 279     AC_MSG_RESULT([yes])
 280     POD2_UTF8_OPTION="-u"
 281 else
 282     AC_MSG_RESULT([no])
 283     POD2_UTF8_OPTION=""
 284 fi
 285 AC_SUBST([POD2_UTF8_OPTION])
 286
 287 dnl Check for genisoimage.
 288 AC_PATH_PROGS([GENISOIMAGE],[genisoimage],[no],
 289         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 290 test "x$GENISOIMAGE" = "xno" && AC_MSG_ERROR([genisoimage must be installed])
 291
 292 dnl Check for optional xmllint.
 293 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 294 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 295
 296 dnl po4a for translating man pages and POD files (optional).
 297 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
 298 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
 299
 300 dnl Check for db_dump, db_load (optional).
 301 AC_CHECK_PROGS([DB_DUMP],
 302                [db_dump db4_dump db4.8_dump db4.7_dump db4.6_dump],[no])
 303 AC_CHECK_PROGS([DB_LOAD],
 304                [db_load db4_load db4.8_load db4.7_load db4.6_load],[no])
 305 if test "x$DB_DUMP" != "xno"; then
 306     AC_DEFINE_UNQUOTED([DB_DUMP],["$DB_DUMP"],[Name of db_dump program.])
 307 fi
 308 if test "x$DB_LOAD" != "xno"; then
 309     AC_DEFINE_UNQUOTED([DB_LOAD],["$DB_LOAD"],[Name of db_load program.])
 310 fi
 311
 312 dnl Check for QEMU for running binaries on this $host_cpu, fall
 313 dnl back to basic 'qemu'.  Allow the user to override it.
 314 default_qemu="qemu-kvm kvm qemu-system-$host_cpu qemu"
 315 AC_ARG_WITH([qemu],
 316         [AS_HELP_STRING([--with-qemu],
 317           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 318         [],
 319         [with_qemu="$default_qemu"])
 320 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 321         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 322 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 323 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 324
 325 dnl Check that the chosen qemu has virtio-serial support.
 326 if test "x$vmchannel_test" != "xno"; then
 327     AC_MSG_CHECKING([that $QEMU -help works])
 328     if $QEMU -help >&AS_MESSAGE_LOG_FD 2>&1; then
 329         AC_MSG_RESULT([yes])
 330     else
 331         AC_MSG_RESULT([no])
 332         AC_MSG_FAILURE(
 333 [$QEMU -help: command failed.
 334
 335 This could be a very old version of qemu, or qemu might not be
 336 working.
 337 ])
 338     fi
 339
 340     dnl qemu 0.15 was released with broken support for '-machine',
 341     dnl requiring you to add the machine type: '-machine pc,[...]'.
 342     dnl The problem is that 'pc' is only applicable for PC-like
 343     dnl hardware, so we cannot do this as a general solution.  Since
 344     dnl qemu 0.15, this problem has been fixed so now the default
 345     dnl machine type is chosen (qemu commit 2645c6dcaf6ea2a51a).
 346     dnl
 347     dnl We need to work out if this qemu is the broken version, so we
 348     dnl can add 'pc' just for this broken version.
 349     dnl
 350     dnl Note that old qemu didn't support the '-machine' option at all.
 351     dnl
 352     dnl We use the -kernel option for testing this, because this option
 353     dnl is processed very late, after qemu has set up the machine.
 354     AC_MSG_CHECKING([for broken '-machine accel=tcg' option in $QEMU])
 355     LC_ALL=C $QEMU -nographic -machine accel=tcg -kernel /NO_SUCH_FILE \
 356              > config1.tmp 2>&1
 357     LC_ALL=C $QEMU -nographic -machine pc,accel=tcg -kernel /NO_SUCH_FILE \
 358              > config2.tmp 2>&1
 359     if cmp -s config1.tmp config2.tmp; then
 360         AC_MSG_RESULT([no])
 361     else
 362         AC_MSG_RESULT([yes])
 363         AC_DEFINE([QEMU_MACHINE_TYPE_IS_BROKEN],[1],[qemu -machine accel=tcg option is broken (in qemu 0.15 only)])
 364     fi
 365     rm config1.tmp config2.tmp
 366
 367     dnl See if the '-machine [pc,]accel=tcg' option is required in
 368     dnl order to run the virtio-serial test below.  This happens when
 369     dnl we run qemu-kvm inside a VM without forcing TCG:
 370     dnl
 371     dnl   Could not access KVM kernel module: No such file or directory
 372     dnl   failed to initialize KVM: No such file or directory
 373     dnl   No accelerator found!
 374     AC_MSG_CHECKING([if -machine @<:@pc,@:>@accel=tcg option is required to test virtio-serial feature])
 375     if $QEMU -nographic -device \? >/dev/null 2>&1; then
 376         :
 377     elif $QEMU -machine accel=tcg -nographic -device \? >/dev/null 2>&1; then
 378         QEMU_EXTRA_OPTIONS_FOR_TEST="-machine accel=tcg"
 379     elif $QEMU -machine pc,accel=tcg -nographic -device \? >/dev/null 2>&1; then
 380         QEMU_EXTRA_OPTIONS_FOR_TEST="-machine pc,accel=tcg"
 381     # else nothing ... it'll fail below.
 382     fi
 383     AC_MSG_RESULT([$QEMU_EXTRA_OPTIONS_FOR_TEST])
 384
 385     AC_MSG_CHECKING([for virtio-serial support in $QEMU])
 386     if $QEMU $QEMU_EXTRA_OPTIONS_FOR_TEST -nographic -device \? 2>&1 | grep -sq virtio-serial; then
 387         AC_MSG_RESULT([yes])
 388     else
 389         AC_MSG_RESULT([no])
 390         AC_MSG_FAILURE(
 391 [I did not find virtio-serial support in
 392 $QEMU.
 393
 394 virtio-serial support in qemu or KVM is essential for libguestfs
 395 to operate.
 396
 397 Usually this means that you have to install a newer version of qemu
 398 and/or KVM.  Please read the relevant section in the README file for
 399 more information about this.
 400
 401 You can override this test by setting the environment variable
 402 vmchannel_test=no  However if you don't have the right support
 403 in your qemu, then this just delays the pain.
 404
 405 If I am using the wrong qemu or you want to compile qemu from source
 406 and install it in another location, then you should configure with
 407 the --with-qemu option.
 408 ])
 409     fi
 410 fi
 411
 412 dnl Set default drive interface used by the guestfs_add_drive_opts call
 413 dnl ('-drive ...,if=...' option to qemu).
 414 dnl
 415 dnl If you encounter performance problems with virtio (RHBZ#509383)
 416 dnl then try '--with-drive-if=ide'.
 417 AC_ARG_WITH([drive-if],
 418         [AS_HELP_STRING([--with-drive-if],
 419           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 420         [],
 421         [with_drive_if=virtio])
 422 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 423
 424 dnl Set interface used by the network.  Normally you should
 425 dnl leave this at the default (virtio-net-pci) but you can use the
 426 dnl alternative (ne2k_pci) because of bugs in virtio networking
 427 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 428 AC_ARG_WITH([net-if],
 429         [AS_HELP_STRING([--with-net-if],
 430           [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
 431         [],
 432         [with_net_if=virtio-net-pci])
 433 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 434
 435 dnl Enable packet dumps when in verbose mode.  This generates lots
 436 dnl of debug info, only useful for people debugging the RPC mechanism.
 437 AC_ARG_ENABLE([packet-dump],
 438         [AS_HELP_STRING([--enable-packet-dump],
 439           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 440         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 441         [])
 442
 443 dnl Readline.
 444 AC_ARG_WITH([readline],
 445     [AS_HELP_STRING([--with-readline],
 446         [support fancy command line editing @<:@default=check@:>@])],
 447     [],
 448     [with_readline=check])
 449
 450 LIBREADLINE=
 451 AS_IF([test "x$with_readline" != xno],
 452     [AC_CHECK_LIB([readline], [main],
 453         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 454          AC_DEFINE([HAVE_LIBREADLINE], [1],
 455                    [Define if you have libreadline])
 456         ],
 457         [if test "x$with_readline" != xcheck; then
 458          AC_MSG_FAILURE(
 459              [--with-readline was given, but test for readline failed])
 460          fi
 461         ], -lncurses)
 462      old_LIBS="$LIBS"
 463      LIBS="$LIBS $LIBREADLINE"
 464      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 465      LIBS="$old_LIBS"
 466     ])
 467
 468 dnl For i18n.
 469 AM_GNU_GETTEXT([external])
 470
 471 dnl Check for PCRE (required)
 472 PKG_CHECK_MODULES([PCRE], [libpcre])
 473
 474 dnl libmagic (highly recommended)
 475 AC_CHECK_LIB([magic],[magic_file],
 476         [AC_CHECK_HEADER([magic.h],
 477                 [AC_SUBST([MAGIC_LIBS], ["-lmagic"])
 478                  AC_DEFINE([HAVE_LIBMAGIC],[1],[libmagic found at compile time.])
 479                 ], [])
 480         ],
 481         [AC_MSG_WARN([libmagic not found, some core features will be disabled])])
 482
 483 dnl libvirt (highly recommended)
 484 PKG_CHECK_MODULES([LIBVIRT], [libvirt],
 485         [AC_SUBST([LIBVIRT_CFLAGS])
 486          AC_SUBST([LIBVIRT_LIBS])
 487          AC_DEFINE([HAVE_LIBVIRT],[1],[libvirt found at compile time.])
 488         ],
 489         [AC_MSG_WARN([libvirt not found, some core features will be disabled])])
 490 AM_CONDITIONAL([HAVE_LIBVIRT],[test "x$LIBVIRT_LIBS" != "x"])
 491
 492 dnl libxml2 (highly recommended)
 493 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0],
 494         [AC_SUBST([LIBXML2_CFLAGS])
 495          AC_SUBST([LIBXML2_LIBS])
 496          AC_DEFINE([HAVE_LIBXML2],[1],[libxml2 found at compile time.])
 497         ],
 498         [AC_MSG_WARN([libxml2 not found, some core features will be disabled])])
 499 AM_CONDITIONAL([HAVE_LIBXML2],[test "x$LIBXML2_LIBS" != "x"])
 500
 501 dnl libconfig (highly recommended)
 502 PKG_CHECK_MODULES([LIBCONFIG], [libconfig],
 503         [AC_SUBST([LIBCONFIG_CFLAGS])
 504          AC_SUBST([LIBCONFIG_LIBS])
 505          AC_DEFINE([HAVE_LIBCONFIG],[1],[libconfig found at compile time.])
 506         ],
 507         [AC_MSG_WARN([libconfig not found, some features will be disabled])])
 508 AM_CONDITIONAL([HAVE_LIBCONFIG],[test "x$LIBCONFIG_LIBS" != "x"])
 509
 510 dnl hivex library (highly recommended)
 511 dnl This used to be a part of libguestfs, but was spun off into its
 512 dnl own separate upstream project in libguestfs 1.0.85.
 513 PKG_CHECK_MODULES([HIVEX], [hivex],
 514         [AC_SUBST([HIVEX_CFLAGS])
 515          AC_SUBST([HIVEX_LIBS])
 516          AC_DEFINE([HAVE_HIVEX],[1],[hivex library found at compile time.])
 517         ],
 518         [AC_MSG_WARN([hivex not found, some core features will be disabled])])
 519 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HIVEX_LIBS" != "x"])
 520
 521 dnl FUSE is optional to build the FUSE module.
 522 AC_ARG_ENABLE([fuse],
 523         AS_HELP_STRING([--disable-fuse], [Disable FUSE (guestmount) support]),
 524         [],
 525         [enable_fuse=yes])
 526 AS_IF([test "x$enable_fuse" != "xno"],
 527         [PKG_CHECK_MODULES([FUSE],[fuse],,[
 528                 enable_fuse=no
 529                 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])])
 530 AM_CONDITIONAL([HAVE_FUSE],[test "x$enable_fuse" != "xno"])
 531
 532 dnl Check for OCaml (optional, for OCaml bindings).
 533 OCAMLC=no
 534 OCAMLFIND=no
 535 AC_ARG_ENABLE([ocaml],
 536         AS_HELP_STRING([--disable-ocaml], [Disable OCaml language bindings]),
 537         [],
 538         [enable_ocaml=yes])
 539 AS_IF([test "x$enable_ocaml" != "xno"],
 540         [dnl OCAMLC and OCAMLFIND have to be unset first, otherwise
 541          dnl AC_CHECK_TOOL (inside AC_PROG_OCAML) will not look.
 542          OCAMLC=
 543          OCAMLFIND=
 544          AC_PROG_OCAML
 545          AC_PROG_FINDLIB
 546
 547          AS_IF([test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"],
 548                 [AC_CHECK_OCAML_PKG([pcre])])
 549         ])
 550 AM_CONDITIONAL([HAVE_OCAML],
 551                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
 552 AM_CONDITIONAL([HAVE_OCAML_PCRE],
 553                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno" && test "x$OCAML_PKG_pcre" != "xno"])
 554 AM_CONDITIONAL([HAVE_OCAMLDOC],
 555                [test "x$OCAMLDOC" != "xno"])
 556
 557 dnl Check for Perl (optional, for Perl bindings).
 558 PERL=no
 559 AC_ARG_ENABLE([perl],
 560         AS_HELP_STRING([--disable-perl], [Disable Perl language bindings]),
 561         [],
 562         [enable_perl=yes])
 563 AS_IF([test "x$enable_perl" != "xno"],
 564         [
 565         PERL=
 566         AC_CHECK_PROG([PERL],[perl],[perl],[no])
 567
 568         dnl Check for Perl modules that must be present to compile and
 569         dnl test the Perl bindings.
 570         missing_perl_modules=no
 571         for pm in Test::More ExtUtils::MakeMaker; do
 572             AC_MSG_CHECKING([for $pm])
 573             if ! perl -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
 574                 AC_MSG_RESULT([no])
 575                 missing_perl_modules=yes
 576             else
 577                 AC_MSG_RESULT([yes])
 578             fi
 579         done
 580         if test "x$missing_perl_modules" = "xyes"; then
 581             AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 582         fi
 583         ])
 584 AM_CONDITIONAL([HAVE_PERL],
 585     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 586
 587 dnl Check for Python (optional, for Python bindings).
 588 PYTHON_PREFIX=
 589 PYTHON_VERSION=
 590 PYTHON_INCLUDEDIR=
 591 PYTHON_INSTALLDIR=
 592
 593 AC_ARG_ENABLE([python],
 594         AS_HELP_STRING([--disable-python], [Disable Python language bindings]),
 595         [],
 596         [enable_python=yes])
 597 AS_IF([test "x$enable_python" != "xno"],
 598         [
 599         AC_CHECK_PROG([PYTHON],[python],[python],[no])
 600
 601         if test "x$PYTHON" != "xno"; then
 602             AC_MSG_CHECKING([Python prefix])
 603             PYTHON_PREFIX=`$PYTHON -c "import sys; print (sys.prefix)"`
 604             AC_MSG_RESULT([$PYTHON_PREFIX])
 605
 606             AC_MSG_CHECKING([Python version])
 607             PYTHON_VERSION=`$PYTHON -c "import sys; print (sys.version[[0:3]])"`
 608             AC_MSG_RESULT([$PYTHON_VERSION])
 609
 610             AC_MSG_CHECKING([for Python include path])
 611             if test -z "$PYTHON_INCLUDEDIR"; then
 612                 python_path=`$PYTHON -c "import distutils.sysconfig; \
 613                                          print (distutils.sysconfig.get_python_inc ());"`
 614                 PYTHON_INCLUDEDIR=$python_path
 615             fi
 616             AC_MSG_RESULT([$PYTHON_INCLUDEDIR])
 617
 618             AC_ARG_WITH([python-installdir],
 619                         [AS_HELP_STRING([--with-python-installdir],
 620                                         [directory to install python modules @<:@default=check@:>@])],
 621                         [PYTHON_INSTALLDIR="$withval"
 622                         AC_MSG_NOTICE([Python install dir $PYTHON_INSTALLDIR])],
 623                         [PYTHON_INSTALLDIR=check])
 624
 625             if test "x$PYTHON_INSTALLDIR" = "xcheck"; then
 626                 PYTHON_INSTALLDIR=
 627                 AC_MSG_CHECKING([for Python site-packages path])
 628                 if test -z "$PYTHON_INSTALLDIR"; then
 629                     PYTHON_INSTALLDIR=`$PYTHON -c "import distutils.sysconfig; \
 630                                                    print (distutils.sysconfig.get_python_lib(1,0));"`
 631                 fi
 632                 AC_MSG_RESULT([$PYTHON_INSTALLDIR])
 633             fi
 634
 635             old_LIBS="$LIBS"
 636             LIBS="$LIBS -lpython$PYTHON_VERSION"
 637             AC_CHECK_FUNCS([PyCapsule_New])
 638             LIBS="$old_LIBS"
 639         fi
 640
 641         AC_SUBST(PYTHON_PREFIX)
 642         AC_SUBST(PYTHON_VERSION)
 643         AC_SUBST(PYTHON_INCLUDEDIR)
 644         AC_SUBST(PYTHON_INSTALLDIR)
 645         ])
 646 AM_CONDITIONAL([HAVE_PYTHON],
 647     [test "x$PYTHON" != "xno" && test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_INSTALLDIR" != "x"])
 648
 649 dnl Check for Ruby and rake (optional, for Ruby bindings).
 650 AC_ARG_ENABLE([ruby],
 651         AS_HELP_STRING([--disable-ruby], [Disable Ruby language bindings]),
 652         [],
 653         [enable_ruby=yes])
 654 AS_IF([test "x$enable_ruby" != "xno"],
 655         [
 656         AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 657         AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 658         ])
 659 AM_CONDITIONAL([HAVE_RUBY],
 660     [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
 661
 662 dnl Check for Java.
 663 AC_ARG_WITH(java_home,
 664     [AS_HELP_STRING([--with-java-home],
 665         [specify path to JDK directory @<:@default=check@:>@])],
 666     [],
 667     [with_java_home=check])
 668
 669 if test "x$with_java_home" != "xno"; then
 670     if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
 671     then
 672         # Reject unsafe characters in $JAVA_HOME
 673         jh_lf='
 674 '
 675         case $JAVA_HOME in
 676           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 677             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 678         esac
 679         if test -d "$with_java_home"; then
 680             JAVA_HOME="$with_java_home"
 681         else
 682             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 683         fi
 684     fi
 685
 686     if test "x$JAVA_HOME" = "x"; then
 687         # Look for Java in some likely locations.
 688         for d in \
 689             /usr/lib/jvm/java \
 690             /usr/lib/jvm/java-6-openjdk
 691         do
 692             if test -d $d && test -f $d/bin/java; then
 693                 JAVA_HOME=$d
 694                 break
 695             fi
 696         done
 697     fi
 698
 699     if test "x$JAVA_HOME" != "x"; then
 700         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 701         if test ! -x "$JAVA_HOME/bin/java"; then
 702             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 703         else
 704             JAVA="$JAVA_HOME/bin/java"
 705         fi
 706         if test ! -x "$JAVA_HOME/bin/javac"; then
 707             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 708         else
 709             JAVAC="$JAVA_HOME/bin/javac"
 710         fi
 711         if test ! -x "$JAVA_HOME/bin/javah"; then
 712             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 713         else
 714             JAVAH="$JAVA_HOME/bin/javah"
 715         fi
 716         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 717             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 718         else
 719             JAVADOC="$JAVA_HOME/bin/javadoc"
 720         fi
 721         if test ! -x "$JAVA_HOME/bin/jar"; then
 722             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 723         else
 724             JAR="$JAVA_HOME/bin/jar"
 725         fi
 726         java_version=`$JAVA -version 2>&1 | grep "java version"`
 727         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 728
 729         dnl Find jni.h.
 730         AC_MSG_CHECKING([for jni.h])
 731         if test -f "$JAVA_HOME/include/jni.h"; then
 732             JNI_CFLAGS="-I$JAVA_HOME/include"
 733         else
 734             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 735                 head=`find $JAVA_HOME -name jni.h | tail -1`
 736                 dir=`dirname "$head"`
 737                 JNI_CFLAGS="-I$dir"
 738             else
 739                 AC_MSG_FAILURE([missing jni.h header file])
 740             fi
 741         fi
 742         AC_MSG_RESULT([$JNI_CFLAGS])
 743
 744         dnl Find jni_md.h.
 745         AC_MSG_CHECKING([for jni_md.h])
 746         case "$build_os" in
 747         *linux*) system="linux" ;;
 748         *SunOS*) system="solaris" ;;
 749         *cygwin*) system="win32" ;;
 750         *) system="$build_os" ;;
 751         esac
 752         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 753             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 754         else
 755             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 756                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 757                 dir=`dirname "$head"`
 758                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 759             else
 760                 AC_MSG_FAILURE([missing jni_md.h header file])
 761             fi
 762         fi
 763         AC_MSG_RESULT([$JNI_CFLAGS])
 764
 765         dnl Need extra version flag?
 766         AC_MSG_CHECKING([extra javac flags])
 767         JAVAC_FLAGS=
 768         javac_version=`$JAVAC -version 2>&1`
 769         case "$javac_version" in
 770         *Eclipse*)
 771             JAVAC_FLAGS="-source 1.5" ;;
 772         esac
 773         AC_MSG_RESULT([$JAVAC_FLAGS])
 774
 775         dnl Where to install jarfiles.
 776         dnl XXX How to make it configurable?
 777         JAR_INSTALL_DIR=\${prefix}/share/java
 778         JNI_INSTALL_DIR=\${libdir}
 779
 780         dnl JNI version.
 781         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 782         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 783         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 784         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 785     fi
 786 fi
 787
 788 AC_SUBST(JAVA_HOME)
 789 AC_SUBST(JAVA)
 790 AC_SUBST(JAVAC)
 791 AC_SUBST(JAVAH)
 792 AC_SUBST(JAVADOC)
 793 AC_SUBST(JAR)
 794 AC_SUBST(JNI_CFLAGS)
 795 AC_SUBST(JAVAC_FLAGS)
 796 AC_SUBST(JAR_INSTALL_DIR)
 797 AC_SUBST(JNI_INSTALL_DIR)
 798 AC_SUBST(JNI_VERSION_INFO)
 799
 800 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 801
 802 dnl Check for Haskell (GHC).
 803 GHC=no
 804 AC_ARG_ENABLE([haskell],
 805         AS_HELP_STRING([--disable-haskell], [Disable Haskell language bindings]),
 806         [],
 807         [enable_haskell=yes])
 808 AS_IF([test "x$enable_haskell" != "xno"],
 809         [
 810         GHC=
 811         AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 812         ])
 813 AM_CONDITIONAL([HAVE_HASKELL],
 814     [test "x$GHC" != "xno"])
 815
 816 dnl PHP
 817 PHP=no
 818 AC_ARG_ENABLE([php],
 819         AS_HELP_STRING([--disable-php], [Disable PHP language bindings]),
 820         [],
 821         [enable_php=yes])
 822 AS_IF([test "x$enable_php" != "xno"],
 823         [
 824         PHP=
 825         AC_CHECK_PROG([PHP],[php],[php],[no])
 826         AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
 827         ])
 828 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
 829
 830 dnl Check for Perl modules needed by Perl virt tools (virt-df, etc.)
 831 AS_IF([test "x$PERL" != "xno"],
 832         [
 833         missing_perl_modules=no
 834         for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper Locale::TextDomain Win::Hivex Win::Hivex::Regedit String::ShellQuote; do
 835             AC_MSG_CHECKING([for $pm])
 836             if ! $PERL -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
 837                 AC_MSG_RESULT([no])
 838                 missing_perl_modules=yes
 839             else
 840                 AC_MSG_RESULT([yes])
 841             fi
 842         done
 843         if test "x$missing_perl_modules" = "xyes"; then
 844             AC_MSG_WARN([some Perl modules required to compile the Perl virt-* tools are missing])
 845         fi
 846         ])
 847
 848 AM_CONDITIONAL([HAVE_TOOLS],
 849     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 850
 851 dnl Library versioning.
 852 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 853 AC_SUBST(MAX_PROC_NR)
 854
 855 dnl Replace libtool with a wrapper that clobbers dependency_libs in *.la files
 856 dnl http://lists.fedoraproject.org/pipermail/devel/2010-November/146343.html
 857 LIBTOOL='bash $(top_srcdir)/libtool-kill-dependency_libs.sh $(top_builddir)/libtool'
 858 AC_SUBST([LIBTOOL])
 859
 860 dnl Run in subdirs.
 861 if test "x$enable_daemon" = "xyes"; then
 862     AC_CONFIG_SUBDIRS([daemon])
 863 fi
 864
 865 dnl Produce output files.
 866 AC_CONFIG_HEADERS([config.h])
 867 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 868 AC_CONFIG_FILES([podwrapper.sh],
 869                 [chmod +x podwrapper.sh])
 870 AC_CONFIG_FILES([run],
 871                 [chmod +x run])
 872 AC_CONFIG_FILES([Makefile
 873                  appliance/Makefile
 874                  capitests/Makefile
 875                  cat/Makefile
 876                  caution/Makefile
 877                  csharp/Makefile
 878                  debian/changelog
 879                  df/Makefile
 880                  edit/Makefile
 881                  examples/Makefile
 882                  fish/Makefile
 883                  fuse/Makefile
 884                  generator/Makefile
 885                  gnulib/lib/Makefile
 886                  gnulib/tests/Makefile
 887                  haskell/Makefile
 888                  images/Makefile
 889                  inspector/Makefile
 890                  java/Makefile
 891                  java/examples/Makefile
 892                  libguestfs.pc
 893                  ocaml/META
 894                  ocaml/Makefile
 895                  ocaml/examples/Makefile
 896                  perl/Makefile
 897                  perl/Makefile.PL
 898                  perl/examples/Makefile
 899                  php/Makefile
 900                  po-docs/Makefile
 901                  po-docs/ja/Makefile
 902                  po-docs/uk/Makefile
 903                  po/Makefile.in
 904                  python/Makefile
 905                  python/examples/Makefile
 906                  regressions/Makefile
 907                  rescue/Makefile
 908                  resize/Makefile
 909                  ruby/Makefile
 910                  ruby/Rakefile
 911                  ruby/examples/Makefile
 912                  src/Makefile
 913                  test-tool/Makefile
 914                  tools/Makefile])
 915 AC_OUTPUT
 916
 917 dnl Produce summary.
 918 echo
 919 echo
 920 echo "------------------------------------------------------------"
 921 echo "Thank you for downloading $PACKAGE_STRING"
 922 echo
 923 echo "This is how we have configured the optional components for you today:"
 924 echo
 925 echo    "Daemon .............................. $enable_daemon"
 926 echo    "Appliance ........................... $enable_appliance"
 927 echo    "QEMU ................................ $QEMU"
 928 echo -n "OCaml bindings ...................... "
 929 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 930 echo -n "Perl bindings ....................... "
 931 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 932 echo -n "Python bindings ..................... "
 933 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 934 echo -n "Ruby bindings ....................... "
 935 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 936 echo -n "Java bindings ....................... "
 937 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 938 echo -n "Haskell bindings .................... "
 939 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 940 echo -n "PHP bindings ........................ "
 941 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 942 echo    "guestfish and C virt tools .......... yes"
 943 echo -n "Perl virt tools ..................... "
 944 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 945 echo -n "virt-resize ......................... "
 946 if test "x$HAVE_OCAML_TRUE" = "x" && test "x$HAVE_OCAML_PCRE_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 947 echo "FUSE filesystem ..................... $enable_fuse"
 948 echo
 949 echo "If any optional component is configured 'no' when you expected 'yes'"
 950 echo "then you should check the preceeding messages."
 951 echo
 952 echo "Please report bugs back to the mailing list:"
 953 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 954 echo
 955 echo "Next you should type 'make' to build the package,"
 956 echo "then 'make check' to run the tests."
 957 echo "------------------------------------------------------------"