configure.ac

   1 # ocaml-libvirt
   2 # Copyright (C) 2007 Red Hat Inc., Richard W.M. Jones
   3 #
   4 # This library is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU Lesser General Public
   6 # License as published by the Free Software Foundation; either
   7 # version 2 of the License, or (at your option) any later version.
   8 #
   9 # This library is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Lesser General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Lesser General Public
  15 # License along with this library; if not, write to the Free Software
  16 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  17
  18 dnl Process this file with autoconf to produce a configure script.
  19
  20 AC_INIT(ocaml-libvirt,0.4.0.2)
  21
  22 dnl Check for basic C environment.
  23 AC_PROG_CC
  24 AC_PROG_INSTALL
  25 AC_PROG_CPP
  26
  27 AC_C_PROTOTYPES
  28 test "x$U" != "x" && AC_MSG_ERROR(Compiler not ANSI compliant)
  29
  30 AC_PROG_CC_C_O
  31
  32 dnl Select some C flags based on the host type.
  33 AC_CANONICAL_HOST
  34
  35 DEBUG="-g"
  36 WARNINGS="-Wall -Werror"
  37 CFLAGS_FPIC="-fPIC"
  38 WIN32=no
  39 case "$host" in
  40   *-*-mingw*)
  41     WARNINGS="$WARNINGS -Wno-unused"
  42     CFLAGS_FPIC=""
  43     WIN32=yes
  44 esac
  45 AC_SUBST(DEBUG)
  46 AC_SUBST(WARNINGS)
  47 AC_SUBST(CFLAGS_FPIC)
  48 AC_SUBST(WIN32)
  49
  50 dnl Check for libvirt development environment.
  51 AC_ARG_WITH(libvirt,
  52         AC_HELP_STRING([--with-libvirt=PATH],[Set path to installed libvirt]),
  53         [if test "x$withval" != "x"; then
  54            CFLAGS="$CFLAGS -I$withval/include"
  55            LDFLAGS="$LDFLAGS -L$withval/lib"
  56          fi
  57         ])
  58 AC_CHECK_LIB(virt,virConnectOpen,
  59         [],
  60         AC_MSG_ERROR([You must install libvirt library]))
  61 AC_CHECK_HEADER([libvirt/libvirt.h],
  62         [],
  63         AC_MSG_ERROR([You must install libvirt development package]))
  64
  65 dnl We also use <libvirt/virterror.h>
  66 AC_CHECK_HEADER([libvirt/virterror.h],
  67         [],
  68         AC_MSG_ERROR([You must install libvirt development package]))
  69
  70 dnl Check for libvirt >= 0.2.1 (our minimum supported version).
  71 dnl See: http://libvirt.org/hvsupport.html
  72 AC_CHECK_FUNC(virConnectGetCapabilities,
  73         [],
  74         AC_MSG_ERROR([You must have libvirt >= 0.2.1]))
  75
  76 dnl Check for optional libvirt functions added since 0.2.1.
  77 dnl See: http://libvirt.org/hvsupport.html
  78 AC_CHECK_FUNCS([virConnectGetHostname \
  79                 virConnectGetURI \
  80                 virDomainBlockStats \
  81                 virDomainGetSchedulerParameters \
  82                 virDomainGetSchedulerType \
  83                 virDomainInterfaceStats \
  84                 virDomainMigrate \
  85                 virDomainSetSchedulerParameters \
  86                 virNodeGetFreeMemory \
  87                 virNodeGetCellsFreeMemory \
  88                 virJobGetInfo \
  89                 virJobGetDomain \
  90                 virJobGetNetwork \
  91                 virJobCancel \
  92                 virJobFree \
  93                 virDomainCreateLinuxJob \
  94                 virDomainSaveJob \
  95                 virDomainRestoreJob \
  96                 virDomainCoreDumpJob \
  97                 virDomainCreateJob \
  98                 virNetworkCreateXMLJob \
  99                 virNetworkCreateJob \
 100                 virStoragePoolGetConnect \
 101                 virConnectNumOfStoragePools \
 102                 virConnectListStoragePools \
 103                 virConnectNumOfDefinedStoragePools \
 104                 virConnectListDefinedStoragePools \
 105                 virConnectDiscoverStoragePools \
 106                 virStoragePoolLookupByName \
 107                 virStoragePoolLookupByUUID \
 108                 virStoragePoolLookupByUUIDString \
 109                 virStoragePoolLookupByVolume \
 110                 virStoragePoolCreateXML \
 111                 virStoragePoolDefineXML \
 112                 virStoragePoolUndefine \
 113                 virStoragePoolCreate \
 114                 virStoragePoolDestroy \
 115                 virStoragePoolShutdown \
 116                 virStoragePoolFree \
 117                 virStoragePoolRefresh \
 118                 virStoragePoolGetName \
 119                 virStoragePoolGetUUID \
 120                 virStoragePoolGetUUIDString \
 121                 virStoragePoolGetInfo \
 122                 virStoragePoolGetXMLDesc \
 123                 virStoragePoolGetAutostart \
 124                 virStoragePoolSetAutostart \
 125                 virStoragePoolNumOfVolumes \
 126                 virStoragePoolListVolumes \
 127                 virStorageVolLookupByName \
 128                 virStorageVolLookupByKey \
 129                 virStorageVolLookupByPath \
 130                 virStorageVolGetName \
 131                 virStorageVolGetKey \
 132                 virStorageVolCreateXML \
 133                 virStorageVolDestroy \
 134                 virStorageVolFree \
 135                 virStorageVolGetInfo \
 136                 virStorageVolGetXMLDesc \
 137                 virStorageVolGetPath \
 138 ])
 139
 140 dnl Check for optional types added since 0.2.1.
 141 AC_CHECK_TYPES([virJobPtr, virStoragePoolPtr, virStorageVolPtr],,,
 142                [#include <libvirt/libvirt.h>])
 143
 144 dnl Check for optional ncurses.
 145 AC_CHECK_LIB(ncurses,initscr)
 146
 147 dnl Check for basic OCaml environment & findlib.
 148 dnl Note that findlib is not necessary, but things will work better
 149 dnl if it is present.
 150 AC_PROG_OCAML
 151 AC_PROG_FINDLIB
 152
 153 if test "x$OCAMLFIND" != "x"; then
 154     dnl Use ocamlfind to find the required packages ...
 155
 156     dnl Check for required OCaml packages.
 157     AC_CHECK_OCAML_PKG(unix)
 158     if test "x$pkg_unix" != "xyes"; then
 159         AC_MSG_ERROR([Cannot find required OCaml package 'unix'])
 160     fi
 161
 162     dnl Check for optional OCaml packages.
 163     AC_CHECK_OCAML_PKG(extlib)
 164     AC_CHECK_OCAML_PKG(lablgtk2)
 165     AC_CHECK_OCAML_PKG(curses)
 166     AC_CHECK_OCAML_PKG(gettext)
 167     AC_CHECK_OCAML_PKG(xml-light)
 168     AC_CHECK_OCAML_PKG(csv)
 169     AC_CHECK_OCAML_PKG(calendar)
 170
 171     AC_SUBST(pkg_unix)
 172     AC_SUBST(pkg_extlib)
 173     AC_SUBST(pkg_lablgtk2)
 174     AC_SUBST(pkg_curses)
 175     AC_SUBST(pkg_gettext)
 176     AC_SUBST(pkg_xml_light)
 177     AC_SUBST(pkg_csv)
 178     AC_SUBST(pkg_calendar)
 179 else
 180     dnl Use a basic module test if there is no findlib ...
 181
 182     dnl Check for required OCaml modules.
 183     AC_CHECK_OCAML_MODULE(unix,pkg_unix,Unix,[.])
 184     if test "x$pkg_unix" = "xno"; then
 185         AC_MSG_ERROR([Cannot find required OCaml package 'unix'])
 186     fi
 187
 188     dnl Check for optional OCaml modules.
 189     AC_CHECK_OCAML_MODULE(extlib,pkg_extlib,ExtString,[+extlib])
 190     AC_CHECK_OCAML_MODULE(lablgtk2,pkg_lablgtk2,GMain,[+lablgtk2])
 191     AC_CHECK_OCAML_MODULE(curses,pkg_curses,Curses,[+curses])
 192     AC_CHECK_OCAML_MODULE(gettext,pkg_gettext,Gettext,[+gettext]) dnl XXX
 193     AC_CHECK_OCAML_MODULE(xml-light,pkg_xml_light,Xml,[+xml-light])
 194     AC_CHECK_OCAML_MODULE(csv,pkg_csv,Csv,[+csv])
 195     AC_CHECK_OCAML_MODULE(calendar,pkg_calendar,Calendar,[+calendar])
 196 fi
 197
 198 dnl Which subpackages (== subdirs) will we build?
 199 subdirs="libvirt examples mlvirsh"
 200 if test "x$pkg_lablgtk2" != "xno"; then
 201     subdirs="$subdirs virt-ctrl"
 202 fi
 203 if test "x$pkg_extlib" != "xno" -a "x$pkg_curses" != "xno"; then
 204     subdirs="$subdirs virt-top"
 205 fi
 206 if test "x$pkg_extlib" != "xno" -a "x$pkg_xml_light" != "xno"; then
 207     subdirs="$subdirs virt-df"
 208 fi
 209 AC_SUBST(subdirs)
 210
 211 dnl Check for optional perldoc (for building manual pages).
 212 AC_CHECK_PROG(HAVE_PERLDOC,perldoc,perldoc)
 213
 214 dnl Check for optional NSIS (for building a Windows installer).
 215 AC_ARG_WITH([nsis],
 216         [AS_HELP_STRING([--with-nsis],
 217             [use NSIS to build a Windows installer])],
 218         [],
 219         [with_nsis=no])
 220
 221 MAKENSIS=
 222 LIBVIRT_DLL_PATH=
 223 LIBXDR_DLL_PATH=
 224 LIBXML2_DLL_PATH=
 225 GNUTLS_DLL_PATH=
 226 GTK_PATH=
 227 GTK_DLL_PATH=
 228
 229 [
 230 msys_to_win_dir () {
 231     eval pushd "\$$1" > /dev/null
 232     eval $1=`pwd -W`
 233     popd > /dev/null
 234 }
 235 ]
 236
 237 if test "x$with_nsis" != "xno"; then
 238     AC_PATH_PROG(MAKENSIS,makensis,[],[$with_nsis:$PATH])
 239     if test "x$MAKENSIS" = "x"; then
 240         AC_MSG_FAILURE([--with-nsis was given, but could not find MAKENSIS.EXE])
 241     fi
 242
 243     # MAKENSIS is set so we will build a rule for making a Windows
 244     # installer.  To support this, generate wininstaller.nsis.
 245     saved_IFS=$IFS
 246     IFS=$PATH_SEPARATOR
 247     for d in $PATH; do
 248         IFS=$saved_IFS
 249         echo Checking $d for DLLs ... >&5
 250         if test -f "$d/libvirt-0.dll"; then
 251             LIBVIRT_DLL_PATH="$d"
 252         fi
 253         if test -f "$d/libxdr.dll"; then
 254             LIBXDR_DLL_PATH="$d"
 255         fi
 256         if test -f "$d/libxml2-2.dll"; then
 257             LIBXML2_DLL_PATH="$d"
 258         fi
 259         if test -f "$d/libgpg-error-0.dll"; then
 260             GNUTLS_DLL_PATH="$d"
 261         fi
 262         if test -f "$d/libgtk-win32-2.0-0.dll"; then
 263             GTK_DLL_PATH="$d"
 264             GTK_PATH="$d/.."
 265         fi
 266     done
 267     IFS=$saved_IFS
 268
 269     if test "x$LIBVIRT_DLL_PATH" = "x"; then
 270         AC_MSG_FAILURE([cannot find libvirt-0.dll in PATH])
 271     fi
 272     if test "x$LIBXDR_DLL_PATH" = "x"; then
 273         AC_MSG_FAILURE([cannot find libxdr.dll in PATH])
 274     fi
 275     if test "x$LIBXML2_DLL_PATH" = "x"; then
 276         AC_MSG_FAILURE([cannot find libxml2-2.dll in PATH])
 277     fi
 278     if test "x$GNUTLS_DLL_PATH" = "x"; then
 279         AC_MSG_FAILURE([cannot find GnuTLS DLLs in PATH])
 280     fi
 281     if test "x$GTK_DLL_PATH" = "x"; then
 282         AC_MSG_WARN([cannot find GTK DLLs in PATH])
 283     fi
 284
 285     # Change the paths to Windows paths.
 286     msys_to_win_dir LIBVIRT_DLL_PATH
 287     msys_to_win_dir LIBXDR_DLL_PATH
 288     msys_to_win_dir LIBXML2_DLL_PATH
 289     msys_to_win_dir GNUTLS_DLL_PATH
 290     if test "x$GTK_DLL_PATH" != "x"; then
 291         msys_to_win_dir GTK_DLL_PATH
 292         msys_to_win_dir GTK_PATH
 293     fi
 294 fi
 295 AC_SUBST(MAKENSIS)
 296 AC_SUBST(LIBVIRT_DLL_PATH)
 297 AC_SUBST(LIBXDR_DLL_PATH)
 298 AC_SUBST(LIBXML2_DLL_PATH)
 299 AC_SUBST(GNUTLS_DLL_PATH)
 300 AC_SUBST(GTK_DLL_PATH)
 301 AC_SUBST(GTK_PATH)
 302
 303 dnl Summary.
 304 echo "------------------------------------------------------------"
 305 echo "Thanks for downloading" $PACKAGE_STRING
 306 echo " subpackages to build : $subdirs"
 307 echo "------------------------------------------------------------"
 308
 309 dnl Produce output files.
 310 AC_CONFIG_HEADERS([config.h])
 311 AC_CONFIG_FILES([META
 312         libvirt/libvirt_version.ml
 313         Makefile
 314         Make.rules
 315         libvirt/Makefile
 316         examples/Makefile
 317         mlvirsh/Makefile
 318         virt-ctrl/Makefile
 319         virt-top/Makefile
 320         virt-df/Makefile
 321         ])
 322 if test "x$MAKENSIS" != "x"; then
 323         AC_CONFIG_FILES([wininstaller.nsis])
 324 fi
 325 AC_OUTPUT