configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2011 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  17
  18 # The major, minor, and release fields MUST be numbers.  Packagers can
  19 # add extra information using --with-extra="..." which may be any
  20 # freeform string.
  21 m4_define([libguestfs_major],   [1])
  22 m4_define([libguestfs_minor],   [14])
  23 m4_define([libguestfs_release], [4])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Stable or unstable version?
  35 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  36 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  37             AC_MSG_RESULT([stable])
  38        ],[
  39             AC_MSG_RESULT([unstable])
  40             AC_MSG_NOTICE([
  41 ***
  42 This is a development version of libguestfs. Some APIs may be unstable
  43 until they appear in a stable release of libguestfs (at which point
  44 the C API and ABI is guaranteed to remain stable forever).  For
  45 more information about stable and development branches of libguestfs
  46 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  47 ***])
  48        ])
  49
  50 dnl Extra string, a freeform string defined by packagers.
  51 AC_ARG_WITH([extra],
  52   [AS_HELP_STRING([--with-extra],
  53                   [extra version string (for use by packagers)])],
  54   [libguestfs_extra="$withval"],
  55   [libguestfs_extra=]
  56 )
  57
  58 AC_MSG_NOTICE([libguestfs version libguestfs_major.libguestfs_minor.libguestfs_release$libguestfs_extra])
  59
  60 dnl Split up the version string.
  61 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  62 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  63 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  64 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_EXTRA],["$libguestfs_extra"],[Extra version string])
  65
  66 dnl Early gnulib initialization.
  67 gl_EARLY
  68 gl_INIT
  69
  70 AC_PROG_LIBTOOL
  71
  72 AC_PROG_SED
  73
  74 dnl Check for basic C environment.
  75 AC_PROG_CC_STDC
  76 AC_PROG_INSTALL
  77 AC_PROG_CPP
  78
  79 AC_ARG_ENABLE([gcc-warnings],
  80   [AS_HELP_STRING([--enable-gcc-warnings],
  81                   [turn on lots of GCC warnings (for developers)])],
  82   [case $enableval in
  83      yes|no) ;;
  84      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  85    esac
  86    gl_gcc_warnings=$enableval],
  87   [gl_gcc_warnings=no]
  88 )
  89
  90 if test "$gl_gcc_warnings" = yes; then
  91   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  92   AC_SUBST([WERROR_CFLAGS])
  93
  94   nw=
  95   # This, $nw, is the list of warnings we disable.
  96   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  97   nw="$nw -Waggregate-return"       # anachronistic
  98   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  99   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 100   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 101   nw="$nw -Wcast-qual"              # Too many warnings for now
 102   nw="$nw -Wconversion"             # Too many warnings for now
 103   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 104   nw="$nw -Wsign-conversion"        # Too many warnings for now
 105   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 106   nw="$nw -Wunreachable-code"       # Too many warnings for now
 107   nw="$nw -Wpadded"                 # Our structs are not padded
 108   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 109   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 110   nw="$nw -Wvla"                    # two warnings in mount.c
 111   # things I might fix soon:
 112   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 113   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 114   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 115   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 116                                     # was not possible, safe to ignore
 117   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 118   nw="$nw -Wlong-long"              # Allow long long since it's required
 119                                     # by Python, Ruby and xstrtoll.
 120   nw="$nw -Wstack-protector"        # Don't warn about stack-protector
 121                                     # failures (seen on Ubuntu).
 122   nw="$nw -Wmissing-noreturn"       # Don't warn about missed noreturn funcs
 123                                     # (seen on Ubuntu).
 124   nw="$nw -Wsuggest-attribute=pure" # Don't suggest pure functions.
 125   nw="$nw -Wsuggest-attribute=const" # Don't suggest const functions.
 126   nw="$nw -Wunsuffixed-float-constants" # Don't care about these.
 127
 128   gl_MANYWARN_ALL_GCC([ws])
 129   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 130   for w in $ws; do
 131     gl_WARN_ADD([$w])
 132   done
 133   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 134   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 135   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 136
 137   # In spite of excluding -Wlogical-op above, it is enabled, as of
 138   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 139   gl_WARN_ADD([-Wno-logical-op])
 140
 141   # Work around warning in src/inspect.c.  This seems to be a bug in gcc 4.5.1.
 142   gl_WARN_ADD([-Wno-strict-overflow])
 143
 144   gl_WARN_ADD([-fdiagnostics-show-option])
 145
 146   AC_SUBST([WARN_CFLAGS])
 147
 148   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 149   AC_DEFINE([_FORTIFY_SOURCE], [2],
 150     [enable compile-time and run-time bounds-checking, and some warnings])
 151   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 152 fi
 153
 154 AC_C_PROTOTYPES
 155 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 156
 157 AM_PROG_CC_C_O
 158
 159 dnl Work out how to specify the linker script to the linker.
 160 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 161 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 162     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 163 AC_SUBST(VERSION_SCRIPT_FLAGS)
 164
 165 dnl Check support for 64 bit file offsets.
 166 AC_SYS_LARGEFILE
 167
 168 dnl Check sizeof long.
 169 AC_CHECK_SIZEOF([long])
 170
 171 dnl Check if dirent (readdir) supports d_type member.
 172 AC_STRUCT_DIRENT_D_TYPE
 173
 174 dnl Check if stat has the required fields.
 175 AC_STRUCT_ST_BLOCKS
 176 AC_CHECK_MEMBER([struct stat.st_blksize],[
 177         AC_DEFINE([HAVE_STRUCT_STAT_ST_BLKSIZE],[1],[Define to 1 if 'st_blksize' is a member of 'struct stat'])])
 178
 179 dnl Define a C symbol for the host CPU architecture.
 180 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 181
 182 dnl Headers.
 183 AC_CHECK_HEADERS([\
 184         attr/xattr.h \
 185         byteswap.h \
 186         endian.h \
 187         errno.h \
 188         printf.h \
 189         sys/inotify.h \
 190         sys/socket.h \
 191         sys/statvfs.h \
 192         sys/types.h \
 193         sys/un.h \
 194         sys/wait.h \
 195         windows.h \
 196         sys/xattr.h])
 197
 198 dnl Functions.
 199 AC_CHECK_FUNCS([\
 200         futimens \
 201         getxattr \
 202         htonl \
 203         htons \
 204         inotify_init1 \
 205         lgetxattr \
 206         listxattr \
 207         llistxattr \
 208         lsetxattr \
 209         lremovexattr \
 210         mknod \
 211         ntohl \
 212         ntohs \
 213         posix_fallocate \
 214         realpath \
 215         removexattr \
 216         setitimer \
 217         setxattr \
 218         sigaction \
 219         statvfs \
 220         sync])
 221
 222 dnl For modified printf in the daemon, we need glibc either (old-style)
 223 dnl register_printf_function or (new-style) register_printf_specifier.
 224 AC_CHECK_FUNC([register_printf_specifier],[
 225         AC_DEFINE([HAVE_REGISTER_PRINTF_SPECIFIER],[1],
 226                 [Define to 1 if you have new-style register_printf_specifier])
 227         ],[
 228         AC_CHECK_FUNC([register_printf_function],[
 229                 AC_DEFINE([HAVE_REGISTER_PRINTF_FUNCTION],[1],
 230                         [Define to 1 if you have old-style register_printf_function])
 231                 ],[
 232                 AC_MSG_FAILURE(
 233 [No support for glibc-style extended printf formatters.
 234
 235 This means you either have a very old glibc (pre-2.0) or you
 236 are using some other libc where this is not supported.])])])
 237
 238 dnl Build the daemon?
 239 AC_MSG_CHECKING([if we should build the daemon])
 240 AC_ARG_ENABLE([daemon],
 241         [AS_HELP_STRING([--enable-daemon],
 242           [enable building the daemon @<:@default=yes@:>@])],
 243         [],
 244         [enable_daemon=yes])
 245 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 246 AC_MSG_RESULT([$enable_daemon])
 247
 248 if test "x$enable_daemon" = "xyes"; then
 249         dnl Install the daemon (for libguestfs live service)
 250         AC_MSG_CHECKING([if we should install the daemon])
 251         AC_ARG_ENABLE([install-daemon],
 252                 [AS_HELP_STRING([--enable-install-daemon],
 253                   [enable installing the daemon under $sbindir @<:@default=no@:>@])],
 254                 [],
 255                 [enable_install_daemon=no])
 256         AM_CONDITIONAL([INSTALL_DAEMON],[test "x$enable_install_daemon" = "xyes"])
 257         AC_MSG_RESULT([$enable_install_daemon])
 258 fi
 259
 260 dnl Build the appliance?
 261 AC_MSG_CHECKING([if we should build the appliance])
 262 AC_ARG_ENABLE([appliance],
 263         [AS_HELP_STRING([--enable-appliance],
 264           [enable building the appliance @<:@default=yes@:>@])],
 265         [],
 266         [enable_appliance=yes])
 267 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 268 AC_MSG_RESULT([$enable_appliance])
 269
 270 if test "x$enable_appliance" = "xyes"; then
 271     dnl Check for febootstrap >= 3.0
 272     AC_CHECK_PROG([FEBOOTSTRAP],
 273                   [febootstrap],[febootstrap],[no])
 274     test "x$FEBOOTSTRAP" = "xno" &&
 275         AC_MSG_ERROR([febootstrap must be installed])
 276     dnl febootstrap 2.x did not support the --version parameter
 277     $FEBOOTSTRAP --version >&AS_MESSAGE_LOG_FD 2>&1 ||
 278         AC_MSG_ERROR([febootstrap >= 3.0 must be installed, your version is too old])
 279
 280     dnl Pass a febootstrap --yum-config option.
 281     AC_MSG_CHECKING([if user requested febootstrap --yum-config option])
 282     AC_ARG_WITH([febootstrap-yum-config],
 283         [AS_HELP_STRING([--with-febootstrap-yum-config=FILE],
 284           [pass febootstrap --yum-config option @<:@default=no@:>@])],
 285         [FEBOOTSTRAP_YUM_CONFIG="$withval"],
 286         [FEBOOTSTRAP_YUM_CONFIG=no])
 287     AC_MSG_RESULT([$FEBOOTSTRAP_YUM_CONFIG])
 288     AC_SUBST([FEBOOTSTRAP_YUM_CONFIG])
 289
 290     dnl Which distro?
 291     dnl
 292     dnl This used to be Very Important but is now just used to select
 293     dnl which packages to install in the appliance, since the package
 294     dnl names vary slightly across distros.  (See
 295     dnl appliance/packagelist.in and appliance/excludelist.in)
 296     AC_MSG_CHECKING([which Linux distro for package names])
 297     DISTRO=REDHAT
 298     if test -f /etc/debian_version; then
 299         DISTRO=DEBIAN
 300         if grep -q 'DISTRIB_ID=Ubuntu' /etc/lsb-release 2>&AS_MESSAGE_LOG_FD; then
 301             DISTRO=UBUNTU
 302         fi
 303     fi
 304     if test -f /etc/arch-release; then
 305         DISTRO=ARCHLINUX
 306     fi
 307     AC_MSG_RESULT([$DISTRO])
 308     AC_SUBST([DISTRO])
 309 fi
 310
 311 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 312 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 313 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 314 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 315         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 316         ])
 317
 318 dnl Check for Augeas (now optional).
 319 AC_CHECK_LIB([augeas],[aug_match],[
 320         have_augeas=yes
 321         AUGEAS_LIB="-laugeas"
 322
 323         old_LIBS="$LIBS"
 324         LIBS="$LIBS $AUGEAS_LIB"
 325         dnl Check for functions not available in earlier versions of Augeas.
 326         AC_CHECK_FUNCS([aug_load aug_defvar aug_defnode])
 327         LIBS="$old_LIBS"
 328
 329         ],[have_augeas=no])
 330 if test "x$have_augeas" = "xyes"; then
 331         AC_DEFINE([HAVE_AUGEAS],[1],[Define to 1 if you have Augeas])
 332 fi
 333 AC_SUBST([AUGEAS_LIB])
 334
 335 dnl Check for libselinux (optional).
 336 AC_CHECK_HEADERS([selinux/selinux.h])
 337 AC_CHECK_LIB([selinux],[setexeccon],[
 338         have_libselinux="$ac_cv_header_selinux_selinux_h"
 339         SELINUX_LIB="-lselinux"
 340
 341         old_LIBS="$LIBS"
 342         LIBS="$LIBS $SELINUX_LIB"
 343         AC_CHECK_FUNCS([setcon getcon])
 344         LIBS="$old_LIBS"
 345
 346         ],[have_libselinux=no])
 347 if test "x$have_libselinux" = "xyes"; then
 348         AC_DEFINE([HAVE_LIBSELINUX],[1],[Define to 1 if you have libselinux])
 349 fi
 350 AC_SUBST([SELINUX_LIB])
 351
 352 dnl Check for systemtap/DTrace userspace probes (optional).
 353 dnl http://sourceware.org/systemtap/wiki/AddingUserSpaceProbingToApps
 354 AC_CHECK_HEADERS([sys/sdt.h])
 355 dnl AC_CHECK_PROG([DTRACE],[dtrace],[dtrace],[no])
 356
 357 dnl Check for cpio which isn't in the default Pardus install amazingly.
 358 AC_CHECK_PROG([CPIO],[cpio],[cpio],[no])
 359 test "x$CPIO" = "xno" &&
 360      AC_MSG_ERROR([cpio must be installed])
 361
 362 dnl Check for gperf.
 363 AC_CHECK_PROG([GPERF],[gperf],[gperf],[no])
 364 test "x$GPERF" = "xno" &&
 365      AC_MSG_ERROR([gperf must be installed])
 366
 367 dnl Check for pod2man, pod2text, pod2html.
 368 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 369 test "x$POD2MAN" = "xno" &&
 370      AC_MSG_ERROR([pod2man must be installed])
 371 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 372 test "x$POD2TEXT" = "xno" &&
 373      AC_MSG_ERROR([pod2text must be installed])
 374 AC_CHECK_PROG([POD2HTML],[pod2html],[pod2html],[no])
 375 test "x$POD2HTML" = "xno" &&
 376      AC_MSG_ERROR([pod2html must be installed])
 377
 378 dnl Check if pod2man, pod2text take --stderr and -u options (not in RHEL 5).
 379 AC_MSG_CHECKING([if pod2man takes --stderr option])
 380 if "$POD2MAN" --stderr >&AS_MESSAGE_LOG_FD 2>&1; then
 381     AC_MSG_RESULT([yes])
 382     POD2_STDERR_OPTION="--stderr"
 383 else
 384     AC_MSG_RESULT([no])
 385     POD2_STDERR_OPTION=""
 386 fi
 387 AC_SUBST([POD2_STDERR_OPTION])
 388
 389 AC_MSG_CHECKING([if pod2man takes -u option])
 390 if "$POD2MAN" -u >&AS_MESSAGE_LOG_FD 2>&1; then
 391     AC_MSG_RESULT([yes])
 392     POD2_UTF8_OPTION="-u"
 393 else
 394     AC_MSG_RESULT([no])
 395     POD2_UTF8_OPTION=""
 396 fi
 397 AC_SUBST([POD2_UTF8_OPTION])
 398
 399 dnl Check for genisoimage.
 400 AC_PATH_PROGS([GENISOIMAGE],[genisoimage],[no],
 401         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 402 test "x$GENISOIMAGE" = "xno" && AC_MSG_ERROR([genisoimage must be installed])
 403
 404 dnl Check for optional xmllint.
 405 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 406 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 407
 408 dnl po4a for translating man pages and POD files (optional).
 409 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
 410 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
 411
 412 dnl Check for db_dump, db_load (optional).
 413 AC_CHECK_PROGS([DB_DUMP],
 414                [db_dump db4_dump db4.8_dump db4.7_dump db4.6_dump],[no])
 415 AC_CHECK_PROGS([DB_LOAD],
 416                [db_load db4_load db4.8_load db4.7_load db4.6_load],[no])
 417 if test "x$DB_DUMP" != "xno"; then
 418     AC_DEFINE_UNQUOTED([DB_DUMP],["$DB_DUMP"],[Name of db_dump program.])
 419 fi
 420 if test "x$DB_LOAD" != "xno"; then
 421     AC_DEFINE_UNQUOTED([DB_LOAD],["$DB_LOAD"],[Name of db_load program.])
 422 fi
 423
 424 dnl Check for QEMU for running binaries on this $host_cpu, fall
 425 dnl back to basic 'qemu'.  Allow the user to override it.
 426 default_qemu="qemu-kvm kvm qemu-system-$host_cpu qemu"
 427 AC_ARG_WITH([qemu],
 428         [AS_HELP_STRING([--with-qemu],
 429           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 430         [],
 431         [with_qemu="$default_qemu"])
 432 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 433         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 434 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 435 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 436
 437 dnl Check that the chosen qemu has virtio-serial support.
 438 if test "x$vmchannel_test" != "xno"; then
 439     AC_MSG_CHECKING([that $QEMU -help works])
 440     if $QEMU -help >&AS_MESSAGE_LOG_FD 2>&1; then
 441         AC_MSG_RESULT([yes])
 442     else
 443         AC_MSG_RESULT([no])
 444         AC_MSG_FAILURE(
 445 [$QEMU -help: command failed.
 446
 447 This could be a very old version of qemu, or qemu might not be
 448 working.
 449 ])
 450     fi
 451
 452     dnl qemu 0.15 was released with broken support for '-machine',
 453     dnl requiring you to add the machine type: '-machine pc,[...]'.
 454     dnl The problem is that 'pc' is only applicable for PC-like
 455     dnl hardware, so we cannot do this as a general solution.  Since
 456     dnl qemu 0.15, this problem has been fixed so now the default
 457     dnl machine type is chosen (qemu commit 2645c6dcaf6ea2a51a).
 458     dnl
 459     dnl We need to work out if this qemu is the broken version, so we
 460     dnl can add 'pc' just for this broken version.
 461     dnl
 462     dnl Note that old qemu didn't support the '-machine' option at all.
 463     dnl
 464     dnl We use the -kernel option for testing this, because this option
 465     dnl is processed very late, after qemu has set up the machine.
 466     AC_MSG_CHECKING([for broken '-machine accel=tcg' option in $QEMU])
 467     LC_ALL=C $QEMU -nographic -machine accel=tcg -kernel /NO_SUCH_FILE \
 468              > config1.tmp 2>&1
 469     LC_ALL=C $QEMU -nographic -machine pc,accel=tcg -kernel /NO_SUCH_FILE \
 470              > config2.tmp 2>&1
 471     if cmp -s config1.tmp config2.tmp; then
 472         AC_MSG_RESULT([no])
 473     else
 474         AC_MSG_RESULT([yes])
 475         AC_DEFINE([QEMU_MACHINE_TYPE_IS_BROKEN],[1],[qemu -machine accel=tcg option is broken (in qemu 0.15 only)])
 476     fi
 477     rm config1.tmp config2.tmp
 478
 479     dnl See if the '-machine [pc,]accel=tcg' option is required in
 480     dnl order to run the virtio-serial test below.  This happens when
 481     dnl we run qemu-kvm inside a VM without forcing TCG:
 482     dnl
 483     dnl   Could not access KVM kernel module: No such file or directory
 484     dnl   failed to initialize KVM: No such file or directory
 485     dnl   No accelerator found!
 486     AC_MSG_CHECKING([if -machine @<:@pc,@:>@accel=tcg option is required to test virtio-serial feature])
 487     if $QEMU -nographic -device \? >/dev/null 2>&1; then
 488         :
 489     elif $QEMU -machine accel=tcg -nographic -device \? >/dev/null 2>&1; then
 490         QEMU_EXTRA_OPTIONS_FOR_TEST="-machine accel=tcg"
 491     elif $QEMU -machine pc,accel=tcg -nographic -device \? >/dev/null 2>&1; then
 492         QEMU_EXTRA_OPTIONS_FOR_TEST="-machine pc,accel=tcg"
 493     # else nothing ... it'll fail below.
 494     fi
 495     AC_MSG_RESULT([$QEMU_EXTRA_OPTIONS_FOR_TEST])
 496
 497     AC_MSG_CHECKING([for virtio-serial support in $QEMU])
 498     if $QEMU $QEMU_EXTRA_OPTIONS_FOR_TEST -nographic -device \? 2>&1 | grep -sq virtio-serial; then
 499         AC_MSG_RESULT([yes])
 500     else
 501         AC_MSG_RESULT([no])
 502         AC_MSG_FAILURE(
 503 [I did not find virtio-serial support in
 504 $QEMU.
 505
 506 virtio-serial support in qemu or KVM is essential for libguestfs
 507 to operate.
 508
 509 Usually this means that you have to install a newer version of qemu
 510 and/or KVM.  Please read the relevant section in the README file for
 511 more information about this.
 512
 513 You can override this test by setting the environment variable
 514 vmchannel_test=no  However if you don't have the right support
 515 in your qemu, then this just delays the pain.
 516
 517 If I am using the wrong qemu or you want to compile qemu from source
 518 and install it in another location, then you should configure with
 519 the --with-qemu option.
 520 ])
 521     fi
 522 fi
 523
 524 dnl Set default drive interface used by the guestfs_add_drive_opts call
 525 dnl ('-drive ...,if=...' option to qemu).
 526 dnl
 527 dnl If you encounter performance problems with virtio (RHBZ#509383)
 528 dnl then try '--with-drive-if=ide'.
 529 AC_ARG_WITH([drive-if],
 530         [AS_HELP_STRING([--with-drive-if],
 531           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 532         [],
 533         [with_drive_if=virtio])
 534 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 535
 536 dnl Set interface used by the network.  Normally you should
 537 dnl leave this at the default (virtio-net-pci) but you can use the
 538 dnl alternative (ne2k_pci) because of bugs in virtio networking
 539 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 540 AC_ARG_WITH([net-if],
 541         [AS_HELP_STRING([--with-net-if],
 542           [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
 543         [],
 544         [with_net_if=virtio-net-pci])
 545 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 546
 547 dnl Enable packet dumps when in verbose mode.  This generates lots
 548 dnl of debug info, only useful for people debugging the RPC mechanism.
 549 AC_ARG_ENABLE([packet-dump],
 550         [AS_HELP_STRING([--enable-packet-dump],
 551           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 552         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 553         [])
 554
 555 dnl Readline.
 556 AC_ARG_WITH([readline],
 557     [AS_HELP_STRING([--with-readline],
 558         [support fancy command line editing @<:@default=check@:>@])],
 559     [],
 560     [with_readline=check])
 561
 562 LIBREADLINE=
 563 AS_IF([test "x$with_readline" != xno],
 564     [AC_CHECK_LIB([readline], [main],
 565         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 566          AC_DEFINE([HAVE_LIBREADLINE], [1],
 567                    [Define if you have libreadline])
 568         ],
 569         [if test "x$with_readline" != xcheck; then
 570          AC_MSG_FAILURE(
 571              [--with-readline was given, but test for readline failed])
 572          fi
 573         ], -lncurses)
 574      old_LIBS="$LIBS"
 575      LIBS="$LIBS $LIBREADLINE"
 576      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 577      LIBS="$old_LIBS"
 578     ])
 579
 580 dnl For i18n.
 581 AM_GNU_GETTEXT([external])
 582
 583 dnl Check for PCRE (required)
 584 PKG_CHECK_MODULES([PCRE], [libpcre])
 585
 586 dnl libmagic (highly recommended)
 587 AC_CHECK_LIB([magic],[magic_file],
 588         [AC_CHECK_HEADER([magic.h],
 589                 [AC_SUBST([MAGIC_LIBS], ["-lmagic"])
 590                  AC_DEFINE([HAVE_LIBMAGIC],[1],[libmagic found at compile time.])
 591                 ], [])
 592         ],
 593         [AC_MSG_WARN([libmagic not found, some core features will be disabled])])
 594
 595 dnl libvirt (highly recommended)
 596 PKG_CHECK_MODULES([LIBVIRT], [libvirt],
 597         [AC_SUBST([LIBVIRT_CFLAGS])
 598          AC_SUBST([LIBVIRT_LIBS])
 599          AC_DEFINE([HAVE_LIBVIRT],[1],[libvirt found at compile time.])
 600         ],
 601         [AC_MSG_WARN([libvirt not found, some core features will be disabled])])
 602 AM_CONDITIONAL([HAVE_LIBVIRT],[test "x$LIBVIRT_LIBS" != "x"])
 603
 604 dnl libxml2 (highly recommended)
 605 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0],
 606         [AC_SUBST([LIBXML2_CFLAGS])
 607          AC_SUBST([LIBXML2_LIBS])
 608          AC_DEFINE([HAVE_LIBXML2],[1],[libxml2 found at compile time.])
 609         ],
 610         [AC_MSG_WARN([libxml2 not found, some core features will be disabled])])
 611 AM_CONDITIONAL([HAVE_LIBXML2],[test "x$LIBXML2_LIBS" != "x"])
 612
 613 dnl libconfig (highly recommended)
 614 PKG_CHECK_MODULES([LIBCONFIG], [libconfig],
 615         [AC_SUBST([LIBCONFIG_CFLAGS])
 616          AC_SUBST([LIBCONFIG_LIBS])
 617          AC_DEFINE([HAVE_LIBCONFIG],[1],[libconfig found at compile time.])
 618         ],
 619         [AC_MSG_WARN([libconfig not found, some features will be disabled])])
 620 AM_CONDITIONAL([HAVE_LIBCONFIG],[test "x$LIBCONFIG_LIBS" != "x"])
 621
 622 dnl hivex library (highly recommended)
 623 dnl This used to be a part of libguestfs, but was spun off into its
 624 dnl own separate upstream project in libguestfs 1.0.85.
 625 PKG_CHECK_MODULES([HIVEX], [hivex],
 626         [AC_SUBST([HIVEX_CFLAGS])
 627          AC_SUBST([HIVEX_LIBS])
 628          AC_DEFINE([HAVE_HIVEX],[1],[hivex library found at compile time.])
 629         ],
 630         [AC_MSG_WARN([hivex not found, some core features will be disabled])])
 631 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HIVEX_LIBS" != "x"])
 632
 633 dnl FUSE is optional to build the FUSE module.
 634 AC_ARG_ENABLE([fuse],
 635         AS_HELP_STRING([--disable-fuse], [Disable FUSE (guestmount) support]),
 636         [],
 637         [enable_fuse=yes])
 638 AS_IF([test "x$enable_fuse" != "xno"],
 639         [PKG_CHECK_MODULES([FUSE],[fuse],,[
 640                 enable_fuse=no
 641                 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])])
 642 AM_CONDITIONAL([HAVE_FUSE],[test "x$enable_fuse" != "xno"])
 643
 644 dnl Check for OCaml (optional, for OCaml bindings).
 645 OCAMLC=no
 646 OCAMLFIND=no
 647 AC_ARG_ENABLE([ocaml],
 648         AS_HELP_STRING([--disable-ocaml], [Disable OCaml language bindings]),
 649         [],
 650         [enable_ocaml=yes])
 651 AS_IF([test "x$enable_ocaml" != "xno"],
 652         [dnl OCAMLC and OCAMLFIND have to be unset first, otherwise
 653          dnl AC_CHECK_TOOL (inside AC_PROG_OCAML) will not look.
 654          OCAMLC=
 655          OCAMLFIND=
 656          AC_PROG_OCAML
 657          AC_PROG_FINDLIB
 658         ])
 659 AM_CONDITIONAL([HAVE_OCAML],
 660                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
 661 AM_CONDITIONAL([HAVE_OCAMLDOC],
 662                [test "x$OCAMLDOC" != "xno"])
 663
 664 dnl Check for Perl (optional, for Perl bindings).
 665 PERL=no
 666 AC_ARG_ENABLE([perl],
 667         AS_HELP_STRING([--disable-perl], [Disable Perl language bindings]),
 668         [],
 669         [enable_perl=yes])
 670 AS_IF([test "x$enable_perl" != "xno"],
 671         [
 672         PERL=
 673         AC_CHECK_PROG([PERL],[perl],[perl],[no])
 674
 675         dnl Check for Perl modules that must be present to compile and
 676         dnl test the Perl bindings.
 677         missing_perl_modules=no
 678         for pm in Test::More ExtUtils::MakeMaker; do
 679             AC_MSG_CHECKING([for $pm])
 680             if ! perl -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
 681                 AC_MSG_RESULT([no])
 682                 missing_perl_modules=yes
 683             else
 684                 AC_MSG_RESULT([yes])
 685             fi
 686         done
 687         if test "x$missing_perl_modules" = "xyes"; then
 688             AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 689         fi
 690         ])
 691 AM_CONDITIONAL([HAVE_PERL],
 692     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 693
 694 dnl Check for Python (optional, for Python bindings).
 695 PYTHON_PREFIX=
 696 PYTHON_VERSION=
 697 PYTHON_INCLUDEDIR=
 698 PYTHON_INSTALLDIR=
 699
 700 AC_ARG_ENABLE([python],
 701         AS_HELP_STRING([--disable-python], [Disable Python language bindings]),
 702         [],
 703         [enable_python=yes])
 704 AS_IF([test "x$enable_python" != "xno"],
 705         [
 706         AC_CHECK_PROG([PYTHON],[python],[python],[no])
 707
 708         if test "x$PYTHON" != "xno"; then
 709             AC_MSG_CHECKING([Python prefix])
 710             PYTHON_PREFIX=`$PYTHON -c "import sys; print (sys.prefix)"`
 711             AC_MSG_RESULT([$PYTHON_PREFIX])
 712
 713             AC_MSG_CHECKING([Python version])
 714             PYTHON_VERSION_MAJOR=`$PYTHON -c "import sys; print (sys.version_info@<:@0@:>@)"`
 715             PYTHON_VERSION_MINOR=`$PYTHON -c "import sys; print (sys.version_info@<:@1@:>@)"`
 716             PYTHON_VERSION="$PYTHON_VERSION_MAJOR.$PYTHON_VERSION_MINOR"
 717             AC_MSG_RESULT([$PYTHON_VERSION])
 718
 719             AC_MSG_CHECKING([for Python include path])
 720             if test -z "$PYTHON_INCLUDEDIR"; then
 721                 python_path=`$PYTHON -c "import distutils.sysconfig; \
 722                                          print (distutils.sysconfig.get_python_inc ());"`
 723                 PYTHON_INCLUDEDIR=$python_path
 724             fi
 725             AC_MSG_RESULT([$PYTHON_INCLUDEDIR])
 726
 727             AC_ARG_WITH([python-installdir],
 728                         [AS_HELP_STRING([--with-python-installdir],
 729                                         [directory to install python modules @<:@default=check@:>@])],
 730                         [PYTHON_INSTALLDIR="$withval"
 731                         AC_MSG_NOTICE([Python install dir $PYTHON_INSTALLDIR])],
 732                         [PYTHON_INSTALLDIR=check])
 733
 734             if test "x$PYTHON_INSTALLDIR" = "xcheck"; then
 735                 PYTHON_INSTALLDIR=
 736                 AC_MSG_CHECKING([for Python site-packages path])
 737                 if test -z "$PYTHON_INSTALLDIR"; then
 738                     PYTHON_INSTALLDIR=`$PYTHON -c "import distutils.sysconfig; \
 739                                                    print (distutils.sysconfig.get_python_lib(1,0));"`
 740                 fi
 741                 AC_MSG_RESULT([$PYTHON_INSTALLDIR])
 742             fi
 743
 744             dnl Look for libpython and some optional symbols in it.
 745             old_LIBS="$LIBS"
 746             if test "x$PYTHON_VERSION_MAJOR" = "x3"; then
 747                 dnl libpython3 is called "libpython3.Xmu.so"
 748                 LIBPYTHON="python${PYTHON_VERSION}mu"
 749             else
 750                 LIBPYTHON="python$PYTHON_VERSION"
 751             fi
 752             AC_CHECK_LIB([$LIBPYTHON], [PyList_Size], [],
 753                          [AC_MSG_FAILURE([$LIBPYTHON is not installed])])
 754
 755             AC_CHECK_FUNCS([PyCapsule_New \
 756                             PyString_AsString])
 757             LIBS="$old_LIBS"
 758         fi
 759
 760         AC_SUBST(PYTHON_PREFIX)
 761         AC_SUBST(PYTHON_VERSION)
 762         AC_SUBST(PYTHON_INCLUDEDIR)
 763         AC_SUBST(PYTHON_INSTALLDIR)
 764         ])
 765 AM_CONDITIONAL([HAVE_PYTHON],
 766     [test "x$PYTHON" != "xno" && test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_INSTALLDIR" != "x"])
 767
 768 dnl Check for Ruby and rake (optional, for Ruby bindings).
 769 AC_ARG_ENABLE([ruby],
 770         AS_HELP_STRING([--disable-ruby], [Disable Ruby language bindings]),
 771         [],
 772         [enable_ruby=yes])
 773 AS_IF([test "x$enable_ruby" != "xno"],
 774         [
 775         AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 776         AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 777         ])
 778 AM_CONDITIONAL([HAVE_RUBY],
 779     [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
 780
 781 dnl Check for Java.
 782 AC_ARG_WITH(java_home,
 783     [AS_HELP_STRING([--with-java-home],
 784         [specify path to JDK directory @<:@default=check@:>@])],
 785     [],
 786     [with_java_home=check])
 787
 788 if test "x$with_java_home" != "xno"; then
 789     if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
 790     then
 791         # Reject unsafe characters in $JAVA_HOME
 792         jh_lf='
 793 '
 794         case $JAVA_HOME in
 795           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 796             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 797         esac
 798         if test -d "$with_java_home"; then
 799             JAVA_HOME="$with_java_home"
 800         else
 801             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 802         fi
 803     fi
 804
 805     if test "x$JAVA_HOME" = "x"; then
 806         # Look for Java in some likely locations.
 807         for d in \
 808             /usr/lib/jvm/java \
 809             /usr/lib/jvm/java-6-openjdk
 810         do
 811             if test -d $d && test -f $d/bin/java; then
 812                 JAVA_HOME=$d
 813                 break
 814             fi
 815         done
 816     fi
 817
 818     if test "x$JAVA_HOME" != "x"; then
 819         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 820         if test ! -x "$JAVA_HOME/bin/java"; then
 821             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 822         else
 823             JAVA="$JAVA_HOME/bin/java"
 824         fi
 825         if test ! -x "$JAVA_HOME/bin/javac"; then
 826             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 827         else
 828             JAVAC="$JAVA_HOME/bin/javac"
 829         fi
 830         if test ! -x "$JAVA_HOME/bin/javah"; then
 831             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 832         else
 833             JAVAH="$JAVA_HOME/bin/javah"
 834         fi
 835         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 836             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 837         else
 838             JAVADOC="$JAVA_HOME/bin/javadoc"
 839         fi
 840         if test ! -x "$JAVA_HOME/bin/jar"; then
 841             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 842         else
 843             JAR="$JAVA_HOME/bin/jar"
 844         fi
 845         java_version=`$JAVA -version 2>&1 | grep "java version"`
 846         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 847
 848         dnl Find jni.h.
 849         AC_MSG_CHECKING([for jni.h])
 850         if test -f "$JAVA_HOME/include/jni.h"; then
 851             JNI_CFLAGS="-I$JAVA_HOME/include"
 852         else
 853             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 854                 head=`find $JAVA_HOME -name jni.h | tail -1`
 855                 dir=`dirname "$head"`
 856                 JNI_CFLAGS="-I$dir"
 857             else
 858                 AC_MSG_FAILURE([missing jni.h header file])
 859             fi
 860         fi
 861         AC_MSG_RESULT([$JNI_CFLAGS])
 862
 863         dnl Find jni_md.h.
 864         AC_MSG_CHECKING([for jni_md.h])
 865         case "$build_os" in
 866         *linux*) system="linux" ;;
 867         *SunOS*) system="solaris" ;;
 868         *cygwin*) system="win32" ;;
 869         *) system="$build_os" ;;
 870         esac
 871         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 872             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 873         else
 874             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 875                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 876                 dir=`dirname "$head"`
 877                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 878             else
 879                 AC_MSG_FAILURE([missing jni_md.h header file])
 880             fi
 881         fi
 882         AC_MSG_RESULT([$JNI_CFLAGS])
 883
 884         dnl Need extra version flag?
 885         AC_MSG_CHECKING([extra javac flags])
 886         JAVAC_FLAGS=
 887         javac_version=`$JAVAC -version 2>&1`
 888         case "$javac_version" in
 889         *Eclipse*)
 890             JAVAC_FLAGS="-source 1.5" ;;
 891         esac
 892         AC_MSG_RESULT([$JAVAC_FLAGS])
 893
 894         dnl Where to install jarfiles.
 895         dnl XXX How to make it configurable?
 896         JAR_INSTALL_DIR=\${prefix}/share/java
 897         JNI_INSTALL_DIR=\${libdir}
 898
 899         dnl JNI version.
 900         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 901         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 902         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 903         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 904     fi
 905 fi
 906
 907 AC_SUBST(JAVA_HOME)
 908 AC_SUBST(JAVA)
 909 AC_SUBST(JAVAC)
 910 AC_SUBST(JAVAH)
 911 AC_SUBST(JAVADOC)
 912 AC_SUBST(JAR)
 913 AC_SUBST(JNI_CFLAGS)
 914 AC_SUBST(JAVAC_FLAGS)
 915 AC_SUBST(JAR_INSTALL_DIR)
 916 AC_SUBST(JNI_INSTALL_DIR)
 917 AC_SUBST(JNI_VERSION_INFO)
 918
 919 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 920
 921 dnl Check for Haskell (GHC).
 922 GHC=no
 923 AC_ARG_ENABLE([haskell],
 924         AS_HELP_STRING([--disable-haskell], [Disable Haskell language bindings]),
 925         [],
 926         [enable_haskell=yes])
 927 AS_IF([test "x$enable_haskell" != "xno"],
 928         [
 929         GHC=
 930         AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 931         ])
 932 AM_CONDITIONAL([HAVE_HASKELL],
 933     [test "x$GHC" != "xno"])
 934
 935 dnl PHP
 936 PHP=no
 937 AC_ARG_ENABLE([php],
 938         AS_HELP_STRING([--disable-php], [Disable PHP language bindings]),
 939         [],
 940         [enable_php=yes])
 941 AS_IF([test "x$enable_php" != "xno"],
 942         [
 943         PHP=
 944         AC_CHECK_PROG([PHP],[php],[php],[no])
 945         AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
 946         ])
 947 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
 948
 949 dnl Erlang
 950 ERLANG=no
 951 AC_ARG_ENABLE([erlang],
 952     AS_HELP_STRING([--disable-erlang], [Disable Erlang language bindings]),
 953          [],
 954          [enable_erlang=yes])
 955 # NB: Don't use AS_IF here: it doesn't work.
 956 if test "x$enable_erlang" != "xno"; then
 957         ERLANG=
 958         AC_ERLANG_PATH_ERLC([no])
 959
 960         if test "x$ERLC" != "xno"; then
 961             AC_ERLANG_CHECK_LIB([erl_interface], [],
 962                                 [AC_MSG_FAILURE([Erlang erl_interface library not installed.  Use --disable-erlang to disable.])])
 963             AC_ERLANG_SUBST_LIB_DIR
 964         fi
 965 fi
 966 AM_CONDITIONAL([HAVE_ERLANG], [test "x$ERLANG" != "xno" && test "x$ERLC" != "xno"])
 967
 968 dnl Check for Perl modules needed by Perl virt tools (virt-df, etc.)
 969 AS_IF([test "x$PERL" != "xno"],
 970         [
 971         missing_perl_modules=no
 972         for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper Locale::TextDomain Win::Hivex Win::Hivex::Regedit String::ShellQuote; do
 973             AC_MSG_CHECKING([for $pm])
 974             if ! $PERL -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
 975                 AC_MSG_RESULT([no])
 976                 missing_perl_modules=yes
 977             else
 978                 AC_MSG_RESULT([yes])
 979             fi
 980         done
 981         if test "x$missing_perl_modules" = "xyes"; then
 982             AC_MSG_WARN([some Perl modules required to compile the Perl virt-* tools are missing])
 983         fi
 984         ])
 985
 986 AM_CONDITIONAL([HAVE_TOOLS],
 987     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 988
 989 dnl Library versioning.
 990 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 991 AC_SUBST(MAX_PROC_NR)
 992
 993 dnl Replace libtool with a wrapper that clobbers dependency_libs in *.la files
 994 dnl http://lists.fedoraproject.org/pipermail/devel/2010-November/146343.html
 995 LIBTOOL='bash $(top_srcdir)/libtool-kill-dependency_libs.sh $(top_builddir)/libtool'
 996 AC_SUBST([LIBTOOL])
 997
 998 dnl Produce output files.
 999 AC_CONFIG_HEADERS([config.h])
1000 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
1001 AC_CONFIG_FILES([clone/virt-sysprep],
1002                 [chmod +x clone/virt-sysprep])
1003 AC_CONFIG_FILES([podwrapper.sh],
1004                 [chmod +x podwrapper.sh])
1005 AC_CONFIG_FILES([run],
1006                 [chmod +x run])
1007 AC_CONFIG_FILES([Makefile
1008                  align/Makefile
1009                  appliance/Makefile
1010                  capitests/Makefile
1011                  cat/Makefile
1012                  caution/Makefile
1013                  clone/Makefile
1014                  csharp/Makefile
1015                  daemon/Makefile
1016                  debian/changelog
1017                  df/Makefile
1018                  edit/Makefile
1019                  erlang/Makefile
1020                  erlang/examples/Makefile
1021                  examples/Makefile
1022                  extratests/Makefile
1023                  fish/Makefile
1024                  fuse/Makefile
1025                  generator/Makefile
1026                  gnulib/lib/Makefile
1027                  gnulib/tests/Makefile
1028                  haskell/Makefile
1029                  images/Makefile
1030                  inspector/Makefile
1031                  java/Makefile
1032                  java/examples/Makefile
1033                  libguestfs.pc
1034                  ocaml/META
1035                  ocaml/Makefile
1036                  ocaml/examples/Makefile
1037                  perl/Makefile
1038                  perl/Makefile.PL
1039                  perl/examples/Makefile
1040                  php/Makefile
1041                  po-docs/Makefile
1042                  po-docs/ja/Makefile
1043                  po-docs/uk/Makefile
1044                  po/Makefile.in
1045                  python/Makefile
1046                  python/examples/Makefile
1047                  regressions/Makefile
1048                  rescue/Makefile
1049                  resize/Makefile
1050                  ruby/Makefile
1051                  ruby/Rakefile
1052                  ruby/examples/Makefile
1053                  sparsify/Makefile
1054                  src/Makefile
1055                  test-tool/Makefile
1056                  tools/Makefile])
1057 AC_OUTPUT
1058
1059 dnl Produce summary.
1060 echo
1061 echo
1062 echo "------------------------------------------------------------"
1063 echo "Thank you for downloading $PACKAGE_STRING"
1064 echo
1065 echo "This is how we have configured the optional components for you today:"
1066 echo
1067 echo    "Daemon .............................. $enable_daemon"
1068 echo    "Appliance ........................... $enable_appliance"
1069 echo    "QEMU ................................ $QEMU"
1070 echo -n "OCaml bindings ...................... "
1071 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1072 echo -n "Perl bindings ....................... "
1073 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1074 echo -n "Python bindings ..................... "
1075 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1076 echo -n "Ruby bindings ....................... "
1077 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1078 echo -n "Java bindings ....................... "
1079 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1080 echo -n "Haskell bindings .................... "
1081 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1082 echo -n "PHP bindings ........................ "
1083 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1084 echo -n "Erlang bindings ..................... "
1085 if test "x$HAVE_ERLANG_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1086 echo    "guestfish and C virt tools .......... yes"
1087 echo -n "Perl virt tools ..................... "
1088 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1089 echo -n "virt-resize ......................... "
1090 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1091 echo "FUSE filesystem ..................... $enable_fuse"
1092 echo
1093 echo "If any optional component is configured 'no' when you expected 'yes'"
1094 echo "then you should check the preceeding messages."
1095 echo
1096 echo "Please report bugs back to the mailing list:"
1097 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
1098 echo
1099 echo "Next you should type 'make' to build the package,"
1100 echo "then 'make check' to run the tests."
1101 echo "------------------------------------------------------------"