2 # Copyright (C) 2009-2010 Red Hat Inc.
4 # This program is free software; you can redistribute it and/or modify
5 # it under the terms of the GNU General Public License as published by
6 # the Free Software Foundation; either version 2 of the License, or
7 # (at your option) any later version.
9 # This program is distributed in the hope that it will be useful,
10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
12 # GNU General Public License for more details.
14 # You should have received a copy of the GNU General Public License
15 # along with this program; if not, write to the Free Software
16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
18 # major/minor/release must be numbers
19 m4_define([libguestfs_major], [1])
20 m4_define([libguestfs_minor], [3])
21 m4_define([libguestfs_release], [17])
22 # extra can be any string
23 m4_define([libguestfs_extra], [])
25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release[]libguestfs_extra)
26 AC_CONFIG_AUX_DIR([build-aux])
27 AM_INIT_AUTOMAKE([foreign])
29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
32 AC_CONFIG_MACRO_DIR([m4])
34 dnl Split up the version string.
35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
40 dnl Stable or unstable version?
41 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
42 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
43 AC_MSG_RESULT([stable])
45 AC_MSG_RESULT([unstable])
48 This is a development version of libguestfs. Some APIs may be unstable
49 until they appear in a stable release of libguestfs (at which point
50 the C API and ABI is guaranteed to remain stable forever). For
51 more information about stable and development branches of libguestfs
52 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
56 dnl Die if the user tries to configure as root, see:
57 dnl https://www.redhat.com/archives/libguestfs/2010-April/msg00098.html
58 AC_MSG_CHECKING([if you are trying to configure as root])
59 AS_IF([test "`id -u`" = 0 ],[
61 AC_MSG_FAILURE([Don't run './configure' or 'make' as root.])
66 dnl Early gnulib initialization.
72 dnl Check for basic C environment.
77 AC_ARG_ENABLE([gcc-warnings],
78 [AS_HELP_STRING([--enable-gcc-warnings],
79 [turn on lots of GCC warnings (for developers)])],
82 *) AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
84 gl_gcc_warnings=$enableval],
88 if test "$gl_gcc_warnings" = yes; then
89 gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
90 AC_SUBST([WERROR_CFLAGS])
93 # This, $nw, is the list of warnings we disable.
94 nw="$nw -Wdeclaration-after-statement" # too useful to forbid
95 nw="$nw -Waggregate-return" # anachronistic
96 nw="$nw -Wc++-compat" # We don't care about C++ compilers
97 nw="$nw -Wundef" # Warns on '#if GNULIB_FOO' etc in gnulib
98 nw="$nw -Wtraditional" # Warns on #elif which we use often
99 nw="$nw -Wcast-qual" # Too many warnings for now
100 nw="$nw -Wconversion" # Too many warnings for now
101 nw="$nw -Wsystem-headers" # Don't let system headers trigger warnings
102 nw="$nw -Wsign-conversion" # Too many warnings for now
103 nw="$nw -Wtraditional-conversion" # Too many warnings for now
104 nw="$nw -Wunreachable-code" # Too many warnings for now
105 nw="$nw -Wpadded" # Our structs are not padded
106 nw="$nw -Wredundant-decls" # openat.h declares e.g., mkdirat
107 nw="$nw -Wlogical-op" # any use of fwrite provokes this
108 nw="$nw -Wvla" # two warnings in mount.c
109 # things I might fix soon:
110 nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
111 nw="$nw -Winline" # daemon.h's asprintf_nowarn
112 nw="$nw -Wshadow" # numerous, plus we're not unanimous
113 # ?? -Wstrict-overflow
114 nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
115 # was not possible, safe to ignore
116 nw="$nw -Wpacked" # Allow attribute((packed)) on structs
118 gl_MANYWARN_ALL_GCC([ws])
119 gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
123 gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
124 gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
125 gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
127 # In spite of excluding -Wlogical-op above, it is enabled, as of
128 # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
129 gl_WARN_ADD([-Wno-logical-op])
131 gl_WARN_ADD([-fdiagnostics-show-option])
133 AC_SUBST([WARN_CFLAGS])
135 AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
136 AC_DEFINE([_FORTIFY_SOURCE], [2],
137 [enable compile-time and run-time bounds-checking, and some warnings])
138 AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
142 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
146 dnl Work out how to specify the linker script to the linker.
147 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
148 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
149 VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
150 AC_SUBST(VERSION_SCRIPT_FLAGS)
152 dnl Check support for 64 bit file offsets.
155 dnl Check sizeof long.
156 AC_CHECK_SIZEOF([long])
158 dnl Define a C symbol for the host CPU architecture.
159 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
162 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
165 AC_CHECK_FUNCS([posix_fallocate])
167 dnl Build the daemon?
168 AC_MSG_CHECKING([if we should build the daemon])
169 AC_ARG_ENABLE([daemon],
170 [AS_HELP_STRING([--enable-daemon],
171 [enable building the daemon @<:@default=yes@:>@])],
174 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
175 AC_MSG_RESULT([$enable_daemon])
177 dnl Build the appliance?
178 AC_MSG_CHECKING([if we should build the appliance])
179 AC_ARG_ENABLE([appliance],
180 [AS_HELP_STRING([--enable-appliance],
181 [enable building the appliance @<:@default=yes@:>@])],
183 [enable_appliance=yes])
184 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
185 AC_MSG_RESULT([$enable_appliance])
187 dnl Check for rpcgen and XDR library. rpcgen is optional.
188 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
189 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
190 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
191 AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
194 dnl Check for pod2man and pod2text.
195 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
196 test "x$POD2MAN" = "xno" &&
197 AC_MSG_ERROR([pod2man must be installed])
198 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
199 test "x$POD2TEXT" = "xno" &&
200 AC_MSG_ERROR([pod2text must be installed])
202 dnl Check for mkisofs.
203 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
204 [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
205 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
207 dnl Check for optional xmllint.
208 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
209 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
211 dnl Check for QEMU for running binaries on this $host_cpu, fall
212 dnl back to basic 'qemu'. Allow the user to override it.
213 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
215 [AS_HELP_STRING([--with-qemu],
216 [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
218 [with_qemu="$default_qemu"])
219 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
220 [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
221 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
222 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
224 dnl Check that the chosen qemu has vmchannel support or we can
225 dnl fallback to null vmchannel (still using SLIRP). See the
226 dnl discussion in the README file.
227 if test "x$vmchannel_test" != "xno"; then
228 AC_MSG_CHECKING([for guestfwd support in $QEMU])
229 if $QEMU -nographic --help | grep -sq guestfwd; then
231 vmchannel_guestfwd=guestfwd
234 # Note that this test must be conditional on the previous
235 # test failing. This is because recent qemu will throw
236 # up an SDL window and hang if we try to run this test.
237 AC_MSG_CHECKING([for "-net channel" (old guestfwd) support in $QEMU])
238 vmchannelout=`$QEMU -nographic -net channel /dev/zero 2>&1 ||:`
239 echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
240 if echo "$vmchannelout" | grep -sq "vmchannel wrong port number" ; then
242 vmchannel_guestfwd=net_channel
245 vmchannel_guestfwd=no
249 AC_MSG_CHECKING([for "-net user" (user mode network) support in $QEMU])
250 if $QEMU -nographic --help | grep -sq -- "-net user"; then
252 vmchannel_net_user=yes
255 vmchannel_net_user=no
258 if test "x$vmchannel_net_user" = "xno" -a "x$vmchannel_guestfwd" = "xno"; then
260 [I did not find user mode network or vmchannel support in
263 Either user mode networking or vmchannel support is vital for
264 libguestfs to operate.
266 Please read the relevant section in the README file for more
267 information about this.
269 You can override this test by setting the environment variable
270 vmchannel_test=no However if you don't have the right support
271 in your qemu, then this just delays the pain.
273 If I am using the wrong qemu or you want to compile qemu from source
274 and install it in another location, then you should configure with
275 the --with-qemu option.
280 dnl Set drive interface used by the guestfs_add_drive{,_ro} calls
281 dnl ('-drive ...,if=...' option to qemu).
283 dnl If you encounter performance problems with virtio (RHBZ#509383)
284 dnl then try '--with-drive-if=ide'.
285 AC_ARG_WITH([drive-if],
286 [AS_HELP_STRING([--with-drive-if],
287 [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
289 [with_drive_if=virtio])
290 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
292 dnl Set interface used by the network. Normally you should
293 dnl leave this at the default (virtio) but you can use the
294 dnl alternative (ne2k_pci) because of bugs in virtio networking
295 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
296 AC_ARG_WITH([net-if],
297 [AS_HELP_STRING([--with-net-if],
298 [set default net driver (virtio|ne2k_pci) @<:@default=virtio@:>@])],
300 [with_net_if=virtio])
301 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
303 dnl Check for febootstrap etc.
304 if test "x$enable_appliance" = "xyes"; then
305 AC_CHECK_PROG([FEBOOTSTRAP],
306 [febootstrap],[febootstrap],[no])
307 if test "x$FEBOOTSTRAP" != "xno"; then
308 AC_CHECK_PROG([FEBOOTSTRAP_RUN],
309 [febootstrap-run],[febootstrap-run],[no])
310 test "x$FEBOOTSTRAP_RUN" = "xno" && \
311 AC_MSG_ERROR([febootstrap-run must be installed])
312 AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
313 [febootstrap-install],[febootstrap-install],[no])
314 test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
315 AC_MSG_ERROR([febootstrap-install must be installed])
316 AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
317 [febootstrap-minimize],[febootstrap-minimize],[no])
318 test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
319 AC_MSG_ERROR([febootstrap-minimize must be installed])
320 AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
321 [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
322 test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
323 AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
324 AC_CHECK_PROG([FEBOOTSTRAP_TO_SUPERMIN],
325 [febootstrap-to-supermin],[febootstrap-to-supermin],[no])
326 test "x$FEBOOTSTRAP_TO_SUPERMIN" = "xno" && \
327 AC_MSG_ERROR([febootstrap-to-supermin must be installed])
329 dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
330 dnl of febootstrap, but old versions will fail with yum).
331 AC_CHECK_PROG([FAKECHROOT],
332 [fakechroot],[fakechroot],[no])
333 test "x$FAKECHROOT" = "xno" && \
334 AC_MSG_ERROR([fakechroot must be installed])
336 AC_MSG_CHECKING([fakechroot version])
337 fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
338 if test -z "$fakechroot_version"; then
339 AC_MSG_RESULT([failed])
340 AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
342 AC_MSG_RESULT([$fakechroot_version])
343 fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
344 fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
345 if test "$fakechroot_major" -lt 2 -o \
346 \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
347 AC_MSG_ERROR([fakechroot version must be >= 2.9])
352 # check for debootstrap and debirf
353 AC_CHECK_PROG([DEBOOTSTRAP],
354 [debootstrap],[debootstrap],[no])
355 test "x$DEBOOTSTRAP" = "xno" && \
356 AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
357 AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
358 test "x$DEBIRF" = "xno" &&
359 AC_MSG_ERROR([debirf must be installed])
363 DEBIAN_KERNEL_ARCH=486
366 DEBIAN_KERNEL_ARCH=amd64
369 DEBIAN_KERNEL_ARCH=$host_cpu
372 AC_SUBST(DEBIAN_KERNEL_ARCH)
376 dnl --with-updates to specify a Fedora updates repository.
377 AC_ARG_WITH([updates],
378 [AS_HELP_STRING([--with-updates],
379 [set name of Fedora updates repository @<:@default=updates-released-f12@:>@])],
381 [with_updates=updates-released-f12])
382 UPDATES="$with_updates"
385 dnl --with-mirror to specify a local Fedora mirror.
386 AC_ARG_WITH([mirror],
387 [AS_HELP_STRING([--with-mirror],
388 [set URI of a local Fedora mirror])],
391 MIRROR="$with_mirror"
395 dnl --with-repo to specify a Fedora repository.
397 [AS_HELP_STRING([--with-repo],
398 [set name of Fedora repository @<:@default=fedora-12@:>@])],
400 [with_repo=fedora-12])
403 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
405 dnl Build the supermin appliance? Please see README file before
406 dnl enabling this option.
407 AC_ARG_ENABLE([supermin],
408 [AS_HELP_STRING([--enable-supermin],
409 [enable supermin appliance (see README) @<:@default=no@:>@])],
411 [enable_supermin=no])
412 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
414 dnl Enable packet dumps when in verbose mode. This generates lots
415 dnl of debug info, only useful for people debugging the RPC mechanism.
416 AC_ARG_ENABLE([packet-dump],
417 [AS_HELP_STRING([--enable-packet-dump],
418 [enable packet dumps in verbose mode @<:@default=no@:>@])],
419 [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
423 AC_ARG_WITH([readline],
424 [AS_HELP_STRING([--with-readline],
425 [support fancy command line editing @<:@default=check@:>@])],
427 [with_readline=check])
430 AS_IF([test "x$with_readline" != xno],
431 [AC_CHECK_LIB([readline], [main],
432 [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
433 AC_DEFINE([HAVE_LIBREADLINE], [1],
434 [Define if you have libreadline])
436 [if test "x$with_readline" != xcheck; then
438 [--with-readline was given, but test for readline failed])
442 LIBS="$LIBS $LIBREADLINE"
443 AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
448 AM_GNU_GETTEXT([external])
449 AM_GNU_GETTEXT_VERSION([0.17])
451 dnl hivex library (highly recommended).
452 dnl This used to be a part of libguestfs, but was spun off into its
453 dnl own separate upstream project in libguestfs 1.0.85.
455 PKG_CHECK_MODULES([HIVEX], [hivex],,[
457 AC_MSG_WARN([Hivex library and headers are missing, so optional Windows Registry tools won't be built])])
458 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HAVE_HIVEX" = "xyes"])
459 AC_SUBST([HIVEX_CFLAGS])
460 AC_SUBST([HIVEX_LIBS])
462 dnl FUSE is optional to build the FUSE module.
464 PKG_CHECK_MODULES([FUSE],[fuse],,[
466 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])
467 AM_CONDITIONAL([HAVE_FUSE],[test "x$HAVE_FUSE" = "xyes"])
469 dnl Check for OCaml (optional, for OCaml bindings).
472 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
474 dnl Optional xml-light for running the generator.
475 OCAML_PKG_xml_light=no
476 if test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"; then
477 AC_CHECK_OCAML_PKG([xml-light])
479 AM_CONDITIONAL([HAVE_XML_LIGHT],[test "x$OCAML_PKG_xml_light" != "xno"])
481 dnl Build the OCaml viewer example. This has a lengthy list of
482 dnl dependencies and we don't attempt to detect them all. Read
483 dnl the top of ocaml/examples/viewer.ml before enabling this.
484 AC_ARG_ENABLE([ocaml-viewer],
485 [AS_HELP_STRING([--enable-ocaml-viewer],
486 [enable OCaml viewer (see ocaml/examples) @<:@default=no@:>@])],
488 [enable_ocaml_viewer=no])
489 AM_CONDITIONAL([BUILD_OCAML_VIEWER],[test "x$enable_ocaml_viewer" = "xyes"])
491 dnl Check for Perl (optional, for Perl bindings).
492 dnl XXX This isn't quite right, we should check for Perl devel library.
493 AC_CHECK_PROG([PERL],[perl],[perl],[no])
495 dnl Check for Perl modules that must be present to compile and
496 dnl test the Perl bindings.
497 missing_perl_modules=no
498 for pm in Test::More ExtUtils::MakeMaker; do
499 AC_MSG_CHECKING([for $pm])
500 if ! perl -M$pm -e1 >/dev/null 2>&1; then
502 missing_perl_modules=yes
507 if test "x$missing_perl_modules" = "xyes"; then
508 AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
511 AM_CONDITIONAL([HAVE_PERL],
512 [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
514 dnl Check for Python (optional, for Python bindings).
515 AC_CHECK_PROG([PYTHON],[python],[python],[no])
520 PYTHON_SITE_PACKAGES=
522 if test "x$PYTHON" != "xno"; then
523 PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
524 PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
526 $PYTHON_PREFIX/include/python$PYTHON_VERSION \
527 /usr/include/python$PYTHON_VERSION \
528 /usr/local/include/python$PYTHON_VERSION
530 AC_MSG_CHECKING([Python.h in $d])
531 if test -r "$d/Python.h"; then
532 AC_MSG_RESULT([found])
536 AC_MSG_RESULT([not found])
539 $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
540 $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
541 /usr/lib64/python$PYTHON_VERSION/site-packages \
542 /usr/lib/python$PYTHON_VERSION/site-packages \
543 /usr/local/lib/python$PYTHON_VERSION/site-packages
545 AC_MSG_CHECKING([for $d])
546 if test -d "$d"; then
547 AC_MSG_RESULT([found])
548 PYTHON_SITE_PACKAGES=$d
551 AC_MSG_RESULT([not found])
555 AC_SUBST(PYTHON_PREFIX)
556 AC_SUBST(PYTHON_VERSION)
557 AC_SUBST(PYTHON_INCLUDEDIR)
558 AC_SUBST(PYTHON_SITE_PACKAGES)
560 AM_CONDITIONAL([HAVE_PYTHON],
561 [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
563 dnl Check for Ruby and rake (optional, for Ruby bindings).
564 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
565 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
567 AM_CONDITIONAL([HAVE_RUBY],
568 [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
571 AC_ARG_WITH(java_home,
572 [AS_HELP_STRING([--with-java-home],
573 [specify path to JDK directory @<:@default=check@:>@])],
575 [with_java_home=check])
577 if test "x$with_java_home" != "xno"; then
578 if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
580 # Reject unsafe characters in $JAVA_HOME
584 *[\\\"\#\$\&\'\`$jh_lf\ \ ]*)
585 AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
587 if test -d "$with_java_home"; then
588 JAVA_HOME="$with_java_home"
590 AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
594 if test "x$JAVA_HOME" = "x"; then
595 # Look for Java in some likely locations.
598 /usr/lib/jvm/java-6-openjdk
600 if test -d $d -a -f $d/bin/java; then
607 if test "x$JAVA_HOME" != "x"; then
608 AC_MSG_CHECKING(for JDK in $JAVA_HOME)
609 if test ! -x "$JAVA_HOME/bin/java"; then
610 AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
612 JAVA="$JAVA_HOME/bin/java"
614 if test ! -x "$JAVA_HOME/bin/javac"; then
615 AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
617 JAVAC="$JAVA_HOME/bin/javac"
619 if test ! -x "$JAVA_HOME/bin/javah"; then
620 AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
622 JAVAH="$JAVA_HOME/bin/javah"
624 if test ! -x "$JAVA_HOME/bin/javadoc"; then
625 AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
627 JAVADOC="$JAVA_HOME/bin/javadoc"
629 if test ! -x "$JAVA_HOME/bin/jar"; then
630 AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
632 JAR="$JAVA_HOME/bin/jar"
634 java_version=`$JAVA -version 2>&1 | grep "java version"`
635 AC_MSG_RESULT(found $java_version in $JAVA_HOME)
638 AC_MSG_CHECKING([for jni.h])
639 if test -f "$JAVA_HOME/include/jni.h"; then
640 JNI_CFLAGS="-I$JAVA_HOME/include"
642 if test "`find $JAVA_HOME -name jni.h`" != ""; then
643 head=`find $JAVA_HOME -name jni.h | tail -1`
644 dir=`dirname "$head"`
647 AC_MSG_FAILURE([missing jni.h header file])
650 AC_MSG_RESULT([$JNI_CFLAGS])
653 AC_MSG_CHECKING([for jni_md.h])
655 *linux*) system="linux" ;;
656 *SunOS*) system="solaris" ;;
657 *cygwin*) system="win32" ;;
658 *) system="$build_os" ;;
660 if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
661 JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
663 if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
664 head=`find $JAVA_HOME -name jni_md.h | tail -1`
665 dir=`dirname "$head"`
666 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
668 AC_MSG_FAILURE([missing jni_md.h header file])
671 AC_MSG_RESULT([$JNI_CFLAGS])
673 dnl Need extra version flag?
674 AC_MSG_CHECKING([extra javac flags])
676 javac_version=`$JAVAC -version 2>&1`
677 case "$javac_version" in
679 JAVAC_FLAGS="-source 1.5" ;;
681 AC_MSG_RESULT([$JAVAC_FLAGS])
683 dnl Where to install jarfiles.
684 dnl XXX How to make it configurable?
685 JAR_INSTALL_DIR=\${prefix}/share/java
686 JNI_INSTALL_DIR=\${libdir}
689 jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
690 jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
691 jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
692 JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
703 AC_SUBST(JAVAC_FLAGS)
704 AC_SUBST(JAR_INSTALL_DIR)
705 AC_SUBST(JNI_INSTALL_DIR)
706 AC_SUBST(JNI_VERSION_INFO)
708 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
710 dnl Check for Haskell (GHC).
711 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
713 AM_CONDITIONAL([HAVE_HASKELL],
714 [test "x$GHC" != "xno"])
716 dnl Check for Perl modules needed by virt-df, inspector, etc.
717 missing_perl_modules=no
718 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer Locale::TextDomain Win::Hivex Win::Hivex::Regedit; do
719 AC_MSG_CHECKING([for $pm])
720 if ! perl -M$pm -e1 >/dev/null 2>&1; then
722 missing_perl_modules=yes
727 if test "x$missing_perl_modules" = "xyes"; then
728 AC_MSG_WARN([some Perl modules required to compile virt-inspector and the other virt-* tools are missing])
731 AM_CONDITIONAL([HAVE_INSPECTOR],
732 [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
733 AM_CONDITIONAL([HAVE_TOOLS],
734 [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
736 dnl Library versioning.
737 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
738 AC_SUBST(MAX_PROC_NR)
741 if test "x$enable_daemon" = "xyes"; then
742 AC_CONFIG_SUBDIRS([daemon])
745 dnl Produce output files.
746 AC_CONFIG_HEADERS([config.h])
747 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
748 AC_CONFIG_FILES([appliance/update.sh],
749 [chmod +x appliance/update.sh])
750 AC_CONFIG_FILES([Makefile
751 src/Makefile fish/Makefile po/Makefile.in examples/Makefile
753 appliance/debian/debirf.conf
758 ocaml/Makefile ocaml/examples/Makefile
761 ruby/Makefile ruby/Rakefile
768 gnulib/tests/Makefile
770 ocaml/META perl/Makefile.PL])
776 echo "------------------------------------------------------------"
777 echo "Thank you for downloading $PACKAGE_STRING"
779 echo "This is how we have configured the optional components for you today:"
781 echo "Daemon .............................. $enable_daemon"
782 echo "Appliance ........................... $enable_appliance"
783 echo "QEMU ................................ $QEMU"
784 echo -n "OCaml bindings ...................... "
785 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
786 echo -n "Perl bindings ....................... "
787 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
788 echo -n "Python bindings ..................... "
789 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
790 echo -n "Ruby bindings ....................... "
791 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
792 echo -n "Java bindings ....................... "
793 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
794 echo -n "Haskell bindings .................... "
795 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
796 echo -n "virt-inspector ...................... "
797 if test "x$HAVE_INSPECTOR_TRUE" = "x"; then echo "yes"; else echo "no"; fi
798 echo -n "virt-* tools ........................ "
799 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
800 echo "supermin appliance .................. $enable_supermin"
801 echo "FUSE filesystem ..................... $HAVE_FUSE"
803 echo "If any optional component is configured 'no' when you expected 'yes'"
804 echo "then you should check the preceeding messages."
806 echo "Please report bugs back to the mailing list:"
807 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
809 echo "Next you should type 'make' to build the package,"
810 echo "then 'make check' to run the tests."
811 echo "------------------------------------------------------------"