configure.ac

   1 # a-fedora-appliance
   2 # Copyright (C) 2011 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 AC_INIT([a-fedora-appliance],[1.0])
  19 AM_INIT_AUTOMAKE([foreign])
  20
  21 dnl RPM release.
  22 RELEASE=6
  23 AC_SUBST([RELEASE])
  24
  25 dnl The list of packages included in the appliance.
  26 dnl NOTE: After changing this: touch make.sh.in; make
  27 PACKAGELIST="\
  28 bash \
  29 binutils \
  30 coreutils \
  31 dbus \
  32 file \
  33 findutils \
  34 gawk \
  35 grep \
  36 gzip \
  37 less \
  38 NetworkManager \
  39 openssh-clients \
  40 openssh-server \
  41 perl \
  42 procps \
  43 python \
  44 rsyslog \
  45 systemd \
  46 udev \
  47 "
  48 AC_SUBST([PACKAGELIST])
  49
  50 dnl Check for febootstrap >= 3.0.
  51 AC_CHECK_PROG([FEBOOTSTRAP],
  52               [febootstrap],[febootstrap],[no])
  53 test "x$FEBOOTSTRAP" = "xno" &&
  54     AC_MSG_ERROR([febootstrap must be installed])
  55 dnl febootstrap 2.x did not support the --version parameter
  56 $FEBOOTSTRAP --version >&AS_MESSAGE_LOG_FD 2>&1 ||
  57     AC_MSG_ERROR([febootstrap >= 3.0 must be installed, your version is too old])
  58
  59 dnl Pass a febootstrap --yum-config option.
  60 AC_MSG_CHECKING([if user requested febootstrap --yum-config option])
  61 AC_ARG_WITH([yum-config],
  62     [AS_HELP_STRING([--with-yum-config=FILE],
  63       [pass febootstrap --yum-config option @<:@default=no@:>@])],
  64     [YUM_CONFIG="$withval"],
  65     [YUM_CONFIG=no])
  66 AC_MSG_RESULT([$YUM_CONFIG])
  67 AC_SUBST([YUM_CONFIG])
  68
  69 dnl Produce output files.
  70 AC_CONFIG_FILES([Makefile
  71                  a-fedora-appliance.spec
  72                 ])
  73 AC_CONFIG_FILES([build-a-fedora-appliance],
  74                 [chmod 0555 build-a-fedora-appliance])
  75 AC_CONFIG_FILES([boot-a-fedora-appliance],
  76                 [chmod 0555 boot-a-fedora-appliance])
  77 AC_OUTPUT