configure.ac

   1 # ocaml-libvirt
   2 # Copyright (C) 2007 Red Hat Inc., Richard W.M. Jones
   3 #
   4 # This library is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU Lesser General Public
   6 # License as published by the Free Software Foundation; either
   7 # version 2 of the License, or (at your option) any later version.
   8 #
   9 # This library is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Lesser General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Lesser General Public
  15 # License along with this library; if not, write to the Free Software
  16 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  17
  18 dnl Process this file with autoconf to produce a configure script.
  19
  20 AC_INIT(ocaml-libvirt,0.4.0.3)
  21
  22 dnl Check for basic C environment.
  23 AC_PROG_CC
  24 AC_PROG_INSTALL
  25 AC_PROG_CPP
  26
  27 AC_C_PROTOTYPES
  28 test "x$U" != "x" && AC_MSG_ERROR(Compiler not ANSI compliant)
  29
  30 AC_PROG_CC_C_O
  31
  32 dnl Select some C flags based on the host type.
  33 AC_CANONICAL_HOST
  34
  35 DEBUG="-g"
  36 WARNINGS="-Wall -Werror"
  37 CFLAGS_FPIC="-fPIC"
  38 WIN32=no
  39 case "$host" in
  40   *-*-mingw*)
  41     WARNINGS="$WARNINGS -Wno-unused"
  42     CFLAGS_FPIC=""
  43     WIN32=yes
  44 esac
  45 AC_SUBST(DEBUG)
  46 AC_SUBST(WARNINGS)
  47 AC_SUBST(CFLAGS_FPIC)
  48 AC_SUBST(WIN32)
  49
  50 dnl Check for libvirt development environment.
  51 AC_ARG_WITH(libvirt,
  52         AC_HELP_STRING([--with-libvirt=PATH],[Set path to installed libvirt]),
  53         [if test "x$withval" != "x"; then
  54            CFLAGS="$CFLAGS -I$withval/include"
  55            LDFLAGS="$LDFLAGS -L$withval/lib"
  56          fi
  57         ])
  58 AC_CHECK_LIB(virt,virConnectOpen,
  59         [],
  60         AC_MSG_ERROR([You must install libvirt library]))
  61 AC_CHECK_HEADER([libvirt/libvirt.h],
  62         [],
  63         AC_MSG_ERROR([You must install libvirt development package]))
  64
  65 dnl We also use <libvirt/virterror.h>
  66 AC_CHECK_HEADER([libvirt/virterror.h],
  67         [],
  68         AC_MSG_ERROR([You must install libvirt development package]))
  69
  70 dnl Check for libvirt >= 0.2.1 (our minimum supported version).
  71 dnl See: http://libvirt.org/hvsupport.html
  72 AC_CHECK_FUNC(virConnectGetCapabilities,
  73         [],
  74         AC_MSG_ERROR([You must have libvirt >= 0.2.1]))
  75
  76 dnl Check for optional libvirt functions added since 0.2.1.
  77 dnl See: http://libvirt.org/hvsupport.html
  78 AC_CHECK_FUNCS([virConnectGetHostname \
  79                 virConnectGetURI \
  80                 virDomainBlockStats \
  81                 virDomainGetSchedulerParameters \
  82                 virDomainGetSchedulerType \
  83                 virDomainInterfaceStats \
  84                 virDomainMigrate \
  85                 virDomainSetSchedulerParameters \
  86                 virNodeGetFreeMemory \
  87                 virNodeGetCellsFreeMemory \
  88                 virJobGetInfo \
  89                 virJobGetDomain \
  90                 virJobGetNetwork \
  91                 virJobCancel \
  92                 virJobFree \
  93                 virDomainCreateLinuxJob \
  94                 virDomainSaveJob \
  95                 virDomainRestoreJob \
  96                 virDomainCoreDumpJob \
  97                 virDomainCreateJob \
  98                 virNetworkCreateXMLJob \
  99                 virNetworkCreateJob \
 100                 virStoragePoolGetConnect \
 101                 virConnectNumOfStoragePools \
 102                 virConnectListStoragePools \
 103                 virConnectNumOfDefinedStoragePools \
 104                 virConnectListDefinedStoragePools \
 105                 virConnectDiscoverStoragePools \
 106                 virStoragePoolLookupByName \
 107                 virStoragePoolLookupByUUID \
 108                 virStoragePoolLookupByUUIDString \
 109                 virStoragePoolLookupByVolume \
 110                 virStoragePoolCreateXML \
 111                 virStoragePoolDefineXML \
 112                 virStoragePoolUndefine \
 113                 virStoragePoolCreate \
 114                 virStoragePoolDestroy \
 115                 virStoragePoolShutdown \
 116                 virStoragePoolFree \
 117                 virStoragePoolRefresh \
 118                 virStoragePoolGetName \
 119                 virStoragePoolGetUUID \
 120                 virStoragePoolGetUUIDString \
 121                 virStoragePoolGetInfo \
 122                 virStoragePoolGetXMLDesc \
 123                 virStoragePoolGetAutostart \
 124                 virStoragePoolSetAutostart \
 125                 virStoragePoolNumOfVolumes \
 126                 virStoragePoolListVolumes \
 127                 virStorageVolLookupByName \
 128                 virStorageVolLookupByKey \
 129                 virStorageVolLookupByPath \
 130                 virStorageVolGetName \
 131                 virStorageVolGetKey \
 132                 virStorageVolCreateXML \
 133                 virStorageVolDestroy \
 134                 virStorageVolFree \
 135                 virStorageVolGetInfo \
 136                 virStorageVolGetXMLDesc \
 137                 virStorageVolGetPath \
 138 ])
 139
 140 dnl Check for optional types added since 0.2.1.
 141 AC_CHECK_TYPES([virJobPtr, virStoragePoolPtr, virStorageVolPtr],,,
 142                [#include <libvirt/libvirt.h>])
 143
 144 dnl Check for optional ncurses.
 145 AC_CHECK_LIB(ncurses,initscr)
 146
 147 dnl Check for basic OCaml environment & findlib.
 148 dnl Note that findlib is not necessary, but things will work better
 149 dnl if it is present.
 150 AC_PROG_OCAML
 151 AC_PROG_FINDLIB
 152
 153 if test "x$OCAMLFIND" != "x"; then
 154     dnl Use ocamlfind to find the required packages ...
 155
 156     dnl Check for required OCaml packages.
 157     AC_CHECK_OCAML_PKG(unix)
 158     if test "x$pkg_unix" != "xyes"; then
 159         AC_MSG_ERROR([Cannot find required OCaml package 'unix'])
 160     fi
 161
 162     dnl Check for optional OCaml packages.
 163     AC_CHECK_OCAML_PKG(extlib)
 164     AC_CHECK_OCAML_PKG(lablgtk2)
 165     AC_CHECK_OCAML_PKG(curses)
 166     AC_CHECK_OCAML_PKG(gettext)
 167     AC_CHECK_OCAML_PKG(xml-light)
 168     AC_CHECK_OCAML_PKG(csv)
 169     AC_CHECK_OCAML_PKG(dbus)
 170
 171     dnl Need to check which version of calendar is installed.
 172     AC_CHECK_OCAML_MODULE(calendar,pkg_calendar2,CalendarLib.Date,[+calendar])
 173     if test "x$pkg_calendar2" = "xno"; then
 174         AC_CHECK_OCAML_PKG(calendar)
 175     fi
 176
 177     AC_SUBST(pkg_unix)
 178     AC_SUBST(pkg_extlib)
 179     AC_SUBST(pkg_lablgtk2)
 180     AC_SUBST(pkg_curses)
 181     AC_SUBST(pkg_gettext)
 182     AC_SUBST(pkg_xml_light)
 183     AC_SUBST(pkg_csv)
 184     AC_SUBST(pkg_dbus)
 185     AC_SUBST(pkg_calendar)
 186     AC_SUBST(pkg_calendar2)
 187 else
 188     dnl Use a basic module test if there is no findlib ...
 189
 190     dnl Check for required OCaml modules.
 191     AC_CHECK_OCAML_MODULE(unix,pkg_unix,Unix,[.])
 192     if test "x$pkg_unix" = "xno"; then
 193         AC_MSG_ERROR([Cannot find required OCaml package 'unix'])
 194     fi
 195
 196     dnl Check for optional OCaml modules.
 197     AC_CHECK_OCAML_MODULE(extlib,pkg_extlib,ExtString,[+extlib])
 198     AC_CHECK_OCAML_MODULE(lablgtk2,pkg_lablgtk2,GMain,[+lablgtk2])
 199     AC_CHECK_OCAML_MODULE(curses,pkg_curses,Curses,[+curses])
 200     AC_CHECK_OCAML_MODULE(gettext,pkg_gettext,Gettext,[+gettext]) dnl XXX
 201     AC_CHECK_OCAML_MODULE(xml-light,pkg_xml_light,Xml,[+xml-light])
 202     AC_CHECK_OCAML_MODULE(csv,pkg_csv,Csv,[+csv])
 203     AC_CHECK_OCAML_MODULE(dbus,pkg_dbus,DBus,[+dbus])
 204     dnl XXX Version check - see above.
 205     AC_CHECK_OCAML_MODULE(calendar,pkg_calendar,Calendar,[+calendar])
 206 fi
 207
 208 dnl Which subpackages (== subdirs) will we build?
 209 subdirs="libvirt examples mlvirsh"
 210 if test "x$pkg_lablgtk2" != "xno"; then
 211     subdirs="$subdirs virt-ctrl"
 212 fi
 213 if test "x$pkg_extlib" != "xno" -a "x$pkg_curses" != "xno"; then
 214     subdirs="$subdirs virt-top"
 215 fi
 216 if test "x$pkg_extlib" != "xno" -a "x$pkg_xml_light" != "xno"; then
 217     subdirs="$subdirs virt-df"
 218 fi
 219 AC_SUBST(subdirs)
 220
 221 dnl Check for optional perldoc (for building manual pages).
 222 AC_CHECK_PROG(HAVE_PERLDOC,perldoc,perldoc)
 223
 224 dnl Check for optional NSIS (for building a Windows installer).
 225 AC_ARG_WITH([nsis],
 226         [AS_HELP_STRING([--with-nsis],
 227             [use NSIS to build a Windows installer])],
 228         [],
 229         [with_nsis=no])
 230
 231 MAKENSIS=
 232 LIBVIRT_DLL_PATH=
 233 LIBXDR_DLL_PATH=
 234 LIBXML2_DLL_PATH=
 235 GNUTLS_DLL_PATH=
 236 GTK_PATH=
 237 GTK_DLL_PATH=
 238
 239 [
 240 msys_to_win_dir () {
 241     eval pushd "\$$1" > /dev/null
 242     eval $1=`pwd -W`
 243     popd > /dev/null
 244 }
 245 ]
 246
 247 if test "x$with_nsis" != "xno"; then
 248     AC_PATH_PROG(MAKENSIS,makensis,[],[$with_nsis:$PATH])
 249     if test "x$MAKENSIS" = "x"; then
 250         AC_MSG_FAILURE([--with-nsis was given, but could not find MAKENSIS.EXE])
 251     fi
 252
 253     # MAKENSIS is set so we will build a rule for making a Windows
 254     # installer.  To support this, generate wininstaller.nsis.
 255     saved_IFS=$IFS
 256     IFS=$PATH_SEPARATOR
 257     for d in $PATH; do
 258         IFS=$saved_IFS
 259         echo Checking $d for DLLs ... >&5
 260         if test -f "$d/libvirt-0.dll"; then
 261             LIBVIRT_DLL_PATH="$d"
 262         fi
 263         if test -f "$d/libxdr.dll"; then
 264             LIBXDR_DLL_PATH="$d"
 265         fi
 266         if test -f "$d/libxml2-2.dll"; then
 267             LIBXML2_DLL_PATH="$d"
 268         fi
 269         if test -f "$d/libgpg-error-0.dll"; then
 270             GNUTLS_DLL_PATH="$d"
 271         fi
 272         if test -f "$d/libgtk-win32-2.0-0.dll"; then
 273             GTK_DLL_PATH="$d"
 274             GTK_PATH="$d/.."
 275         fi
 276     done
 277     IFS=$saved_IFS
 278
 279     if test "x$LIBVIRT_DLL_PATH" = "x"; then
 280         AC_MSG_FAILURE([cannot find libvirt-0.dll in PATH])
 281     fi
 282     if test "x$LIBXDR_DLL_PATH" = "x"; then
 283         AC_MSG_FAILURE([cannot find libxdr.dll in PATH])
 284     fi
 285     if test "x$LIBXML2_DLL_PATH" = "x"; then
 286         AC_MSG_FAILURE([cannot find libxml2-2.dll in PATH])
 287     fi
 288     if test "x$GNUTLS_DLL_PATH" = "x"; then
 289         AC_MSG_FAILURE([cannot find GnuTLS DLLs in PATH])
 290     fi
 291     if test "x$GTK_DLL_PATH" = "x"; then
 292         AC_MSG_WARN([cannot find GTK DLLs in PATH])
 293     fi
 294
 295     # Change the paths to Windows paths.
 296     msys_to_win_dir LIBVIRT_DLL_PATH
 297     msys_to_win_dir LIBXDR_DLL_PATH
 298     msys_to_win_dir LIBXML2_DLL_PATH
 299     msys_to_win_dir GNUTLS_DLL_PATH
 300     if test "x$GTK_DLL_PATH" != "x"; then
 301         msys_to_win_dir GTK_DLL_PATH
 302         msys_to_win_dir GTK_PATH
 303     fi
 304 fi
 305 AC_SUBST(MAKENSIS)
 306 AC_SUBST(LIBVIRT_DLL_PATH)
 307 AC_SUBST(LIBXDR_DLL_PATH)
 308 AC_SUBST(LIBXML2_DLL_PATH)
 309 AC_SUBST(GNUTLS_DLL_PATH)
 310 AC_SUBST(GTK_DLL_PATH)
 311 AC_SUBST(GTK_PATH)
 312
 313 dnl Summary.
 314 echo "------------------------------------------------------------"
 315 echo "Thanks for downloading" $PACKAGE_STRING
 316 echo " subpackages to build : $subdirs"
 317 echo "------------------------------------------------------------"
 318
 319 dnl Produce output files.
 320 AC_CONFIG_HEADERS([config.h])
 321 AC_CONFIG_FILES([META
 322         libvirt/libvirt_version.ml
 323         Makefile
 324         Make.rules
 325         libvirt/Makefile
 326         examples/Makefile
 327         mlvirsh/Makefile
 328         virt-ctrl/Makefile
 329         virt-top/Makefile
 330         virt-df/Makefile
 331         ])
 332 if test "x$MAKENSIS" != "x"; then
 333         AC_CONFIG_FILES([wininstaller.nsis])
 334 fi
 335 AC_OUTPUT