configure.ac

   1 # ocaml-libvirt
   2 # Copyright (C) 2007-2008 Red Hat Inc., Richard W.M. Jones
   3 #
   4 # This library is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU Lesser General Public
   6 # License as published by the Free Software Foundation; either
   7 # version 2 of the License, or (at your option) any later version.
   8 #
   9 # This library is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Lesser General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Lesser General Public
  15 # License along with this library; if not, write to the Free Software
  16 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  17
  18 dnl Process this file with autoconf to produce a configure script.
  19
  20 AC_INIT(ocaml-libvirt,0.4.1.1)
  21
  22 dnl Check for basic C environment.
  23 AC_PROG_CC
  24 AC_PROG_INSTALL
  25 AC_PROG_CPP
  26
  27 AC_C_PROTOTYPES
  28 test "x$U" != "x" && AC_MSG_ERROR(Compiler not ANSI compliant)
  29
  30 AC_PROG_CC_C_O
  31
  32 dnl Select some C flags based on the host type.
  33 AC_CANONICAL_HOST
  34
  35 DEBUG="-g"
  36 WARNINGS="-Wall -Werror"
  37 CFLAGS_FPIC="-fPIC"
  38 WIN32=no
  39 case "$host" in
  40   *-*-mingw*)
  41     WARNINGS="$WARNINGS -Wno-unused"
  42     CFLAGS_FPIC=""
  43     WIN32=yes
  44 esac
  45 AC_SUBST(DEBUG)
  46 AC_SUBST(WARNINGS)
  47 AC_SUBST(CFLAGS_FPIC)
  48 AC_SUBST(WIN32)
  49
  50 dnl Check for libvirt development environment.
  51 AC_ARG_WITH(libvirt,
  52         AC_HELP_STRING([--with-libvirt=PATH],[Set path to installed libvirt]),
  53         [if test "x$withval" != "x"; then
  54            CFLAGS="$CFLAGS -I$withval/include"
  55            LDFLAGS="$LDFLAGS -L$withval/lib"
  56          fi
  57         ])
  58 AC_CHECK_LIB(virt,virConnectOpen,
  59         [],
  60         AC_MSG_ERROR([You must install libvirt library]))
  61 AC_CHECK_HEADER([libvirt/libvirt.h],
  62         [],
  63         AC_MSG_ERROR([You must install libvirt development package]))
  64
  65 dnl We also use <libvirt/virterror.h>
  66 AC_CHECK_HEADER([libvirt/virterror.h],
  67         [],
  68         AC_MSG_ERROR([You must install libvirt development package]))
  69
  70 dnl Check for libvirt >= 0.2.1 (our minimum supported version).
  71 dnl See: http://libvirt.org/hvsupport.html
  72 AC_CHECK_FUNC(virConnectGetCapabilities,
  73         [],
  74         AC_MSG_ERROR([You must have libvirt >= 0.2.1]))
  75
  76 dnl Check for optional libvirt functions added since 0.2.1.
  77 dnl See: http://libvirt.org/hvsupport.html
  78 AC_CHECK_FUNCS([virConnectGetHostname \
  79                 virConnectGetURI \
  80                 virDomainBlockStats \
  81                 virDomainGetSchedulerParameters \
  82                 virDomainGetSchedulerType \
  83                 virDomainInterfaceStats \
  84                 virDomainMigrate \
  85                 virDomainSetSchedulerParameters \
  86                 virNodeGetFreeMemory \
  87                 virNodeGetCellsFreeMemory \
  88                 virStoragePoolGetConnect \
  89                 virConnectNumOfStoragePools \
  90                 virConnectListStoragePools \
  91                 virConnectNumOfDefinedStoragePools \
  92                 virConnectListDefinedStoragePools \
  93                 virStoragePoolLookupByName \
  94                 virStoragePoolLookupByUUID \
  95                 virStoragePoolLookupByUUIDString \
  96                 virStoragePoolLookupByVolume \
  97                 virStoragePoolCreateXML \
  98                 virStoragePoolDefineXML \
  99                 virStoragePoolBuild \
 100                 virStoragePoolUndefine \
 101                 virStoragePoolCreate \
 102                 virStoragePoolDestroy \
 103                 virStoragePoolDelete \
 104                 virStoragePoolFree \
 105                 virStoragePoolRefresh \
 106                 virStoragePoolGetName \
 107                 virStoragePoolGetUUID \
 108                 virStoragePoolGetUUIDString \
 109                 virStoragePoolGetInfo \
 110                 virStoragePoolGetXMLDesc \
 111                 virStoragePoolGetAutostart \
 112                 virStoragePoolSetAutostart \
 113                 virStoragePoolNumOfVolumes \
 114                 virStoragePoolListVolumes \
 115                 virStorageVolLookupByName \
 116                 virStorageVolLookupByKey \
 117                 virStorageVolLookupByPath \
 118                 virStorageVolGetName \
 119                 virStorageVolGetKey \
 120                 virStorageVolCreateXML \
 121                 virStorageVolDelete \
 122                 virStorageVolFree \
 123                 virStorageVolGetInfo \
 124                 virStorageVolGetXMLDesc \
 125                 virStorageVolGetPath \
 126 ])
 127
 128 # This jobs API was never published and is due to get overhauled
 129 # in the near future:
 130 #               virJobGetInfo
 131 #               virJobGetDomain
 132 #               virJobGetNetwork
 133 #               virJobCancel
 134 #               virJobFree
 135 #               virDomainCreateLinuxJob
 136 #               virDomainSaveJob
 137 #               virDomainRestoreJob
 138 #               virDomainCoreDumpJob
 139 #               virDomainCreateJob
 140 #               virNetworkCreateXMLJob
 141 #               virNetworkCreateJob
 142
 143 dnl Check for optional types added since 0.2.1.
 144 AC_CHECK_TYPES([virJobPtr, virStoragePoolPtr, virStorageVolPtr],,,
 145                [#include <libvirt/libvirt.h>])
 146
 147 dnl Check for optional ncurses.
 148 AC_CHECK_LIB(ncurses,initscr)
 149
 150 dnl Check for optional GNOME icons (from gnome-icon-theme package).
 151 AC_ARG_WITH(icons,
 152         AC_HELP_STRING([--with-icons=PATH],
 153                 [Set path to installed icons @<:@default=/usr/share/icons@:>@]),
 154         [],[with_icons=/usr/share/icons])
 155 icons=""
 156 if test "x$with_icons" != "xno"; then
 157     for size in 16 24 32 48; do
 158         for f in devices/computer.png; do
 159             fname="${with_icons}/gnome/${size}x${size}/${f}"
 160             AC_MSG_CHECKING([checking for icon $fname])
 161             if test -f "$fname"; then
 162                 AC_MSG_RESULT([yes])
 163                 icons="$size $f $fname $icons"
 164             else
 165                 AC_MSG_RESULT([no])
 166             fi
 167         done
 168     done
 169 fi
 170 AC_SUBST(with_icons)
 171 AC_SUBST(icons)
 172
 173 dnl Check for basic OCaml environment & findlib.
 174 dnl Note that findlib is not necessary, but things will work better
 175 dnl if it is present.
 176 AC_PROG_OCAML
 177 AC_PROG_FINDLIB
 178
 179 if test "x$OCAMLFIND" != "x"; then
 180     dnl Use ocamlfind to find the required packages ...
 181
 182     dnl Check for required OCaml packages.
 183     AC_CHECK_OCAML_PKG(unix)
 184     if test "x$pkg_unix" != "xyes"; then
 185         AC_MSG_ERROR([Cannot find required OCaml package 'unix'])
 186     fi
 187
 188     dnl Check for optional OCaml packages.
 189     AC_CHECK_OCAML_PKG(extlib)
 190     AC_CHECK_OCAML_PKG(lablgtk2)
 191     AC_CHECK_OCAML_PKG(curses)
 192     AC_CHECK_OCAML_PKG(gettext)
 193     AC_CHECK_OCAML_PKG(xml-light)
 194     AC_CHECK_OCAML_PKG(csv)
 195     AC_CHECK_OCAML_PKG(dbus)
 196     AC_CHECK_OCAML_PKG(gettext)
 197
 198     dnl Need to check which version of calendar is installed.
 199     AC_CHECK_OCAML_MODULE(calendar,pkg_calendar2,CalendarLib.Date,[+calendar])
 200     if test "x$pkg_calendar2" = "xno"; then
 201         AC_CHECK_OCAML_PKG(calendar)
 202     fi
 203
 204     AC_SUBST(pkg_unix)
 205     AC_SUBST(pkg_extlib)
 206     AC_SUBST(pkg_lablgtk2)
 207     AC_SUBST(pkg_curses)
 208     AC_SUBST(pkg_gettext)
 209     AC_SUBST(pkg_xml_light)
 210     AC_SUBST(pkg_csv)
 211     AC_SUBST(pkg_dbus)
 212     AC_SUBST(pkg_gettext)
 213     AC_SUBST(pkg_calendar)
 214     AC_SUBST(pkg_calendar2)
 215 else
 216     dnl Use a basic module test if there is no findlib ...
 217
 218     dnl Check for required OCaml modules.
 219     AC_CHECK_OCAML_MODULE(unix,pkg_unix,Unix,[.])
 220     if test "x$pkg_unix" = "xno"; then
 221         AC_MSG_ERROR([Cannot find required OCaml package 'unix'])
 222     fi
 223
 224     dnl Check for optional OCaml modules.
 225     AC_CHECK_OCAML_MODULE(extlib,pkg_extlib,ExtString,[+extlib])
 226     AC_CHECK_OCAML_MODULE(lablgtk2,pkg_lablgtk2,GMain,[+lablgtk2])
 227     AC_CHECK_OCAML_MODULE(curses,pkg_curses,Curses,[+curses])
 228     AC_CHECK_OCAML_MODULE(gettext,pkg_gettext,Gettext,[+gettext]) dnl XXX
 229     AC_CHECK_OCAML_MODULE(xml-light,pkg_xml_light,Xml,[+xml-light])
 230     AC_CHECK_OCAML_MODULE(csv,pkg_csv,Csv,[+csv])
 231     AC_CHECK_OCAML_MODULE(dbus,pkg_dbus,DBus,[+dbus])
 232     AC_CHECK_OCAML_MODULE(gettext,pkg_gettext,Gettext,[+gettext])
 233     dnl XXX Version check - see above.
 234     AC_CHECK_OCAML_MODULE(calendar,pkg_calendar,Calendar,[+calendar])
 235 fi
 236
 237 dnl Which subpackages (== subdirs) will we build?
 238 subdirs="libvirt examples mlvirsh"
 239 if test "x$pkg_lablgtk2" != "xno"; then
 240     subdirs="$subdirs virt-ctrl"
 241 fi
 242 if test "x$pkg_extlib" != "xno" -a "x$pkg_curses" != "xno"; then
 243     subdirs="$subdirs virt-top"
 244 fi
 245 if test "x$pkg_extlib" != "xno" -a "x$pkg_xml_light" != "xno"; then
 246     subdirs="$subdirs virt-df"
 247 fi
 248 AC_SUBST(subdirs)
 249
 250 dnl Check for optional perldoc (for building manual pages).
 251 AC_CHECK_PROG(HAVE_PERLDOC,perldoc,perldoc)
 252
 253 dnl Check for optional gdk-pixbuf-mlsource (for icons).
 254 AC_CHECK_PROG(HAVE_GDK_PIXBUF_MLSOURCE,gdk-pixbuf-mlsource,gdk-pixbuf-mlsource)
 255
 256 dnl Check for recommended ocaml-gettext tool.
 257 AC_CHECK_PROG(OCAML_GETTEXT,ocaml-gettext,ocaml-gettext)
 258
 259 dnl Check for optional NSIS (for building a Windows installer).
 260 AC_ARG_WITH([nsis],
 261         [AS_HELP_STRING([--with-nsis],
 262             [use NSIS to build a Windows installer])],
 263         [],
 264         [with_nsis=no])
 265
 266 MAKENSIS=
 267 LIBVIRT_DLL_PATH=
 268 LIBXDR_DLL_PATH=
 269 LIBXML2_DLL_PATH=
 270 GNUTLS_DLL_PATH=
 271 GTK_PATH=
 272 GTK_DLL_PATH=
 273
 274 [
 275 msys_to_win_dir () {
 276     eval pushd "\$$1" > /dev/null
 277     eval $1=`pwd -W`
 278     popd > /dev/null
 279 }
 280 ]
 281
 282 if test "x$with_nsis" != "xno"; then
 283     AC_PATH_PROG(MAKENSIS,makensis,[],[$with_nsis:$PATH])
 284     if test "x$MAKENSIS" = "x"; then
 285         AC_MSG_FAILURE([--with-nsis was given, but could not find MAKENSIS.EXE])
 286     fi
 287
 288     # MAKENSIS is set so we will build a rule for making a Windows
 289     # installer.  To support this, generate wininstaller.nsis.
 290     saved_IFS=$IFS
 291     IFS=$PATH_SEPARATOR
 292     for d in $PATH; do
 293         IFS=$saved_IFS
 294         echo Checking $d for DLLs ... >&5
 295         if test -f "$d/libvirt-0.dll"; then
 296             LIBVIRT_DLL_PATH="$d"
 297         fi
 298         if test -f "$d/libxdr.dll"; then
 299             LIBXDR_DLL_PATH="$d"
 300         fi
 301         if test -f "$d/libxml2-2.dll"; then
 302             LIBXML2_DLL_PATH="$d"
 303         fi
 304         if test -f "$d/libgpg-error-0.dll"; then
 305             GNUTLS_DLL_PATH="$d"
 306         fi
 307         if test -f "$d/libgtk-win32-2.0-0.dll"; then
 308             GTK_DLL_PATH="$d"
 309             GTK_PATH="$d/.."
 310         fi
 311     done
 312     IFS=$saved_IFS
 313
 314     if test "x$LIBVIRT_DLL_PATH" = "x"; then
 315         AC_MSG_FAILURE([cannot find libvirt-0.dll in PATH])
 316     fi
 317     if test "x$LIBXDR_DLL_PATH" = "x"; then
 318         AC_MSG_FAILURE([cannot find libxdr.dll in PATH])
 319     fi
 320     if test "x$LIBXML2_DLL_PATH" = "x"; then
 321         AC_MSG_FAILURE([cannot find libxml2-2.dll in PATH])
 322     fi
 323     if test "x$GNUTLS_DLL_PATH" = "x"; then
 324         AC_MSG_FAILURE([cannot find GnuTLS DLLs in PATH])
 325     fi
 326     if test "x$GTK_DLL_PATH" = "x"; then
 327         AC_MSG_WARN([cannot find GTK DLLs in PATH])
 328     fi
 329
 330     # Change the paths to Windows paths.
 331     msys_to_win_dir LIBVIRT_DLL_PATH
 332     msys_to_win_dir LIBXDR_DLL_PATH
 333     msys_to_win_dir LIBXML2_DLL_PATH
 334     msys_to_win_dir GNUTLS_DLL_PATH
 335     if test "x$GTK_DLL_PATH" != "x"; then
 336         msys_to_win_dir GTK_DLL_PATH
 337         msys_to_win_dir GTK_PATH
 338     fi
 339 fi
 340 AC_SUBST(MAKENSIS)
 341 AC_SUBST(LIBVIRT_DLL_PATH)
 342 AC_SUBST(LIBXDR_DLL_PATH)
 343 AC_SUBST(LIBXML2_DLL_PATH)
 344 AC_SUBST(GNUTLS_DLL_PATH)
 345 AC_SUBST(GTK_DLL_PATH)
 346 AC_SUBST(GTK_PATH)
 347
 348 dnl Write gettext modules for the programs.
 349 dnl http://www.le-gall.net/sylvain+violaine/documentation/ocaml-gettext/html/reference-manual/ch03s04.html
 350 for d in mlvirsh virt-ctrl virt-df virt-top; do
 351     f=`echo $d | tr - _`_gettext.ml
 352     AC_MSG_NOTICE([creating $d/$f])
 353     rm -f $d/$f
 354     echo "(* This file is generated automatically by ./configure. *)" > $d/$f
 355     if test "x$pkg_gettext" != "xno"; then
 356         # Gettext module is available, so use it.
 357         cat <<EOT >>$d/$f
 358 module Gettext = Gettext.Program (
 359   struct
 360     let textdomain = "$d"
 361     let codeset = None
 362     let dir = None
 363     let dependencies = [[]]
 364   end
 365 ) (GettextStub.Native)
 366 EOT
 367     else
 368         # No gettext module is available, so fake the translation functions.
 369         cat <<EOT >>$d/$f
 370 module Gettext = struct
 371   external s_ : string -> string = "%identity"
 372   external f_ : ('a -> 'b, 'c, 'd) format -> ('a -> 'b, 'c, 'd) format
 373     = "%identity"
 374   let sn_ : string -> string -> int -> string
 375     = fun s p n -> if n = 1 then s else p
 376   let fn_ : ('a -> 'b, 'c, 'd) format -> ('a -> 'b, 'c, 'd) format -> int
 377       -> ('a -> 'b, 'c, 'd) format
 378     = fun s p n -> if n = 1 then s else p
 379 end
 380 EOT
 381     fi
 382 done
 383
 384 dnl Summary.
 385 echo "------------------------------------------------------------"
 386 echo "Thanks for downloading" $PACKAGE_STRING
 387 echo " subpackages to build : $subdirs"
 388 echo "------------------------------------------------------------"
 389
 390 dnl Produce output files.
 391 AC_CONFIG_HEADERS([config.h])
 392 AC_CONFIG_FILES([META
 393         libvirt/libvirt_version.ml
 394         Makefile
 395         Make.rules
 396         po/Makefile
 397         libvirt/Makefile
 398         examples/Makefile
 399         mlvirsh/Makefile
 400         virt-ctrl/Makefile
 401         virt-top/Makefile
 402         virt-df/Makefile
 403         ])
 404 if test "x$MAKENSIS" != "x"; then
 405         AC_CONFIG_FILES([wininstaller.nsis])
 406 fi
 407 AC_OUTPUT