configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2011 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [8])
  21 m4_define([libguestfs_release], [14])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 dnl Stable or unstable version?
  41 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  42 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  43             AC_MSG_RESULT([stable])
  44        ],[
  45             AC_MSG_RESULT([unstable])
  46             AC_MSG_NOTICE([
  47 ***
  48 This is a development version of libguestfs. Some APIs may be unstable
  49 until they appear in a stable release of libguestfs (at which point
  50 the C API and ABI is guaranteed to remain stable forever).  For
  51 more information about stable and development branches of libguestfs
  52 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  53 ***])
  54        ])
  55
  56 dnl Early gnulib initialization.
  57 gl_EARLY
  58 gl_INIT
  59
  60 AC_PROG_LIBTOOL
  61
  62 dnl Check for basic C environment.
  63 AC_PROG_CC_STDC
  64 AC_PROG_INSTALL
  65 AC_PROG_CPP
  66
  67 AC_ARG_ENABLE([gcc-warnings],
  68   [AS_HELP_STRING([--enable-gcc-warnings],
  69                   [turn on lots of GCC warnings (for developers)])],
  70   [case $enableval in
  71      yes|no) ;;
  72      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  73    esac
  74    gl_gcc_warnings=$enableval],
  75   [gl_gcc_warnings=no]
  76 )
  77
  78 if test "$gl_gcc_warnings" = yes; then
  79   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  80   AC_SUBST([WERROR_CFLAGS])
  81
  82   nw=
  83   # This, $nw, is the list of warnings we disable.
  84   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  85   nw="$nw -Waggregate-return"       # anachronistic
  86   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  87   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  88   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  89   nw="$nw -Wcast-qual"              # Too many warnings for now
  90   nw="$nw -Wconversion"             # Too many warnings for now
  91   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  92   nw="$nw -Wsign-conversion"        # Too many warnings for now
  93   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  94   nw="$nw -Wunreachable-code"       # Too many warnings for now
  95   nw="$nw -Wpadded"                 # Our structs are not padded
  96   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  97   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  98   nw="$nw -Wvla"                    # two warnings in mount.c
  99   # things I might fix soon:
 100   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 101   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 102   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 103   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 104                                     # was not possible, safe to ignore
 105   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 106   nw="$nw -Wlong-long"              # Allow long long since it's required
 107                                     # by Python, Ruby and xstrtoll.
 108   nw="$nw -Wstack-protector"        # Don't warn about stack-protector
 109                                     # failures (seen on Ubuntu).
 110
 111   gl_MANYWARN_ALL_GCC([ws])
 112   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 113   for w in $ws; do
 114     gl_WARN_ADD([$w])
 115   done
 116   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 117   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 118   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 119
 120   # In spite of excluding -Wlogical-op above, it is enabled, as of
 121   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 122   gl_WARN_ADD([-Wno-logical-op])
 123
 124   # Work around warning in src/inspect.c.  This seems to be a bug in gcc 4.5.1.
 125   gl_WARN_ADD([-Wno-strict-overflow])
 126
 127   gl_WARN_ADD([-fdiagnostics-show-option])
 128
 129   AC_SUBST([WARN_CFLAGS])
 130
 131   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 132   AC_DEFINE([_FORTIFY_SOURCE], [2],
 133     [enable compile-time and run-time bounds-checking, and some warnings])
 134   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 135 fi
 136
 137 AC_C_PROTOTYPES
 138 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 139
 140 AM_PROG_CC_C_O
 141
 142 dnl Work out how to specify the linker script to the linker.
 143 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 144 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 145     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 146 AC_SUBST(VERSION_SCRIPT_FLAGS)
 147
 148 dnl Check support for 64 bit file offsets.
 149 AC_SYS_LARGEFILE
 150
 151 dnl Check sizeof long.
 152 AC_CHECK_SIZEOF([long])
 153
 154 dnl Define a C symbol for the host CPU architecture.
 155 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 156
 157 dnl Headers.
 158 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 159
 160 dnl Functions.
 161 AC_CHECK_FUNCS([futimens posix_fallocate])
 162
 163 dnl Build the daemon?
 164 AC_MSG_CHECKING([if we should build the daemon])
 165 AC_ARG_ENABLE([daemon],
 166         [AS_HELP_STRING([--enable-daemon],
 167           [enable building the daemon @<:@default=yes@:>@])],
 168         [],
 169         [enable_daemon=yes])
 170 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 171 AC_MSG_RESULT([$enable_daemon])
 172
 173 dnl Build the appliance?
 174 AC_MSG_CHECKING([if we should build the appliance])
 175 AC_ARG_ENABLE([appliance],
 176         [AS_HELP_STRING([--enable-appliance],
 177           [enable building the appliance @<:@default=yes@:>@])],
 178         [],
 179         [enable_appliance=yes])
 180 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 181 AC_MSG_RESULT([$enable_appliance])
 182
 183 if test "x$enable_appliance" = "xyes"; then
 184     dnl Check for febootstrap >= 3.0
 185     AC_CHECK_PROG([FEBOOTSTRAP],
 186                   [febootstrap],[febootstrap],[no])
 187     test "x$FEBOOTSTRAP" = "xno" &&
 188         AC_MSG_ERROR([febootstrap must be installed])
 189     dnl febootstrap 2.x did not support the --version parameter
 190     $FEBOOTSTRAP --version >&AS_MESSAGE_LOG_FD 2>&1 ||
 191         AC_MSG_ERROR([febootstrap >= 3.0 must be installed, your version is too old])
 192
 193     dnl Pass a febootstrap --yum-config option.
 194     AC_MSG_CHECKING([if user requested febootstrap --yum-config option])
 195     AC_ARG_WITH([febootstrap-yum-config],
 196         [AS_HELP_STRING([--with-febootstrap-yum-config=FILE],
 197           [pass febootstrap --yum-config option @<:@default=no@:>@])],
 198         [FEBOOTSTRAP_YUM_CONFIG="$withval"],
 199         [FEBOOTSTRAP_YUM_CONFIG=no])
 200     AC_MSG_RESULT([$FEBOOTSTRAP_YUM_CONFIG])
 201     AC_SUBST([FEBOOTSTRAP_YUM_CONFIG])
 202
 203     dnl Which distro?
 204     dnl
 205     dnl This used to be Very Important but is now just used to select
 206     dnl which packages to install in the appliance, since the package
 207     dnl names vary slightly across distros.  (See
 208     dnl appliance/packagelist.in and appliance/excludelist.in)
 209     AC_MSG_CHECKING([which Linux distro for package names])
 210     DISTRO=REDHAT
 211     if test -f /etc/debian_version; then
 212         DISTRO=DEBIAN
 213         if grep -q 'DISTRIB_ID=Ubuntu' /etc/lsb-release 2>&AS_MESSAGE_LOG_FD; then
 214             DISTRO=UBUNTU
 215         fi
 216     fi
 217     if test -f /etc/arch-release; then
 218         DISTRO=ARCHLINUX
 219     fi
 220     AC_MSG_RESULT([$DISTRO])
 221     AC_SUBST([DISTRO])
 222 fi
 223
 224 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 225 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 226 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 227 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 228         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 229         ])
 230
 231 dnl Check for cpio which isn't in the default Pardus install amazingly.
 232 AC_CHECK_PROG([CPIO],[cpio],[cpio],[no])
 233 test "x$CPIO" = "xno" &&
 234      AC_MSG_ERROR([cpio must be installed])
 235
 236 dnl Check for gperf.
 237 AC_CHECK_PROG([GPERF],[gperf],[gperf],[no])
 238 test "x$GPERF" = "xno" &&
 239      AC_MSG_ERROR([gperf must be installed])
 240
 241 dnl Check for pod2man, pod2text, pod2html.
 242 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 243 test "x$POD2MAN" = "xno" &&
 244      AC_MSG_ERROR([pod2man must be installed])
 245 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 246 test "x$POD2TEXT" = "xno" &&
 247      AC_MSG_ERROR([pod2text must be installed])
 248 AC_CHECK_PROG([POD2HTML],[pod2html],[pod2html],[no])
 249 test "x$POD2HTML" = "xno" &&
 250      AC_MSG_ERROR([pod2html must be installed])
 251
 252 dnl Check if pod2man, pod2text take --stderr and -u options (not in RHEL 5).
 253 AC_MSG_CHECKING([if pod2man takes --stderr option])
 254 if "$POD2MAN" --stderr >&AS_MESSAGE_LOG_FD 2>&1; then
 255     AC_MSG_RESULT([yes])
 256     POD2_STDERR_OPTION="--stderr"
 257 else
 258     AC_MSG_RESULT([no])
 259     POD2_STDERR_OPTION=""
 260 fi
 261 AC_SUBST([POD2_STDERR_OPTION])
 262
 263 AC_MSG_CHECKING([if pod2man takes -u option])
 264 if "$POD2MAN" -u >&AS_MESSAGE_LOG_FD 2>&1; then
 265     AC_MSG_RESULT([yes])
 266     POD2_UTF8_OPTION="-u"
 267 else
 268     AC_MSG_RESULT([no])
 269     POD2_UTF8_OPTION=""
 270 fi
 271 AC_SUBST([POD2_UTF8_OPTION])
 272
 273 dnl Check for mkisofs.
 274 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 275         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 276 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 277
 278 dnl Check for optional xmllint.
 279 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 280 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 281
 282 dnl po4a for translating man pages and POD files (optional).
 283 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
 284 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
 285
 286 dnl Check for db_dump, db_load (optional).
 287 AC_CHECK_PROGS([DB_DUMP],
 288                [db_dump db4_dump db4.8_dump db4.7_dump db4.6_dump],[no])
 289 AC_CHECK_PROGS([DB_LOAD],
 290                [db_load db4_load db4.8_load db4.7_load db4.6_load],[no])
 291 if test "x$DB_DUMP" != "xno"; then
 292     AC_DEFINE_UNQUOTED([DB_DUMP],["$DB_DUMP"],[Name of db_dump program.])
 293 fi
 294 if test "x$DB_LOAD" != "xno"; then
 295     AC_DEFINE_UNQUOTED([DB_LOAD],["$DB_LOAD"],[Name of db_load program.])
 296 fi
 297
 298 dnl Check for QEMU for running binaries on this $host_cpu, fall
 299 dnl back to basic 'qemu'.  Allow the user to override it.
 300 default_qemu="qemu-kvm kvm qemu-system-$host_cpu qemu"
 301 AC_ARG_WITH([qemu],
 302         [AS_HELP_STRING([--with-qemu],
 303           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 304         [],
 305         [with_qemu="$default_qemu"])
 306 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 307         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 308 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 309 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 310
 311 dnl Check that the chosen qemu has virtio-serial support.
 312 if test "x$vmchannel_test" != "xno"; then
 313     AC_MSG_CHECKING([that $QEMU -help works])
 314     if $QEMU -help >&AS_MESSAGE_LOG_FD 2>&1; then
 315         AC_MSG_RESULT([yes])
 316     else
 317         AC_MSG_RESULT([no])
 318         AC_MSG_FAILURE(
 319 [$QEMU -help: command failed.
 320
 321 This could be a very old version of qemu, or qemu might not be
 322 working.
 323 ])
 324     fi
 325
 326     dnl qemu 0.15 was released with broken support for '-machine',
 327     dnl requiring you to add the machine type: '-machine pc,[...]'.
 328     dnl The problem is that 'pc' is only applicable for PC-like
 329     dnl hardware, so we cannot do this as a general solution.  Since
 330     dnl qemu 0.15, this problem has been fixed so now the default
 331     dnl machine type is chosen (qemu commit 2645c6dcaf6ea2a51a).
 332     dnl
 333     dnl We need to work out if this qemu is the broken version, so we
 334     dnl can add 'pc' just for this broken version.
 335     dnl
 336     dnl Note that old qemu didn't support the '-machine' option at all.
 337     dnl
 338     dnl We use the -kernel option for testing this, because this option
 339     dnl is processed very late, after qemu has set up the machine.
 340     AC_MSG_CHECKING([for broken '-machine accel=tcg' option in $QEMU])
 341     LC_ALL=C $QEMU -nographic -machine accel=tcg -kernel /NO_SUCH_FILE \
 342              > config1.tmp 2>&1
 343     LC_ALL=C $QEMU -nographic -machine pc,accel=tcg -kernel /NO_SUCH_FILE \
 344              > config2.tmp 2>&1
 345     if cmp -s config1.tmp config2.tmp; then
 346         AC_MSG_RESULT([no])
 347     else
 348         AC_MSG_RESULT([yes])
 349         AC_DEFINE([QEMU_MACHINE_TYPE_IS_BROKEN],[1],[qemu -machine accel=tcg option is broken (in qemu 0.15 only)])
 350     fi
 351     rm config1.tmp config2.tmp
 352
 353     dnl See if the '-machine [pc,]accel=tcg' option is required in
 354     dnl order to run the virtio-serial test below.  This happens when
 355     dnl we run qemu-kvm inside a VM without forcing TCG:
 356     dnl
 357     dnl   Could not access KVM kernel module: No such file or directory
 358     dnl   failed to initialize KVM: No such file or directory
 359     dnl   No accelerator found!
 360     AC_MSG_CHECKING([if -machine @<:@pc,@:>@accel=tcg option is required to test virtio-serial feature])
 361     if $QEMU -nographic -device \? >/dev/null 2>&1; then
 362         :
 363     elif $QEMU -machine accel=tcg -nographic -device \? >/dev/null 2>&1; then
 364         QEMU_EXTRA_OPTIONS_FOR_TEST="-machine accel=tcg"
 365     elif $QEMU -machine pc,accel=tcg -nographic -device \? >/dev/null 2>&1; then
 366         QEMU_EXTRA_OPTIONS_FOR_TEST="-machine pc,accel=tcg"
 367     # else nothing ... it'll fail below.
 368     fi
 369     AC_MSG_RESULT([$QEMU_EXTRA_OPTIONS_FOR_TEST])
 370
 371     AC_MSG_CHECKING([for virtio-serial support in $QEMU])
 372     if $QEMU $QEMU_EXTRA_OPTIONS_FOR_TEST -nographic -device \? 2>&1 | grep -sq virtio-serial; then
 373         AC_MSG_RESULT([yes])
 374     else
 375         AC_MSG_RESULT([no])
 376         AC_MSG_FAILURE(
 377 [I did not find virtio-serial support in
 378 $QEMU.
 379
 380 virtio-serial support in qemu or KVM is essential for libguestfs
 381 to operate.
 382
 383 Usually this means that you have to install a newer version of qemu
 384 and/or KVM.  Please read the relevant section in the README file for
 385 more information about this.
 386
 387 You can override this test by setting the environment variable
 388 vmchannel_test=no  However if you don't have the right support
 389 in your qemu, then this just delays the pain.
 390
 391 If I am using the wrong qemu or you want to compile qemu from source
 392 and install it in another location, then you should configure with
 393 the --with-qemu option.
 394 ])
 395     fi
 396 fi
 397
 398 dnl Set default drive interface used by the guestfs_add_drive_opts call
 399 dnl ('-drive ...,if=...' option to qemu).
 400 dnl
 401 dnl If you encounter performance problems with virtio (RHBZ#509383)
 402 dnl then try '--with-drive-if=ide'.
 403 AC_ARG_WITH([drive-if],
 404         [AS_HELP_STRING([--with-drive-if],
 405           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 406         [],
 407         [with_drive_if=virtio])
 408 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 409
 410 dnl Set interface used by the network.  Normally you should
 411 dnl leave this at the default (virtio-net-pci) but you can use the
 412 dnl alternative (ne2k_pci) because of bugs in virtio networking
 413 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 414 AC_ARG_WITH([net-if],
 415         [AS_HELP_STRING([--with-net-if],
 416           [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
 417         [],
 418         [with_net_if=virtio-net-pci])
 419 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 420
 421 dnl Enable packet dumps when in verbose mode.  This generates lots
 422 dnl of debug info, only useful for people debugging the RPC mechanism.
 423 AC_ARG_ENABLE([packet-dump],
 424         [AS_HELP_STRING([--enable-packet-dump],
 425           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 426         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 427         [])
 428
 429 dnl Readline.
 430 AC_ARG_WITH([readline],
 431     [AS_HELP_STRING([--with-readline],
 432         [support fancy command line editing @<:@default=check@:>@])],
 433     [],
 434     [with_readline=check])
 435
 436 LIBREADLINE=
 437 AS_IF([test "x$with_readline" != xno],
 438     [AC_CHECK_LIB([readline], [main],
 439         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 440          AC_DEFINE([HAVE_LIBREADLINE], [1],
 441                    [Define if you have libreadline])
 442         ],
 443         [if test "x$with_readline" != xcheck; then
 444          AC_MSG_FAILURE(
 445              [--with-readline was given, but test for readline failed])
 446          fi
 447         ], -lncurses)
 448      old_LIBS="$LIBS"
 449      LIBS="$LIBS $LIBREADLINE"
 450      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 451      LIBS="$old_LIBS"
 452     ])
 453
 454 dnl For i18n.
 455 AM_GNU_GETTEXT([external])
 456
 457 dnl libmagic (highly recommended)
 458 AC_CHECK_LIB([magic],[magic_file],
 459         [AC_CHECK_HEADER([magic.h],
 460                 [AC_SUBST([MAGIC_LIBS], ["-lmagic"])
 461                  AC_DEFINE([HAVE_LIBMAGIC],[1],[libmagic found at compile time.])
 462                 ], [])
 463         ],
 464         [AC_MSG_WARN([libmagic not found, some core features will be disabled])])
 465
 466 dnl Check for PCRE (highly recommended)
 467 PKG_CHECK_MODULES([PCRE], [libpcre],
 468         [AC_SUBST([PCRE_CFLAGS])
 469          AC_SUBST([PCRE_LIBS])
 470          AC_DEFINE([HAVE_PCRE],[1],[PCRE found at compile time.])
 471         ],
 472         [AC_MSG_WARN([PCRE not found, some core features will be disabled])])
 473
 474 dnl libvirt (highly recommended)
 475 PKG_CHECK_MODULES([LIBVIRT], [libvirt],
 476         [AC_SUBST([LIBVIRT_CFLAGS])
 477          AC_SUBST([LIBVIRT_LIBS])
 478          AC_DEFINE([HAVE_LIBVIRT],[1],[libvirt found at compile time.])
 479         ],
 480         [AC_MSG_WARN([libvirt not found, some core features will be disabled])])
 481 AM_CONDITIONAL([HAVE_LIBVIRT],[test "x$LIBVIRT_LIBS" != "x"])
 482
 483 dnl libxml2 (highly recommended)
 484 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0],
 485         [AC_SUBST([LIBXML2_CFLAGS])
 486          AC_SUBST([LIBXML2_LIBS])
 487          AC_DEFINE([HAVE_LIBXML2],[1],[libxml2 found at compile time.])
 488         ],
 489         [AC_MSG_WARN([libxml2 not found, some core features will be disabled])])
 490 AM_CONDITIONAL([HAVE_LIBXML2],[test "x$LIBXML2_LIBS" != "x"])
 491
 492 dnl hivex library (highly recommended)
 493 dnl This used to be a part of libguestfs, but was spun off into its
 494 dnl own separate upstream project in libguestfs 1.0.85.
 495 PKG_CHECK_MODULES([HIVEX], [hivex],
 496         [AC_SUBST([HIVEX_CFLAGS])
 497          AC_SUBST([HIVEX_LIBS])
 498          AC_DEFINE([HAVE_HIVEX],[1],[hivex library found at compile time.])
 499         ],
 500         [AC_MSG_WARN([hivex not found, some core features will be disabled])])
 501
 502 dnl FUSE is optional to build the FUSE module.
 503 AC_ARG_ENABLE([fuse],
 504         AS_HELP_STRING([--disable-fuse], [Disable FUSE (guestmount) support]),
 505         [],
 506         [enable_fuse=yes])
 507 AS_IF([test "x$enable_fuse" != "xno"],
 508         [PKG_CHECK_MODULES([FUSE],[fuse],,[
 509                 enable_fuse=no
 510                 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])])
 511 AM_CONDITIONAL([HAVE_FUSE],[test "x$enable_fuse" != "xno"])
 512
 513 dnl Check for OCaml (optional, for OCaml bindings).
 514 OCAMLC=no
 515 OCAMLFIND=no
 516 AC_ARG_ENABLE([ocaml],
 517         AS_HELP_STRING([--disable-ocaml], [Disable OCaml language bindings]),
 518         [],
 519         [enable_ocaml=yes])
 520 AS_IF([test "x$enable_ocaml" != "xno"],
 521         [dnl OCAMLC and OCAMLFIND have to be unset first, otherwise
 522          dnl AC_CHECK_TOOL (inside AC_PROG_OCAML) will not look.
 523          OCAMLC=
 524          OCAMLFIND=
 525          AC_PROG_OCAML
 526          AC_PROG_FINDLIB
 527         ])
 528 AM_CONDITIONAL([HAVE_OCAML],
 529                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
 530
 531 dnl Check for Perl (optional, for Perl bindings).
 532 PERL=no
 533 AC_ARG_ENABLE([perl],
 534         AS_HELP_STRING([--disable-perl], [Disable Perl language bindings]),
 535         [],
 536         [enable_perl=yes])
 537 AS_IF([test "x$enable_perl" != "xno"],
 538         [
 539         PERL=
 540         AC_CHECK_PROG([PERL],[perl],[perl],[no])
 541
 542         dnl Check for Perl modules that must be present to compile and
 543         dnl test the Perl bindings.
 544         missing_perl_modules=no
 545         for pm in Test::More ExtUtils::MakeMaker; do
 546             AC_MSG_CHECKING([for $pm])
 547             if ! perl -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
 548                 AC_MSG_RESULT([no])
 549                 missing_perl_modules=yes
 550             else
 551                 AC_MSG_RESULT([yes])
 552             fi
 553         done
 554         if test "x$missing_perl_modules" = "xyes"; then
 555             AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 556         fi
 557         ])
 558 AM_CONDITIONAL([HAVE_PERL],
 559     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 560
 561 dnl Check for Python (optional, for Python bindings).
 562 PYTHON_PREFIX=
 563 PYTHON_VERSION=
 564 PYTHON_INCLUDEDIR=
 565 PYTHON_INSTALLDIR=
 566
 567 AC_ARG_ENABLE([python],
 568         AS_HELP_STRING([--disable-python], [Disable Python language bindings]),
 569         [],
 570         [enable_python=yes])
 571 AS_IF([test "x$enable_python" != "xno"],
 572         [
 573         AC_CHECK_PROG([PYTHON],[python],[python],[no])
 574
 575         if test "x$PYTHON" != "xno"; then
 576             AC_MSG_CHECKING([Python prefix])
 577             PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 578             AC_MSG_RESULT([$PYTHON_PREFIX])
 579
 580             AC_MSG_CHECKING([Python version])
 581             PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 582             AC_MSG_RESULT([$PYTHON_VERSION])
 583
 584             for d in \
 585                 $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 586                 /usr/include/python$PYTHON_VERSION \
 587                 /usr/local/include/python$PYTHON_VERSION
 588             do
 589                 AC_MSG_CHECKING([Python.h in $d])
 590                 if test -r "$d/Python.h"; then
 591                     AC_MSG_RESULT([found])
 592                     PYTHON_INCLUDEDIR=$d
 593                     break
 594                 fi
 595                 AC_MSG_RESULT([not found])
 596             done
 597             if test "x$PYTHON_INCLUDEDIR" = "x"; then
 598                 AC_MSG_WARN([Python include directory not found])
 599             fi
 600
 601             AC_ARG_WITH([python-installdir],
 602                         [AS_HELP_STRING([--with-python-installdir],
 603                                         [directory to install python modules @<:@default=check@:>@])],
 604                         [PYTHON_INSTALLDIR="$withval"
 605                         AC_MSG_NOTICE([Python install dir $PYTHON_INSTALLDIR])],
 606                         [PYTHON_INSTALLDIR=check])
 607
 608             if test "x$PYTHON_INSTALLDIR" = "xcheck"; then
 609                 PYTHON_INSTALLDIR=
 610                 for d in \
 611                     $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 612                     $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 613                     /usr/lib64/python$PYTHON_VERSION/site-packages \
 614                     /usr/lib/python$PYTHON_VERSION/site-packages \
 615                     /usr/local/lib/python$PYTHON_VERSION/site-packages
 616                 do
 617                     AC_MSG_CHECKING([for $d])
 618                     if test -d "$d"; then
 619                         AC_MSG_RESULT([found])
 620                         PYTHON_INSTALLDIR=$d
 621                         break
 622                     fi
 623                     AC_MSG_RESULT([not found])
 624                 done
 625                 if test "x$PYTHON_INSTALLDIR" = "x"; then
 626                     AC_MSG_WARN([Python site-packages directory not found])
 627                 fi
 628             fi
 629
 630             old_LIBS="$LIBS"
 631             LIBS="$LIBS -lpython$PYTHON_VERSION"
 632             AC_CHECK_FUNCS([PyCapsule_New])
 633             LIBS="$old_LIBS"
 634         fi
 635
 636         AC_SUBST(PYTHON_PREFIX)
 637         AC_SUBST(PYTHON_VERSION)
 638         AC_SUBST(PYTHON_INCLUDEDIR)
 639         AC_SUBST(PYTHON_INSTALLDIR)
 640         ])
 641 AM_CONDITIONAL([HAVE_PYTHON],
 642     [test "x$PYTHON" != "xno" && test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_INSTALLDIR" != "x"])
 643
 644 dnl Check for Ruby and rake (optional, for Ruby bindings).
 645 AC_ARG_ENABLE([ruby],
 646         AS_HELP_STRING([--disable-ruby], [Disable Ruby language bindings]),
 647         [],
 648         [enable_ruby=yes])
 649 AS_IF([test "x$enable_ruby" != "xno"],
 650         [
 651         AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 652         AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 653         ])
 654 AM_CONDITIONAL([HAVE_RUBY],
 655     [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
 656
 657 dnl Check for Java.
 658 AC_ARG_WITH(java_home,
 659     [AS_HELP_STRING([--with-java-home],
 660         [specify path to JDK directory @<:@default=check@:>@])],
 661     [],
 662     [with_java_home=check])
 663
 664 if test "x$with_java_home" != "xno"; then
 665     if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
 666     then
 667         # Reject unsafe characters in $JAVA_HOME
 668         jh_lf='
 669 '
 670         case $JAVA_HOME in
 671           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 672             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 673         esac
 674         if test -d "$with_java_home"; then
 675             JAVA_HOME="$with_java_home"
 676         else
 677             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 678         fi
 679     fi
 680
 681     if test "x$JAVA_HOME" = "x"; then
 682         # Look for Java in some likely locations.
 683         for d in \
 684             /usr/lib/jvm/java \
 685             /usr/lib/jvm/java-6-openjdk
 686         do
 687             if test -d $d && test -f $d/bin/java; then
 688                 JAVA_HOME=$d
 689                 break
 690             fi
 691         done
 692     fi
 693
 694     if test "x$JAVA_HOME" != "x"; then
 695         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 696         if test ! -x "$JAVA_HOME/bin/java"; then
 697             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 698         else
 699             JAVA="$JAVA_HOME/bin/java"
 700         fi
 701         if test ! -x "$JAVA_HOME/bin/javac"; then
 702             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 703         else
 704             JAVAC="$JAVA_HOME/bin/javac"
 705         fi
 706         if test ! -x "$JAVA_HOME/bin/javah"; then
 707             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 708         else
 709             JAVAH="$JAVA_HOME/bin/javah"
 710         fi
 711         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 712             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 713         else
 714             JAVADOC="$JAVA_HOME/bin/javadoc"
 715         fi
 716         if test ! -x "$JAVA_HOME/bin/jar"; then
 717             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 718         else
 719             JAR="$JAVA_HOME/bin/jar"
 720         fi
 721         java_version=`$JAVA -version 2>&1 | grep "java version"`
 722         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 723
 724         dnl Find jni.h.
 725         AC_MSG_CHECKING([for jni.h])
 726         if test -f "$JAVA_HOME/include/jni.h"; then
 727             JNI_CFLAGS="-I$JAVA_HOME/include"
 728         else
 729             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 730                 head=`find $JAVA_HOME -name jni.h | tail -1`
 731                 dir=`dirname "$head"`
 732                 JNI_CFLAGS="-I$dir"
 733             else
 734                 AC_MSG_FAILURE([missing jni.h header file])
 735             fi
 736         fi
 737         AC_MSG_RESULT([$JNI_CFLAGS])
 738
 739         dnl Find jni_md.h.
 740         AC_MSG_CHECKING([for jni_md.h])
 741         case "$build_os" in
 742         *linux*) system="linux" ;;
 743         *SunOS*) system="solaris" ;;
 744         *cygwin*) system="win32" ;;
 745         *) system="$build_os" ;;
 746         esac
 747         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 748             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 749         else
 750             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 751                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 752                 dir=`dirname "$head"`
 753                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 754             else
 755                 AC_MSG_FAILURE([missing jni_md.h header file])
 756             fi
 757         fi
 758         AC_MSG_RESULT([$JNI_CFLAGS])
 759
 760         dnl Need extra version flag?
 761         AC_MSG_CHECKING([extra javac flags])
 762         JAVAC_FLAGS=
 763         javac_version=`$JAVAC -version 2>&1`
 764         case "$javac_version" in
 765         *Eclipse*)
 766             JAVAC_FLAGS="-source 1.5" ;;
 767         esac
 768         AC_MSG_RESULT([$JAVAC_FLAGS])
 769
 770         dnl Where to install jarfiles.
 771         dnl XXX How to make it configurable?
 772         JAR_INSTALL_DIR=\${prefix}/share/java
 773         JNI_INSTALL_DIR=\${libdir}
 774
 775         dnl JNI version.
 776         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 777         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 778         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 779         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 780     fi
 781 fi
 782
 783 AC_SUBST(JAVA_HOME)
 784 AC_SUBST(JAVA)
 785 AC_SUBST(JAVAC)
 786 AC_SUBST(JAVAH)
 787 AC_SUBST(JAVADOC)
 788 AC_SUBST(JAR)
 789 AC_SUBST(JNI_CFLAGS)
 790 AC_SUBST(JAVAC_FLAGS)
 791 AC_SUBST(JAR_INSTALL_DIR)
 792 AC_SUBST(JNI_INSTALL_DIR)
 793 AC_SUBST(JNI_VERSION_INFO)
 794
 795 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 796
 797 dnl Check for Haskell (GHC).
 798 GHC=no
 799 AC_ARG_ENABLE([haskell],
 800         AS_HELP_STRING([--disable-haskell], [Disable Haskell language bindings]),
 801         [],
 802         [enable_haskell=yes])
 803 AS_IF([test "x$enable_haskell" != "xno"],
 804         [
 805         GHC=
 806         AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 807         ])
 808 AM_CONDITIONAL([HAVE_HASKELL],
 809     [test "x$GHC" != "xno"])
 810
 811 dnl PHP
 812 PHP=no
 813 AC_ARG_ENABLE([php],
 814         AS_HELP_STRING([--disable-php], [Disable PHP language bindings]),
 815         [],
 816         [enable_php=yes])
 817 AS_IF([test "x$enable_php" != "xno"],
 818         [
 819         PHP=
 820         AC_CHECK_PROG([PHP],[php],[php],[no])
 821         AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
 822         ])
 823 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
 824
 825 dnl Check for Perl modules needed by Perl virt tools (virt-df, etc.)
 826 AS_IF([test "x$PERL" != "xno"],
 827         [
 828         missing_perl_modules=no
 829         for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper Locale::TextDomain Win::Hivex Win::Hivex::Regedit String::ShellQuote; do
 830             AC_MSG_CHECKING([for $pm])
 831             if ! $PERL -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
 832                 AC_MSG_RESULT([no])
 833                 missing_perl_modules=yes
 834             else
 835                 AC_MSG_RESULT([yes])
 836             fi
 837         done
 838         if test "x$missing_perl_modules" = "xyes"; then
 839             AC_MSG_WARN([some Perl modules required to compile the Perl virt-* tools are missing])
 840         fi
 841         ])
 842
 843 AM_CONDITIONAL([HAVE_TOOLS],
 844     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 845
 846 dnl Library versioning.
 847 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 848 AC_SUBST(MAX_PROC_NR)
 849
 850 dnl Replace libtool with a wrapper that clobbers dependency_libs in *.la files
 851 dnl http://lists.fedoraproject.org/pipermail/devel/2010-November/146343.html
 852 LIBTOOL='bash $(top_srcdir)/libtool-kill-dependency_libs.sh $(top_builddir)/libtool'
 853 AC_SUBST([LIBTOOL])
 854
 855 dnl Run in subdirs.
 856 if test "x$enable_daemon" = "xyes"; then
 857     AC_CONFIG_SUBDIRS([daemon])
 858 fi
 859
 860 dnl Produce output files.
 861 AC_CONFIG_HEADERS([config.h])
 862 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 863 AC_CONFIG_FILES([podwrapper.sh],
 864                 [chmod +x podwrapper.sh])
 865 AC_CONFIG_FILES([Makefile
 866                  generator/Makefile
 867                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 868                  appliance/Makefile
 869                  images/Makefile
 870                  capitests/Makefile
 871                  caution/Makefile
 872                  regressions/Makefile
 873                  test-tool/Makefile
 874                  ocaml/Makefile ocaml/examples/Makefile
 875                  perl/Makefile
 876                  python/Makefile python/examples/Makefile
 877                  ruby/Makefile ruby/Rakefile ruby/examples/Makefile
 878                  java/Makefile
 879                  haskell/Makefile
 880                  inspector/Makefile
 881                  tools/Makefile
 882                  libguestfs.pc
 883                  gnulib/lib/Makefile
 884                  gnulib/tests/Makefile
 885                  fuse/Makefile
 886                  po-docs/Makefile
 887                  po-docs/ja/Makefile
 888                  php/Makefile
 889                  csharp/Makefile
 890                  cat/Makefile
 891                  df/Makefile
 892                  rescue/Makefile
 893                  debian/changelog
 894                  ocaml/META perl/Makefile.PL])
 895 AC_OUTPUT
 896
 897 dnl Produce summary.
 898 echo
 899 echo
 900 echo "------------------------------------------------------------"
 901 echo "Thank you for downloading $PACKAGE_STRING"
 902 echo
 903 echo "This is how we have configured the optional components for you today:"
 904 echo
 905 echo    "Daemon .............................. $enable_daemon"
 906 echo    "Appliance ........................... $enable_appliance"
 907 echo    "QEMU ................................ $QEMU"
 908 echo -n "OCaml bindings ...................... "
 909 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 910 echo -n "Perl bindings ....................... "
 911 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 912 echo -n "Python bindings ..................... "
 913 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 914 echo -n "Ruby bindings ....................... "
 915 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 916 echo -n "Java bindings ....................... "
 917 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 918 echo -n "Haskell bindings .................... "
 919 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 920 echo -n "PHP bindings ........................ "
 921 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 922 echo -n "virt-* tools ........................ "
 923 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 924 echo "FUSE filesystem ..................... $enable_fuse"
 925 echo
 926 echo "If any optional component is configured 'no' when you expected 'yes'"
 927 echo "then you should check the preceeding messages."
 928 echo
 929 echo "Please report bugs back to the mailing list:"
 930 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 931 echo
 932 echo "Next you should type 'make' to build the package,"
 933 echo "then 'make check' to run the tests."
 934 echo "------------------------------------------------------------"