configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2011 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # The major, minor, and release fields MUST be numbers.  Packagers can
  19 # add extra information using --with-extra="..." which may be any
  20 # freeform string.
  21 m4_define([libguestfs_major],   [1])
  22 m4_define([libguestfs_minor],   [12])
  23 m4_define([libguestfs_release], [8])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Stable or unstable version?
  35 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  36 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  37             AC_MSG_RESULT([stable])
  38        ],[
  39             AC_MSG_RESULT([unstable])
  40             AC_MSG_NOTICE([
  41 ***
  42 This is a development version of libguestfs. Some APIs may be unstable
  43 until they appear in a stable release of libguestfs (at which point
  44 the C API and ABI is guaranteed to remain stable forever).  For
  45 more information about stable and development branches of libguestfs
  46 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  47 ***])
  48        ])
  49
  50 dnl Extra string, a freeform string defined by packagers.
  51 AC_ARG_WITH([extra],
  52   [AS_HELP_STRING([--with-extra],
  53                   [extra version string (for use by packagers)])],
  54   [libguestfs_extra="$withval"],
  55   [libguestfs_extra=]
  56 )
  57
  58 AC_MSG_NOTICE([libguestfs version libguestfs_major.libguestfs_minor.libguestfs_release$libguestfs_extra])
  59
  60 dnl Split up the version string.
  61 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  62 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  63 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  64 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_EXTRA],["$libguestfs_extra"],[Extra version string])
  65
  66 dnl Early gnulib initialization.
  67 gl_EARLY
  68 gl_INIT
  69
  70 AC_PROG_LIBTOOL
  71
  72 AC_PROG_SED
  73
  74 dnl Check for basic C environment.
  75 AC_PROG_CC_STDC
  76 AC_PROG_INSTALL
  77 AC_PROG_CPP
  78
  79 AC_ARG_ENABLE([gcc-warnings],
  80   [AS_HELP_STRING([--enable-gcc-warnings],
  81                   [turn on lots of GCC warnings (for developers)])],
  82   [case $enableval in
  83      yes|no) ;;
  84      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  85    esac
  86    gl_gcc_warnings=$enableval],
  87   [gl_gcc_warnings=no]
  88 )
  89
  90 if test "$gl_gcc_warnings" = yes; then
  91   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  92   AC_SUBST([WERROR_CFLAGS])
  93
  94   nw=
  95   # This, $nw, is the list of warnings we disable.
  96   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  97   nw="$nw -Waggregate-return"       # anachronistic
  98   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  99   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 100   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 101   nw="$nw -Wcast-qual"              # Too many warnings for now
 102   nw="$nw -Wconversion"             # Too many warnings for now
 103   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 104   nw="$nw -Wsign-conversion"        # Too many warnings for now
 105   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 106   nw="$nw -Wunreachable-code"       # Too many warnings for now
 107   nw="$nw -Wpadded"                 # Our structs are not padded
 108   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 109   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 110   nw="$nw -Wvla"                    # two warnings in mount.c
 111   # things I might fix soon:
 112   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 113   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 114   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 115   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 116                                     # was not possible, safe to ignore
 117   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 118   nw="$nw -Wlong-long"              # Allow long long since it's required
 119                                     # by Python, Ruby and xstrtoll.
 120   nw="$nw -Wstack-protector"        # Don't warn about stack-protector
 121                                     # failures (seen on Ubuntu).
 122   nw="$nw -Wmissing-noreturn"       # Don't warn about missed noreturn funcs
 123                                     # (seen on Ubuntu).
 124
 125   gl_MANYWARN_ALL_GCC([ws])
 126   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 127   for w in $ws; do
 128     gl_WARN_ADD([$w])
 129   done
 130   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 131   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 132   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 133
 134   # In spite of excluding -Wlogical-op above, it is enabled, as of
 135   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 136   gl_WARN_ADD([-Wno-logical-op])
 137
 138   # Work around warning in src/inspect.c.  This seems to be a bug in gcc 4.5.1.
 139   gl_WARN_ADD([-Wno-strict-overflow])
 140
 141   gl_WARN_ADD([-fdiagnostics-show-option])
 142
 143   AC_SUBST([WARN_CFLAGS])
 144
 145   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 146   AC_DEFINE([_FORTIFY_SOURCE], [2],
 147     [enable compile-time and run-time bounds-checking, and some warnings])
 148   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 149 fi
 150
 151 AC_C_PROTOTYPES
 152 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 153
 154 AM_PROG_CC_C_O
 155
 156 dnl Work out how to specify the linker script to the linker.
 157 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 158 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 159     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 160 AC_SUBST(VERSION_SCRIPT_FLAGS)
 161
 162 dnl Check support for 64 bit file offsets.
 163 AC_SYS_LARGEFILE
 164
 165 dnl Check sizeof long.
 166 AC_CHECK_SIZEOF([long])
 167
 168 dnl Define a C symbol for the host CPU architecture.
 169 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 170
 171 dnl Headers.
 172 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 173
 174 dnl Functions.
 175 AC_CHECK_FUNCS([futimens posix_fallocate])
 176
 177 dnl Build the daemon?
 178 AC_MSG_CHECKING([if we should build the daemon])
 179 AC_ARG_ENABLE([daemon],
 180         [AS_HELP_STRING([--enable-daemon],
 181           [enable building the daemon @<:@default=yes@:>@])],
 182         [],
 183         [enable_daemon=yes])
 184 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 185 AC_MSG_RESULT([$enable_daemon])
 186
 187 dnl Build the appliance?
 188 AC_MSG_CHECKING([if we should build the appliance])
 189 AC_ARG_ENABLE([appliance],
 190         [AS_HELP_STRING([--enable-appliance],
 191           [enable building the appliance @<:@default=yes@:>@])],
 192         [],
 193         [enable_appliance=yes])
 194 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 195 AC_MSG_RESULT([$enable_appliance])
 196
 197 if test "x$enable_appliance" = "xyes"; then
 198     dnl Check for febootstrap >= 3.0
 199     AC_CHECK_PROG([FEBOOTSTRAP],
 200                   [febootstrap],[febootstrap],[no])
 201     test "x$FEBOOTSTRAP" = "xno" &&
 202         AC_MSG_ERROR([febootstrap must be installed])
 203     dnl febootstrap 2.x did not support the --version parameter
 204     $FEBOOTSTRAP --version >&AS_MESSAGE_LOG_FD 2>&1 ||
 205         AC_MSG_ERROR([febootstrap >= 3.0 must be installed, your version is too old])
 206
 207     dnl Pass a febootstrap --yum-config option.
 208     AC_MSG_CHECKING([if user requested febootstrap --yum-config option])
 209     AC_ARG_WITH([febootstrap-yum-config],
 210         [AS_HELP_STRING([--with-febootstrap-yum-config=FILE],
 211           [pass febootstrap --yum-config option @<:@default=no@:>@])],
 212         [FEBOOTSTRAP_YUM_CONFIG="$withval"],
 213         [FEBOOTSTRAP_YUM_CONFIG=no])
 214     AC_MSG_RESULT([$FEBOOTSTRAP_YUM_CONFIG])
 215     AC_SUBST([FEBOOTSTRAP_YUM_CONFIG])
 216
 217     dnl Which distro?
 218     dnl
 219     dnl This used to be Very Important but is now just used to select
 220     dnl which packages to install in the appliance, since the package
 221     dnl names vary slightly across distros.  (See
 222     dnl appliance/packagelist.in and appliance/excludelist.in)
 223     AC_MSG_CHECKING([which Linux distro for package names])
 224     DISTRO=REDHAT
 225     if test -f /etc/debian_version; then
 226         DISTRO=DEBIAN
 227         if grep -q 'DISTRIB_ID=Ubuntu' /etc/lsb-release 2>&AS_MESSAGE_LOG_FD; then
 228             DISTRO=UBUNTU
 229         fi
 230     fi
 231     if test -f /etc/arch-release; then
 232         DISTRO=ARCHLINUX
 233     fi
 234     AC_MSG_RESULT([$DISTRO])
 235     AC_SUBST([DISTRO])
 236 fi
 237
 238 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 239 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 240 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 241 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 242         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 243         ])
 244
 245 dnl Check for cpio which isn't in the default Pardus install amazingly.
 246 AC_CHECK_PROG([CPIO],[cpio],[cpio],[no])
 247 test "x$CPIO" = "xno" &&
 248      AC_MSG_ERROR([cpio must be installed])
 249
 250 dnl Check for gperf.
 251 AC_CHECK_PROG([GPERF],[gperf],[gperf],[no])
 252 test "x$GPERF" = "xno" &&
 253      AC_MSG_ERROR([gperf must be installed])
 254
 255 dnl Check for pod2man, pod2text, pod2html.
 256 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 257 test "x$POD2MAN" = "xno" &&
 258      AC_MSG_ERROR([pod2man must be installed])
 259 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 260 test "x$POD2TEXT" = "xno" &&
 261      AC_MSG_ERROR([pod2text must be installed])
 262 AC_CHECK_PROG([POD2HTML],[pod2html],[pod2html],[no])
 263 test "x$POD2HTML" = "xno" &&
 264      AC_MSG_ERROR([pod2html must be installed])
 265
 266 dnl Check if pod2man, pod2text take --stderr and -u options (not in RHEL 5).
 267 AC_MSG_CHECKING([if pod2man takes --stderr option])
 268 if "$POD2MAN" --stderr >&AS_MESSAGE_LOG_FD 2>&1; then
 269     AC_MSG_RESULT([yes])
 270     POD2_STDERR_OPTION="--stderr"
 271 else
 272     AC_MSG_RESULT([no])
 273     POD2_STDERR_OPTION=""
 274 fi
 275 AC_SUBST([POD2_STDERR_OPTION])
 276
 277 AC_MSG_CHECKING([if pod2man takes -u option])
 278 if "$POD2MAN" -u >&AS_MESSAGE_LOG_FD 2>&1; then
 279     AC_MSG_RESULT([yes])
 280     POD2_UTF8_OPTION="-u"
 281 else
 282     AC_MSG_RESULT([no])
 283     POD2_UTF8_OPTION=""
 284 fi
 285 AC_SUBST([POD2_UTF8_OPTION])
 286
 287 dnl Check for genisoimage.
 288 AC_PATH_PROGS([GENISOIMAGE],[genisoimage],[no],
 289         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 290 test "x$GENISOIMAGE" = "xno" && AC_MSG_ERROR([genisoimage must be installed])
 291
 292 dnl Check for optional xmllint.
 293 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 294 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 295
 296 dnl po4a for translating man pages and POD files (optional).
 297 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
 298 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
 299
 300 dnl Check for db_dump, db_load (optional).
 301 AC_CHECK_PROGS([DB_DUMP],
 302                [db_dump db4_dump db4.8_dump db4.7_dump db4.6_dump],[no])
 303 AC_CHECK_PROGS([DB_LOAD],
 304                [db_load db4_load db4.8_load db4.7_load db4.6_load],[no])
 305 if test "x$DB_DUMP" != "xno"; then
 306     AC_DEFINE_UNQUOTED([DB_DUMP],["$DB_DUMP"],[Name of db_dump program.])
 307 fi
 308 if test "x$DB_LOAD" != "xno"; then
 309     AC_DEFINE_UNQUOTED([DB_LOAD],["$DB_LOAD"],[Name of db_load program.])
 310 fi
 311
 312 dnl Check for QEMU for running binaries on this $host_cpu, fall
 313 dnl back to basic 'qemu'.  Allow the user to override it.
 314 default_qemu="qemu-kvm kvm qemu-system-$host_cpu qemu"
 315 AC_ARG_WITH([qemu],
 316         [AS_HELP_STRING([--with-qemu],
 317           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 318         [],
 319         [with_qemu="$default_qemu"])
 320 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 321         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 322 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 323 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 324
 325 dnl Check that the chosen qemu has virtio-serial support.
 326 if test "x$vmchannel_test" != "xno"; then
 327     AC_MSG_CHECKING([that $QEMU -help works])
 328     if $QEMU -help >&AS_MESSAGE_LOG_FD 2>&1; then
 329         AC_MSG_RESULT([yes])
 330     else
 331         AC_MSG_RESULT([no])
 332         AC_MSG_FAILURE(
 333 [$QEMU -help: command failed.
 334
 335 This could be a very old version of qemu, or qemu might not be
 336 working.
 337 ])
 338     fi
 339
 340     AC_MSG_CHECKING([for virtio-serial support in $QEMU])
 341     if $QEMU -nographic -device \? 2>&1 | grep -sq virtio-serial; then
 342         AC_MSG_RESULT([yes])
 343     else
 344         AC_MSG_RESULT([no])
 345         AC_MSG_FAILURE(
 346 [I did not find virtio-serial support in
 347 $QEMU.
 348
 349 virtio-serial support in qemu or KVM is essential for libguestfs
 350 to operate.
 351
 352 Usually this means that you have to install a newer version of qemu
 353 and/or KVM.  Please read the relevant section in the README file for
 354 more information about this.
 355
 356 You can override this test by setting the environment variable
 357 vmchannel_test=no  However if you don't have the right support
 358 in your qemu, then this just delays the pain.
 359
 360 If I am using the wrong qemu or you want to compile qemu from source
 361 and install it in another location, then you should configure with
 362 the --with-qemu option.
 363 ])
 364     fi
 365 fi
 366
 367 dnl Set default drive interface used by the guestfs_add_drive_opts call
 368 dnl ('-drive ...,if=...' option to qemu).
 369 dnl
 370 dnl If you encounter performance problems with virtio (RHBZ#509383)
 371 dnl then try '--with-drive-if=ide'.
 372 AC_ARG_WITH([drive-if],
 373         [AS_HELP_STRING([--with-drive-if],
 374           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 375         [],
 376         [with_drive_if=virtio])
 377 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 378
 379 dnl Set interface used by the network.  Normally you should
 380 dnl leave this at the default (virtio-net-pci) but you can use the
 381 dnl alternative (ne2k_pci) because of bugs in virtio networking
 382 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 383 AC_ARG_WITH([net-if],
 384         [AS_HELP_STRING([--with-net-if],
 385           [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
 386         [],
 387         [with_net_if=virtio-net-pci])
 388 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 389
 390 dnl Enable packet dumps when in verbose mode.  This generates lots
 391 dnl of debug info, only useful for people debugging the RPC mechanism.
 392 AC_ARG_ENABLE([packet-dump],
 393         [AS_HELP_STRING([--enable-packet-dump],
 394           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 395         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 396         [])
 397
 398 dnl Readline.
 399 AC_ARG_WITH([readline],
 400     [AS_HELP_STRING([--with-readline],
 401         [support fancy command line editing @<:@default=check@:>@])],
 402     [],
 403     [with_readline=check])
 404
 405 LIBREADLINE=
 406 AS_IF([test "x$with_readline" != xno],
 407     [AC_CHECK_LIB([readline], [main],
 408         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 409          AC_DEFINE([HAVE_LIBREADLINE], [1],
 410                    [Define if you have libreadline])
 411         ],
 412         [if test "x$with_readline" != xcheck; then
 413          AC_MSG_FAILURE(
 414              [--with-readline was given, but test for readline failed])
 415          fi
 416         ], -lncurses)
 417      old_LIBS="$LIBS"
 418      LIBS="$LIBS $LIBREADLINE"
 419      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 420      LIBS="$old_LIBS"
 421     ])
 422
 423 dnl For i18n.
 424 AM_GNU_GETTEXT([external])
 425
 426 dnl Check for PCRE (required)
 427 PKG_CHECK_MODULES([PCRE], [libpcre])
 428
 429 dnl libmagic (highly recommended)
 430 AC_CHECK_LIB([magic],[magic_file],
 431         [AC_CHECK_HEADER([magic.h],
 432                 [AC_SUBST([MAGIC_LIBS], ["-lmagic"])
 433                  AC_DEFINE([HAVE_LIBMAGIC],[1],[libmagic found at compile time.])
 434                 ], [])
 435         ],
 436         [AC_MSG_WARN([libmagic not found, some core features will be disabled])])
 437
 438 dnl libvirt (highly recommended)
 439 PKG_CHECK_MODULES([LIBVIRT], [libvirt],
 440         [AC_SUBST([LIBVIRT_CFLAGS])
 441          AC_SUBST([LIBVIRT_LIBS])
 442          AC_DEFINE([HAVE_LIBVIRT],[1],[libvirt found at compile time.])
 443         ],
 444         [AC_MSG_WARN([libvirt not found, some core features will be disabled])])
 445 AM_CONDITIONAL([HAVE_LIBVIRT],[test "x$LIBVIRT_LIBS" != "x"])
 446
 447 dnl libxml2 (highly recommended)
 448 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0],
 449         [AC_SUBST([LIBXML2_CFLAGS])
 450          AC_SUBST([LIBXML2_LIBS])
 451          AC_DEFINE([HAVE_LIBXML2],[1],[libxml2 found at compile time.])
 452         ],
 453         [AC_MSG_WARN([libxml2 not found, some core features will be disabled])])
 454 AM_CONDITIONAL([HAVE_LIBXML2],[test "x$LIBXML2_LIBS" != "x"])
 455
 456 dnl libconfig (highly recommended)
 457 PKG_CHECK_MODULES([LIBCONFIG], [libconfig],
 458         [AC_SUBST([LIBCONFIG_CFLAGS])
 459          AC_SUBST([LIBCONFIG_LIBS])
 460          AC_DEFINE([HAVE_LIBCONFIG],[1],[libconfig found at compile time.])
 461         ],
 462         [AC_MSG_WARN([libconfig not found, some features will be disabled])])
 463 AM_CONDITIONAL([HAVE_LIBCONFIG],[test "x$LIBCONFIG_LIBS" != "x"])
 464
 465 dnl hivex library (highly recommended)
 466 dnl This used to be a part of libguestfs, but was spun off into its
 467 dnl own separate upstream project in libguestfs 1.0.85.
 468 PKG_CHECK_MODULES([HIVEX], [hivex],
 469         [AC_SUBST([HIVEX_CFLAGS])
 470          AC_SUBST([HIVEX_LIBS])
 471          AC_DEFINE([HAVE_HIVEX],[1],[hivex library found at compile time.])
 472         ],
 473         [AC_MSG_WARN([hivex not found, some core features will be disabled])])
 474 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HIVEX_LIBS" != "x"])
 475
 476 dnl FUSE is optional to build the FUSE module.
 477 AC_ARG_ENABLE([fuse],
 478         AS_HELP_STRING([--disable-fuse], [Disable FUSE (guestmount) support]),
 479         [],
 480         [enable_fuse=yes])
 481 AS_IF([test "x$enable_fuse" != "xno"],
 482         [PKG_CHECK_MODULES([FUSE],[fuse],,[
 483                 enable_fuse=no
 484                 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])])
 485 AM_CONDITIONAL([HAVE_FUSE],[test "x$enable_fuse" != "xno"])
 486
 487 dnl Check for OCaml (optional, for OCaml bindings).
 488 OCAMLC=no
 489 OCAMLFIND=no
 490 AC_ARG_ENABLE([ocaml],
 491         AS_HELP_STRING([--disable-ocaml], [Disable OCaml language bindings]),
 492         [],
 493         [enable_ocaml=yes])
 494 AS_IF([test "x$enable_ocaml" != "xno"],
 495         [dnl OCAMLC and OCAMLFIND have to be unset first, otherwise
 496          dnl AC_CHECK_TOOL (inside AC_PROG_OCAML) will not look.
 497          OCAMLC=
 498          OCAMLFIND=
 499          AC_PROG_OCAML
 500          AC_PROG_FINDLIB
 501
 502          AS_IF([test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"],
 503                 [AC_CHECK_OCAML_PKG([pcre])])
 504         ])
 505 AM_CONDITIONAL([HAVE_OCAML],
 506                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
 507 AM_CONDITIONAL([HAVE_OCAML_PCRE],
 508                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno" && test "x$OCAML_PKG_pcre" != "xno"])
 509 AM_CONDITIONAL([HAVE_OCAMLDOC],
 510                [test "x$OCAMLDOC" != "xno"])
 511
 512 dnl Check for Perl (optional, for Perl bindings).
 513 PERL=no
 514 AC_ARG_ENABLE([perl],
 515         AS_HELP_STRING([--disable-perl], [Disable Perl language bindings]),
 516         [],
 517         [enable_perl=yes])
 518 AS_IF([test "x$enable_perl" != "xno"],
 519         [
 520         PERL=
 521         AC_CHECK_PROG([PERL],[perl],[perl],[no])
 522
 523         dnl Check for Perl modules that must be present to compile and
 524         dnl test the Perl bindings.
 525         missing_perl_modules=no
 526         for pm in Test::More ExtUtils::MakeMaker; do
 527             AC_MSG_CHECKING([for $pm])
 528             if ! perl -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
 529                 AC_MSG_RESULT([no])
 530                 missing_perl_modules=yes
 531             else
 532                 AC_MSG_RESULT([yes])
 533             fi
 534         done
 535         if test "x$missing_perl_modules" = "xyes"; then
 536             AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 537         fi
 538         ])
 539 AM_CONDITIONAL([HAVE_PERL],
 540     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 541
 542 dnl Check for Python (optional, for Python bindings).
 543 PYTHON_PREFIX=
 544 PYTHON_VERSION=
 545 PYTHON_INCLUDEDIR=
 546 PYTHON_INSTALLDIR=
 547
 548 AC_ARG_ENABLE([python],
 549         AS_HELP_STRING([--disable-python], [Disable Python language bindings]),
 550         [],
 551         [enable_python=yes])
 552 AS_IF([test "x$enable_python" != "xno"],
 553         [
 554         AC_CHECK_PROG([PYTHON],[python],[python],[no])
 555
 556         if test "x$PYTHON" != "xno"; then
 557             AC_MSG_CHECKING([Python prefix])
 558             PYTHON_PREFIX=`$PYTHON -c "import sys; print (sys.prefix)"`
 559             AC_MSG_RESULT([$PYTHON_PREFIX])
 560
 561             AC_MSG_CHECKING([Python version])
 562             PYTHON_VERSION=`$PYTHON -c "import sys; print (sys.version[[0:3]])"`
 563             AC_MSG_RESULT([$PYTHON_VERSION])
 564
 565             AC_MSG_CHECKING([for Python include path])
 566             if test -z "$PYTHON_INCLUDEDIR"; then
 567                 python_path=`$PYTHON -c "import distutils.sysconfig; \
 568                                          print (distutils.sysconfig.get_python_inc ());"`
 569                 PYTHON_INCLUDEDIR=$python_path
 570             fi
 571             AC_MSG_RESULT([$PYTHON_INCLUDEDIR])
 572
 573             AC_ARG_WITH([python-installdir],
 574                         [AS_HELP_STRING([--with-python-installdir],
 575                                         [directory to install python modules @<:@default=check@:>@])],
 576                         [PYTHON_INSTALLDIR="$withval"
 577                         AC_MSG_NOTICE([Python install dir $PYTHON_INSTALLDIR])],
 578                         [PYTHON_INSTALLDIR=check])
 579
 580             if test "x$PYTHON_INSTALLDIR" = "xcheck"; then
 581                 PYTHON_INSTALLDIR=
 582                 AC_MSG_CHECKING([for Python site-packages path])
 583                 if test -z "$PYTHON_INSTALLDIR"; then
 584                     PYTHON_INSTALLDIR=`$PYTHON -c "import distutils.sysconfig; \
 585                                                    print (distutils.sysconfig.get_python_lib(1,0));"`
 586                 fi
 587                 AC_MSG_RESULT([$PYTHON_INSTALLDIR])
 588             fi
 589
 590             old_LIBS="$LIBS"
 591             LIBS="$LIBS -lpython$PYTHON_VERSION"
 592             AC_CHECK_FUNCS([PyCapsule_New])
 593             LIBS="$old_LIBS"
 594         fi
 595
 596         AC_SUBST(PYTHON_PREFIX)
 597         AC_SUBST(PYTHON_VERSION)
 598         AC_SUBST(PYTHON_INCLUDEDIR)
 599         AC_SUBST(PYTHON_INSTALLDIR)
 600         ])
 601 AM_CONDITIONAL([HAVE_PYTHON],
 602     [test "x$PYTHON" != "xno" && test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_INSTALLDIR" != "x"])
 603
 604 dnl Check for Ruby and rake (optional, for Ruby bindings).
 605 AC_ARG_ENABLE([ruby],
 606         AS_HELP_STRING([--disable-ruby], [Disable Ruby language bindings]),
 607         [],
 608         [enable_ruby=yes])
 609 AS_IF([test "x$enable_ruby" != "xno"],
 610         [
 611         AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 612         AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 613         ])
 614 AM_CONDITIONAL([HAVE_RUBY],
 615     [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
 616
 617 dnl Check for Java.
 618 AC_ARG_WITH(java_home,
 619     [AS_HELP_STRING([--with-java-home],
 620         [specify path to JDK directory @<:@default=check@:>@])],
 621     [],
 622     [with_java_home=check])
 623
 624 if test "x$with_java_home" != "xno"; then
 625     if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
 626     then
 627         # Reject unsafe characters in $JAVA_HOME
 628         jh_lf='
 629 '
 630         case $JAVA_HOME in
 631           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 632             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 633         esac
 634         if test -d "$with_java_home"; then
 635             JAVA_HOME="$with_java_home"
 636         else
 637             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 638         fi
 639     fi
 640
 641     if test "x$JAVA_HOME" = "x"; then
 642         # Look for Java in some likely locations.
 643         for d in \
 644             /usr/lib/jvm/java \
 645             /usr/lib/jvm/java-6-openjdk
 646         do
 647             if test -d $d && test -f $d/bin/java; then
 648                 JAVA_HOME=$d
 649                 break
 650             fi
 651         done
 652     fi
 653
 654     if test "x$JAVA_HOME" != "x"; then
 655         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 656         if test ! -x "$JAVA_HOME/bin/java"; then
 657             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 658         else
 659             JAVA="$JAVA_HOME/bin/java"
 660         fi
 661         if test ! -x "$JAVA_HOME/bin/javac"; then
 662             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 663         else
 664             JAVAC="$JAVA_HOME/bin/javac"
 665         fi
 666         if test ! -x "$JAVA_HOME/bin/javah"; then
 667             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 668         else
 669             JAVAH="$JAVA_HOME/bin/javah"
 670         fi
 671         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 672             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 673         else
 674             JAVADOC="$JAVA_HOME/bin/javadoc"
 675         fi
 676         if test ! -x "$JAVA_HOME/bin/jar"; then
 677             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 678         else
 679             JAR="$JAVA_HOME/bin/jar"
 680         fi
 681         java_version=`$JAVA -version 2>&1 | grep "java version"`
 682         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 683
 684         dnl Find jni.h.
 685         AC_MSG_CHECKING([for jni.h])
 686         if test -f "$JAVA_HOME/include/jni.h"; then
 687             JNI_CFLAGS="-I$JAVA_HOME/include"
 688         else
 689             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 690                 head=`find $JAVA_HOME -name jni.h | tail -1`
 691                 dir=`dirname "$head"`
 692                 JNI_CFLAGS="-I$dir"
 693             else
 694                 AC_MSG_FAILURE([missing jni.h header file])
 695             fi
 696         fi
 697         AC_MSG_RESULT([$JNI_CFLAGS])
 698
 699         dnl Find jni_md.h.
 700         AC_MSG_CHECKING([for jni_md.h])
 701         case "$build_os" in
 702         *linux*) system="linux" ;;
 703         *SunOS*) system="solaris" ;;
 704         *cygwin*) system="win32" ;;
 705         *) system="$build_os" ;;
 706         esac
 707         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 708             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 709         else
 710             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 711                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 712                 dir=`dirname "$head"`
 713                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 714             else
 715                 AC_MSG_FAILURE([missing jni_md.h header file])
 716             fi
 717         fi
 718         AC_MSG_RESULT([$JNI_CFLAGS])
 719
 720         dnl Need extra version flag?
 721         AC_MSG_CHECKING([extra javac flags])
 722         JAVAC_FLAGS=
 723         javac_version=`$JAVAC -version 2>&1`
 724         case "$javac_version" in
 725         *Eclipse*)
 726             JAVAC_FLAGS="-source 1.5" ;;
 727         esac
 728         AC_MSG_RESULT([$JAVAC_FLAGS])
 729
 730         dnl Where to install jarfiles.
 731         dnl XXX How to make it configurable?
 732         JAR_INSTALL_DIR=\${prefix}/share/java
 733         JNI_INSTALL_DIR=\${libdir}
 734
 735         dnl JNI version.
 736         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 737         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 738         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 739         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 740     fi
 741 fi
 742
 743 AC_SUBST(JAVA_HOME)
 744 AC_SUBST(JAVA)
 745 AC_SUBST(JAVAC)
 746 AC_SUBST(JAVAH)
 747 AC_SUBST(JAVADOC)
 748 AC_SUBST(JAR)
 749 AC_SUBST(JNI_CFLAGS)
 750 AC_SUBST(JAVAC_FLAGS)
 751 AC_SUBST(JAR_INSTALL_DIR)
 752 AC_SUBST(JNI_INSTALL_DIR)
 753 AC_SUBST(JNI_VERSION_INFO)
 754
 755 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 756
 757 dnl Check for Haskell (GHC).
 758 GHC=no
 759 AC_ARG_ENABLE([haskell],
 760         AS_HELP_STRING([--disable-haskell], [Disable Haskell language bindings]),
 761         [],
 762         [enable_haskell=yes])
 763 AS_IF([test "x$enable_haskell" != "xno"],
 764         [
 765         GHC=
 766         AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 767         ])
 768 AM_CONDITIONAL([HAVE_HASKELL],
 769     [test "x$GHC" != "xno"])
 770
 771 dnl PHP
 772 PHP=no
 773 AC_ARG_ENABLE([php],
 774         AS_HELP_STRING([--disable-php], [Disable PHP language bindings]),
 775         [],
 776         [enable_php=yes])
 777 AS_IF([test "x$enable_php" != "xno"],
 778         [
 779         PHP=
 780         AC_CHECK_PROG([PHP],[php],[php],[no])
 781         AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
 782         ])
 783 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
 784
 785 dnl Check for Perl modules needed by Perl virt tools (virt-df, etc.)
 786 AS_IF([test "x$PERL" != "xno"],
 787         [
 788         missing_perl_modules=no
 789         for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper Locale::TextDomain Win::Hivex Win::Hivex::Regedit String::ShellQuote; do
 790             AC_MSG_CHECKING([for $pm])
 791             if ! $PERL -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
 792                 AC_MSG_RESULT([no])
 793                 missing_perl_modules=yes
 794             else
 795                 AC_MSG_RESULT([yes])
 796             fi
 797         done
 798         if test "x$missing_perl_modules" = "xyes"; then
 799             AC_MSG_WARN([some Perl modules required to compile the Perl virt-* tools are missing])
 800         fi
 801         ])
 802
 803 AM_CONDITIONAL([HAVE_TOOLS],
 804     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 805
 806 dnl Library versioning.
 807 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 808 AC_SUBST(MAX_PROC_NR)
 809
 810 dnl Replace libtool with a wrapper that clobbers dependency_libs in *.la files
 811 dnl http://lists.fedoraproject.org/pipermail/devel/2010-November/146343.html
 812 LIBTOOL='bash $(top_srcdir)/libtool-kill-dependency_libs.sh $(top_builddir)/libtool'
 813 AC_SUBST([LIBTOOL])
 814
 815 dnl Run in subdirs.
 816 if test "x$enable_daemon" = "xyes"; then
 817     AC_CONFIG_SUBDIRS([daemon])
 818 fi
 819
 820 dnl Produce output files.
 821 AC_CONFIG_HEADERS([config.h])
 822 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 823 AC_CONFIG_FILES([podwrapper.sh],
 824                 [chmod +x podwrapper.sh])
 825 AC_CONFIG_FILES([run],
 826                 [chmod +x run])
 827 AC_CONFIG_FILES([Makefile
 828                  appliance/Makefile
 829                  capitests/Makefile
 830                  cat/Makefile
 831                  caution/Makefile
 832                  csharp/Makefile
 833                  debian/changelog
 834                  df/Makefile
 835                  edit/Makefile
 836                  examples/Makefile
 837                  fish/Makefile
 838                  fuse/Makefile
 839                  generator/Makefile
 840                  gnulib/lib/Makefile
 841                  gnulib/tests/Makefile
 842                  haskell/Makefile
 843                  images/Makefile
 844                  inspector/Makefile
 845                  java/Makefile
 846                  java/examples/Makefile
 847                  libguestfs.pc
 848                  ocaml/META
 849                  ocaml/Makefile
 850                  ocaml/examples/Makefile
 851                  perl/Makefile
 852                  perl/Makefile.PL
 853                  perl/examples/Makefile
 854                  php/Makefile
 855                  po-docs/Makefile
 856                  po-docs/ja/Makefile
 857                  po-docs/uk/Makefile
 858                  po/Makefile.in
 859                  python/Makefile
 860                  python/examples/Makefile
 861                  regressions/Makefile
 862                  rescue/Makefile
 863                  resize/Makefile
 864                  ruby/Makefile
 865                  ruby/Rakefile
 866                  ruby/examples/Makefile
 867                  src/Makefile
 868                  test-tool/Makefile
 869                  tools/Makefile])
 870 AC_OUTPUT
 871
 872 dnl Produce summary.
 873 echo
 874 echo
 875 echo "------------------------------------------------------------"
 876 echo "Thank you for downloading $PACKAGE_STRING"
 877 echo
 878 echo "This is how we have configured the optional components for you today:"
 879 echo
 880 echo    "Daemon .............................. $enable_daemon"
 881 echo    "Appliance ........................... $enable_appliance"
 882 echo    "QEMU ................................ $QEMU"
 883 echo -n "OCaml bindings ...................... "
 884 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 885 echo -n "Perl bindings ....................... "
 886 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 887 echo -n "Python bindings ..................... "
 888 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 889 echo -n "Ruby bindings ....................... "
 890 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 891 echo -n "Java bindings ....................... "
 892 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 893 echo -n "Haskell bindings .................... "
 894 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 895 echo -n "PHP bindings ........................ "
 896 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 897 echo    "guestfish and C virt tools .......... yes"
 898 echo -n "Perl virt tools ..................... "
 899 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 900 echo -n "virt-resize ......................... "
 901 if test "x$HAVE_OCAML_TRUE" = "x" && test "x$HAVE_OCAML_PCRE_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 902 echo "FUSE filesystem ..................... $enable_fuse"
 903 echo
 904 echo "If any optional component is configured 'no' when you expected 'yes'"
 905 echo "then you should check the preceeding messages."
 906 echo
 907 echo "Please report bugs back to the mailing list:"
 908 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 909 echo
 910 echo "Next you should type 'make' to build the package,"
 911 echo "then 'make check' to run the tests."
 912 echo "------------------------------------------------------------"