configure.ac

   1 # virt-top
   2 # Copyright (C) 2007-2021 Red Hat Inc., Richard W.M. Jones
   3 #
   4 # This library is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU Lesser General Public
   6 # License as published by the Free Software Foundation; either
   7 # version 2 of the License, or (at your option) any later version.
   8 #
   9 # This library is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Lesser General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Lesser General Public
  15 # License along with this library; if not, write to the Free Software
  16 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  17
  18 dnl Process this file with autoconf to produce a configure script.
  19
  20 AC_INIT([virt-top],[1.1.0])
  21 AM_INIT_AUTOMAKE([foreign])
  22 AC_CONFIG_MACRO_DIR([m4])
  23
  24 AC_PROG_INSTALL
  25
  26 dnl Enable GNU stuff.
  27 AC_USE_SYSTEM_EXTENSIONS
  28
  29 dnl Check for basic C environment.
  30 AC_PROG_CC_STDC
  31 AC_PROG_CPP
  32 AC_C_PROTOTYPES
  33 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
  34 AM_PROG_CC_C_O
  35
  36 dnl Check support for 64 bit file offsets.
  37 AC_SYS_LARGEFILE
  38
  39 dnl Check for basic OCaml environment & findlib.
  40 AC_PROG_OCAML
  41 if test "$OCAMLC" = "no"; then
  42     AC_MSG_ERROR([You must install the OCaml compiler])
  43 fi
  44
  45 AM_CONDITIONAL([HAVE_OCAMLOPT],[test "$OCAMLBEST" = "opt"])
  46
  47 AC_PROG_FINDLIB
  48 if test "x$OCAMLFIND" = "xno"; then
  49     AC_MSG_ERROR([OCaml findlib is required])
  50 fi
  51
  52 dnl Use ocamlfind to find the required packages ...
  53
  54 dnl Check for required OCaml packages.
  55 AC_CHECK_OCAML_PKG(unix)
  56 if test "x$OCAML_PKG_unix" = "xno"; then
  57     AC_MSG_ERROR([Cannot find required OCaml package 'unix'])
  58 fi
  59
  60 AC_CHECK_OCAML_PKG(libvirt)
  61 if test "x$OCAML_PKG_libvirt" = "xno"; then
  62     AC_MSG_ERROR([Cannot find required OCaml package 'libvirt'])
  63 fi
  64
  65 AC_CHECK_OCAML_PKG(curses)
  66 if test "x$OCAML_PKG_curses" = "xno"; then
  67     AC_MSG_ERROR([Cannot find required OCaml package 'curses'])
  68 fi
  69
  70 dnl Check for optional OCaml packages.
  71 AC_CHECK_OCAML_PKG(calendar)
  72 AC_CHECK_OCAML_PKG(gettext)
  73 AC_CHECK_OCAML_PKG(xml-light)
  74
  75 AM_CONDITIONAL([HAVE_PKG_CALENDAR], [test "x$OCAML_PKG_calendar" != "xno"])
  76 AM_CONDITIONAL([HAVE_PKG_GETTEXT],  [test "x$OCAML_PKG_gettext" != "xno"])
  77 AM_CONDITIONAL([HAVE_PKG_XML_LIGHT],[test "x$OCAML_PKG_xml_light" != "xno"])
  78
  79 dnl Check if ocamlc/ocamlopt -runtime-variant _pic works.  It was
  80 dnl added in OCaml >= 4.03, but in theory might be disabled by
  81 dnl downstream distros.
  82 OCAML_RUNTIME_VARIANT_PIC_OPTION=""
  83 if test "x$OCAMLC" != "xno"; then
  84     AC_MSG_CHECKING([if OCaml ‘-runtime-variant _pic’ works])
  85     rm -f conftest.ml contest
  86     echo 'print_endline "hello world"' > conftest.ml
  87     if $OCAMLOPT conftest.ml -runtime-variant _pic -o conftest >&5 2>&5 ; then
  88         AC_MSG_RESULT([yes])
  89         OCAML_RUNTIME_VARIANT_PIC_OPTION="-runtime-variant _pic"
  90     else
  91         AC_MSG_RESULT([no])
  92     fi
  93     rm -f conftest.ml contest
  94 fi
  95 AC_SUBST([OCAML_RUNTIME_VARIANT_PIC_OPTION])
  96
  97 dnl Check for optional perldoc (for building manual pages).
  98 AC_CHECK_PROG([HAVE_PERLDOC], perldoc, perldoc)
  99 AM_CONDITIONAL([HAVE_PERLDOC], [test "x$HAVE_PERLDOC" = "xperldoc"])
 100
 101 dnl Check for recommended ocaml-gettext tool.
 102 AC_CHECK_PROG([OCAML_GETTEXT], ocaml-gettext, ocaml-gettext)
 103 AM_CONDITIONAL([HAVE_OCAML_GETTEXT],[test "x$OCAML_GETTEXT" = "xocaml-gettext"])
 104
 105 dnl Check for GNU gettext tools (optional).
 106 AC_CHECK_PROG([XGETTEXT],[xgettext],[xgettext],[no])
 107 AC_CHECK_PROG([MSGCAT],[msgcat],[msgcat],[no])
 108 AC_CHECK_PROG([MSGFMT],[msgfmt],[msgfmt],[no])
 109 AC_CHECK_PROG([MSGMERGE],[msgmerge],[msgmerge],[no])
 110
 111 dnl Check they are the GNU gettext tools.
 112 AC_MSG_CHECKING([msgfmt is GNU tool])
 113 if $MSGFMT --version >/dev/null 2>&1 && $MSGFMT --version | grep -q 'GNU gettext
 114 '; then
 115     msgfmt_is_gnu=yes
 116 else
 117     msgfmt_is_gnu=no
 118 fi
 119 AC_MSG_RESULT([$msgfmt_is_gnu])
 120 AM_CONDITIONAL([HAVE_GNU_GETTEXT],
 121     [test "x$XGETTEXT" != "xno" && test "x$MSGCAT" != "xno" && test "x$MSGFMT" != "xno" && test "x$MSGMERGE" != "xno" && test "x$msgfmt_is_gnu" != "xno"])
 122
 123 dnl Check for gettext.
 124 AM_GNU_GETTEXT([external])
 125
 126 dnl Write gettext modules for the programs.
 127 dnl http://www.le-gall.net/sylvain+violaine/documentation/ocaml-gettext/html/reference-manual/ch03s04.html
 128 AC_MSG_NOTICE([creating src/opt_gettext.ml])
 129 rm -f src/opt_gettext.ml
 130 echo "(* This file is generated automatically by ./configure. *)" > src/opt_gettext.ml
 131 if test "x$OCAML_PKG_gettext" != "xno"; then
 132     # Gettext module is available, so use it.
 133     cat <<EOT >>src/opt_gettext.ml
 134 module Gettext = Gettext.Program (
 135   struct
 136     let textdomain = "virt-top"
 137     let codeset = None
 138     let dir = None
 139     let dependencies = [[]]
 140   end
 141 ) (GettextStub.Native)
 142 EOT
 143 else
 144     # No gettext module is available, so fake the translation functions.
 145     cat <<EOT >>src/opt_gettext.ml
 146 module Gettext = struct
 147   external s_ : string -> string = "%identity"
 148   external f_ : ('a -> 'b, 'c, 'd) format -> ('a -> 'b, 'c, 'd) format
 149     = "%identity"
 150   let sn_ : string -> string -> int -> string
 151     = fun s p n -> if n = 1 then s else p
 152   let fn_ : ('a -> 'b, 'c, 'd) format -> ('a -> 'b, 'c, 'd) format -> int
 153       -> ('a -> 'b, 'c, 'd) format
 154     = fun s p n -> if n = 1 then s else p
 155 end
 156 EOT
 157 fi
 158
 159 dnl Summary.
 160 echo "------------------------------------------------------------"
 161 echo "Thanks for downloading" $PACKAGE_STRING
 162 echo "------------------------------------------------------------"
 163
 164 dnl Produce output files.
 165 AC_CONFIG_HEADERS([config.h])
 166 AC_CONFIG_FILES([ocaml-dep.sh],  [chmod +x,-w ocaml-dep.sh])
 167 AC_CONFIG_FILES([ocaml-link.sh], [chmod +x,-w ocaml-link.sh])
 168 AC_CONFIG_FILES([Makefile
 169         po/Makefile
 170         src/Makefile
 171         src/version.ml
 172         ])
 173 AC_OUTPUT