configure.ac

   1 # ocaml-libvirt
   2 # Copyright (C) 2007 Red Hat Inc., Richard W.M. Jones
   3 #
   4 # This library is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU Lesser General Public
   6 # License as published by the Free Software Foundation; either
   7 # version 2 of the License, or (at your option) any later version.
   8 #
   9 # This library is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Lesser General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Lesser General Public
  15 # License along with this library; if not, write to the Free Software
  16 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  17
  18 dnl Process this file with autoconf to produce a configure script.
  19
  20 AC_INIT(ocaml-libvirt,0.4.0.3)
  21
  22 dnl Check for basic C environment.
  23 AC_PROG_CC
  24 AC_PROG_INSTALL
  25 AC_PROG_CPP
  26
  27 AC_C_PROTOTYPES
  28 test "x$U" != "x" && AC_MSG_ERROR(Compiler not ANSI compliant)
  29
  30 AC_PROG_CC_C_O
  31
  32 dnl Select some C flags based on the host type.
  33 AC_CANONICAL_HOST
  34
  35 DEBUG="-g"
  36 WARNINGS="-Wall -Werror"
  37 CFLAGS_FPIC="-fPIC"
  38 WIN32=no
  39 case "$host" in
  40   *-*-mingw*)
  41     WARNINGS="$WARNINGS -Wno-unused"
  42     CFLAGS_FPIC=""
  43     WIN32=yes
  44 esac
  45 AC_SUBST(DEBUG)
  46 AC_SUBST(WARNINGS)
  47 AC_SUBST(CFLAGS_FPIC)
  48 AC_SUBST(WIN32)
  49
  50 dnl Check for libvirt development environment.
  51 AC_ARG_WITH(libvirt,
  52         AC_HELP_STRING([--with-libvirt=PATH],[Set path to installed libvirt]),
  53         [if test "x$withval" != "x"; then
  54            CFLAGS="$CFLAGS -I$withval/include"
  55            LDFLAGS="$LDFLAGS -L$withval/lib"
  56          fi
  57         ])
  58 AC_CHECK_LIB(virt,virConnectOpen,
  59         [],
  60         AC_MSG_ERROR([You must install libvirt library]))
  61 AC_CHECK_HEADER([libvirt/libvirt.h],
  62         [],
  63         AC_MSG_ERROR([You must install libvirt development package]))
  64
  65 dnl We also use <libvirt/virterror.h>
  66 AC_CHECK_HEADER([libvirt/virterror.h],
  67         [],
  68         AC_MSG_ERROR([You must install libvirt development package]))
  69
  70 dnl Check for libvirt >= 0.2.1 (our minimum supported version).
  71 dnl See: http://libvirt.org/hvsupport.html
  72 AC_CHECK_FUNC(virConnectGetCapabilities,
  73         [],
  74         AC_MSG_ERROR([You must have libvirt >= 0.2.1]))
  75
  76 dnl Check for optional libvirt functions added since 0.2.1.
  77 dnl See: http://libvirt.org/hvsupport.html
  78 AC_CHECK_FUNCS([virConnectGetHostname \
  79                 virConnectGetURI \
  80                 virDomainBlockStats \
  81                 virDomainGetSchedulerParameters \
  82                 virDomainGetSchedulerType \
  83                 virDomainInterfaceStats \
  84                 virDomainMigrate \
  85                 virDomainSetSchedulerParameters \
  86                 virNodeGetFreeMemory \
  87                 virNodeGetCellsFreeMemory \
  88                 virStoragePoolGetConnect \
  89                 virConnectNumOfStoragePools \
  90                 virConnectListStoragePools \
  91                 virConnectNumOfDefinedStoragePools \
  92                 virConnectListDefinedStoragePools \
  93                 virStoragePoolLookupByName \
  94                 virStoragePoolLookupByUUID \
  95                 virStoragePoolLookupByUUIDString \
  96                 virStoragePoolLookupByVolume \
  97                 virStoragePoolCreateXML \
  98                 virStoragePoolDefineXML \
  99                 virStoragePoolBuild \
 100                 virStoragePoolUndefine \
 101                 virStoragePoolCreate \
 102                 virStoragePoolDestroy \
 103                 virStoragePoolDelete \
 104                 virStoragePoolFree \
 105                 virStoragePoolRefresh \
 106                 virStoragePoolGetName \
 107                 virStoragePoolGetUUID \
 108                 virStoragePoolGetUUIDString \
 109                 virStoragePoolGetInfo \
 110                 virStoragePoolGetXMLDesc \
 111                 virStoragePoolGetAutostart \
 112                 virStoragePoolSetAutostart \
 113                 virStoragePoolNumOfVolumes \
 114                 virStoragePoolListVolumes \
 115                 virStorageVolLookupByName \
 116                 virStorageVolLookupByKey \
 117                 virStorageVolLookupByPath \
 118                 virStorageVolGetName \
 119                 virStorageVolGetKey \
 120                 virStorageVolCreateXML \
 121                 virStorageVolDelete \
 122                 virStorageVolFree \
 123                 virStorageVolGetInfo \
 124                 virStorageVolGetXMLDesc \
 125                 virStorageVolGetPath \
 126 ])
 127
 128 # This jobs API was never published and is due to get overhauled
 129 # in the near future:
 130 #               virJobGetInfo
 131 #               virJobGetDomain
 132 #               virJobGetNetwork
 133 #               virJobCancel
 134 #               virJobFree
 135 #               virDomainCreateLinuxJob
 136 #               virDomainSaveJob
 137 #               virDomainRestoreJob
 138 #               virDomainCoreDumpJob
 139 #               virDomainCreateJob
 140 #               virNetworkCreateXMLJob
 141 #               virNetworkCreateJob
 142
 143 dnl Check for optional types added since 0.2.1.
 144 AC_CHECK_TYPES([virJobPtr, virStoragePoolPtr, virStorageVolPtr],,,
 145                [#include <libvirt/libvirt.h>])
 146
 147 dnl Check for optional ncurses.
 148 AC_CHECK_LIB(ncurses,initscr)
 149
 150 dnl Check for basic OCaml environment & findlib.
 151 dnl Note that findlib is not necessary, but things will work better
 152 dnl if it is present.
 153 AC_PROG_OCAML
 154 AC_PROG_FINDLIB
 155
 156 if test "x$OCAMLFIND" != "x"; then
 157     dnl Use ocamlfind to find the required packages ...
 158
 159     dnl Check for required OCaml packages.
 160     AC_CHECK_OCAML_PKG(unix)
 161     if test "x$pkg_unix" != "xyes"; then
 162         AC_MSG_ERROR([Cannot find required OCaml package 'unix'])
 163     fi
 164
 165     dnl Check for optional OCaml packages.
 166     AC_CHECK_OCAML_PKG(extlib)
 167     AC_CHECK_OCAML_PKG(lablgtk2)
 168     AC_CHECK_OCAML_PKG(curses)
 169     AC_CHECK_OCAML_PKG(gettext)
 170     AC_CHECK_OCAML_PKG(xml-light)
 171     AC_CHECK_OCAML_PKG(csv)
 172     AC_CHECK_OCAML_PKG(dbus)
 173
 174     dnl Need to check which version of calendar is installed.
 175     AC_CHECK_OCAML_MODULE(calendar,pkg_calendar2,CalendarLib.Date,[+calendar])
 176     if test "x$pkg_calendar2" = "xno"; then
 177         AC_CHECK_OCAML_PKG(calendar)
 178     fi
 179
 180     AC_SUBST(pkg_unix)
 181     AC_SUBST(pkg_extlib)
 182     AC_SUBST(pkg_lablgtk2)
 183     AC_SUBST(pkg_curses)
 184     AC_SUBST(pkg_gettext)
 185     AC_SUBST(pkg_xml_light)
 186     AC_SUBST(pkg_csv)
 187     AC_SUBST(pkg_dbus)
 188     AC_SUBST(pkg_calendar)
 189     AC_SUBST(pkg_calendar2)
 190 else
 191     dnl Use a basic module test if there is no findlib ...
 192
 193     dnl Check for required OCaml modules.
 194     AC_CHECK_OCAML_MODULE(unix,pkg_unix,Unix,[.])
 195     if test "x$pkg_unix" = "xno"; then
 196         AC_MSG_ERROR([Cannot find required OCaml package 'unix'])
 197     fi
 198
 199     dnl Check for optional OCaml modules.
 200     AC_CHECK_OCAML_MODULE(extlib,pkg_extlib,ExtString,[+extlib])
 201     AC_CHECK_OCAML_MODULE(lablgtk2,pkg_lablgtk2,GMain,[+lablgtk2])
 202     AC_CHECK_OCAML_MODULE(curses,pkg_curses,Curses,[+curses])
 203     AC_CHECK_OCAML_MODULE(gettext,pkg_gettext,Gettext,[+gettext]) dnl XXX
 204     AC_CHECK_OCAML_MODULE(xml-light,pkg_xml_light,Xml,[+xml-light])
 205     AC_CHECK_OCAML_MODULE(csv,pkg_csv,Csv,[+csv])
 206     AC_CHECK_OCAML_MODULE(dbus,pkg_dbus,DBus,[+dbus])
 207     dnl XXX Version check - see above.
 208     AC_CHECK_OCAML_MODULE(calendar,pkg_calendar,Calendar,[+calendar])
 209 fi
 210
 211 dnl Which subpackages (== subdirs) will we build?
 212 subdirs="libvirt examples mlvirsh"
 213 if test "x$pkg_lablgtk2" != "xno"; then
 214     subdirs="$subdirs virt-ctrl"
 215 fi
 216 if test "x$pkg_extlib" != "xno" -a "x$pkg_curses" != "xno"; then
 217     subdirs="$subdirs virt-top"
 218 fi
 219 if test "x$pkg_extlib" != "xno" -a "x$pkg_xml_light" != "xno"; then
 220     subdirs="$subdirs virt-df"
 221 fi
 222 AC_SUBST(subdirs)
 223
 224 dnl Check for optional perldoc (for building manual pages).
 225 AC_CHECK_PROG(HAVE_PERLDOC,perldoc,perldoc)
 226
 227 dnl Check for optional NSIS (for building a Windows installer).
 228 AC_ARG_WITH([nsis],
 229         [AS_HELP_STRING([--with-nsis],
 230             [use NSIS to build a Windows installer])],
 231         [],
 232         [with_nsis=no])
 233
 234 MAKENSIS=
 235 LIBVIRT_DLL_PATH=
 236 LIBXDR_DLL_PATH=
 237 LIBXML2_DLL_PATH=
 238 GNUTLS_DLL_PATH=
 239 GTK_PATH=
 240 GTK_DLL_PATH=
 241
 242 [
 243 msys_to_win_dir () {
 244     eval pushd "\$$1" > /dev/null
 245     eval $1=`pwd -W`
 246     popd > /dev/null
 247 }
 248 ]
 249
 250 if test "x$with_nsis" != "xno"; then
 251     AC_PATH_PROG(MAKENSIS,makensis,[],[$with_nsis:$PATH])
 252     if test "x$MAKENSIS" = "x"; then
 253         AC_MSG_FAILURE([--with-nsis was given, but could not find MAKENSIS.EXE])
 254     fi
 255
 256     # MAKENSIS is set so we will build a rule for making a Windows
 257     # installer.  To support this, generate wininstaller.nsis.
 258     saved_IFS=$IFS
 259     IFS=$PATH_SEPARATOR
 260     for d in $PATH; do
 261         IFS=$saved_IFS
 262         echo Checking $d for DLLs ... >&5
 263         if test -f "$d/libvirt-0.dll"; then
 264             LIBVIRT_DLL_PATH="$d"
 265         fi
 266         if test -f "$d/libxdr.dll"; then
 267             LIBXDR_DLL_PATH="$d"
 268         fi
 269         if test -f "$d/libxml2-2.dll"; then
 270             LIBXML2_DLL_PATH="$d"
 271         fi
 272         if test -f "$d/libgpg-error-0.dll"; then
 273             GNUTLS_DLL_PATH="$d"
 274         fi
 275         if test -f "$d/libgtk-win32-2.0-0.dll"; then
 276             GTK_DLL_PATH="$d"
 277             GTK_PATH="$d/.."
 278         fi
 279     done
 280     IFS=$saved_IFS
 281
 282     if test "x$LIBVIRT_DLL_PATH" = "x"; then
 283         AC_MSG_FAILURE([cannot find libvirt-0.dll in PATH])
 284     fi
 285     if test "x$LIBXDR_DLL_PATH" = "x"; then
 286         AC_MSG_FAILURE([cannot find libxdr.dll in PATH])
 287     fi
 288     if test "x$LIBXML2_DLL_PATH" = "x"; then
 289         AC_MSG_FAILURE([cannot find libxml2-2.dll in PATH])
 290     fi
 291     if test "x$GNUTLS_DLL_PATH" = "x"; then
 292         AC_MSG_FAILURE([cannot find GnuTLS DLLs in PATH])
 293     fi
 294     if test "x$GTK_DLL_PATH" = "x"; then
 295         AC_MSG_WARN([cannot find GTK DLLs in PATH])
 296     fi
 297
 298     # Change the paths to Windows paths.
 299     msys_to_win_dir LIBVIRT_DLL_PATH
 300     msys_to_win_dir LIBXDR_DLL_PATH
 301     msys_to_win_dir LIBXML2_DLL_PATH
 302     msys_to_win_dir GNUTLS_DLL_PATH
 303     if test "x$GTK_DLL_PATH" != "x"; then
 304         msys_to_win_dir GTK_DLL_PATH
 305         msys_to_win_dir GTK_PATH
 306     fi
 307 fi
 308 AC_SUBST(MAKENSIS)
 309 AC_SUBST(LIBVIRT_DLL_PATH)
 310 AC_SUBST(LIBXDR_DLL_PATH)
 311 AC_SUBST(LIBXML2_DLL_PATH)
 312 AC_SUBST(GNUTLS_DLL_PATH)
 313 AC_SUBST(GTK_DLL_PATH)
 314 AC_SUBST(GTK_PATH)
 315
 316 dnl Summary.
 317 echo "------------------------------------------------------------"
 318 echo "Thanks for downloading" $PACKAGE_STRING
 319 echo " subpackages to build : $subdirs"
 320 echo "------------------------------------------------------------"
 321
 322 dnl Produce output files.
 323 AC_CONFIG_HEADERS([config.h])
 324 AC_CONFIG_FILES([META
 325         libvirt/libvirt_version.ml
 326         Makefile
 327         Make.rules
 328         libvirt/Makefile
 329         examples/Makefile
 330         mlvirsh/Makefile
 331         virt-ctrl/Makefile
 332         virt-top/Makefile
 333         virt-df/Makefile
 334         ])
 335 if test "x$MAKENSIS" != "x"; then
 336         AC_CONFIG_FILES([wininstaller.nsis])
 337 fi
 338 AC_OUTPUT