configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2010 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [3])
  21 m4_define([libguestfs_release], [13])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release[]libguestfs_extra)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 dnl Die if the user tries to configure as root, see:
  41 dnl https://www.redhat.com/archives/libguestfs/2010-April/msg00098.html
  42 AC_MSG_CHECKING([if you are trying to configure as root])
  43 AS_IF([test "`id -u`" = 0 ],[
  44             AC_MSG_RESULT([yes])
  45             AC_MSG_FAILURE([Don't run './configure' or 'make' as root.])
  46       ],[
  47             AC_MSG_RESULT([no])
  48       ])
  49
  50 dnl Early gnulib initialization.
  51 gl_EARLY
  52 gl_INIT
  53
  54 AC_PROG_LIBTOOL
  55
  56 dnl Check for basic C environment.
  57 AC_PROG_CC_STDC
  58 AC_PROG_INSTALL
  59 AC_PROG_CPP
  60
  61 AC_ARG_ENABLE([gcc-warnings],
  62   [AS_HELP_STRING([--enable-gcc-warnings],
  63                   [turn on lots of GCC warnings (for developers)])],
  64   [case $enableval in
  65      yes|no) ;;
  66      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  67    esac
  68    gl_gcc_warnings=$enableval],
  69   [gl_gcc_warnings=no]
  70 )
  71
  72 if test "$gl_gcc_warnings" = yes; then
  73   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  74   AC_SUBST([WERROR_CFLAGS])
  75
  76   nw=
  77   # This, $nw, is the list of warnings we disable.
  78   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  79   nw="$nw -Waggregate-return"       # anachronistic
  80   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  81   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  82   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  83   nw="$nw -Wcast-qual"              # Too many warnings for now
  84   nw="$nw -Wconversion"             # Too many warnings for now
  85   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  86   nw="$nw -Wsign-conversion"        # Too many warnings for now
  87   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  88   nw="$nw -Wunreachable-code"       # Too many warnings for now
  89   nw="$nw -Wpadded"                 # Our structs are not padded
  90   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  91   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  92   nw="$nw -Wvla"                    # two warnings in mount.c
  93   # things I might fix soon:
  94   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
  95   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
  96   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
  97   # ?? -Wstrict-overflow
  98   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
  99                                     # was not possible, safe to ignore
 100   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 101
 102   gl_MANYWARN_ALL_GCC([ws])
 103   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 104   for w in $ws; do
 105     gl_WARN_ADD([$w])
 106   done
 107   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 108   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 109   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 110
 111   # In spite of excluding -Wlogical-op above, it is enabled, as of
 112   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 113   gl_WARN_ADD([-Wno-logical-op])
 114
 115   gl_WARN_ADD([-fdiagnostics-show-option])
 116
 117   AC_SUBST([WARN_CFLAGS])
 118
 119   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 120   AC_DEFINE([_FORTIFY_SOURCE], [2],
 121     [enable compile-time and run-time bounds-checking, and some warnings])
 122   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 123 fi
 124
 125 AC_C_PROTOTYPES
 126 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 127
 128 AM_PROG_CC_C_O
 129
 130 dnl Work out how to specify the linker script to the linker.
 131 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 132 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 133     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 134 AC_SUBST(VERSION_SCRIPT_FLAGS)
 135
 136 dnl Check support for 64 bit file offsets.
 137 AC_SYS_LARGEFILE
 138
 139 dnl Check sizeof long.
 140 AC_CHECK_SIZEOF([long])
 141
 142 dnl Define a C symbol for the host CPU architecture.
 143 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 144
 145 dnl Headers.
 146 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 147
 148 dnl Functions.
 149 AC_CHECK_FUNCS([posix_fallocate])
 150
 151 dnl Build the daemon?
 152 AC_MSG_CHECKING([if we should build the daemon])
 153 AC_ARG_ENABLE([daemon],
 154         [AS_HELP_STRING([--enable-daemon],
 155           [enable building the daemon @<:@default=yes@:>@])],
 156         [],
 157         [enable_daemon=yes])
 158 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 159 AC_MSG_RESULT([$enable_daemon])
 160
 161 dnl Build the appliance?
 162 AC_MSG_CHECKING([if we should build the appliance])
 163 AC_ARG_ENABLE([appliance],
 164         [AS_HELP_STRING([--enable-appliance],
 165           [enable building the appliance @<:@default=yes@:>@])],
 166         [],
 167         [enable_appliance=yes])
 168 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 169 AC_MSG_RESULT([$enable_appliance])
 170
 171 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 172 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 173 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 174 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 175         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 176         ])
 177
 178 dnl Check for pod2man and pod2text.
 179 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 180 test "x$POD2MAN" = "xno" &&
 181      AC_MSG_ERROR([pod2man must be installed])
 182 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 183 test "x$POD2TEXT" = "xno" &&
 184      AC_MSG_ERROR([pod2text must be installed])
 185
 186 dnl Check for mkisofs.
 187 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 188         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 189 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 190
 191 dnl Check for optional xmllint.
 192 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 193 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 194
 195 dnl Check for QEMU for running binaries on this $host_cpu, fall
 196 dnl back to basic 'qemu'.  Allow the user to override it.
 197 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
 198 AC_ARG_WITH([qemu],
 199         [AS_HELP_STRING([--with-qemu],
 200           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 201         [],
 202         [with_qemu="$default_qemu"])
 203 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 204         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 205 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 206 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 207
 208 dnl Check that the chosen qemu has vmchannel support or we can
 209 dnl fallback to null vmchannel (still using SLIRP).  See the
 210 dnl discussion in the README file.
 211 if test "x$vmchannel_test" != "xno"; then
 212     AC_MSG_CHECKING([for guestfwd support in $QEMU])
 213     if $QEMU -nographic --help | grep -sq guestfwd; then
 214         AC_MSG_RESULT([yes])
 215         vmchannel_guestfwd=guestfwd
 216     else
 217         AC_MSG_RESULT([no])
 218         # Note that this test must be conditional on the previous
 219         # test failing.  This is because recent qemu will throw
 220         # up an SDL window and hang if we try to run this test.
 221         AC_MSG_CHECKING([for "-net channel" (old guestfwd) support in $QEMU])
 222         vmchannelout=`$QEMU -nographic -net channel /dev/zero 2>&1 ||:`
 223         echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
 224         if echo "$vmchannelout" | grep -sq "vmchannel wrong port number" ; then
 225             AC_MSG_RESULT([yes])
 226             vmchannel_guestfwd=net_channel
 227         else
 228             AC_MSG_RESULT([no])
 229             vmchannel_guestfwd=no
 230         fi
 231     fi
 232
 233     AC_MSG_CHECKING([for "-net user" (user mode network) support in $QEMU])
 234     if $QEMU -nographic --help | grep -sq -- "-net user"; then
 235         AC_MSG_RESULT([yes])
 236         vmchannel_net_user=yes
 237     else
 238         AC_MSG_RESULT([no])
 239         vmchannel_net_user=no
 240     fi
 241
 242     if test "x$vmchannel_net_user" = "xno" -a "x$vmchannel_guestfwd" = "xno"; then
 243         AC_MSG_FAILURE(
 244 [I did not find user mode network or vmchannel support in
 245 $QEMU.
 246
 247 Either user mode networking or vmchannel support is vital for
 248 libguestfs to operate.
 249
 250 Please read the relevant section in the README file for more
 251 information about this.
 252
 253 You can override this test by setting the environment variable
 254 vmchannel_test=no  However if you don't have the right support
 255 in your qemu, then this just delays the pain.
 256
 257 If I am using the wrong qemu or you want to compile qemu from source
 258 and install it in another location, then you should configure with
 259 the --with-qemu option.
 260 ])
 261     fi
 262 fi
 263
 264 dnl Set drive interface used by the guestfs_add_drive{,_ro} calls
 265 dnl ('-drive ...,if=...' option to qemu).
 266 dnl
 267 dnl If you encounter performance problems with virtio (RHBZ#509383)
 268 dnl then try '--with-drive-if=ide'.
 269 AC_ARG_WITH([drive-if],
 270         [AS_HELP_STRING([--with-drive-if],
 271           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 272         [],
 273         [with_drive_if=virtio])
 274 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 275
 276 dnl Set interface used by the network.  Normally you should
 277 dnl leave this at the default (virtio) but you can use the
 278 dnl alternative (ne2k_pci) because of bugs in virtio networking
 279 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 280 AC_ARG_WITH([net-if],
 281         [AS_HELP_STRING([--with-net-if],
 282           [set default net driver (virtio|ne2k_pci) @<:@default=virtio@:>@])],
 283         [],
 284         [with_net_if=virtio])
 285 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 286
 287 dnl Check for febootstrap etc.
 288 if test "x$enable_appliance" = "xyes"; then
 289     AC_CHECK_PROG([FEBOOTSTRAP],
 290                   [febootstrap],[febootstrap],[no])
 291     if test "x$FEBOOTSTRAP" != "xno"; then
 292       AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 293                     [febootstrap-run],[febootstrap-run],[no])
 294       test "x$FEBOOTSTRAP_RUN" = "xno" && \
 295           AC_MSG_ERROR([febootstrap-run must be installed])
 296       AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 297                     [febootstrap-install],[febootstrap-install],[no])
 298       test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 299           AC_MSG_ERROR([febootstrap-install must be installed])
 300       AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 301                     [febootstrap-minimize],[febootstrap-minimize],[no])
 302       test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 303           AC_MSG_ERROR([febootstrap-minimize must be installed])
 304       AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 305                     [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 306       test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 307           AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 308       AC_CHECK_PROG([FEBOOTSTRAP_TO_SUPERMIN],
 309                     [febootstrap-to-supermin],[febootstrap-to-supermin],[no])
 310       test "x$FEBOOTSTRAP_TO_SUPERMIN" = "xno" && \
 311           AC_MSG_ERROR([febootstrap-to-supermin must be installed])
 312
 313       dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 314       dnl of febootstrap, but old versions will fail with yum).
 315       AC_CHECK_PROG([FAKECHROOT],
 316                     [fakechroot],[fakechroot],[no])
 317       test "x$FAKECHROOT" = "xno" && \
 318          AC_MSG_ERROR([fakechroot must be installed])
 319
 320       AC_MSG_CHECKING([fakechroot version])
 321       fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 322       if test -z "$fakechroot_version"; then
 323         AC_MSG_RESULT([failed])
 324         AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 325       else
 326         AC_MSG_RESULT([$fakechroot_version])
 327         fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 328         fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 329         if test "$fakechroot_major" -lt 2 -o \
 330             \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
 331           AC_MSG_ERROR([fakechroot version must be >= 2.9])
 332         fi
 333       fi
 334       DIST="REDHAT"
 335     else
 336       # check for debootstrap and debirf
 337       AC_CHECK_PROG([DEBOOTSTRAP],
 338                     [debootstrap],[debootstrap],[no])
 339       test "x$DEBOOTSTRAP" = "xno" && \
 340           AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 341       AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 342       test "x$DEBIRF" = "xno" &&
 343           AC_MSG_ERROR([debirf must be installed])
 344       DIST="DEBIAN"
 345       case "$host_cpu" in
 346       *86)
 347           DEBIAN_KERNEL_ARCH=486
 348           ;;
 349       x86_64)
 350           DEBIAN_KERNEL_ARCH=amd64
 351           ;;
 352       *)
 353          DEBIAN_KERNEL_ARCH=$host_cpu
 354          ;;
 355       esac
 356       AC_SUBST(DEBIAN_KERNEL_ARCH)
 357     fi
 358     AC_SUBST(DIST)
 359
 360     dnl --with-updates to specify a Fedora updates repository.
 361     AC_ARG_WITH([updates],
 362         [AS_HELP_STRING([--with-updates],
 363           [set name of Fedora updates repository @<:@default=updates-released-f12@:>@])],
 364         [],
 365         [with_updates=updates-released-f12])
 366     UPDATES="$with_updates"
 367     AC_SUBST(UPDATES)
 368
 369     dnl --with-mirror to specify a local Fedora mirror.
 370     AC_ARG_WITH([mirror],
 371         [AS_HELP_STRING([--with-mirror],
 372           [set URI of a local Fedora mirror])],
 373         [],
 374         [with_mirror=])
 375     MIRROR="$with_mirror"
 376     AC_SUBST(MIRROR)
 377 fi
 378
 379 dnl --with-repo to specify a Fedora repository.
 380 AC_ARG_WITH([repo],
 381         [AS_HELP_STRING([--with-repo],
 382           [set name of Fedora repository @<:@default=fedora-12@:>@])],
 383         [],
 384         [with_repo=fedora-12])
 385 REPO="$with_repo"
 386 AC_SUBST(REPO)
 387 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 388
 389 dnl Build the supermin appliance?  Please see README file before
 390 dnl enabling this option.
 391 AC_ARG_ENABLE([supermin],
 392         [AS_HELP_STRING([--enable-supermin],
 393           [enable supermin appliance (see README) @<:@default=no@:>@])],
 394         [],
 395         [enable_supermin=no])
 396 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 397
 398 dnl Enable packet dumps when in verbose mode.  This generates lots
 399 dnl of debug info, only useful for people debugging the RPC mechanism.
 400 AC_ARG_ENABLE([packet-dump],
 401         [AS_HELP_STRING([--enable-packet-dump],
 402           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 403         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 404         [])
 405
 406 dnl Readline.
 407 AC_ARG_WITH([readline],
 408     [AS_HELP_STRING([--with-readline],
 409         [support fancy command line editing @<:@default=check@:>@])],
 410     [],
 411     [with_readline=check])
 412
 413 LIBREADLINE=
 414 AS_IF([test "x$with_readline" != xno],
 415     [AC_CHECK_LIB([readline], [main],
 416         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 417          AC_DEFINE([HAVE_LIBREADLINE], [1],
 418                    [Define if you have libreadline])
 419         ],
 420         [if test "x$with_readline" != xcheck; then
 421          AC_MSG_FAILURE(
 422              [--with-readline was given, but test for readline failed])
 423          fi
 424         ], -lncurses)
 425      old_LIBS="$LIBS"
 426      LIBS="$LIBS $LIBREADLINE"
 427      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 428      LIBS="$old_LIBS"
 429     ])
 430
 431 dnl For i18n.
 432 AM_GNU_GETTEXT([external])
 433 AM_GNU_GETTEXT_VERSION([0.17])
 434
 435 dnl hivex library (highly recommended).
 436 dnl This used to be a part of libguestfs, but was spun off into its
 437 dnl own separate upstream project in libguestfs 1.0.85.
 438 HAVE_HIVEX=yes
 439 PKG_CHECK_MODULES([HIVEX], [hivex],,[
 440         HAVE_HIVEX=no
 441         AC_MSG_WARN([Hivex library and headers are missing, so optional Windows Registry tools won't be built])])
 442 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HAVE_HIVEX" = "xyes"])
 443 AC_SUBST([HIVEX_CFLAGS])
 444 AC_SUBST([HIVEX_LIBS])
 445
 446 dnl FUSE is optional to build the FUSE module.
 447 HAVE_FUSE=yes
 448 PKG_CHECK_MODULES([FUSE],[fuse],,[
 449         HAVE_FUSE=no
 450         AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])
 451 AM_CONDITIONAL([HAVE_FUSE],[test "x$HAVE_FUSE" = "xyes"])
 452
 453 dnl Check for OCaml (optional, for OCaml bindings).
 454 AC_PROG_OCAML
 455 AC_PROG_FINDLIB
 456 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
 457
 458 dnl Optional xml-light for running the generator.
 459 OCAML_PKG_xml_light=no
 460 if test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"; then
 461     AC_CHECK_OCAML_PKG([xml-light])
 462 fi
 463 AM_CONDITIONAL([HAVE_XML_LIGHT],[test "x$OCAML_PKG_xml_light" != "xno"])
 464
 465 dnl Build the OCaml viewer example.  This has a lengthy list of
 466 dnl dependencies and we don't attempt to detect them all.  Read
 467 dnl the top of ocaml/examples/viewer.ml before enabling this.
 468 AC_ARG_ENABLE([ocaml-viewer],
 469         [AS_HELP_STRING([--enable-ocaml-viewer],
 470           [enable OCaml viewer (see ocaml/examples) @<:@default=no@:>@])],
 471         [],
 472         [enable_ocaml_viewer=no])
 473 AM_CONDITIONAL([BUILD_OCAML_VIEWER],[test "x$enable_ocaml_viewer" = "xyes"])
 474
 475 dnl Check for Perl (optional, for Perl bindings).
 476 dnl XXX This isn't quite right, we should check for Perl devel library.
 477 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 478
 479 dnl Check for Perl modules that must be present to compile and
 480 dnl test the Perl bindings.
 481 missing_perl_modules=no
 482 for pm in Test::More ExtUtils::MakeMaker; do
 483     AC_MSG_CHECKING([for $pm])
 484     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 485         AC_MSG_RESULT([no])
 486         missing_perl_modules=yes
 487     else
 488         AC_MSG_RESULT([yes])
 489     fi
 490 done
 491 if test "x$missing_perl_modules" = "xyes"; then
 492     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 493 fi
 494
 495 AM_CONDITIONAL([HAVE_PERL],
 496     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 497
 498 dnl Check for Python (optional, for Python bindings).
 499 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 500
 501 PYTHON_PREFIX=
 502 PYTHON_VERSION=
 503 PYTHON_INCLUDEDIR=
 504 PYTHON_SITE_PACKAGES=
 505
 506 if test "x$PYTHON" != "xno"; then
 507     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 508     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 509     for d in \
 510         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 511         /usr/include/python$PYTHON_VERSION \
 512         /usr/local/include/python$PYTHON_VERSION
 513     do
 514         AC_MSG_CHECKING([Python.h in $d])
 515         if test -r "$d/Python.h"; then
 516             AC_MSG_RESULT([found])
 517             PYTHON_INCLUDEDIR=$d
 518             break
 519         fi
 520         AC_MSG_RESULT([not found])
 521     done
 522     for d in \
 523         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 524         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 525         /usr/lib64/python$PYTHON_VERSION/site-packages \
 526         /usr/lib/python$PYTHON_VERSION/site-packages \
 527         /usr/local/lib/python$PYTHON_VERSION/site-packages
 528     do
 529         AC_MSG_CHECKING([for $d])
 530         if test -d "$d"; then
 531             AC_MSG_RESULT([found])
 532             PYTHON_SITE_PACKAGES=$d
 533             break
 534         fi
 535         AC_MSG_RESULT([not found])
 536     done
 537 fi
 538
 539 AC_SUBST(PYTHON_PREFIX)
 540 AC_SUBST(PYTHON_VERSION)
 541 AC_SUBST(PYTHON_INCLUDEDIR)
 542 AC_SUBST(PYTHON_SITE_PACKAGES)
 543
 544 AM_CONDITIONAL([HAVE_PYTHON],
 545     [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
 546
 547 dnl Check for Ruby and rake (optional, for Ruby bindings).
 548 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 549 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 550
 551 AM_CONDITIONAL([HAVE_RUBY],
 552     [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
 553
 554 dnl Check for Java.
 555 AC_ARG_WITH(java_home,
 556     [AS_HELP_STRING([--with-java-home],
 557         [specify path to JDK directory @<:@default=check@:>@])],
 558     [],
 559     [with_java_home=check])
 560
 561 if test "x$with_java_home" != "xno"; then
 562     if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
 563     then
 564         # Reject unsafe characters in $JAVA_HOME
 565         jh_lf='
 566 '
 567         case $JAVA_HOME in
 568           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 569             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 570         esac
 571         if test -d "$with_java_home"; then
 572             JAVA_HOME="$with_java_home"
 573         else
 574             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 575         fi
 576     fi
 577
 578     if test "x$JAVA_HOME" = "x"; then
 579         # Look for Java in some likely locations.
 580         for d in \
 581             /usr/lib/jvm/java \
 582             /usr/lib/jvm/java-6-openjdk
 583         do
 584             if test -d $d -a -f $d/bin/java; then
 585                 JAVA_HOME=$d
 586                 break
 587             fi
 588         done
 589     fi
 590
 591     if test "x$JAVA_HOME" != "x"; then
 592         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 593         if test ! -x "$JAVA_HOME/bin/java"; then
 594             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 595         else
 596             JAVA="$JAVA_HOME/bin/java"
 597         fi
 598         if test ! -x "$JAVA_HOME/bin/javac"; then
 599             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 600         else
 601             JAVAC="$JAVA_HOME/bin/javac"
 602         fi
 603         if test ! -x "$JAVA_HOME/bin/javah"; then
 604             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 605         else
 606             JAVAH="$JAVA_HOME/bin/javah"
 607         fi
 608         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 609             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 610         else
 611             JAVADOC="$JAVA_HOME/bin/javadoc"
 612         fi
 613         if test ! -x "$JAVA_HOME/bin/jar"; then
 614             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 615         else
 616             JAR="$JAVA_HOME/bin/jar"
 617         fi
 618         java_version=`$JAVA -version 2>&1 | grep "java version"`
 619         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 620
 621         dnl Find jni.h.
 622         AC_MSG_CHECKING([for jni.h])
 623         if test -f "$JAVA_HOME/include/jni.h"; then
 624             JNI_CFLAGS="-I$JAVA_HOME/include"
 625         else
 626             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 627                 head=`find $JAVA_HOME -name jni.h | tail -1`
 628                 dir=`dirname "$head"`
 629                 JNI_CFLAGS="-I$dir"
 630             else
 631                 AC_MSG_FAILURE([missing jni.h header file])
 632             fi
 633         fi
 634         AC_MSG_RESULT([$JNI_CFLAGS])
 635
 636         dnl Find jni_md.h.
 637         AC_MSG_CHECKING([for jni_md.h])
 638         case "$build_os" in
 639         *linux*) system="linux" ;;
 640         *SunOS*) system="solaris" ;;
 641         *cygwin*) system="win32" ;;
 642         *) system="$build_os" ;;
 643         esac
 644         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 645             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 646         else
 647             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 648                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 649                 dir=`dirname "$head"`
 650                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 651             else
 652                 AC_MSG_FAILURE([missing jni_md.h header file])
 653             fi
 654         fi
 655         AC_MSG_RESULT([$JNI_CFLAGS])
 656
 657         dnl Need extra version flag?
 658         AC_MSG_CHECKING([extra javac flags])
 659         JAVAC_FLAGS=
 660         javac_version=`$JAVAC -version 2>&1`
 661         case "$javac_version" in
 662         *Eclipse*)
 663             JAVAC_FLAGS="-source 1.5" ;;
 664         esac
 665         AC_MSG_RESULT([$JAVAC_FLAGS])
 666
 667         dnl Where to install jarfiles.
 668         dnl XXX How to make it configurable?
 669         JAR_INSTALL_DIR=\${prefix}/share/java
 670         JNI_INSTALL_DIR=\${libdir}
 671
 672         dnl JNI version.
 673         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 674         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 675         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 676         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 677     fi
 678 fi
 679
 680 AC_SUBST(JAVA_HOME)
 681 AC_SUBST(JAVA)
 682 AC_SUBST(JAVAC)
 683 AC_SUBST(JAVAH)
 684 AC_SUBST(JAVADOC)
 685 AC_SUBST(JAR)
 686 AC_SUBST(JNI_CFLAGS)
 687 AC_SUBST(JAVAC_FLAGS)
 688 AC_SUBST(JAR_INSTALL_DIR)
 689 AC_SUBST(JNI_INSTALL_DIR)
 690 AC_SUBST(JNI_VERSION_INFO)
 691
 692 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 693
 694 dnl Check for Haskell (GHC).
 695 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 696
 697 AM_CONDITIONAL([HAVE_HASKELL],
 698     [test "x$GHC" != "xno"])
 699
 700 dnl Check for Perl modules needed by virt-df, inspector, etc.
 701 missing_perl_modules=no
 702 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer Locale::TextDomain Win::Hivex Win::Hivex::Regedit; do
 703     AC_MSG_CHECKING([for $pm])
 704     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 705         AC_MSG_RESULT([no])
 706         missing_perl_modules=yes
 707     else
 708         AC_MSG_RESULT([yes])
 709     fi
 710 done
 711 if test "x$missing_perl_modules" = "xyes"; then
 712     AC_MSG_WARN([some Perl modules required to compile virt-inspector and the other virt-* tools are missing])
 713 fi
 714
 715 AM_CONDITIONAL([HAVE_INSPECTOR],
 716     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 717 AM_CONDITIONAL([HAVE_TOOLS],
 718     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 719
 720 dnl Library versioning.
 721 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 722 AC_SUBST(MAX_PROC_NR)
 723
 724 dnl Run in subdirs.
 725 if test "x$enable_daemon" = "xyes"; then
 726     AC_CONFIG_SUBDIRS([daemon])
 727 fi
 728
 729 dnl Produce output files.
 730 AC_CONFIG_HEADERS([config.h])
 731 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 732 AC_CONFIG_FILES([appliance/update.sh],
 733                 [chmod +x appliance/update.sh])
 734 AC_CONFIG_FILES([Makefile
 735                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 736                  appliance/Makefile
 737                  appliance/debian/debirf.conf
 738                  images/Makefile
 739                  capitests/Makefile
 740                  regressions/Makefile
 741                  test-tool/Makefile
 742                  ocaml/Makefile ocaml/examples/Makefile
 743                  perl/Makefile
 744                  python/Makefile
 745                  ruby/Makefile ruby/Rakefile
 746                  java/Makefile
 747                  haskell/Makefile
 748                  inspector/Makefile
 749                  tools/Makefile
 750                  libguestfs.pc
 751                  gnulib/lib/Makefile
 752                  gnulib/tests/Makefile
 753                  fuse/Makefile
 754                  ocaml/META perl/Makefile.PL])
 755 AC_OUTPUT
 756
 757 dnl Produce summary.
 758 echo
 759 echo
 760 echo "------------------------------------------------------------"
 761 echo "Thank you for downloading $PACKAGE_STRING"
 762 echo
 763 echo "This is how we have configured the optional components for you today:"
 764 echo
 765 echo    "Daemon .............................. $enable_daemon"
 766 echo    "Appliance ........................... $enable_appliance"
 767 echo    "QEMU ................................ $QEMU"
 768 echo -n "OCaml bindings ...................... "
 769 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 770 echo -n "Perl bindings ....................... "
 771 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 772 echo -n "Python bindings ..................... "
 773 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 774 echo -n "Ruby bindings ....................... "
 775 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 776 echo -n "Java bindings ....................... "
 777 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 778 echo -n "Haskell bindings .................... "
 779 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 780 echo -n "virt-inspector ...................... "
 781 if test "x$HAVE_INSPECTOR_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 782 echo -n "virt-* tools ........................ "
 783 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 784 echo "supermin appliance .................. $enable_supermin"
 785 echo "FUSE filesystem ..................... $HAVE_FUSE"
 786 echo
 787 echo "If any optional component is configured 'no' when you expected 'yes'"
 788 echo "then you should check the preceeding messages."
 789 echo
 790 echo "Please report bugs back to the mailing list:"
 791 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 792 echo
 793 echo "Next you should type 'make' to build the package,"
 794 echo "then 'make check' to run the tests."
 795 echo "------------------------------------------------------------"