m4/printf-posix.m4

   1 # printf-posix.m4 serial 2 (gettext-0.13.1)
   2 dnl Copyright (C) 2003 Free Software Foundation, Inc.
   3 dnl This file is free software, distributed under the terms of the GNU
   4 dnl General Public License.  As a special exception to the GNU General
   5 dnl Public License, this file may be distributed as part of a program
   6 dnl that contains a configuration script generated by Autoconf, under
   7 dnl the same distribution terms as the rest of that program.
   8
   9 dnl From Bruno Haible.
  10 dnl Test whether the printf() function supports POSIX/XSI format strings with
  11 dnl positions.
  12
  13 AC_DEFUN([gt_PRINTF_POSIX],
  14 [
  15   AC_REQUIRE([AC_PROG_CC])
  16   AC_CACHE_CHECK([whether printf() supports POSIX/XSI format strings],
  17     gt_cv_func_printf_posix,
  18     [
  19       AC_TRY_RUN([
  20 #include <stdio.h>
  21 #include <string.h>
  22 /* The string "%2$d %1$d", with dollar characters protected from the shell's
  23    dollar expansion (possibly an autoconf bug).  */
  24 static char format[] = { '%', '2', '$', 'd', ' ', '%', '1', '$', 'd', '\0' };
  25 static char buf[100];
  26 int main ()
  27 {
  28   sprintf (buf, format, 33, 55);
  29   return (strcmp (buf, "55 33") != 0);
  30 }], gt_cv_func_printf_posix=yes, gt_cv_func_printf_posix=no,
  31       [
  32         AC_EGREP_CPP(notposix, [
  33 #if defined __NetBSD__ || defined _MSC_VER || defined __MINGW32__ || defined __CYGWIN__
  34   notposix
  35 #endif
  36         ], gt_cv_func_printf_posix="guessing no",
  37            gt_cv_func_printf_posix="guessing yes")
  38       ])
  39     ])
  40   case $gt_cv_func_printf_posix in
  41     *yes)
  42       AC_DEFINE(HAVE_POSIX_PRINTF, 1,
  43         [Define if your printf() function supports format strings with positions.])
  44       ;;
  45   esac
  46 ])