#!/usr/bin/perl -wT
# xavierbot : an OCaml interpreter IRC bot.
# By Richard W.M. Jones <rich@annexia.org>.
# This code is in the Public Domain.
# $Id: xavierbot.pl,v 1.5 2007/06/28 23:18:28 rjones Exp $

use strict;
use POE qw(Component::IRC Wheel::Run);

#----------------------------------------------------------------------
# Start of configuration.

my $nick = "xavierbot";
my $ircname = "Xavierbot";		# Printable name.
my $server = "chat.freenode.net";
#my $server = "devserv.devel.redhat.com";
my $port = 6667;
my $channel = "#ocaml";

# End of configuration.
#----------------------------------------------------------------------

$ENV{PATH} = "/usr/bin:/bin";

POE::Session->create (
  package_states => [
    main => [ qw(_default _start irc_001 irc_public got_stdout) ],
  ],
);

POE::Kernel->run ();
exit 0;

sub _start
{
    my ($kernel, $heap) = @_[KERNEL,HEAP];

    my $irc = POE::Component::IRC->spawn
	(
	 nick => $nick,
	 ircname => $ircname,
	 server => $server,
	 port => $port,
	 ) or die "POE::Component::IRC->spawn failed: $!";

    my $ocaml = POE::Wheel::Run->new
	(
	 Program => "./ocamlbotwrapper",
	 StdoutEvent => "got_stdout",
	 StderrEvent => "got_stdout",
	 ) or die "POE::Wheel::Run->new ./ocamlbotwrapper failed: $!";

    $heap->{irc} = $irc;
    $heap->{ocaml} = $ocaml;

    my $irc_session = $heap->{irc}->session_id ();
    $kernel->post ($irc_session => register => "all");
    $kernel->post ($irc_session => connect => { });

    undef;
}

sub irc_001
{
    my ($kernel, $sender) = @_[KERNEL,SENDER];

    my $poco_object = $sender->get_heap ();
    print "Connected to ", $poco_object->server_name (), "\n";

    $kernel->post ($sender => join => $channel);
    undef;
}

sub irc_public
{
    my ($kernel, $sender, $who, $where, $what, $heap) =
	@_[KERNEL,SENDER,ARG0,ARG1,ARG2,HEAP];
    my $nick = (split /!/, $who)[0];
    my $channel = $where->[0];

    print "got: $what\n";
    if (my ($stmt) = $what =~ /^\s*([^#].*;;)\s*$/) {
	$heap->{ocaml}->put ("$stmt\n");
    }
    elsif ($what =~ /$nick.*restart/) {
	print STDOUT "got instruction to restart ...\n"
    }
    undef;
}

sub _default
{
    my ($event, $args) = @_[ARG0 .. $#_];
    my @output = ("$event: ");

    foreach my $arg (@$args) {
	if (ref ($arg) eq "ARRAY") {
	    push @output, "[" . join (" ,", @$arg) . "]";
	} else {
	    push @output, "'$arg'";
	}
    }
    print STDOUT join " ", @output, "\n";
    return 0;
}

#----------------------------------------------------------------------

# Bot wrote something.

sub got_stdout
{
    my ($kernel,$heap, $input, $wheel_id) = @_[KERNEL,HEAP,ARG0,ARG1];
    print "Child said: $input\n";
    $kernel->post ($heap->{irc} => privmsg => $channel => "$input");
}
