From: Jim Meyering <meyering@redhat.com>
Date: Mon, 17 Aug 2009 08:35:05 +0000 (+0200)
Subject: daemon: enable -Werror and many gcc warnings when --enable-gcc-warnings
X-Git-Tag: 1.0.68~36
X-Git-Url: http://git.annexia.org/?p=libguestfs.git;a=commitdiff_plain;h=9dd53bcb10283295d7fb5f0a3469be2984d99926

daemon: enable -Werror and many gcc warnings when --enable-gcc-warnings

* daemon/m4/gnulib-cache.m4: Add two modules: manywarnings, warnings.
* daemon/configure.ac: Implement --enable-gcc-warnings, and selectively
disable a few warning options that are either not useful or that provoke
too many warnings for now.
Define and AC_SUBST WARN_CFLAGS and WERROR_CFLAGS.
* daemon/Makefile.am (guestfsd_CFLAGS): Use $(WARN_CFLAGS)
and $(WERROR_CFLAGS), rather than just -Wall.
---

diff --git a/daemon/Makefile.am b/daemon/Makefile.am
index e6af0fe..097d89d 100644
--- a/daemon/Makefile.am
+++ b/daemon/Makefile.am
@@ -81,5 +81,6 @@ guestfsd_SOURCES = \
 	$(top_builddir)/../src/guestfs_protocol.c
 
 AM_CPPFLAGS = -I$(srcdir)/lib -Ilib
-guestfsd_CFLAGS = -Wall
+guestfsd_CFLAGS = $(WARN_CFLAGS) $(WERROR_CFLAGS)
+
 LDADD = lib/libgnu.a
diff --git a/daemon/configure.ac b/daemon/configure.ac
index b0c7f26..f2f96c2 100644
--- a/daemon/configure.ac
+++ b/daemon/configure.ac
@@ -48,6 +48,67 @@ AC_PROG_CPP
 gl_EARLY
 gl_INIT
 
+AC_ARG_ENABLE([gcc-warnings],
+  [AS_HELP_STRING([--enable-gcc-warnings],
+		  [turn on lots of GCC warnings (for developers)])],
+  [case $enableval in
+     yes|no) ;;
+     *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
+   esac
+   gl_gcc_warnings=$enableval],
+  [gl_gcc_warnings=no]
+)
+
+if test "$gl_gcc_warnings" = yes; then
+  gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
+  AC_SUBST([WERROR_CFLAGS])
+
+  nw=
+  # This, $nw, is the list of warnings we disable.
+  nw="$nw -Wdeclaration-after-statement" # too useful to forbid
+  nw="$nw -Waggregate-return"       # anachronistic
+  nw="$nw -Wc++-compat"             # We don't care about C++ compilers
+  nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
+  nw="$nw -Wtraditional"            # Warns on #elif which we use often
+  nw="$nw -Wcast-qual"              # Too many warnings for now
+  nw="$nw -Wconversion"             # Too many warnings for now
+  nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
+  nw="$nw -Wsign-conversion"        # Too many warnings for now
+  nw="$nw -Wtraditional-conversion" # Too many warnings for now
+  nw="$nw -Wunreachable-code"       # Too many warnings for now
+  nw="$nw -Wpadded"                 # Our structs are not padded
+  nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
+  nw="$nw -Wlogical-op"             # any use of fwrite provokes this
+  nw="$nw -Wvla"                    # two warnings in mount.c
+  # things I might fix soon:
+  nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
+  nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
+  nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
+  # ?? -Wstrict-overflow
+
+  gl_MANYWARN_ALL_GCC([ws])
+  gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
+  for w in $ws; do
+    gl_WARN_ADD([$w])
+  done
+  gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
+  gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
+  gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
+
+  # In spite of excluding -Wlogical-op above, it is enabled, as of
+  # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
+  gl_WARN_ADD([-Wno-logical-op])
+
+  gl_WARN_ADD([-fdiagnostics-show-option])
+
+  AC_SUBST([WARN_CFLAGS])
+
+  AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
+  AC_DEFINE([_FORTIFY_SOURCE], [2],
+    [enable compile-time and run-time bounds-checking, and some warnings])
+  AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
+fi
+
 AC_C_PROTOTYPES
 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 
diff --git a/daemon/m4/gnulib-cache.m4 b/daemon/m4/gnulib-cache.m4
index 8aa504a..ea499d8 100644
--- a/daemon/m4/gnulib-cache.m4
+++ b/daemon/m4/gnulib-cache.m4
@@ -15,12 +15,14 @@
 
 
 # Specification in the form of a command-line invocation:
-#   gnulib-tool --import --dir=. --lib=libgnu --source-base=lib --m4-base=m4 --doc-base=doc --tests-base=tests --aux-dir=build-aux --with-tests --no-libtool --macro-prefix=gl hash
+#   gnulib-tool --import --dir=. --lib=libgnu --source-base=lib --m4-base=m4 --doc-base=doc --tests-base=tests --aux-dir=build-aux --with-tests --no-libtool --macro-prefix=gl hash manywarnings warnings
 
 # Specification in the form of a few gnulib-tool.m4 macro invocations:
 gl_LOCAL_DIR([])
 gl_MODULES([
   hash
+  manywarnings
+  warnings
 ])
 gl_AVOID([])
 gl_SOURCE_BASE([lib])