configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2011 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # The major, minor, and release fields MUST be numbers.  Packagers can
  19 # add extra information using --with-extra="..." which may be any
  20 # freeform string.
  21 m4_define([libguestfs_major],   [1])
  22 m4_define([libguestfs_minor],   [10])
  23 m4_define([libguestfs_release], [8])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Stable or unstable version?
  35 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  36 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  37             AC_MSG_RESULT([stable])
  38        ],[
  39             AC_MSG_RESULT([unstable])
  40             AC_MSG_NOTICE([
  41 ***
  42 This is a development version of libguestfs. Some APIs may be unstable
  43 until they appear in a stable release of libguestfs (at which point
  44 the C API and ABI is guaranteed to remain stable forever).  For
  45 more information about stable and development branches of libguestfs
  46 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  47 ***])
  48        ])
  49
  50 dnl Extra string, a freeform string defined by packagers.
  51 AC_ARG_WITH([extra],
  52   [AS_HELP_STRING([--with-extra],
  53                   [extra version string (for use by packagers)])],
  54   [libguestfs_extra="$withval"],
  55   [libguestfs_extra=]
  56 )
  57
  58 AC_MSG_NOTICE([libguestfs version libguestfs_major.libguestfs_minor.libguestfs_release$libguestfs_extra])
  59
  60 dnl Split up the version string.
  61 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  62 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  63 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  64 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_EXTRA],["$libguestfs_extra"],[Extra version string])
  65
  66 dnl Early gnulib initialization.
  67 gl_EARLY
  68 gl_INIT
  69
  70 AC_PROG_LIBTOOL
  71
  72 dnl Check for basic C environment.
  73 AC_PROG_CC_STDC
  74 AC_PROG_INSTALL
  75 AC_PROG_CPP
  76
  77 AC_ARG_ENABLE([gcc-warnings],
  78   [AS_HELP_STRING([--enable-gcc-warnings],
  79                   [turn on lots of GCC warnings (for developers)])],
  80   [case $enableval in
  81      yes|no) ;;
  82      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  83    esac
  84    gl_gcc_warnings=$enableval],
  85   [gl_gcc_warnings=no]
  86 )
  87
  88 if test "$gl_gcc_warnings" = yes; then
  89   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  90   AC_SUBST([WERROR_CFLAGS])
  91
  92   nw=
  93   # This, $nw, is the list of warnings we disable.
  94   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  95   nw="$nw -Waggregate-return"       # anachronistic
  96   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  97   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  98   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  99   nw="$nw -Wcast-qual"              # Too many warnings for now
 100   nw="$nw -Wconversion"             # Too many warnings for now
 101   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 102   nw="$nw -Wsign-conversion"        # Too many warnings for now
 103   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 104   nw="$nw -Wunreachable-code"       # Too many warnings for now
 105   nw="$nw -Wpadded"                 # Our structs are not padded
 106   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 107   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 108   nw="$nw -Wvla"                    # two warnings in mount.c
 109   # things I might fix soon:
 110   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 111   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 112   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 113   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 114                                     # was not possible, safe to ignore
 115   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 116   nw="$nw -Wlong-long"              # Allow long long since it's required
 117                                     # by Python, Ruby and xstrtoll.
 118   nw="$nw -Wstack-protector"        # Don't warn about stack-protector
 119                                     # failures (seen on Ubuntu).
 120
 121   gl_MANYWARN_ALL_GCC([ws])
 122   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 123   for w in $ws; do
 124     gl_WARN_ADD([$w])
 125   done
 126   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 127   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 128   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 129
 130   # In spite of excluding -Wlogical-op above, it is enabled, as of
 131   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 132   gl_WARN_ADD([-Wno-logical-op])
 133
 134   # Work around warning in src/inspect.c.  This seems to be a bug in gcc 4.5.1.
 135   gl_WARN_ADD([-Wno-strict-overflow])
 136
 137   gl_WARN_ADD([-fdiagnostics-show-option])
 138
 139   AC_SUBST([WARN_CFLAGS])
 140
 141   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 142   AC_DEFINE([_FORTIFY_SOURCE], [2],
 143     [enable compile-time and run-time bounds-checking, and some warnings])
 144   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 145 fi
 146
 147 AC_C_PROTOTYPES
 148 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 149
 150 AM_PROG_CC_C_O
 151
 152 dnl Work out how to specify the linker script to the linker.
 153 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 154 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 155     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 156 AC_SUBST(VERSION_SCRIPT_FLAGS)
 157
 158 dnl Check support for 64 bit file offsets.
 159 AC_SYS_LARGEFILE
 160
 161 dnl Check sizeof long.
 162 AC_CHECK_SIZEOF([long])
 163
 164 dnl Define a C symbol for the host CPU architecture.
 165 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 166
 167 dnl Headers.
 168 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 169
 170 dnl Functions.
 171 AC_CHECK_FUNCS([futimens posix_fallocate])
 172
 173 dnl Build the daemon?
 174 AC_MSG_CHECKING([if we should build the daemon])
 175 AC_ARG_ENABLE([daemon],
 176         [AS_HELP_STRING([--enable-daemon],
 177           [enable building the daemon @<:@default=yes@:>@])],
 178         [],
 179         [enable_daemon=yes])
 180 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 181 AC_MSG_RESULT([$enable_daemon])
 182
 183 dnl Build the appliance?
 184 AC_MSG_CHECKING([if we should build the appliance])
 185 AC_ARG_ENABLE([appliance],
 186         [AS_HELP_STRING([--enable-appliance],
 187           [enable building the appliance @<:@default=yes@:>@])],
 188         [],
 189         [enable_appliance=yes])
 190 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 191 AC_MSG_RESULT([$enable_appliance])
 192
 193 if test "x$enable_appliance" = "xyes"; then
 194     dnl Check for febootstrap >= 3.0
 195     AC_CHECK_PROG([FEBOOTSTRAP],
 196                   [febootstrap],[febootstrap],[no])
 197     test "x$FEBOOTSTRAP" = "xno" &&
 198         AC_MSG_ERROR([febootstrap must be installed])
 199     dnl febootstrap 2.x did not support the --version parameter
 200     $FEBOOTSTRAP --version >&AS_MESSAGE_LOG_FD 2>&1 ||
 201         AC_MSG_ERROR([febootstrap >= 3.0 must be installed, your version is too old])
 202
 203     dnl Pass a febootstrap --yum-config option.
 204     AC_MSG_CHECKING([if user requested febootstrap --yum-config option])
 205     AC_ARG_WITH([febootstrap-yum-config],
 206         [AS_HELP_STRING([--with-febootstrap-yum-config=FILE],
 207           [pass febootstrap --yum-config option @<:@default=no@:>@])],
 208         [FEBOOTSTRAP_YUM_CONFIG="$withval"],
 209         [FEBOOTSTRAP_YUM_CONFIG=no])
 210     AC_MSG_RESULT([$FEBOOTSTRAP_YUM_CONFIG])
 211     AC_SUBST([FEBOOTSTRAP_YUM_CONFIG])
 212
 213     dnl Which distro?
 214     dnl
 215     dnl This used to be Very Important but is now just used to select
 216     dnl which packages to install in the appliance, since the package
 217     dnl names vary slightly across distros.  (See
 218     dnl appliance/packagelist.in and appliance/excludelist.in)
 219     AC_MSG_CHECKING([which Linux distro for package names])
 220     DISTRO=REDHAT
 221     if test -f /etc/debian_version; then
 222         DISTRO=DEBIAN
 223         if grep -q 'DISTRIB_ID=Ubuntu' /etc/lsb-release 2>&AS_MESSAGE_LOG_FD; then
 224             DISTRO=UBUNTU
 225         fi
 226     fi
 227     if test -f /etc/arch-release; then
 228         DISTRO=ARCHLINUX
 229     fi
 230     AC_MSG_RESULT([$DISTRO])
 231     AC_SUBST([DISTRO])
 232 fi
 233
 234 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 235 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 236 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 237 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 238         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 239         ])
 240
 241 dnl Check for cpio which isn't in the default Pardus install amazingly.
 242 AC_CHECK_PROG([CPIO],[cpio],[cpio],[no])
 243 test "x$CPIO" = "xno" &&
 244      AC_MSG_ERROR([cpio must be installed])
 245
 246 dnl Check for gperf.
 247 AC_CHECK_PROG([GPERF],[gperf],[gperf],[no])
 248 test "x$GPERF" = "xno" &&
 249      AC_MSG_ERROR([gperf must be installed])
 250
 251 dnl Check for pod2man, pod2text, pod2html.
 252 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 253 test "x$POD2MAN" = "xno" &&
 254      AC_MSG_ERROR([pod2man must be installed])
 255 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 256 test "x$POD2TEXT" = "xno" &&
 257      AC_MSG_ERROR([pod2text must be installed])
 258 AC_CHECK_PROG([POD2HTML],[pod2html],[pod2html],[no])
 259 test "x$POD2HTML" = "xno" &&
 260      AC_MSG_ERROR([pod2html must be installed])
 261
 262 dnl Check if pod2man, pod2text take --stderr and -u options (not in RHEL 5).
 263 AC_MSG_CHECKING([if pod2man takes --stderr option])
 264 if "$POD2MAN" --stderr >&AS_MESSAGE_LOG_FD 2>&1; then
 265     AC_MSG_RESULT([yes])
 266     POD2_STDERR_OPTION="--stderr"
 267 else
 268     AC_MSG_RESULT([no])
 269     POD2_STDERR_OPTION=""
 270 fi
 271 AC_SUBST([POD2_STDERR_OPTION])
 272
 273 AC_MSG_CHECKING([if pod2man takes -u option])
 274 if "$POD2MAN" -u >&AS_MESSAGE_LOG_FD 2>&1; then
 275     AC_MSG_RESULT([yes])
 276     POD2_UTF8_OPTION="-u"
 277 else
 278     AC_MSG_RESULT([no])
 279     POD2_UTF8_OPTION=""
 280 fi
 281 AC_SUBST([POD2_UTF8_OPTION])
 282
 283 dnl Check for genisoimage.
 284 AC_PATH_PROGS([GENISOIMAGE],[genisoimage],[no],
 285         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 286 test "x$GENISOIMAGE" = "xno" && AC_MSG_ERROR([genisoimage must be installed])
 287
 288 dnl Check for optional xmllint.
 289 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 290 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 291
 292 dnl po4a for translating man pages and POD files (optional).
 293 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
 294 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
 295
 296 dnl Check for db_dump, db_load (optional).
 297 AC_CHECK_PROGS([DB_DUMP],
 298                [db_dump db4_dump db4.8_dump db4.7_dump db4.6_dump],[no])
 299 AC_CHECK_PROGS([DB_LOAD],
 300                [db_load db4_load db4.8_load db4.7_load db4.6_load],[no])
 301 if test "x$DB_DUMP" != "xno"; then
 302     AC_DEFINE_UNQUOTED([DB_DUMP],["$DB_DUMP"],[Name of db_dump program.])
 303 fi
 304 if test "x$DB_LOAD" != "xno"; then
 305     AC_DEFINE_UNQUOTED([DB_LOAD],["$DB_LOAD"],[Name of db_load program.])
 306 fi
 307
 308 dnl Check for QEMU for running binaries on this $host_cpu, fall
 309 dnl back to basic 'qemu'.  Allow the user to override it.
 310 default_qemu="qemu-kvm kvm qemu-system-$host_cpu qemu"
 311 AC_ARG_WITH([qemu],
 312         [AS_HELP_STRING([--with-qemu],
 313           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 314         [],
 315         [with_qemu="$default_qemu"])
 316 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 317         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 318 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 319 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 320
 321 dnl Check that the chosen qemu has virtio-serial support.
 322 if test "x$vmchannel_test" != "xno"; then
 323     AC_MSG_CHECKING([that $QEMU -help works])
 324     if $QEMU -help >&AS_MESSAGE_LOG_FD 2>&1; then
 325         AC_MSG_RESULT([yes])
 326     else
 327         AC_MSG_RESULT([no])
 328         AC_MSG_FAILURE(
 329 [$QEMU -help: command failed.
 330
 331 This could be a very old version of qemu, or qemu might not be
 332 working.
 333 ])
 334     fi
 335
 336     AC_MSG_CHECKING([for virtio-serial support in $QEMU])
 337     if $QEMU -nographic -device \? 2>&1 | grep -sq virtio-serial; then
 338         AC_MSG_RESULT([yes])
 339     else
 340         AC_MSG_RESULT([no])
 341         AC_MSG_FAILURE(
 342 [I did not find virtio-serial support in
 343 $QEMU.
 344
 345 virtio-serial support in qemu or KVM is essential for libguestfs
 346 to operate.
 347
 348 Usually this means that you have to install a newer version of qemu
 349 and/or KVM.  Please read the relevant section in the README file for
 350 more information about this.
 351
 352 You can override this test by setting the environment variable
 353 vmchannel_test=no  However if you don't have the right support
 354 in your qemu, then this just delays the pain.
 355
 356 If I am using the wrong qemu or you want to compile qemu from source
 357 and install it in another location, then you should configure with
 358 the --with-qemu option.
 359 ])
 360     fi
 361 fi
 362
 363 dnl Set default drive interface used by the guestfs_add_drive_opts call
 364 dnl ('-drive ...,if=...' option to qemu).
 365 dnl
 366 dnl If you encounter performance problems with virtio (RHBZ#509383)
 367 dnl then try '--with-drive-if=ide'.
 368 AC_ARG_WITH([drive-if],
 369         [AS_HELP_STRING([--with-drive-if],
 370           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 371         [],
 372         [with_drive_if=virtio])
 373 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 374
 375 dnl Set interface used by the network.  Normally you should
 376 dnl leave this at the default (virtio-net-pci) but you can use the
 377 dnl alternative (ne2k_pci) because of bugs in virtio networking
 378 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 379 AC_ARG_WITH([net-if],
 380         [AS_HELP_STRING([--with-net-if],
 381           [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
 382         [],
 383         [with_net_if=virtio-net-pci])
 384 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 385
 386 dnl Enable packet dumps when in verbose mode.  This generates lots
 387 dnl of debug info, only useful for people debugging the RPC mechanism.
 388 AC_ARG_ENABLE([packet-dump],
 389         [AS_HELP_STRING([--enable-packet-dump],
 390           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 391         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 392         [])
 393
 394 dnl Readline.
 395 AC_ARG_WITH([readline],
 396     [AS_HELP_STRING([--with-readline],
 397         [support fancy command line editing @<:@default=check@:>@])],
 398     [],
 399     [with_readline=check])
 400
 401 LIBREADLINE=
 402 AS_IF([test "x$with_readline" != xno],
 403     [AC_CHECK_LIB([readline], [main],
 404         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 405          AC_DEFINE([HAVE_LIBREADLINE], [1],
 406                    [Define if you have libreadline])
 407         ],
 408         [if test "x$with_readline" != xcheck; then
 409          AC_MSG_FAILURE(
 410              [--with-readline was given, but test for readline failed])
 411          fi
 412         ], -lncurses)
 413      old_LIBS="$LIBS"
 414      LIBS="$LIBS $LIBREADLINE"
 415      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 416      LIBS="$old_LIBS"
 417     ])
 418
 419 dnl For i18n.
 420 AM_GNU_GETTEXT([external])
 421
 422 dnl libmagic (highly recommended)
 423 AC_CHECK_LIB([magic],[magic_file],
 424         [AC_CHECK_HEADER([magic.h],
 425                 [AC_SUBST([MAGIC_LIBS], ["-lmagic"])
 426                  AC_DEFINE([HAVE_LIBMAGIC],[1],[libmagic found at compile time.])
 427                 ], [])
 428         ],
 429         [AC_MSG_WARN([libmagic not found, some core features will be disabled])])
 430
 431 dnl Check for PCRE (highly recommended)
 432 PKG_CHECK_MODULES([PCRE], [libpcre],
 433         [AC_SUBST([PCRE_CFLAGS])
 434          AC_SUBST([PCRE_LIBS])
 435          AC_DEFINE([HAVE_PCRE],[1],[PCRE found at compile time.])
 436         ],
 437         [AC_MSG_WARN([PCRE not found, some core features will be disabled])])
 438
 439 dnl libvirt (highly recommended)
 440 PKG_CHECK_MODULES([LIBVIRT], [libvirt],
 441         [AC_SUBST([LIBVIRT_CFLAGS])
 442          AC_SUBST([LIBVIRT_LIBS])
 443          AC_DEFINE([HAVE_LIBVIRT],[1],[libvirt found at compile time.])
 444         ],
 445         [AC_MSG_WARN([libvirt not found, some core features will be disabled])])
 446 AM_CONDITIONAL([HAVE_LIBVIRT],[test "x$LIBVIRT_LIBS" != "x"])
 447
 448 dnl libxml2 (highly recommended)
 449 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0],
 450         [AC_SUBST([LIBXML2_CFLAGS])
 451          AC_SUBST([LIBXML2_LIBS])
 452          AC_DEFINE([HAVE_LIBXML2],[1],[libxml2 found at compile time.])
 453         ],
 454         [AC_MSG_WARN([libxml2 not found, some core features will be disabled])])
 455 AM_CONDITIONAL([HAVE_LIBXML2],[test "x$LIBXML2_LIBS" != "x"])
 456
 457 dnl libconfig (highly recommended)
 458 PKG_CHECK_MODULES([LIBCONFIG], [libconfig],
 459         [AC_SUBST([LIBCONFIG_CFLAGS])
 460          AC_SUBST([LIBCONFIG_LIBS])
 461          AC_DEFINE([HAVE_LIBCONFIG],[1],[libconfig found at compile time.])
 462         ],
 463         [AC_MSG_WARN([libconfig not found, some features will be disabled])])
 464 AM_CONDITIONAL([HAVE_LIBCONFIG],[test "x$LIBCONFIG_LIBS" != "x"])
 465
 466 dnl hivex library (highly recommended)
 467 dnl This used to be a part of libguestfs, but was spun off into its
 468 dnl own separate upstream project in libguestfs 1.0.85.
 469 PKG_CHECK_MODULES([HIVEX], [hivex],
 470         [AC_SUBST([HIVEX_CFLAGS])
 471          AC_SUBST([HIVEX_LIBS])
 472          AC_DEFINE([HAVE_HIVEX],[1],[hivex library found at compile time.])
 473         ],
 474         [AC_MSG_WARN([hivex not found, some core features will be disabled])])
 475 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HIVEX_LIBS" != "x"])
 476
 477 dnl FUSE is optional to build the FUSE module.
 478 AC_ARG_ENABLE([fuse],
 479         AS_HELP_STRING([--disable-fuse], [Disable FUSE (guestmount) support]),
 480         [],
 481         [enable_fuse=yes])
 482 AS_IF([test "x$enable_fuse" != "xno"],
 483         [PKG_CHECK_MODULES([FUSE],[fuse],,[
 484                 enable_fuse=no
 485                 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])])
 486 AM_CONDITIONAL([HAVE_FUSE],[test "x$enable_fuse" != "xno"])
 487
 488 dnl Check for OCaml (optional, for OCaml bindings).
 489 OCAMLC=no
 490 OCAMLFIND=no
 491 AC_ARG_ENABLE([ocaml],
 492         AS_HELP_STRING([--disable-ocaml], [Disable OCaml language bindings]),
 493         [],
 494         [enable_ocaml=yes])
 495 AS_IF([test "x$enable_ocaml" != "xno"],
 496         [dnl OCAMLC and OCAMLFIND have to be unset first, otherwise
 497          dnl AC_CHECK_TOOL (inside AC_PROG_OCAML) will not look.
 498          OCAMLC=
 499          OCAMLFIND=
 500          AC_PROG_OCAML
 501          AC_PROG_FINDLIB
 502
 503          AS_IF([test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"],
 504                 [AC_CHECK_OCAML_PKG([pcre])])
 505         ])
 506 AM_CONDITIONAL([HAVE_OCAML],
 507                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
 508 AM_CONDITIONAL([HAVE_OCAML_PCRE],
 509                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno" && test "x$OCAML_PKG_pcre" != "xno"])
 510
 511 dnl Check for Perl (optional, for Perl bindings).
 512 PERL=no
 513 AC_ARG_ENABLE([perl],
 514         AS_HELP_STRING([--disable-perl], [Disable Perl language bindings]),
 515         [],
 516         [enable_perl=yes])
 517 AS_IF([test "x$enable_perl" != "xno"],
 518         [
 519         PERL=
 520         AC_CHECK_PROG([PERL],[perl],[perl],[no])
 521
 522         dnl Check for Perl modules that must be present to compile and
 523         dnl test the Perl bindings.
 524         missing_perl_modules=no
 525         for pm in Test::More ExtUtils::MakeMaker; do
 526             AC_MSG_CHECKING([for $pm])
 527             if ! perl -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
 528                 AC_MSG_RESULT([no])
 529                 missing_perl_modules=yes
 530             else
 531                 AC_MSG_RESULT([yes])
 532             fi
 533         done
 534         if test "x$missing_perl_modules" = "xyes"; then
 535             AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 536         fi
 537         ])
 538 AM_CONDITIONAL([HAVE_PERL],
 539     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 540
 541 dnl Check for Python (optional, for Python bindings).
 542 PYTHON_PREFIX=
 543 PYTHON_VERSION=
 544 PYTHON_INCLUDEDIR=
 545 PYTHON_INSTALLDIR=
 546
 547 AC_ARG_ENABLE([python],
 548         AS_HELP_STRING([--disable-python], [Disable Python language bindings]),
 549         [],
 550         [enable_python=yes])
 551 AS_IF([test "x$enable_python" != "xno"],
 552         [
 553         AC_CHECK_PROG([PYTHON],[python],[python],[no])
 554
 555         if test "x$PYTHON" != "xno"; then
 556             AC_MSG_CHECKING([Python prefix])
 557             PYTHON_PREFIX=`$PYTHON -c "import sys; print (sys.prefix)"`
 558             AC_MSG_RESULT([$PYTHON_PREFIX])
 559
 560             AC_MSG_CHECKING([Python version])
 561             PYTHON_VERSION=`$PYTHON -c "import sys; print (sys.version[[0:3]])"`
 562             AC_MSG_RESULT([$PYTHON_VERSION])
 563
 564             for d in \
 565                 $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 566                 /usr/include/python$PYTHON_VERSION \
 567                 /usr/local/include/python$PYTHON_VERSION
 568             do
 569                 AC_MSG_CHECKING([Python.h in $d])
 570                 if test -r "$d/Python.h"; then
 571                     AC_MSG_RESULT([found])
 572                     PYTHON_INCLUDEDIR=$d
 573                     break
 574                 fi
 575                 AC_MSG_RESULT([not found])
 576             done
 577             if test "x$PYTHON_INCLUDEDIR" = "x"; then
 578                 AC_MSG_WARN([Python include directory not found])
 579             fi
 580
 581             AC_ARG_WITH([python-installdir],
 582                         [AS_HELP_STRING([--with-python-installdir],
 583                                         [directory to install python modules @<:@default=check@:>@])],
 584                         [PYTHON_INSTALLDIR="$withval"
 585                         AC_MSG_NOTICE([Python install dir $PYTHON_INSTALLDIR])],
 586                         [PYTHON_INSTALLDIR=check])
 587
 588             if test "x$PYTHON_INSTALLDIR" = "xcheck"; then
 589                 PYTHON_INSTALLDIR=
 590                 for d in \
 591                     $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 592                     $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 593                     /usr/lib64/python$PYTHON_VERSION/site-packages \
 594                     /usr/lib/python$PYTHON_VERSION/site-packages \
 595                     /usr/local/lib/python$PYTHON_VERSION/site-packages
 596                 do
 597                     AC_MSG_CHECKING([for $d])
 598                     if test -d "$d"; then
 599                         AC_MSG_RESULT([found])
 600                         PYTHON_INSTALLDIR=$d
 601                         break
 602                     fi
 603                     AC_MSG_RESULT([not found])
 604                 done
 605                 if test "x$PYTHON_INSTALLDIR" = "x"; then
 606                     AC_MSG_WARN([Python site-packages directory not found])
 607                 fi
 608             fi
 609
 610             old_LIBS="$LIBS"
 611             LIBS="$LIBS -lpython$PYTHON_VERSION"
 612             AC_CHECK_FUNCS([PyCapsule_New])
 613             LIBS="$old_LIBS"
 614         fi
 615
 616         AC_SUBST(PYTHON_PREFIX)
 617         AC_SUBST(PYTHON_VERSION)
 618         AC_SUBST(PYTHON_INCLUDEDIR)
 619         AC_SUBST(PYTHON_INSTALLDIR)
 620         ])
 621 AM_CONDITIONAL([HAVE_PYTHON],
 622     [test "x$PYTHON" != "xno" && test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_INSTALLDIR" != "x"])
 623
 624 dnl Check for Ruby and rake (optional, for Ruby bindings).
 625 AC_ARG_ENABLE([ruby],
 626         AS_HELP_STRING([--disable-ruby], [Disable Ruby language bindings]),
 627         [],
 628         [enable_ruby=yes])
 629 AS_IF([test "x$enable_ruby" != "xno"],
 630         [
 631         AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 632         AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 633         ])
 634 AM_CONDITIONAL([HAVE_RUBY],
 635     [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
 636
 637 dnl Check for Java.
 638 AC_ARG_WITH(java_home,
 639     [AS_HELP_STRING([--with-java-home],
 640         [specify path to JDK directory @<:@default=check@:>@])],
 641     [],
 642     [with_java_home=check])
 643
 644 if test "x$with_java_home" != "xno"; then
 645     if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
 646     then
 647         # Reject unsafe characters in $JAVA_HOME
 648         jh_lf='
 649 '
 650         case $JAVA_HOME in
 651           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 652             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 653         esac
 654         if test -d "$with_java_home"; then
 655             JAVA_HOME="$with_java_home"
 656         else
 657             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 658         fi
 659     fi
 660
 661     if test "x$JAVA_HOME" = "x"; then
 662         # Look for Java in some likely locations.
 663         for d in \
 664             /usr/lib/jvm/java \
 665             /usr/lib/jvm/java-6-openjdk
 666         do
 667             if test -d $d && test -f $d/bin/java; then
 668                 JAVA_HOME=$d
 669                 break
 670             fi
 671         done
 672     fi
 673
 674     if test "x$JAVA_HOME" != "x"; then
 675         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 676         if test ! -x "$JAVA_HOME/bin/java"; then
 677             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 678         else
 679             JAVA="$JAVA_HOME/bin/java"
 680         fi
 681         if test ! -x "$JAVA_HOME/bin/javac"; then
 682             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 683         else
 684             JAVAC="$JAVA_HOME/bin/javac"
 685         fi
 686         if test ! -x "$JAVA_HOME/bin/javah"; then
 687             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 688         else
 689             JAVAH="$JAVA_HOME/bin/javah"
 690         fi
 691         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 692             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 693         else
 694             JAVADOC="$JAVA_HOME/bin/javadoc"
 695         fi
 696         if test ! -x "$JAVA_HOME/bin/jar"; then
 697             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 698         else
 699             JAR="$JAVA_HOME/bin/jar"
 700         fi
 701         java_version=`$JAVA -version 2>&1 | grep "java version"`
 702         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 703
 704         dnl Find jni.h.
 705         AC_MSG_CHECKING([for jni.h])
 706         if test -f "$JAVA_HOME/include/jni.h"; then
 707             JNI_CFLAGS="-I$JAVA_HOME/include"
 708         else
 709             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 710                 head=`find $JAVA_HOME -name jni.h | tail -1`
 711                 dir=`dirname "$head"`
 712                 JNI_CFLAGS="-I$dir"
 713             else
 714                 AC_MSG_FAILURE([missing jni.h header file])
 715             fi
 716         fi
 717         AC_MSG_RESULT([$JNI_CFLAGS])
 718
 719         dnl Find jni_md.h.
 720         AC_MSG_CHECKING([for jni_md.h])
 721         case "$build_os" in
 722         *linux*) system="linux" ;;
 723         *SunOS*) system="solaris" ;;
 724         *cygwin*) system="win32" ;;
 725         *) system="$build_os" ;;
 726         esac
 727         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 728             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 729         else
 730             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 731                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 732                 dir=`dirname "$head"`
 733                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 734             else
 735                 AC_MSG_FAILURE([missing jni_md.h header file])
 736             fi
 737         fi
 738         AC_MSG_RESULT([$JNI_CFLAGS])
 739
 740         dnl Need extra version flag?
 741         AC_MSG_CHECKING([extra javac flags])
 742         JAVAC_FLAGS=
 743         javac_version=`$JAVAC -version 2>&1`
 744         case "$javac_version" in
 745         *Eclipse*)
 746             JAVAC_FLAGS="-source 1.5" ;;
 747         esac
 748         AC_MSG_RESULT([$JAVAC_FLAGS])
 749
 750         dnl Where to install jarfiles.
 751         dnl XXX How to make it configurable?
 752         JAR_INSTALL_DIR=\${prefix}/share/java
 753         JNI_INSTALL_DIR=\${libdir}
 754
 755         dnl JNI version.
 756         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 757         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 758         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 759         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 760     fi
 761 fi
 762
 763 AC_SUBST(JAVA_HOME)
 764 AC_SUBST(JAVA)
 765 AC_SUBST(JAVAC)
 766 AC_SUBST(JAVAH)
 767 AC_SUBST(JAVADOC)
 768 AC_SUBST(JAR)
 769 AC_SUBST(JNI_CFLAGS)
 770 AC_SUBST(JAVAC_FLAGS)
 771 AC_SUBST(JAR_INSTALL_DIR)
 772 AC_SUBST(JNI_INSTALL_DIR)
 773 AC_SUBST(JNI_VERSION_INFO)
 774
 775 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 776
 777 dnl Check for Haskell (GHC).
 778 GHC=no
 779 AC_ARG_ENABLE([haskell],
 780         AS_HELP_STRING([--disable-haskell], [Disable Haskell language bindings]),
 781         [],
 782         [enable_haskell=yes])
 783 AS_IF([test "x$enable_haskell" != "xno"],
 784         [
 785         GHC=
 786         AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 787         ])
 788 AM_CONDITIONAL([HAVE_HASKELL],
 789     [test "x$GHC" != "xno"])
 790
 791 dnl PHP
 792 PHP=no
 793 AC_ARG_ENABLE([php],
 794         AS_HELP_STRING([--disable-php], [Disable PHP language bindings]),
 795         [],
 796         [enable_php=yes])
 797 AS_IF([test "x$enable_php" != "xno"],
 798         [
 799         PHP=
 800         AC_CHECK_PROG([PHP],[php],[php],[no])
 801         AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
 802         ])
 803 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
 804
 805 dnl Check for Perl modules needed by Perl virt tools (virt-df, etc.)
 806 AS_IF([test "x$PERL" != "xno"],
 807         [
 808         missing_perl_modules=no
 809         for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper Locale::TextDomain Win::Hivex Win::Hivex::Regedit String::ShellQuote; do
 810             AC_MSG_CHECKING([for $pm])
 811             if ! $PERL -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
 812                 AC_MSG_RESULT([no])
 813                 missing_perl_modules=yes
 814             else
 815                 AC_MSG_RESULT([yes])
 816             fi
 817         done
 818         if test "x$missing_perl_modules" = "xyes"; then
 819             AC_MSG_WARN([some Perl modules required to compile the Perl virt-* tools are missing])
 820         fi
 821         ])
 822
 823 AM_CONDITIONAL([HAVE_TOOLS],
 824     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 825
 826 dnl Library versioning.
 827 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 828 AC_SUBST(MAX_PROC_NR)
 829
 830 dnl Replace libtool with a wrapper that clobbers dependency_libs in *.la files
 831 dnl http://lists.fedoraproject.org/pipermail/devel/2010-November/146343.html
 832 LIBTOOL='bash $(top_srcdir)/libtool-kill-dependency_libs.sh $(top_builddir)/libtool'
 833 AC_SUBST([LIBTOOL])
 834
 835 dnl Run in subdirs.
 836 if test "x$enable_daemon" = "xyes"; then
 837     AC_CONFIG_SUBDIRS([daemon])
 838 fi
 839
 840 dnl Produce output files.
 841 AC_CONFIG_HEADERS([config.h])
 842 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 843 AC_CONFIG_FILES([podwrapper.sh],
 844                 [chmod +x podwrapper.sh])
 845 AC_CONFIG_FILES([Makefile
 846                  appliance/Makefile
 847                  capitests/Makefile
 848                  cat/Makefile
 849                  caution/Makefile
 850                  csharp/Makefile
 851                  debian/changelog
 852                  df/Makefile
 853                  examples/Makefile
 854                  fish/Makefile
 855                  fuse/Makefile
 856                  generator/Makefile
 857                  gnulib/lib/Makefile
 858                  gnulib/tests/Makefile
 859                  haskell/Makefile
 860                  images/Makefile
 861                  inspector/Makefile
 862                  java/Makefile
 863                  libguestfs.pc
 864                  ocaml/META
 865                  ocaml/Makefile
 866                  ocaml/examples/Makefile
 867                  perl/Makefile
 868                  perl/Makefile.PL
 869                  perl/examples/Makefile
 870                  php/Makefile
 871                  po-docs/Makefile
 872                  po-docs/ja/Makefile
 873                  po-docs/uk/Makefile
 874                  po/Makefile.in
 875                  python/Makefile
 876                  python/examples/Makefile
 877                  regressions/Makefile
 878                  rescue/Makefile
 879                  resize/Makefile
 880                  ruby/Makefile
 881                  ruby/Rakefile
 882                  ruby/examples/Makefile
 883                  src/Makefile
 884                  test-tool/Makefile
 885                  tools/Makefile])
 886 AC_OUTPUT
 887
 888 dnl Produce summary.
 889 echo
 890 echo
 891 echo "------------------------------------------------------------"
 892 echo "Thank you for downloading $PACKAGE_STRING"
 893 echo
 894 echo "This is how we have configured the optional components for you today:"
 895 echo
 896 echo    "Daemon .............................. $enable_daemon"
 897 echo    "Appliance ........................... $enable_appliance"
 898 echo    "QEMU ................................ $QEMU"
 899 echo -n "OCaml bindings ...................... "
 900 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 901 echo -n "Perl bindings ....................... "
 902 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 903 echo -n "Python bindings ..................... "
 904 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 905 echo -n "Ruby bindings ....................... "
 906 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 907 echo -n "Java bindings ....................... "
 908 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 909 echo -n "Haskell bindings .................... "
 910 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 911 echo -n "PHP bindings ........................ "
 912 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 913 echo    "guestfish and C virt tools .......... yes"
 914 echo -n "Perl virt tools ..................... "
 915 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 916 echo -n "virt-resize ......................... "
 917 if test "x$HAVE_OCAML_TRUE" = "x" && test "x$HAVE_OCAML_PCRE_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 918 echo "FUSE filesystem ..................... $enable_fuse"
 919 echo
 920 echo "If any optional component is configured 'no' when you expected 'yes'"
 921 echo "then you should check the preceeding messages."
 922 echo
 923 echo "Please report bugs back to the mailing list:"
 924 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 925 echo
 926 echo "Next you should type 'make' to build the package,"
 927 echo "then 'make check' to run the tests."
 928 echo "------------------------------------------------------------"