configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 AC_INIT([libguestfs],[1.0.54])
  19 AM_INIT_AUTOMAKE
  20
  21 AC_CONFIG_MACRO_DIR([m4])
  22
  23 AC_PROG_LIBTOOL
  24
  25 dnl Check for basic C environment.
  26 AC_PROG_CC_STDC
  27 AC_PROG_INSTALL
  28 AC_PROG_CPP
  29
  30 AC_C_PROTOTYPES
  31 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
  32
  33 AM_PROG_CC_C_O
  34
  35 dnl Check support for 64 bit file offsets.
  36 AC_SYS_LARGEFILE
  37
  38 dnl Check sizeof long.
  39 AC_CHECK_SIZEOF([long])
  40
  41 dnl Headers.
  42 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h])
  43
  44 dnl Check for rpcgen and XDR library.  rpcgen is optional.
  45 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
  46 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
  47 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
  48         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
  49         ])
  50
  51 dnl Check for pod2man and pod2text.
  52 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
  53 test "x$POD2MAN" = "xno" &&
  54      AC_MSG_ERROR([pod2man must be installed])
  55 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
  56 test "x$POD2TEXT" = "xno" &&
  57      AC_MSG_ERROR([pod2text must be installed])
  58
  59 dnl Check for mksquashfs.
  60 AC_PATH_PROGS([MKSQUASHFS],[mksquashfs],[no],
  61         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
  62 test "x$MKSQUASHFS" = "xno" && AC_MSG_ERROR([mksquashfs must be installed])
  63
  64 dnl Check for QEMU for running binaries on this $host_cpu, fall
  65 dnl back to basic 'qemu'.  Allow the user to override it.
  66 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
  67 AC_ARG_WITH([qemu],
  68         [AS_HELP_STRING([--with-qemu],
  69           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
  70         [],
  71         [with_qemu="$default_qemu"])
  72 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
  73         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
  74 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
  75 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
  76
  77 dnl Check that the chosen qemu has vmchannel support.
  78 dnl http://lists.gnu.org/archive/html/qemu-devel/2009-02/msg01042.html
  79 if test "x$vmchannel_test" != "xno"; then
  80     AC_MSG_CHECKING([for vmchannel support in $QEMU])
  81     vmchannelout=`$QEMU -net channel /dev/zero 2>&1 ||:`
  82     echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
  83     if ! echo $vmchannelout | grep -sq "vmchannel wrong port number" ; then
  84         AC_MSG_RESULT([no])
  85         AC_MSG_FAILURE(
  86 [I did not find vmchannel support in $QEMU.
  87
  88 vmchannel support is vital for libguestfs to operate.  You need a version
  89 of qemu >= 0.10, or the following patch backported to earlier versions:
  90
  91 http://lists.gnu.org/archive/html/qemu-devel/2009-02/msg01042.html
  92
  93 You can override this test by setting the environment variable
  94 vmchannel_test=no  However if you don't have vmchannel support
  95 in your qemu, then this just delays the pain.
  96
  97 If I am using the wrong qemu or you want to compile qemu from source
  98 and install it in another location, then you should configure with
  99 the --with-qemu option.
 100 ])
 101     fi
 102     AC_MSG_RESULT([yes])
 103 fi
 104
 105 dnl Check for febootstrap etc.
 106 AC_CHECK_PROG([FEBOOTSTRAP],
 107         [febootstrap],[febootstrap],[no])
 108 if test "x$FEBOOTSTRAP" != "xno"; then
 109   AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 110         [febootstrap-run],[febootstrap-run],[no])
 111   test "x$FEBOOTSTRAP_RUN" = "xno" && \
 112      AC_MSG_ERROR([febootstrap-run must be installed])
 113   AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 114         [febootstrap-install],[febootstrap-install],[no])
 115   test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 116      AC_MSG_ERROR([febootstrap-install must be installed])
 117   AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 118         [febootstrap-minimize],[febootstrap-minimize],[no])
 119   test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 120      AC_MSG_ERROR([febootstrap-minimize must be installed])
 121   AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 122         [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 123   test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 124      AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 125
 126   dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 127   dnl of febootstrap, but old versions will fail with yum).
 128   AC_CHECK_PROG([FAKECHROOT],
 129         [fakechroot],[fakechroot],[no])
 130   test "x$FAKECHROOT" = "xno" && \
 131     AC_MSG_ERROR([fakechroot must be installed])
 132
 133   AC_MSG_CHECKING([fakechroot version])
 134   fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 135   if test -z "$fakechroot_version"; then
 136     AC_MSG_RESULT([failed])
 137     AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 138   else
 139     AC_MSG_RESULT([$fakechroot_version])
 140     fakechroot_major=`echo $fakechroot_version | awk -F. '{print $1}'`
 141     fakechroot_minor=`echo $fakechroot_version | awk -F. '{print $2}'`
 142     if test "$fakechroot_major" -lt 2 -o \
 143             \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
 144         AC_MSG_ERROR([fakechroot version must be >= 2.9])
 145     fi
 146   fi
 147   DIST="REDHAT"
 148 else
 149   # check for debootstrap and debirf
 150   AC_CHECK_PROG([DEBOOTSTRAP],
 151         [debootstrap],[debootstrap],[no])
 152   test "x$DEBOOTSTRAP" = "xno" && \
 153         AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 154   AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 155   test "x$DEBIRF" = "xno" &&
 156         AC_MSG_ERROR([debirf must be installed])
 157   DIST="DEBIAN"
 158 fi
 159 AC_SUBST(DIST)
 160
 161
 162 dnl --with-repo to specify a Fedora repository.
 163 AC_ARG_WITH([repo],
 164         [AS_HELP_STRING([--with-repo],
 165           [set name of Fedora repository @<:@default=fedora-11@:>@])],
 166         [],
 167         [with_repo=fedora-11])
 168 REPO="$with_repo"
 169 AC_SUBST(REPO)
 170 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 171
 172 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 173
 174 dnl --with-updates to specify a Fedora updates repository.
 175 AC_ARG_WITH([updates],
 176         [AS_HELP_STRING([--with-updates],
 177           [set name of Fedora updates repository @<:@default=updates-released-f11@:>@])],
 178         [],
 179         [with_updates=updates-released-f11])
 180 UPDATES="$with_updates"
 181 AC_SUBST(UPDATES)
 182 AC_DEFINE_UNQUOTED([UPDATES],["$UPDATES"],[Name of Fedora updates repository.])
 183
 184 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 185
 186 dnl --with-mirror to specify a local Fedora mirror.
 187 AC_ARG_WITH([mirror],
 188         [AS_HELP_STRING([--with-mirror],
 189           [set URI of a local Fedora mirror])],
 190         [],
 191         [with_mirror=])
 192 MIRROR="$with_mirror"
 193 AC_SUBST(MIRROR)
 194
 195 dnl Build the supermin appliance?  Please see README file before
 196 dnl enabling this option.
 197 AC_ARG_ENABLE([supermin],
 198         [AS_HELP_STRING([--enable-supermin],
 199           [enable supermin appliance (see README) @<:@default=no@:>@])],
 200         [],
 201         [enable_supermin=no])
 202 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 203
 204 if test "x$enable_supermin" = "xyes"; then
 205     dnl Check febootstrap-to-initramfs accepts the --files option
 206     dnl (febootstrap >= 2.2).
 207     AC_MSG_CHECKING([for --files support in $FEBOOTSTRAP_TO_INITRAMFS])
 208     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 209     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 210     if ! echo $out | grep -sq -- "--files" ; then
 211         AC_MSG_RESULT([no])
 212         AC_MSG_FAILURE(
 213 [febootstrap-to-initramfs does not support the --files option.
 214
 215 To build the supermin appliance, you need to upgrade to the latest
 216 version of febootstrap.
 217 ])
 218     fi
 219     AC_MSG_RESULT([yes])
 220
 221     dnl Check febootstrap-to-initramfs accepts the --nocompress option
 222     dnl (febootstrap >= 2.3).
 223     AC_MSG_CHECKING([for --nocompress support in $FEBOOTSTRAP_TO_INITRAMFS])
 224     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 225     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 226     if ! echo $out | grep -sq -- "--nocompress" ; then
 227         AC_MSG_RESULT([no])
 228         AC_MSG_FAILURE(
 229 [febootstrap-to-initramfs does not support the --nocompress option.
 230
 231 To build the supermin appliance, you need to upgrade to the latest
 232 version of febootstrap.
 233 ])
 234     fi
 235     AC_MSG_RESULT([yes])
 236 fi
 237
 238 dnl Readline.
 239 AC_ARG_WITH([readline],
 240     [AS_HELP_STRING([--with-readline],
 241         [support fancy command line editing @<:@default=check@:>@])],
 242     [],
 243     [with_readline=check])
 244
 245 LIBREADLINE=
 246 AS_IF([test "x$with_readline" != xno],
 247     [AC_CHECK_LIB([readline], [main],
 248         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 249          AC_DEFINE([HAVE_LIBREADLINE], [1],
 250                    [Define if you have libreadline])
 251         ],
 252         [if test "x$with_readline" != xcheck; then
 253          AC_MSG_FAILURE(
 254              [--with-readline was given, but test for readline failed])
 255          fi
 256         ], -lncurses)])
 257
 258 dnl For i18n.
 259 AM_GNU_GETTEXT([external])
 260 AM_GNU_GETTEXT_VERSION([0.14])
 261
 262 dnl Check for OCaml (optional, for OCaml bindings).
 263 AC_PROG_OCAML
 264 AC_PROG_FINDLIB
 265 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
 266
 267 dnl Check for Perl (optional, for Perl bindings).
 268 dnl XXX This isn't quite right, we should check for Perl devel library.
 269 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 270
 271 dnl Check for Perl modules that must be present to compile and
 272 dnl test the Perl bindings.
 273 missing_perl_modules=no
 274 for pm in Test::More Test::Pod Test::Pod::Coverage ExtUtils::MakeMaker; do
 275     AC_MSG_CHECKING([for $pm])
 276     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 277         AC_MSG_RESULT([no])
 278         missing_perl_modules=yes
 279     else
 280         AC_MSG_RESULT([yes])
 281     fi
 282 done
 283 if test "x$missing_perl_modules" = "xyes"; then
 284     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 285 fi
 286
 287 AM_CONDITIONAL([HAVE_PERL],
 288     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 289
 290 dnl Check for Python (optional, for Python bindings).
 291 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 292
 293 PYTHON_PREFIX=
 294 PYTHON_VERSION=
 295 PYTHON_INCLUDEDIR=
 296 PYTHON_SITE_PACKAGES=
 297
 298 if test "x$PYTHON" != "xno"; then
 299     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 300     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 301     for d in \
 302         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 303         /usr/include/python$PYTHON_VERSION \
 304         /usr/local/include/python$PYTHON_VERSION
 305     do
 306         AC_MSG_CHECKING([Python.h in $d])
 307         if test -r "$d/Python.h"; then
 308             AC_MSG_RESULT([found])
 309             PYTHON_INCLUDEDIR=$d
 310             break
 311         fi
 312         AC_MSG_RESULT([not found])
 313     done
 314     for d in \
 315         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 316         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 317         /usr/lib64/python$PYTHON_VERSION/site-packages \
 318         /usr/lib/python$PYTHON_VERSION/site-packages \
 319         /usr/local/lib/python$PYTHON_VERSION/site-packages
 320     do
 321         AC_MSG_CHECKING([for $d])
 322         if test -d "$d"; then
 323             AC_MSG_RESULT([found])
 324             PYTHON_SITE_PACKAGES=$d
 325             break
 326         fi
 327         AC_MSG_RESULT([not found])
 328     done
 329 fi
 330
 331 AC_SUBST(PYTHON_PREFIX)
 332 AC_SUBST(PYTHON_VERSION)
 333 AC_SUBST(PYTHON_INCLUDEDIR)
 334 AC_SUBST(PYTHON_SITE_PACKAGES)
 335
 336 AM_CONDITIONAL([HAVE_PYTHON],
 337     [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
 338
 339 dnl Check for Ruby and rake (optional, for Ruby bindings).
 340 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 341 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 342
 343 AM_CONDITIONAL([HAVE_RUBY],
 344     [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
 345
 346 dnl Check for Java.
 347 AC_ARG_WITH(java_home,
 348     [AS_HELP_STRING([--with-java-home],
 349         [specify path to JDK directory @<:@default=check@:>@])],
 350     [],
 351     [with_java_home=check])
 352
 353 if test "x$with_java_home" != "xno"; then
 354     if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
 355     then
 356         if test -d "$with_java_home"; then
 357             JAVA_HOME="$with_java_home"
 358         else
 359             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 360         fi
 361     fi
 362
 363     if test "x$JAVA_HOME" = "x"; then
 364         # Look for Java in some likely locations.
 365         for d in \
 366             /usr/lib/jvm/java \
 367             /usr/lib/jvm/java-6-openjdk
 368         do
 369             if test -d $d -a -f $d/bin/java; then
 370                 JAVA_HOME=$d
 371                 break
 372             fi
 373         done
 374     fi
 375
 376     if test "x$JAVA_HOME" != "x"; then
 377         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 378         if test ! -x "$JAVA_HOME/bin/java"; then
 379             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 380         else
 381             JAVA="$JAVA_HOME/bin/java"
 382         fi
 383         if test ! -x "$JAVA_HOME/bin/javac"; then
 384             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 385         else
 386             JAVAC="$JAVA_HOME/bin/javac"
 387         fi
 388         if test ! -x "$JAVA_HOME/bin/javah"; then
 389             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 390         else
 391             JAVAH="$JAVA_HOME/bin/javah"
 392         fi
 393         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 394             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 395         else
 396             JAVADOC="$JAVA_HOME/bin/javadoc"
 397         fi
 398         if test ! -x "$JAVA_HOME/bin/jar"; then
 399             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 400         else
 401             JAR="$JAVA_HOME/bin/jar"
 402         fi
 403         java_version=`$JAVA -version 2>&1 | grep "java version"`
 404         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 405
 406         dnl Find jni.h.
 407         AC_MSG_CHECKING([for jni.h])
 408         if test -f "$JAVA_HOME/include/jni.h"; then
 409             JNI_CFLAGS="-I$JAVA_HOME/include"
 410         else
 411             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 412                 head=`find $JAVA_HOME -name jni.h | tail -1`
 413                 dir=`dirname $head`
 414                 JNI_CFLAGS="-I$dir"
 415             else
 416                 AC_MSG_FAILURE([missing jni.h header file])
 417             fi
 418         fi
 419         AC_MSG_RESULT([$JNI_CFLAGS])
 420
 421         dnl Find jni_md.h.
 422         AC_MSG_CHECKING([for jni_md.h])
 423         case "$build_os" in
 424         *linux*) system="linux" ;;
 425         *SunOS*) system="solaris" ;;
 426         *cygwin*) system="win32" ;;
 427         *) system="$build_os" ;;
 428         esac
 429         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 430             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 431         else
 432             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 433                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 434                 dir=`dirname $head`
 435                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 436             else
 437                 AC_MSG_FAILURE([missing jni_md.h header file])
 438             fi
 439         fi
 440         AC_MSG_RESULT([$JNI_CFLAGS])
 441
 442         dnl Need extra version flag?
 443         AC_MSG_CHECKING([extra javac flags])
 444         JAVAC_FLAGS=
 445         javac_version=`$JAVAC -version 2>&1`
 446         case "$javac_version" in
 447         *Eclipse*)
 448             JAVAC_FLAGS="-source 1.5" ;;
 449         esac
 450         AC_MSG_RESULT([$JAVAC_FLAGS])
 451
 452         dnl Where to install jarfiles.
 453         dnl XXX How to make it configurable?
 454         JAR_INSTALL_DIR=\${prefix}/share/java
 455         JNI_INSTALL_DIR=\${libdir}
 456
 457         dnl JNI version.
 458         jni_major_version=`echo $VERSION | awk -F. '{print $1}'`
 459         jni_minor_version=`echo $VERSION | awk -F. '{print $2}'`
 460         jni_micro_version=`echo $VERSION | awk -F. '{print $3}'`
 461         JNI_VERSION_INFO=`expr $jni_major_version + $jni_minor_version`:$jni_micro_version:$jni_minor_version
 462     fi
 463 fi
 464
 465 AC_SUBST(JAVA_HOME)
 466 AC_SUBST(JAVA)
 467 AC_SUBST(JAVAC)
 468 AC_SUBST(JAVAH)
 469 AC_SUBST(JAVADOC)
 470 AC_SUBST(JAR)
 471 AC_SUBST(JNI_CFLAGS)
 472 AC_SUBST(JAVAC_FLAGS)
 473 AC_SUBST(JAR_INSTALL_DIR)
 474 AC_SUBST(JNI_INSTALL_DIR)
 475 AC_SUBST(JNI_VERSION_INFO)
 476
 477 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 478
 479 dnl Check for Haskell (GHC).
 480 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 481
 482 AM_CONDITIONAL([HAVE_HASKELL],
 483     [test "x$GHC" != "xno"])
 484
 485 dnl Check for Perl modules needed by the inspector.
 486 missing_perl_modules=no
 487 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer; do
 488     AC_MSG_CHECKING([for $pm])
 489     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 490         AC_MSG_RESULT([no])
 491         missing_perl_modules=yes
 492     else
 493         AC_MSG_RESULT([yes])
 494     fi
 495 done
 496 if test "x$missing_perl_modules" = "xyes"; then
 497     AC_MSG_WARN([some Perl modules required to compile virt-inspector are missing])
 498 fi
 499
 500 AM_CONDITIONAL([HAVE_INSPECTOR],
 501     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 502
 503 dnl Library versioning.
 504 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 505 AC_SUBST(MAX_PROC_NR)
 506
 507 dnl Run in subdirs.
 508 AC_CONFIG_SUBDIRS([daemon])
 509
 510 dnl Produce output files.
 511 AC_CONFIG_HEADERS([config.h])
 512 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 513 AC_CONFIG_FILES([appliance/make.sh],
 514                 [chmod +x appliance/make.sh])
 515 AC_CONFIG_FILES([appliance/update.sh],
 516                 [chmod +x appliance/update.sh])
 517 AC_CONFIG_FILES([appliance/supermin-split.sh],
 518                 [chmod +x appliance/supermin-split.sh])
 519 AC_CONFIG_FILES([appliance/supermin-make.sh],
 520                 [chmod +x appliance/supermin-make.sh])
 521 AC_CONFIG_FILES([appliance/libguestfs-supermin-helper],
 522                 [chmod +x appliance/libguestfs-supermin-helper])
 523 AC_CONFIG_FILES([Makefile
 524                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 525                  appliance/Makefile
 526                  images/Makefile
 527                  capitests/Makefile
 528                  regressions/Makefile
 529                  ocaml/Makefile ocaml/examples/Makefile
 530                  perl/Makefile
 531                  python/Makefile
 532                  ruby/Makefile ruby/Rakefile
 533                  java/Makefile
 534                  haskell/Makefile
 535                  inspector/Makefile
 536                  libguestfs.pc
 537                  ocaml/META perl/Makefile.PL])
 538 AC_OUTPUT
 539
 540 dnl Produce summary.
 541 echo
 542 echo
 543 echo "------------------------------------------------------------"
 544 echo "Thank you for downloading $PACKAGE_STRING"
 545 echo
 546 echo "This is how we have configured the optional components for you today:"
 547 echo
 548 echo    "QEMU ................................ $QEMU"
 549 echo -n "OCaml bindings ...................... "
 550 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 551 echo -n "Perl bindings ....................... "
 552 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 553 echo -n "Python bindings ..................... "
 554 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 555 echo -n "Ruby bindings ....................... "
 556 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 557 echo -n "Java bindings ....................... "
 558 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 559 echo -n "Haskell bindings .................... "
 560 if test "x$HAVE_HASKELL" = "x"; then echo "yes"; else echo "no"; fi
 561 echo -n "virt-inspector ...................... "
 562 if test "x$HAVE_INSPECTOR" = "x"; then echo "yes"; else echo "no"; fi
 563 echo "supermin appliance .................. $enable_supermin"
 564 echo
 565 echo "If any optional component is configured 'no' when you expected 'yes'"
 566 echo "then you should check the preceeding messages."
 567 echo
 568 echo "Please report bugs back to the fedora-virt mailing list:"
 569 echo "http://www.redhat.com/mailman/listinfo/fedora-virt"
 570 echo
 571 echo "Next you should type 'make' to build the package,"
 572 echo "then 'make check' to run the tests."
 573 echo "------------------------------------------------------------"