configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2010 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [7])
  21 m4_define([libguestfs_release], [12])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 dnl Stable or unstable version?
  41 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  42 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  43             AC_MSG_RESULT([stable])
  44        ],[
  45             AC_MSG_RESULT([unstable])
  46             AC_MSG_NOTICE([
  47 ***
  48 This is a development version of libguestfs. Some APIs may be unstable
  49 until they appear in a stable release of libguestfs (at which point
  50 the C API and ABI is guaranteed to remain stable forever).  For
  51 more information about stable and development branches of libguestfs
  52 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  53 ***])
  54        ])
  55
  56 dnl Die if the user tries to configure as root, see:
  57 dnl https://www.redhat.com/archives/libguestfs/2010-April/msg00098.html
  58 AC_MSG_CHECKING([if you are trying to configure as root])
  59 AS_IF([test "`id -u`" = 0 ],[
  60             AC_MSG_RESULT([yes])
  61             AC_MSG_FAILURE([Don't run './configure' or 'make' as root.])
  62       ],[
  63             AC_MSG_RESULT([no])
  64       ])
  65
  66 dnl Early gnulib initialization.
  67 gl_EARLY
  68 gl_INIT
  69
  70 AC_PROG_LIBTOOL
  71
  72 dnl Check for basic C environment.
  73 AC_PROG_CC_STDC
  74 AC_PROG_INSTALL
  75 AC_PROG_CPP
  76
  77 AC_ARG_ENABLE([gcc-warnings],
  78   [AS_HELP_STRING([--enable-gcc-warnings],
  79                   [turn on lots of GCC warnings (for developers)])],
  80   [case $enableval in
  81      yes|no) ;;
  82      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  83    esac
  84    gl_gcc_warnings=$enableval],
  85   [gl_gcc_warnings=no]
  86 )
  87
  88 if test "$gl_gcc_warnings" = yes; then
  89   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  90   AC_SUBST([WERROR_CFLAGS])
  91
  92   nw=
  93   # This, $nw, is the list of warnings we disable.
  94   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  95   nw="$nw -Waggregate-return"       # anachronistic
  96   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  97   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  98   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  99   nw="$nw -Wcast-qual"              # Too many warnings for now
 100   nw="$nw -Wconversion"             # Too many warnings for now
 101   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 102   nw="$nw -Wsign-conversion"        # Too many warnings for now
 103   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 104   nw="$nw -Wunreachable-code"       # Too many warnings for now
 105   nw="$nw -Wpadded"                 # Our structs are not padded
 106   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 107   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 108   nw="$nw -Wvla"                    # two warnings in mount.c
 109   # things I might fix soon:
 110   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 111   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 112   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 113   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 114                                     # was not possible, safe to ignore
 115   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 116   nw="$nw -Wlong-long"              # Allow long long since it's required
 117                                     # by Python, Ruby and xstrtoll.
 118
 119   gl_MANYWARN_ALL_GCC([ws])
 120   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 121   for w in $ws; do
 122     gl_WARN_ADD([$w])
 123   done
 124   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 125   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 126   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 127
 128   # In spite of excluding -Wlogical-op above, it is enabled, as of
 129   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 130   gl_WARN_ADD([-Wno-logical-op])
 131
 132   # Work around warning in src/inspect.c.  This seems to be a bug in gcc 4.5.1.
 133   gl_WARN_ADD([-Wno-strict-overflow])
 134
 135   gl_WARN_ADD([-fdiagnostics-show-option])
 136
 137   AC_SUBST([WARN_CFLAGS])
 138
 139   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 140   AC_DEFINE([_FORTIFY_SOURCE], [2],
 141     [enable compile-time and run-time bounds-checking, and some warnings])
 142   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 143 fi
 144
 145 AC_C_PROTOTYPES
 146 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 147
 148 AM_PROG_CC_C_O
 149
 150 dnl Work out how to specify the linker script to the linker.
 151 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 152 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 153     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 154 AC_SUBST(VERSION_SCRIPT_FLAGS)
 155
 156 dnl Check support for 64 bit file offsets.
 157 AC_SYS_LARGEFILE
 158
 159 dnl Check sizeof long.
 160 AC_CHECK_SIZEOF([long])
 161
 162 dnl Define a C symbol for the host CPU architecture.
 163 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 164
 165 dnl Headers.
 166 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 167
 168 dnl Functions.
 169 AC_CHECK_FUNCS([posix_fallocate])
 170
 171 dnl Build the daemon?
 172 AC_MSG_CHECKING([if we should build the daemon])
 173 AC_ARG_ENABLE([daemon],
 174         [AS_HELP_STRING([--enable-daemon],
 175           [enable building the daemon @<:@default=yes@:>@])],
 176         [],
 177         [enable_daemon=yes])
 178 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 179 AC_MSG_RESULT([$enable_daemon])
 180
 181 dnl Build the appliance?
 182 AC_MSG_CHECKING([if we should build the appliance])
 183 AC_ARG_ENABLE([appliance],
 184         [AS_HELP_STRING([--enable-appliance],
 185           [enable building the appliance @<:@default=yes@:>@])],
 186         [],
 187         [enable_appliance=yes])
 188 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 189 AC_MSG_RESULT([$enable_appliance])
 190
 191 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 192 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 193 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 194 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 195         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 196         ])
 197
 198 dnl Check for cpio which isn't in the default Pardus install amazingly.
 199 AC_CHECK_PROG([CPIO],[cpio],[cpio],[no])
 200 test "x$CPIO" = "xno" &&
 201      AC_MSG_ERROR([cpio must be installed])
 202
 203 dnl Check for gperf.
 204 AC_CHECK_PROG([GPERF],[gperf],[gperf],[no])
 205 test "x$GPERF" = "xno" &&
 206      AC_MSG_ERROR([gperf must be installed])
 207
 208 dnl Check for pod2man and pod2text.
 209 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 210 test "x$POD2MAN" = "xno" &&
 211      AC_MSG_ERROR([pod2man must be installed])
 212 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 213 test "x$POD2TEXT" = "xno" &&
 214      AC_MSG_ERROR([pod2text must be installed])
 215
 216 dnl Check for mkisofs.
 217 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 218         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 219 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 220
 221 dnl Check for optional xmllint.
 222 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 223 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 224
 225 dnl po4a for translating man pages and POD files (optional).
 226 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
 227 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
 228
 229 dnl Check for QEMU for running binaries on this $host_cpu, fall
 230 dnl back to basic 'qemu'.  Allow the user to override it.
 231 default_qemu="qemu-kvm kvm qemu-system-$host_cpu qemu"
 232 AC_ARG_WITH([qemu],
 233         [AS_HELP_STRING([--with-qemu],
 234           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 235         [],
 236         [with_qemu="$default_qemu"])
 237 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 238         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 239 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 240 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 241
 242 dnl Check that the chosen qemu has virtio-serial support.
 243 if test "x$vmchannel_test" != "xno"; then
 244     AC_MSG_CHECKING([for virtio-serial support in $QEMU])
 245     if $QEMU -nographic -device \? 2>&1 | grep -sq virtio-serial; then
 246         AC_MSG_RESULT([yes])
 247         vmchannel_guestfwd=guestfwd
 248     else
 249         AC_MSG_RESULT([no])
 250         AC_MSG_FAILURE(
 251 [I did not find virtio-serial support in
 252 $QEMU.
 253
 254 virtio-serial support in qemu or KVM is essential for libguestfs
 255 to operate.
 256
 257 Usually this means that you have to install a newer version of qemu
 258 and/or KVM.  Please read the relevant section in the README file for
 259 more information about this.
 260
 261 You can override this test by setting the environment variable
 262 vmchannel_test=no  However if you don't have the right support
 263 in your qemu, then this just delays the pain.
 264
 265 If I am using the wrong qemu or you want to compile qemu from source
 266 and install it in another location, then you should configure with
 267 the --with-qemu option.
 268 ])
 269     fi
 270 fi
 271
 272 dnl Set default drive interface used by the guestfs_add_drive_opts call
 273 dnl ('-drive ...,if=...' option to qemu).
 274 dnl
 275 dnl If you encounter performance problems with virtio (RHBZ#509383)
 276 dnl then try '--with-drive-if=ide'.
 277 AC_ARG_WITH([drive-if],
 278         [AS_HELP_STRING([--with-drive-if],
 279           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 280         [],
 281         [with_drive_if=virtio])
 282 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 283
 284 dnl Set interface used by the network.  Normally you should
 285 dnl leave this at the default (virtio-net-pci) but you can use the
 286 dnl alternative (ne2k_pci) because of bugs in virtio networking
 287 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 288 AC_ARG_WITH([net-if],
 289         [AS_HELP_STRING([--with-net-if],
 290           [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
 291         [],
 292         [with_net_if=virtio-net-pci])
 293 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 294
 295 dnl Check for febootstrap etc.
 296 if test "x$enable_appliance" = "xyes"; then
 297     AC_CHECK_PROG([FEBOOTSTRAP],
 298                   [febootstrap],[febootstrap],[no])
 299     if test "x$FEBOOTSTRAP" != "xno"; then
 300       AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 301                     [febootstrap-run],[febootstrap-run],[no])
 302       test "x$FEBOOTSTRAP_RUN" = "xno" && \
 303           AC_MSG_ERROR([febootstrap-run must be installed])
 304       AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 305                     [febootstrap-install],[febootstrap-install],[no])
 306       test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 307           AC_MSG_ERROR([febootstrap-install must be installed])
 308       AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 309                     [febootstrap-minimize],[febootstrap-minimize],[no])
 310       test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 311           AC_MSG_ERROR([febootstrap-minimize must be installed])
 312       AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 313                     [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 314       test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 315           AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 316       AC_CHECK_PROG([FEBOOTSTRAP_TO_SUPERMIN],
 317                     [febootstrap-to-supermin],[febootstrap-to-supermin],[no])
 318       test "x$FEBOOTSTRAP_TO_SUPERMIN" = "xno" && \
 319           AC_MSG_ERROR([febootstrap-to-supermin must be installed])
 320
 321       dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 322       dnl of febootstrap, but old versions will fail with yum).
 323       AC_CHECK_PROG([FAKECHROOT],
 324                     [fakechroot],[fakechroot],[no])
 325       test "x$FAKECHROOT" = "xno" && \
 326          AC_MSG_ERROR([fakechroot must be installed])
 327
 328       AC_MSG_CHECKING([fakechroot version])
 329       fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 330       if test -z "$fakechroot_version"; then
 331         AC_MSG_RESULT([failed])
 332         AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 333       else
 334         AC_MSG_RESULT([$fakechroot_version])
 335         fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 336         fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 337         if test "$fakechroot_major" -lt 2 || \
 338           ( test "$fakechroot_major" -eq 2 && test "$fakechroot_minor" -lt 9 ); then
 339           AC_MSG_ERROR([fakechroot version must be >= 2.9])
 340         fi
 341       fi
 342       DIST="REDHAT"
 343     else
 344       # check for debootstrap and debirf
 345       AC_CHECK_PROG([DEBOOTSTRAP],
 346                     [debootstrap],[debootstrap],[no])
 347       test "x$DEBOOTSTRAP" = "xno" && \
 348           AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 349       AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 350       test "x$DEBIRF" = "xno" &&
 351           AC_MSG_ERROR([debirf must be installed])
 352       DIST="DEBIAN"
 353       case "$host_cpu" in
 354       *86)
 355           DEBIAN_KERNEL_ARCH=486
 356           ;;
 357       x86_64)
 358           DEBIAN_KERNEL_ARCH=amd64
 359           ;;
 360       *)
 361          DEBIAN_KERNEL_ARCH=$host_cpu
 362          ;;
 363       esac
 364       AC_SUBST(DEBIAN_KERNEL_ARCH)
 365     fi
 366     AC_SUBST(DIST)
 367
 368     dnl --with-updates to specify a Fedora updates repository.
 369     AC_ARG_WITH([updates],
 370         [AS_HELP_STRING([--with-updates],
 371           [set name of Fedora updates repository @<:@default=updates-released-f12@:>@])],
 372         [],
 373         [with_updates=updates-released-f12])
 374     UPDATES="$with_updates"
 375     AC_SUBST(UPDATES)
 376
 377     dnl --with-mirror to specify a local Fedora mirror.
 378     AC_ARG_WITH([mirror],
 379         [AS_HELP_STRING([--with-mirror],
 380           [set URI of a local Fedora mirror])],
 381         [],
 382         [with_mirror=])
 383     MIRROR="$with_mirror"
 384     AC_SUBST(MIRROR)
 385 fi
 386
 387 dnl --with-repo to specify a repository.
 388 AC_ARG_WITH([repo],
 389         [AS_HELP_STRING([--with-repo],
 390           [set name of Fedora repository @<:@default=fedora-13@:>@])],
 391         [],
 392         [with_repo=fedora-13])
 393 REPO="$with_repo"
 394 AC_SUBST(REPO)
 395 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of software repository.])
 396
 397 dnl Build the supermin appliance?  Please see README file before
 398 dnl enabling this option.
 399 AC_ARG_ENABLE([supermin],
 400         [AS_HELP_STRING([--enable-supermin],
 401           [enable supermin appliance (see README) @<:@default=no@:>@])],
 402         [AC_DEFINE([ENABLE_SUPERMIN],[1],[Supermin appliance enabled.])],
 403         [enable_supermin=no])
 404 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 405
 406 dnl Enable packet dumps when in verbose mode.  This generates lots
 407 dnl of debug info, only useful for people debugging the RPC mechanism.
 408 AC_ARG_ENABLE([packet-dump],
 409         [AS_HELP_STRING([--enable-packet-dump],
 410           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 411         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 412         [])
 413
 414 dnl Readline.
 415 AC_ARG_WITH([readline],
 416     [AS_HELP_STRING([--with-readline],
 417         [support fancy command line editing @<:@default=check@:>@])],
 418     [],
 419     [with_readline=check])
 420
 421 LIBREADLINE=
 422 AS_IF([test "x$with_readline" != xno],
 423     [AC_CHECK_LIB([readline], [main],
 424         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 425          AC_DEFINE([HAVE_LIBREADLINE], [1],
 426                    [Define if you have libreadline])
 427         ],
 428         [if test "x$with_readline" != xcheck; then
 429          AC_MSG_FAILURE(
 430              [--with-readline was given, but test for readline failed])
 431          fi
 432         ], -lncurses)
 433      old_LIBS="$LIBS"
 434      LIBS="$LIBS $LIBREADLINE"
 435      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 436      LIBS="$old_LIBS"
 437     ])
 438
 439 dnl For i18n.
 440 AM_GNU_GETTEXT([external])
 441 AM_GNU_GETTEXT_VERSION([0.17])
 442
 443 dnl libmagic (highly recommended)
 444 AC_CHECK_LIB([magic],[magic_file],
 445         [AC_CHECK_HEADER([magic.h],
 446                 [AC_SUBST([MAGIC_LIBS], ["-lmagic"])
 447                  AC_DEFINE([HAVE_LIBMAGIC],[1],[libmagic found at compile time.])
 448                 ], [])
 449         ],
 450         [AC_MSG_WARN([libmagic not found, some core features will be disabled])])
 451
 452 dnl Check for PCRE (highly recommended)
 453 PKG_CHECK_MODULES([PCRE], [libpcre],
 454         [AC_SUBST([PCRE_CFLAGS])
 455          AC_SUBST([PCRE_LIBS])
 456          AC_DEFINE([HAVE_PCRE],[1],[PCRE found at compile time.])
 457         ],
 458         [AC_MSG_WARN([PCRE not found, some core features will be disabled])])
 459
 460 dnl libvirt (highly recommended)
 461 PKG_CHECK_MODULES([LIBVIRT], [libvirt],
 462         [AC_SUBST([LIBVIRT_CFLAGS])
 463          AC_SUBST([LIBVIRT_LIBS])
 464          AC_DEFINE([HAVE_LIBVIRT],[1],[libvirt found at compile time.])
 465         ],
 466         [AC_MSG_WARN([libvirt not found, some core features will be disabled])])
 467 AM_CONDITIONAL([HAVE_LIBVIRT],[test "x$LIBVIRT_LIBS" != "x"])
 468
 469 dnl libxml2 (highly recommended)
 470 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0],
 471         [AC_SUBST([LIBXML2_CFLAGS])
 472          AC_SUBST([LIBXML2_LIBS])
 473          AC_DEFINE([HAVE_LIBXML2],[1],[libxml2 found at compile time.])
 474         ],
 475         [AC_MSG_WARN([libxml2 not found, some core features will be disabled])])
 476 AM_CONDITIONAL([HAVE_LIBXML2],[test "x$LIBXML2_LIBS" != "x"])
 477
 478 dnl hivex library (highly recommended)
 479 dnl This used to be a part of libguestfs, but was spun off into its
 480 dnl own separate upstream project in libguestfs 1.0.85.
 481 PKG_CHECK_MODULES([HIVEX], [hivex],
 482         [AC_SUBST([HIVEX_CFLAGS])
 483          AC_SUBST([HIVEX_LIBS])
 484          AC_DEFINE([HAVE_HIVEX],[1],[hivex library found at compile time.])
 485         ],
 486         [AC_MSG_WARN([hivex not found, some core features will be disabled])])
 487
 488 dnl FUSE is optional to build the FUSE module.
 489 AC_ARG_ENABLE([fuse],
 490         AS_HELP_STRING([--disable-fuse], [Disable FUSE (guestmount) support]),
 491         [],
 492         [enable_fuse=yes])
 493 AS_IF([test "x$enable_fuse" != "xno"],
 494         [PKG_CHECK_MODULES([FUSE],[fuse],,[
 495                 enable_fuse=no
 496                 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])])
 497 AM_CONDITIONAL([HAVE_FUSE],[test "x$enable_fuse" != "xno"])
 498
 499 dnl Check for OCaml (optional, for OCaml bindings).
 500 OCAMLC=no
 501 OCAMLFIND=no
 502 AC_ARG_ENABLE([ocaml],
 503         AS_HELP_STRING([--disable-ocaml], [Disable OCaml language bindings]),
 504         [],
 505         [enable_ocaml=yes])
 506 AS_IF([test "x$enable_ocaml" != "xno"],
 507         [dnl OCAMLC and OCAMLFIND have to be unset first, otherwise
 508          dnl AC_CHECK_TOOL (inside AC_PROG_OCAML) will not look.
 509          OCAMLC=
 510          OCAMLFIND=
 511          AC_PROG_OCAML
 512          AC_PROG_FINDLIB
 513         ])
 514 AM_CONDITIONAL([HAVE_OCAML],
 515                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
 516
 517 dnl Check for Perl (optional, for Perl bindings).
 518 PERL=no
 519 AC_ARG_ENABLE([perl],
 520         AS_HELP_STRING([--disable-perl], [Disable Perl language bindings]),
 521         [],
 522         [enable_perl=yes])
 523 AS_IF([test "x$enable_perl" != "xno"],
 524         [
 525         PERL=
 526         AC_CHECK_PROG([PERL],[perl],[perl],[no])
 527
 528         dnl Check for Perl modules that must be present to compile and
 529         dnl test the Perl bindings.
 530         missing_perl_modules=no
 531         for pm in Test::More ExtUtils::MakeMaker; do
 532             AC_MSG_CHECKING([for $pm])
 533             if ! perl -M$pm -e1 >/dev/null 2>&1; then
 534                 AC_MSG_RESULT([no])
 535                 missing_perl_modules=yes
 536             else
 537                 AC_MSG_RESULT([yes])
 538             fi
 539         done
 540         if test "x$missing_perl_modules" = "xyes"; then
 541             AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 542         fi
 543         ])
 544 AM_CONDITIONAL([HAVE_PERL],
 545     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 546
 547 dnl Check for Python (optional, for Python bindings).
 548 PYTHON_PREFIX=
 549 PYTHON_VERSION=
 550 PYTHON_INCLUDEDIR=
 551 PYTHON_SITE_PACKAGES=
 552
 553 AC_ARG_ENABLE([python],
 554         AS_HELP_STRING([--disable-python], [Disable Python language bindings]),
 555         [],
 556         [enable_python=yes])
 557 AS_IF([test "x$enable_python" != "xno"],
 558         [
 559         AC_CHECK_PROG([PYTHON],[python],[python],[no])
 560
 561         if test "x$PYTHON" != "xno"; then
 562             PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 563             PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 564             for d in \
 565                 $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 566                 /usr/include/python$PYTHON_VERSION \
 567                 /usr/local/include/python$PYTHON_VERSION
 568             do
 569                 AC_MSG_CHECKING([Python.h in $d])
 570                 if test -r "$d/Python.h"; then
 571                     AC_MSG_RESULT([found])
 572                     PYTHON_INCLUDEDIR=$d
 573                     break
 574                 fi
 575                 AC_MSG_RESULT([not found])
 576             done
 577             if test "x$PYTHON_INCLUDEDIR" = "x"; then
 578                 AC_MSG_WARN([Python include directory not found])
 579             fi
 580
 581             for d in \
 582                 $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 583                 $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 584                 /usr/lib64/python$PYTHON_VERSION/site-packages \
 585                 /usr/lib/python$PYTHON_VERSION/site-packages \
 586                 /usr/local/lib/python$PYTHON_VERSION/site-packages
 587             do
 588                 AC_MSG_CHECKING([for $d])
 589                 if test -d "$d"; then
 590                     AC_MSG_RESULT([found])
 591                     PYTHON_SITE_PACKAGES=$d
 592                     break
 593                 fi
 594                 AC_MSG_RESULT([not found])
 595             done
 596             if test "x$PYTHON_SITE_PACKAGES" = "x"; then
 597                 AC_MSG_WARN([Python site-packages directory not found])
 598             fi
 599
 600             old_LIBS="$LIBS"
 601             LIBS="$LIBS -lpython$PYTHON_VERSION"
 602             AC_CHECK_FUNCS([PyCapsule_New])
 603             LIBS="$old_LIBS"
 604         fi
 605
 606         AC_SUBST(PYTHON_PREFIX)
 607         AC_SUBST(PYTHON_VERSION)
 608         AC_SUBST(PYTHON_INCLUDEDIR)
 609         AC_SUBST(PYTHON_SITE_PACKAGES)
 610         ])
 611 AM_CONDITIONAL([HAVE_PYTHON],
 612     [test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_SITE_PACKAGES" != "x"])
 613
 614 dnl Check for Ruby and rake (optional, for Ruby bindings).
 615 AC_ARG_ENABLE([ruby],
 616         AS_HELP_STRING([--disable-ruby], [Disable Ruby language bindings]),
 617         [],
 618         [enable_ruby=yes])
 619 AS_IF([test "x$enable_ruby" != "xno"],
 620         [
 621         AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 622         AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 623         ])
 624 AM_CONDITIONAL([HAVE_RUBY],
 625     [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
 626
 627 dnl Check for Java.
 628 AC_ARG_WITH(java_home,
 629     [AS_HELP_STRING([--with-java-home],
 630         [specify path to JDK directory @<:@default=check@:>@])],
 631     [],
 632     [with_java_home=check])
 633
 634 if test "x$with_java_home" != "xno"; then
 635     if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
 636     then
 637         # Reject unsafe characters in $JAVA_HOME
 638         jh_lf='
 639 '
 640         case $JAVA_HOME in
 641           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 642             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 643         esac
 644         if test -d "$with_java_home"; then
 645             JAVA_HOME="$with_java_home"
 646         else
 647             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 648         fi
 649     fi
 650
 651     if test "x$JAVA_HOME" = "x"; then
 652         # Look for Java in some likely locations.
 653         for d in \
 654             /usr/lib/jvm/java \
 655             /usr/lib/jvm/java-6-openjdk
 656         do
 657             if test -d $d && test -f $d/bin/java; then
 658                 JAVA_HOME=$d
 659                 break
 660             fi
 661         done
 662     fi
 663
 664     if test "x$JAVA_HOME" != "x"; then
 665         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 666         if test ! -x "$JAVA_HOME/bin/java"; then
 667             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 668         else
 669             JAVA="$JAVA_HOME/bin/java"
 670         fi
 671         if test ! -x "$JAVA_HOME/bin/javac"; then
 672             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 673         else
 674             JAVAC="$JAVA_HOME/bin/javac"
 675         fi
 676         if test ! -x "$JAVA_HOME/bin/javah"; then
 677             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 678         else
 679             JAVAH="$JAVA_HOME/bin/javah"
 680         fi
 681         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 682             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 683         else
 684             JAVADOC="$JAVA_HOME/bin/javadoc"
 685         fi
 686         if test ! -x "$JAVA_HOME/bin/jar"; then
 687             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 688         else
 689             JAR="$JAVA_HOME/bin/jar"
 690         fi
 691         java_version=`$JAVA -version 2>&1 | grep "java version"`
 692         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 693
 694         dnl Find jni.h.
 695         AC_MSG_CHECKING([for jni.h])
 696         if test -f "$JAVA_HOME/include/jni.h"; then
 697             JNI_CFLAGS="-I$JAVA_HOME/include"
 698         else
 699             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 700                 head=`find $JAVA_HOME -name jni.h | tail -1`
 701                 dir=`dirname "$head"`
 702                 JNI_CFLAGS="-I$dir"
 703             else
 704                 AC_MSG_FAILURE([missing jni.h header file])
 705             fi
 706         fi
 707         AC_MSG_RESULT([$JNI_CFLAGS])
 708
 709         dnl Find jni_md.h.
 710         AC_MSG_CHECKING([for jni_md.h])
 711         case "$build_os" in
 712         *linux*) system="linux" ;;
 713         *SunOS*) system="solaris" ;;
 714         *cygwin*) system="win32" ;;
 715         *) system="$build_os" ;;
 716         esac
 717         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 718             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 719         else
 720             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 721                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 722                 dir=`dirname "$head"`
 723                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 724             else
 725                 AC_MSG_FAILURE([missing jni_md.h header file])
 726             fi
 727         fi
 728         AC_MSG_RESULT([$JNI_CFLAGS])
 729
 730         dnl Need extra version flag?
 731         AC_MSG_CHECKING([extra javac flags])
 732         JAVAC_FLAGS=
 733         javac_version=`$JAVAC -version 2>&1`
 734         case "$javac_version" in
 735         *Eclipse*)
 736             JAVAC_FLAGS="-source 1.5" ;;
 737         esac
 738         AC_MSG_RESULT([$JAVAC_FLAGS])
 739
 740         dnl Where to install jarfiles.
 741         dnl XXX How to make it configurable?
 742         JAR_INSTALL_DIR=\${prefix}/share/java
 743         JNI_INSTALL_DIR=\${libdir}
 744
 745         dnl JNI version.
 746         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 747         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 748         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 749         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 750     fi
 751 fi
 752
 753 AC_SUBST(JAVA_HOME)
 754 AC_SUBST(JAVA)
 755 AC_SUBST(JAVAC)
 756 AC_SUBST(JAVAH)
 757 AC_SUBST(JAVADOC)
 758 AC_SUBST(JAR)
 759 AC_SUBST(JNI_CFLAGS)
 760 AC_SUBST(JAVAC_FLAGS)
 761 AC_SUBST(JAR_INSTALL_DIR)
 762 AC_SUBST(JNI_INSTALL_DIR)
 763 AC_SUBST(JNI_VERSION_INFO)
 764
 765 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 766
 767 dnl Check for Haskell (GHC).
 768 GHC=no
 769 AC_ARG_ENABLE([haskell],
 770         AS_HELP_STRING([--disable-haskell], [Disable Haskell language bindings]),
 771         [],
 772         [enable_haskell=yes])
 773 AS_IF([test "x$enable_haskell" != "xno"],
 774         [
 775         GHC=
 776         AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 777         ])
 778 AM_CONDITIONAL([HAVE_HASKELL],
 779     [test "x$GHC" != "xno"])
 780
 781 dnl PHP
 782 PHP=no
 783 AC_ARG_ENABLE([php],
 784         AS_HELP_STRING([--disable-php], [Disable PHP language bindings]),
 785         [],
 786         [enable_php=yes])
 787 AS_IF([test "x$enable_php" != "xno"],
 788         [
 789         PHP=
 790         AC_CHECK_PROG([PHP],[php],[php],[no])
 791         AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
 792         ])
 793 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
 794
 795 dnl Check for Perl modules needed by Perl virt tools (virt-df, etc.)
 796 AS_IF([test "x$PERL" != "xno"],
 797         [
 798         missing_perl_modules=no
 799         for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper Locale::TextDomain Win::Hivex Win::Hivex::Regedit; do
 800             AC_MSG_CHECKING([for $pm])
 801             if ! $PERL -M$pm -e1 >/dev/null 2>&1; then
 802                 AC_MSG_RESULT([no])
 803                 missing_perl_modules=yes
 804             else
 805                 AC_MSG_RESULT([yes])
 806             fi
 807         done
 808         if test "x$missing_perl_modules" = "xyes"; then
 809             AC_MSG_WARN([some Perl modules required to compile the Perl virt-* tools are missing])
 810         fi
 811         ])
 812
 813 AM_CONDITIONAL([HAVE_TOOLS],
 814     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 815
 816 dnl Library versioning.
 817 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 818 AC_SUBST(MAX_PROC_NR)
 819
 820 dnl Run in subdirs.
 821 if test "x$enable_daemon" = "xyes"; then
 822     AC_CONFIG_SUBDIRS([daemon])
 823 fi
 824
 825 dnl Produce output files.
 826 AC_CONFIG_HEADERS([config.h])
 827 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 828 AC_CONFIG_FILES([appliance/update.sh],
 829                 [chmod +x appliance/update.sh])
 830 AC_CONFIG_FILES([Makefile
 831                  generator/Makefile
 832                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 833                  appliance/Makefile
 834                  appliance/debian/debirf.conf
 835                  images/Makefile
 836                  capitests/Makefile
 837                  regressions/Makefile
 838                  test-tool/Makefile
 839                  ocaml/Makefile ocaml/examples/Makefile
 840                  perl/Makefile
 841                  python/Makefile
 842                  ruby/Makefile ruby/Rakefile
 843                  java/Makefile
 844                  haskell/Makefile
 845                  inspector/Makefile
 846                  tools/Makefile
 847                  libguestfs.pc
 848                  gnulib/lib/Makefile
 849                  gnulib/tests/Makefile
 850                  fuse/Makefile
 851                  po-docs/Makefile
 852                  po-docs/ja/Makefile
 853                  php/Makefile
 854                  csharp/Makefile
 855                  cat/Makefile
 856                  ocaml/META perl/Makefile.PL])
 857 AC_OUTPUT
 858
 859 dnl Produce summary.
 860 echo
 861 echo
 862 echo "------------------------------------------------------------"
 863 echo "Thank you for downloading $PACKAGE_STRING"
 864 echo
 865 echo "This is how we have configured the optional components for you today:"
 866 echo
 867 echo    "Daemon .............................. $enable_daemon"
 868 echo    "Appliance ........................... $enable_appliance"
 869 echo    "QEMU ................................ $QEMU"
 870 echo -n "OCaml bindings ...................... "
 871 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 872 echo -n "Perl bindings ....................... "
 873 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 874 echo -n "Python bindings ..................... "
 875 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 876 echo -n "Ruby bindings ....................... "
 877 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 878 echo -n "Java bindings ....................... "
 879 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 880 echo -n "Haskell bindings .................... "
 881 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 882 echo -n "PHP bindings ........................ "
 883 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 884 echo -n "virt-* tools ........................ "
 885 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 886 echo "supermin appliance .................. $enable_supermin"
 887 echo "FUSE filesystem ..................... $enable_fuse"
 888 echo
 889 echo "If any optional component is configured 'no' when you expected 'yes'"
 890 echo "then you should check the preceeding messages."
 891 echo
 892 echo "Please report bugs back to the mailing list:"
 893 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 894 echo
 895 echo "Next you should type 'make' to build the package,"
 896 echo "then 'make check' to run the tests."
 897 echo "------------------------------------------------------------"