2 # Copyright (C) 2009-2010 Red Hat Inc.
4 # This program is free software; you can redistribute it and/or modify
5 # it under the terms of the GNU General Public License as published by
6 # the Free Software Foundation; either version 2 of the License, or
7 # (at your option) any later version.
9 # This program is distributed in the hope that it will be useful,
10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
12 # GNU General Public License for more details.
14 # You should have received a copy of the GNU General Public License
15 # along with this program; if not, write to the Free Software
16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
18 # major/minor/release must be numbers
19 m4_define([libguestfs_major], [1])
20 m4_define([libguestfs_minor], [5])
21 m4_define([libguestfs_release], [11])
22 # extra can be any string
23 m4_define([libguestfs_extra], [])
25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
26 AC_CONFIG_AUX_DIR([build-aux])
27 AM_INIT_AUTOMAKE([foreign])
29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
32 AC_CONFIG_MACRO_DIR([m4])
34 dnl Split up the version string.
35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
40 dnl Stable or unstable version?
41 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
42 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
43 AC_MSG_RESULT([stable])
45 AC_MSG_RESULT([unstable])
48 This is a development version of libguestfs. Some APIs may be unstable
49 until they appear in a stable release of libguestfs (at which point
50 the C API and ABI is guaranteed to remain stable forever). For
51 more information about stable and development branches of libguestfs
52 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
56 dnl Die if the user tries to configure as root, see:
57 dnl https://www.redhat.com/archives/libguestfs/2010-April/msg00098.html
58 AC_MSG_CHECKING([if you are trying to configure as root])
59 AS_IF([test "`id -u`" = 0 ],[
61 AC_MSG_FAILURE([Don't run './configure' or 'make' as root.])
66 dnl Early gnulib initialization.
72 dnl Check for basic C environment.
77 AC_ARG_ENABLE([gcc-warnings],
78 [AS_HELP_STRING([--enable-gcc-warnings],
79 [turn on lots of GCC warnings (for developers)])],
82 *) AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
84 gl_gcc_warnings=$enableval],
88 if test "$gl_gcc_warnings" = yes; then
89 gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
90 AC_SUBST([WERROR_CFLAGS])
93 # This, $nw, is the list of warnings we disable.
94 nw="$nw -Wdeclaration-after-statement" # too useful to forbid
95 nw="$nw -Waggregate-return" # anachronistic
96 nw="$nw -Wc++-compat" # We don't care about C++ compilers
97 nw="$nw -Wundef" # Warns on '#if GNULIB_FOO' etc in gnulib
98 nw="$nw -Wtraditional" # Warns on #elif which we use often
99 nw="$nw -Wcast-qual" # Too many warnings for now
100 nw="$nw -Wconversion" # Too many warnings for now
101 nw="$nw -Wsystem-headers" # Don't let system headers trigger warnings
102 nw="$nw -Wsign-conversion" # Too many warnings for now
103 nw="$nw -Wtraditional-conversion" # Too many warnings for now
104 nw="$nw -Wunreachable-code" # Too many warnings for now
105 nw="$nw -Wpadded" # Our structs are not padded
106 nw="$nw -Wredundant-decls" # openat.h declares e.g., mkdirat
107 nw="$nw -Wlogical-op" # any use of fwrite provokes this
108 nw="$nw -Wvla" # two warnings in mount.c
109 # things I might fix soon:
110 nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
111 nw="$nw -Winline" # daemon.h's asprintf_nowarn
112 nw="$nw -Wshadow" # numerous, plus we're not unanimous
113 nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
114 # was not possible, safe to ignore
115 nw="$nw -Wpacked" # Allow attribute((packed)) on structs
116 nw="$nw -Wlong-long" # Allow long long since it's required
117 # by Python, Ruby and xstrtoll.
119 gl_MANYWARN_ALL_GCC([ws])
120 gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
124 gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
125 gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
126 gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
128 # In spite of excluding -Wlogical-op above, it is enabled, as of
129 # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
130 gl_WARN_ADD([-Wno-logical-op])
132 gl_WARN_ADD([-fdiagnostics-show-option])
134 AC_SUBST([WARN_CFLAGS])
136 AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
137 AC_DEFINE([_FORTIFY_SOURCE], [2],
138 [enable compile-time and run-time bounds-checking, and some warnings])
139 AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
143 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
147 dnl Work out how to specify the linker script to the linker.
148 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
149 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
150 VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
151 AC_SUBST(VERSION_SCRIPT_FLAGS)
153 dnl Check support for 64 bit file offsets.
156 dnl Check sizeof long.
157 AC_CHECK_SIZEOF([long])
159 dnl Define a C symbol for the host CPU architecture.
160 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
163 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
166 AC_CHECK_FUNCS([posix_fallocate])
168 dnl Build the daemon?
169 AC_MSG_CHECKING([if we should build the daemon])
170 AC_ARG_ENABLE([daemon],
171 [AS_HELP_STRING([--enable-daemon],
172 [enable building the daemon @<:@default=yes@:>@])],
175 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
176 AC_MSG_RESULT([$enable_daemon])
178 dnl Build the appliance?
179 AC_MSG_CHECKING([if we should build the appliance])
180 AC_ARG_ENABLE([appliance],
181 [AS_HELP_STRING([--enable-appliance],
182 [enable building the appliance @<:@default=yes@:>@])],
184 [enable_appliance=yes])
185 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
186 AC_MSG_RESULT([$enable_appliance])
189 AC_CHECK_LIB([pcre],[pcre_compile],
190 [AC_SUBST([LIBPCRE], ["-lpcre"])],
192 [Perl Compatible Regular Expressions library (PCRE) is required])])
193 AC_CHECK_HEADER([pcre.h],[],
195 [Perl Compatible Regular Expressions library (PCRE) header file pcre.h is required])])
197 dnl Check for rpcgen and XDR library. rpcgen is optional.
198 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
199 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
200 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
201 AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
204 dnl Check for pod2man and pod2text.
205 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
206 test "x$POD2MAN" = "xno" &&
207 AC_MSG_ERROR([pod2man must be installed])
208 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
209 test "x$POD2TEXT" = "xno" &&
210 AC_MSG_ERROR([pod2text must be installed])
212 dnl Check for mkisofs.
213 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
214 [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
215 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
217 dnl Check for optional xmllint.
218 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
219 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
221 dnl Check for QEMU for running binaries on this $host_cpu, fall
222 dnl back to basic 'qemu'. Allow the user to override it.
223 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
225 [AS_HELP_STRING([--with-qemu],
226 [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
228 [with_qemu="$default_qemu"])
229 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
230 [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
231 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
232 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
234 dnl Check that the chosen qemu has vmchannel support or we can
235 dnl fallback to null vmchannel (still using SLIRP). See the
236 dnl discussion in the README file.
237 if test "x$vmchannel_test" != "xno"; then
238 AC_MSG_CHECKING([for guestfwd support in $QEMU])
239 if $QEMU -nographic --help | grep -sq guestfwd; then
241 vmchannel_guestfwd=guestfwd
244 # Note that this test must be conditional on the previous
245 # test failing. This is because recent qemu will throw
246 # up an SDL window and hang if we try to run this test.
247 AC_MSG_CHECKING([for "-net channel" (old guestfwd) support in $QEMU])
248 vmchannelout=`$QEMU -nographic -net channel /dev/zero 2>&1 ||:`
249 echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
250 if echo "$vmchannelout" | grep -sq "vmchannel wrong port number" ; then
252 vmchannel_guestfwd=net_channel
255 vmchannel_guestfwd=no
259 AC_MSG_CHECKING([for "-net user" (user mode network) support in $QEMU])
260 if $QEMU -nographic --help | grep -sq -- "-net user"; then
262 vmchannel_net_user=yes
265 vmchannel_net_user=no
268 if test "x$vmchannel_net_user" = "xno" && test "x$vmchannel_guestfwd" = "xno"; then
270 [I did not find user mode network or vmchannel support in
273 Either user mode networking or vmchannel support is vital for
274 libguestfs to operate.
276 Please read the relevant section in the README file for more
277 information about this.
279 You can override this test by setting the environment variable
280 vmchannel_test=no However if you don't have the right support
281 in your qemu, then this just delays the pain.
283 If I am using the wrong qemu or you want to compile qemu from source
284 and install it in another location, then you should configure with
285 the --with-qemu option.
290 dnl Set drive interface used by the guestfs_add_drive{,_ro} calls
291 dnl ('-drive ...,if=...' option to qemu).
293 dnl If you encounter performance problems with virtio (RHBZ#509383)
294 dnl then try '--with-drive-if=ide'.
295 AC_ARG_WITH([drive-if],
296 [AS_HELP_STRING([--with-drive-if],
297 [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
299 [with_drive_if=virtio])
300 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
302 dnl Set interface used by the network. Normally you should
303 dnl leave this at the default (virtio-net-pci) but you can use the
304 dnl alternative (ne2k_pci) because of bugs in virtio networking
305 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
306 AC_ARG_WITH([net-if],
307 [AS_HELP_STRING([--with-net-if],
308 [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
310 [with_net_if=virtio-net-pci])
311 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
313 dnl Check for febootstrap etc.
314 if test "x$enable_appliance" = "xyes"; then
315 AC_CHECK_PROG([FEBOOTSTRAP],
316 [febootstrap],[febootstrap],[no])
317 if test "x$FEBOOTSTRAP" != "xno"; then
318 AC_CHECK_PROG([FEBOOTSTRAP_RUN],
319 [febootstrap-run],[febootstrap-run],[no])
320 test "x$FEBOOTSTRAP_RUN" = "xno" && \
321 AC_MSG_ERROR([febootstrap-run must be installed])
322 AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
323 [febootstrap-install],[febootstrap-install],[no])
324 test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
325 AC_MSG_ERROR([febootstrap-install must be installed])
326 AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
327 [febootstrap-minimize],[febootstrap-minimize],[no])
328 test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
329 AC_MSG_ERROR([febootstrap-minimize must be installed])
330 AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
331 [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
332 test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
333 AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
334 AC_CHECK_PROG([FEBOOTSTRAP_TO_SUPERMIN],
335 [febootstrap-to-supermin],[febootstrap-to-supermin],[no])
336 test "x$FEBOOTSTRAP_TO_SUPERMIN" = "xno" && \
337 AC_MSG_ERROR([febootstrap-to-supermin must be installed])
339 dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
340 dnl of febootstrap, but old versions will fail with yum).
341 AC_CHECK_PROG([FAKECHROOT],
342 [fakechroot],[fakechroot],[no])
343 test "x$FAKECHROOT" = "xno" && \
344 AC_MSG_ERROR([fakechroot must be installed])
346 AC_MSG_CHECKING([fakechroot version])
347 fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
348 if test -z "$fakechroot_version"; then
349 AC_MSG_RESULT([failed])
350 AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
352 AC_MSG_RESULT([$fakechroot_version])
353 fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
354 fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
355 if test "$fakechroot_major" -lt 2 || \
356 ( test "$fakechroot_major" -eq 2 && test "$fakechroot_minor" -lt 9 ); then
357 AC_MSG_ERROR([fakechroot version must be >= 2.9])
362 # check for debootstrap and debirf
363 AC_CHECK_PROG([DEBOOTSTRAP],
364 [debootstrap],[debootstrap],[no])
365 test "x$DEBOOTSTRAP" = "xno" && \
366 AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
367 AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
368 test "x$DEBIRF" = "xno" &&
369 AC_MSG_ERROR([debirf must be installed])
373 DEBIAN_KERNEL_ARCH=486
376 DEBIAN_KERNEL_ARCH=amd64
379 DEBIAN_KERNEL_ARCH=$host_cpu
382 AC_SUBST(DEBIAN_KERNEL_ARCH)
386 dnl --with-updates to specify a Fedora updates repository.
387 AC_ARG_WITH([updates],
388 [AS_HELP_STRING([--with-updates],
389 [set name of Fedora updates repository @<:@default=updates-released-f12@:>@])],
391 [with_updates=updates-released-f12])
392 UPDATES="$with_updates"
395 dnl --with-mirror to specify a local Fedora mirror.
396 AC_ARG_WITH([mirror],
397 [AS_HELP_STRING([--with-mirror],
398 [set URI of a local Fedora mirror])],
401 MIRROR="$with_mirror"
405 dnl --with-repo to specify a Fedora repository.
407 [AS_HELP_STRING([--with-repo],
408 [set name of Fedora repository @<:@default=fedora-12@:>@])],
410 [with_repo=fedora-12])
413 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
415 dnl Build the supermin appliance? Please see README file before
416 dnl enabling this option.
417 AC_ARG_ENABLE([supermin],
418 [AS_HELP_STRING([--enable-supermin],
419 [enable supermin appliance (see README) @<:@default=no@:>@])],
421 [enable_supermin=no])
422 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
424 dnl Enable packet dumps when in verbose mode. This generates lots
425 dnl of debug info, only useful for people debugging the RPC mechanism.
426 AC_ARG_ENABLE([packet-dump],
427 [AS_HELP_STRING([--enable-packet-dump],
428 [enable packet dumps in verbose mode @<:@default=no@:>@])],
429 [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
433 AC_ARG_WITH([readline],
434 [AS_HELP_STRING([--with-readline],
435 [support fancy command line editing @<:@default=check@:>@])],
437 [with_readline=check])
440 AS_IF([test "x$with_readline" != xno],
441 [AC_CHECK_LIB([readline], [main],
442 [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
443 AC_DEFINE([HAVE_LIBREADLINE], [1],
444 [Define if you have libreadline])
446 [if test "x$with_readline" != xcheck; then
448 [--with-readline was given, but test for readline failed])
452 LIBS="$LIBS $LIBREADLINE"
453 AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
458 AM_GNU_GETTEXT([external])
459 AM_GNU_GETTEXT_VERSION([0.17])
461 dnl libmagic (required)
462 AC_CHECK_LIB([magic],[magic_file],[
463 AC_SUBST([LIBMAGIC], ["-lmagic"])
465 AC_MSG_FAILURE([libmagic is required])
467 AC_CHECK_HEADER([magic.h],[],[
468 AC_MSG_FAILURE([magic.h header file is required])
471 dnl libvirt (required)
472 PKG_CHECK_MODULES([LIBVIRT], [libvirt])
473 AC_SUBST([LIBVIRT_CFLAGS])
474 AC_SUBST([LIBVIRT_LIBS])
476 dnl libxml2 (required)
477 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0])
478 AC_SUBST([LIBXML2_CFLAGS])
479 AC_SUBST([LIBXML2_LIBS])
481 dnl hivex library (highly recommended).
482 dnl This used to be a part of libguestfs, but was spun off into its
483 dnl own separate upstream project in libguestfs 1.0.85.
485 PKG_CHECK_MODULES([HIVEX], [hivex],,[
487 AC_MSG_WARN([Hivex library and headers are missing, so optional Windows Registry tools won't be built])])
488 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HAVE_HIVEX" = "xyes"])
489 AC_SUBST([HIVEX_CFLAGS])
490 AC_SUBST([HIVEX_LIBS])
492 dnl FUSE is optional to build the FUSE module.
494 PKG_CHECK_MODULES([FUSE],[fuse],,[
496 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])
497 AM_CONDITIONAL([HAVE_FUSE],[test "x$HAVE_FUSE" = "xyes"])
499 dnl Check for OCaml (optional, for OCaml bindings).
502 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
504 dnl Optional xml-light for running the generator.
505 OCAML_PKG_xml_light=no
506 if test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"; then
507 AC_CHECK_OCAML_PKG([xml-light])
509 AM_CONDITIONAL([HAVE_XML_LIGHT],[test "x$OCAML_PKG_xml_light" != "xno"])
511 dnl Build the OCaml viewer example. This has a lengthy list of
512 dnl dependencies and we don't attempt to detect them all. Read
513 dnl the top of ocaml/examples/viewer.ml before enabling this.
514 AC_ARG_ENABLE([ocaml-viewer],
515 [AS_HELP_STRING([--enable-ocaml-viewer],
516 [enable OCaml viewer (see ocaml/examples) @<:@default=no@:>@])],
518 [enable_ocaml_viewer=no])
519 AM_CONDITIONAL([BUILD_OCAML_VIEWER],[test "x$enable_ocaml_viewer" = "xyes"])
521 dnl Check for Perl (optional, for Perl bindings).
522 dnl XXX This isn't quite right, we should check for Perl devel library.
523 AC_CHECK_PROG([PERL],[perl],[perl],[no])
525 dnl Check for Perl modules that must be present to compile and
526 dnl test the Perl bindings.
527 missing_perl_modules=no
528 for pm in Test::More ExtUtils::MakeMaker; do
529 AC_MSG_CHECKING([for $pm])
530 if ! perl -M$pm -e1 >/dev/null 2>&1; then
532 missing_perl_modules=yes
537 if test "x$missing_perl_modules" = "xyes"; then
538 AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
541 AM_CONDITIONAL([HAVE_PERL],
542 [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
544 dnl Check for Python (optional, for Python bindings).
545 AC_CHECK_PROG([PYTHON],[python],[python],[no])
550 PYTHON_SITE_PACKAGES=
552 if test "x$PYTHON" != "xno"; then
553 PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
554 PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
556 $PYTHON_PREFIX/include/python$PYTHON_VERSION \
557 /usr/include/python$PYTHON_VERSION \
558 /usr/local/include/python$PYTHON_VERSION
560 AC_MSG_CHECKING([Python.h in $d])
561 if test -r "$d/Python.h"; then
562 AC_MSG_RESULT([found])
566 AC_MSG_RESULT([not found])
569 $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
570 $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
571 /usr/lib64/python$PYTHON_VERSION/site-packages \
572 /usr/lib/python$PYTHON_VERSION/site-packages \
573 /usr/local/lib/python$PYTHON_VERSION/site-packages
575 AC_MSG_CHECKING([for $d])
576 if test -d "$d"; then
577 AC_MSG_RESULT([found])
578 PYTHON_SITE_PACKAGES=$d
581 AC_MSG_RESULT([not found])
585 LIBS="$LIBS -lpython$PYTHON_VERSION"
586 AC_CHECK_FUNCS([PyCapsule_New])
590 AC_SUBST(PYTHON_PREFIX)
591 AC_SUBST(PYTHON_VERSION)
592 AC_SUBST(PYTHON_INCLUDEDIR)
593 AC_SUBST(PYTHON_SITE_PACKAGES)
595 AM_CONDITIONAL([HAVE_PYTHON],
596 [test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_SITE_PACKAGES" != "x"])
598 dnl Check for Ruby and rake (optional, for Ruby bindings).
599 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
600 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
602 AM_CONDITIONAL([HAVE_RUBY],
603 [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
606 AC_ARG_WITH(java_home,
607 [AS_HELP_STRING([--with-java-home],
608 [specify path to JDK directory @<:@default=check@:>@])],
610 [with_java_home=check])
612 if test "x$with_java_home" != "xno"; then
613 if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
615 # Reject unsafe characters in $JAVA_HOME
619 *[\\\"\#\$\&\'\`$jh_lf\ \ ]*)
620 AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
622 if test -d "$with_java_home"; then
623 JAVA_HOME="$with_java_home"
625 AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
629 if test "x$JAVA_HOME" = "x"; then
630 # Look for Java in some likely locations.
633 /usr/lib/jvm/java-6-openjdk
635 if test -d $d && test -f $d/bin/java; then
642 if test "x$JAVA_HOME" != "x"; then
643 AC_MSG_CHECKING(for JDK in $JAVA_HOME)
644 if test ! -x "$JAVA_HOME/bin/java"; then
645 AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
647 JAVA="$JAVA_HOME/bin/java"
649 if test ! -x "$JAVA_HOME/bin/javac"; then
650 AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
652 JAVAC="$JAVA_HOME/bin/javac"
654 if test ! -x "$JAVA_HOME/bin/javah"; then
655 AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
657 JAVAH="$JAVA_HOME/bin/javah"
659 if test ! -x "$JAVA_HOME/bin/javadoc"; then
660 AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
662 JAVADOC="$JAVA_HOME/bin/javadoc"
664 if test ! -x "$JAVA_HOME/bin/jar"; then
665 AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
667 JAR="$JAVA_HOME/bin/jar"
669 java_version=`$JAVA -version 2>&1 | grep "java version"`
670 AC_MSG_RESULT(found $java_version in $JAVA_HOME)
673 AC_MSG_CHECKING([for jni.h])
674 if test -f "$JAVA_HOME/include/jni.h"; then
675 JNI_CFLAGS="-I$JAVA_HOME/include"
677 if test "`find $JAVA_HOME -name jni.h`" != ""; then
678 head=`find $JAVA_HOME -name jni.h | tail -1`
679 dir=`dirname "$head"`
682 AC_MSG_FAILURE([missing jni.h header file])
685 AC_MSG_RESULT([$JNI_CFLAGS])
688 AC_MSG_CHECKING([for jni_md.h])
690 *linux*) system="linux" ;;
691 *SunOS*) system="solaris" ;;
692 *cygwin*) system="win32" ;;
693 *) system="$build_os" ;;
695 if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
696 JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
698 if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
699 head=`find $JAVA_HOME -name jni_md.h | tail -1`
700 dir=`dirname "$head"`
701 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
703 AC_MSG_FAILURE([missing jni_md.h header file])
706 AC_MSG_RESULT([$JNI_CFLAGS])
708 dnl Need extra version flag?
709 AC_MSG_CHECKING([extra javac flags])
711 javac_version=`$JAVAC -version 2>&1`
712 case "$javac_version" in
714 JAVAC_FLAGS="-source 1.5" ;;
716 AC_MSG_RESULT([$JAVAC_FLAGS])
718 dnl Where to install jarfiles.
719 dnl XXX How to make it configurable?
720 JAR_INSTALL_DIR=\${prefix}/share/java
721 JNI_INSTALL_DIR=\${libdir}
724 jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
725 jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
726 jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
727 JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
738 AC_SUBST(JAVAC_FLAGS)
739 AC_SUBST(JAR_INSTALL_DIR)
740 AC_SUBST(JNI_INSTALL_DIR)
741 AC_SUBST(JNI_VERSION_INFO)
743 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
745 dnl Check for Haskell (GHC).
746 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
748 AM_CONDITIONAL([HAVE_HASKELL],
749 [test "x$GHC" != "xno"])
751 dnl Check for Perl modules needed by virt-df, inspector, etc.
752 missing_perl_modules=no
753 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer Locale::TextDomain Win::Hivex Win::Hivex::Regedit; do
754 AC_MSG_CHECKING([for $pm])
755 if ! perl -M$pm -e1 >/dev/null 2>&1; then
757 missing_perl_modules=yes
762 if test "x$missing_perl_modules" = "xyes"; then
763 AC_MSG_WARN([some Perl modules required to compile virt-inspector and the other virt-* tools are missing])
766 AM_CONDITIONAL([HAVE_INSPECTOR],
767 [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
768 AM_CONDITIONAL([HAVE_TOOLS],
769 [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
771 dnl po4a for translating man pages and POD files (optional).
772 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
773 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
776 AC_CHECK_PROG([PHP],[php],[php],[no])
777 AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
778 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
780 dnl Library versioning.
781 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
782 AC_SUBST(MAX_PROC_NR)
785 if test "x$enable_daemon" = "xyes"; then
786 AC_CONFIG_SUBDIRS([daemon])
789 dnl Produce output files.
790 AC_CONFIG_HEADERS([config.h])
791 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
792 AC_CONFIG_FILES([appliance/update.sh],
793 [chmod +x appliance/update.sh])
794 AC_CONFIG_FILES([Makefile
796 src/Makefile fish/Makefile po/Makefile.in examples/Makefile
798 appliance/debian/debirf.conf
803 ocaml/Makefile ocaml/examples/Makefile
806 ruby/Makefile ruby/Rakefile
813 gnulib/tests/Makefile
818 ocaml/META perl/Makefile.PL])
824 echo "------------------------------------------------------------"
825 echo "Thank you for downloading $PACKAGE_STRING"
827 echo "This is how we have configured the optional components for you today:"
829 echo "Daemon .............................. $enable_daemon"
830 echo "Appliance ........................... $enable_appliance"
831 echo "QEMU ................................ $QEMU"
832 echo -n "OCaml bindings ...................... "
833 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
834 echo -n "Perl bindings ....................... "
835 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
836 echo -n "Python bindings ..................... "
837 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
838 echo -n "Ruby bindings ....................... "
839 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
840 echo -n "Java bindings ....................... "
841 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
842 echo -n "Haskell bindings .................... "
843 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
844 echo -n "PHP bindings ........................ "
845 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
846 echo -n "virt-inspector ...................... "
847 if test "x$HAVE_INSPECTOR_TRUE" = "x"; then echo "yes"; else echo "no"; fi
848 echo -n "virt-* tools ........................ "
849 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
850 echo "supermin appliance .................. $enable_supermin"
851 echo "FUSE filesystem ..................... $HAVE_FUSE"
853 echo "If any optional component is configured 'no' when you expected 'yes'"
854 echo "then you should check the preceeding messages."
856 echo "Please report bugs back to the mailing list:"
857 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
859 echo "Next you should type 'make' to build the package,"
860 echo "then 'make check' to run the tests."
861 echo "------------------------------------------------------------"