daemon/configure.ac

   1 # libguestfs-daemon
   2 # Copyright (C) 2009 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 AC_INIT([libguestfs-daemon],[1.0.0])
  19 AC_CONFIG_AUX_DIR([build-aux])
  20 AM_INIT_AUTOMAKE([foreign])
  21
  22 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  23 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  24
  25 AC_CONFIG_MACRO_DIR([m4])
  26
  27 dnl If the user specified --enable-32bit, then force the C compiler
  28 dnl to build 32 bit binaries (gcc -m32).
  29 AC_ARG_ENABLE([32bit],
  30   [AS_HELP_STRING([--enable-32bit], [build 32 bit binaries (gcc -m32)])],
  31   [export CC="gcc -m32"],
  32   [enable_32bit=no])
  33
  34 dnl Enable 'debug' command.
  35 AC_ARG_ENABLE([debug-command],
  36   [AS_HELP_STRING([--enable-debug-command], [enable the 'debug' command])],
  37   [AC_DEFINE_UNQUOTED([ENABLE_DEBUG_COMMAND],[1],[Enable the 'debug' command])],
  38   [])
  39
  40 dnl Enable packet dumps when in verbose mode.  This generates lots
  41 dnl of debug info, only useful for people debugging the RPC mechanism.
  42 AC_ARG_ENABLE([packet-dump],
  43         [AS_HELP_STRING([--enable-packet-dump],
  44           [enable packet dumps in verbose mode @<:@default=no@:>@])],
  45         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
  46         [])
  47
  48 dnl For strchrnul(3), asprintf(3), futimens(2) and getline(3).
  49 AC_GNU_SOURCE
  50
  51 dnl Check for basic C environment.
  52 AC_PROG_CC
  53 AC_PROG_INSTALL
  54 AC_PROG_CPP
  55
  56 gl_EARLY
  57 gl_INIT
  58
  59 AC_ARG_ENABLE([gcc-warnings],
  60   [AS_HELP_STRING([--enable-gcc-warnings],
  61                   [turn on lots of GCC warnings (for developers)])],
  62   [case $enableval in
  63      yes|no) ;;
  64      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  65    esac
  66    gl_gcc_warnings=$enableval],
  67   [gl_gcc_warnings=no]
  68 )
  69
  70 if test "$gl_gcc_warnings" = yes; then
  71   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  72   AC_SUBST([WERROR_CFLAGS])
  73
  74   nw=
  75   # This, $nw, is the list of warnings we disable.
  76   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  77   nw="$nw -Waggregate-return"       # anachronistic
  78   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  79   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  80   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  81   nw="$nw -Wcast-qual"              # Too many warnings for now
  82   nw="$nw -Wconversion"             # Too many warnings for now
  83   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  84   nw="$nw -Wsign-conversion"        # Too many warnings for now
  85   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  86   nw="$nw -Wunreachable-code"       # Too many warnings for now
  87   nw="$nw -Wpadded"                 # Our structs are not padded
  88   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  89   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  90   nw="$nw -Wvla"                    # two warnings in mount.c
  91   # things I might fix soon:
  92   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
  93   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
  94   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
  95   # ?? -Wstrict-overflow
  96   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
  97                                     # was not possible, safe to ignore
  98
  99   gl_MANYWARN_ALL_GCC([ws])
 100   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 101   for w in $ws; do
 102     gl_WARN_ADD([$w])
 103   done
 104   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 105   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 106   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 107
 108   # In spite of excluding -Wlogical-op above, it is enabled, as of
 109   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 110   gl_WARN_ADD([-Wno-logical-op])
 111
 112   gl_WARN_ADD([-fdiagnostics-show-option])
 113
 114   AC_SUBST([WARN_CFLAGS])
 115
 116   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 117   AC_DEFINE([_FORTIFY_SOURCE], [2],
 118     [enable compile-time and run-time bounds-checking, and some warnings])
 119   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 120 fi
 121
 122 AC_C_PROTOTYPES
 123 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 124
 125 AM_PROG_CC_C_O
 126
 127 dnl Check support for 64 bit file offsets.
 128 AC_SYS_LARGEFILE
 129
 130 dnl Check if dirent (readdir) supports d_type member.
 131 AC_STRUCT_DIRENT_D_TYPE
 132
 133 dnl Check if stat has the required fields.
 134 AC_STRUCT_ST_BLOCKS
 135 AC_CHECK_MEMBER([struct stat.st_blksize],[
 136         AC_DEFINE([HAVE_STRUCT_STAT_ST_BLKSIZE],[1],[Define to 1 if 'st_blksize' is a member of 'struct stat'])])
 137
 138 dnl Check for Augeas (now optional).
 139 AC_CHECK_LIB([augeas],[aug_match],[
 140         LIBS="-laugeas $LIBS"
 141         have_augeas=yes
 142         dnl Check for functions not available in earlier versions of Augeas.
 143         AC_CHECK_FUNCS([aug_load aug_defvar aug_defnode])
 144         ],[have_augeas=no])
 145 if test "x$have_augeas" = "xyes"; then
 146         AC_DEFINE([HAVE_AUGEAS],[1],[Define to 1 if you have Augeas])
 147 fi
 148
 149 dnl Check for libselinux (optional).
 150 AC_CHECK_HEADERS([selinux/selinux.h])
 151 AC_CHECK_LIB([selinux],[setexeccon],[
 152         LIBS="-lselinux $LIBS"
 153         have_libselinux="$ac_cv_header_selinux_selinux_h"
 154         AC_CHECK_FUNCS([setcon getcon])
 155         ],[have_libselinux=no])
 156 if test "x$have_libselinux" = "xyes"; then
 157         AC_DEFINE([HAVE_LIBSELINUX],[1],[Define to 1 if you have libselinux])
 158 fi
 159
 160 dnl Check for XDR library.
 161 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 162         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 163         ])
 164
 165 dnl Functions which may not be available in older distributions.
 166 AC_CHECK_FUNCS([\
 167         futimens \
 168         getxattr \
 169         inotify_init1 \
 170         lgetxattr \
 171         listxattr \
 172         llistxattr \
 173         lsetxattr \
 174         lremovexattr \
 175         mknod \
 176         removexattr \
 177         setxattr])
 178
 179 dnl Headers.
 180 AC_CHECK_HEADERS([\
 181         attr/xattr.h \
 182         printf.h \
 183         sys/inotify.h \
 184         sys/xattr.h])
 185
 186 dnl For modified printf, we need glibc either (old-style)
 187 dnl register_printf_function or (new-style) register_printf_specifier.
 188 AC_CHECK_FUNC([register_printf_specifier],[
 189         AC_DEFINE([HAVE_REGISTER_PRINTF_SPECIFIER],[1],
 190                 [Define to 1 if you have new-style register_printf_specifier])
 191         ],[
 192         AC_CHECK_FUNC([register_printf_function],[
 193                 AC_DEFINE([HAVE_REGISTER_PRINTF_FUNCTION],[1],
 194                         [Define to 1 if you have old-style register_printf_function])
 195                 ],[
 196                 AC_MSG_FAILURE(
 197 [No support for glibc-style extended printf formatters.
 198
 199 This means you either have a very old glibc (pre-2.0) or you
 200 are using some other libc where this is not supported.])])])
 201
 202 dnl Produce output files.
 203 AC_CONFIG_HEADERS([config.h])
 204 AC_CONFIG_FILES([Makefile lib/Makefile tests/Makefile])
 205 AC_OUTPUT