configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2011 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # The major, minor, and release fields MUST be numbers.  Packagers can
  19 # add extra information using --with-extra="..." which may be any
  20 # freeform string.
  21 m4_define([libguestfs_major],   [1])
  22 m4_define([libguestfs_minor],   [13])
  23 m4_define([libguestfs_release], [19])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Stable or unstable version?
  35 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  36 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  37             AC_MSG_RESULT([stable])
  38        ],[
  39             AC_MSG_RESULT([unstable])
  40             AC_MSG_NOTICE([
  41 ***
  42 This is a development version of libguestfs. Some APIs may be unstable
  43 until they appear in a stable release of libguestfs (at which point
  44 the C API and ABI is guaranteed to remain stable forever).  For
  45 more information about stable and development branches of libguestfs
  46 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  47 ***])
  48        ])
  49
  50 dnl Extra string, a freeform string defined by packagers.
  51 AC_ARG_WITH([extra],
  52   [AS_HELP_STRING([--with-extra],
  53                   [extra version string (for use by packagers)])],
  54   [libguestfs_extra="$withval"],
  55   [libguestfs_extra=]
  56 )
  57
  58 AC_MSG_NOTICE([libguestfs version libguestfs_major.libguestfs_minor.libguestfs_release$libguestfs_extra])
  59
  60 dnl Split up the version string.
  61 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  62 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  63 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  64 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_EXTRA],["$libguestfs_extra"],[Extra version string])
  65
  66 dnl Early gnulib initialization.
  67 gl_EARLY
  68 gl_INIT
  69
  70 AC_PROG_LIBTOOL
  71
  72 AC_PROG_SED
  73
  74 dnl Check for basic C environment.
  75 AC_PROG_CC_STDC
  76 AC_PROG_INSTALL
  77 AC_PROG_CPP
  78
  79 AC_ARG_ENABLE([gcc-warnings],
  80   [AS_HELP_STRING([--enable-gcc-warnings],
  81                   [turn on lots of GCC warnings (for developers)])],
  82   [case $enableval in
  83      yes|no) ;;
  84      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  85    esac
  86    gl_gcc_warnings=$enableval],
  87   [gl_gcc_warnings=no]
  88 )
  89
  90 if test "$gl_gcc_warnings" = yes; then
  91   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  92   AC_SUBST([WERROR_CFLAGS])
  93
  94   nw=
  95   # This, $nw, is the list of warnings we disable.
  96   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  97   nw="$nw -Waggregate-return"       # anachronistic
  98   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  99   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 100   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 101   nw="$nw -Wcast-qual"              # Too many warnings for now
 102   nw="$nw -Wconversion"             # Too many warnings for now
 103   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 104   nw="$nw -Wsign-conversion"        # Too many warnings for now
 105   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 106   nw="$nw -Wunreachable-code"       # Too many warnings for now
 107   nw="$nw -Wpadded"                 # Our structs are not padded
 108   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 109   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 110   nw="$nw -Wvla"                    # two warnings in mount.c
 111   # things I might fix soon:
 112   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 113   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 114   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 115   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 116                                     # was not possible, safe to ignore
 117   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 118   nw="$nw -Wlong-long"              # Allow long long since it's required
 119                                     # by Python, Ruby and xstrtoll.
 120   nw="$nw -Wstack-protector"        # Don't warn about stack-protector
 121                                     # failures (seen on Ubuntu).
 122   nw="$nw -Wmissing-noreturn"       # Don't warn about missed noreturn funcs
 123                                     # (seen on Ubuntu).
 124
 125   gl_MANYWARN_ALL_GCC([ws])
 126   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 127   for w in $ws; do
 128     gl_WARN_ADD([$w])
 129   done
 130   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 131   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 132   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 133
 134   # In spite of excluding -Wlogical-op above, it is enabled, as of
 135   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 136   gl_WARN_ADD([-Wno-logical-op])
 137
 138   # Work around warning in src/inspect.c.  This seems to be a bug in gcc 4.5.1.
 139   gl_WARN_ADD([-Wno-strict-overflow])
 140
 141   gl_WARN_ADD([-fdiagnostics-show-option])
 142
 143   AC_SUBST([WARN_CFLAGS])
 144
 145   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 146   AC_DEFINE([_FORTIFY_SOURCE], [2],
 147     [enable compile-time and run-time bounds-checking, and some warnings])
 148   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 149 fi
 150
 151 AC_C_PROTOTYPES
 152 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 153
 154 AM_PROG_CC_C_O
 155
 156 dnl Work out how to specify the linker script to the linker.
 157 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 158 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 159     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 160 AC_SUBST(VERSION_SCRIPT_FLAGS)
 161
 162 dnl Check support for 64 bit file offsets.
 163 AC_SYS_LARGEFILE
 164
 165 dnl Check sizeof long.
 166 AC_CHECK_SIZEOF([long])
 167
 168 dnl Check if dirent (readdir) supports d_type member.
 169 AC_STRUCT_DIRENT_D_TYPE
 170
 171 dnl Check if stat has the required fields.
 172 AC_STRUCT_ST_BLOCKS
 173 AC_CHECK_MEMBER([struct stat.st_blksize],[
 174         AC_DEFINE([HAVE_STRUCT_STAT_ST_BLKSIZE],[1],[Define to 1 if 'st_blksize' is a member of 'struct stat'])])
 175
 176 dnl Define a C symbol for the host CPU architecture.
 177 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 178
 179 dnl Headers.
 180 AC_CHECK_HEADERS([\
 181         attr/xattr.h \
 182         byteswap.h \
 183         endian.h \
 184         errno.h \
 185         printf.h \
 186         sys/inotify.h \
 187         sys/socket.h \
 188         sys/statvfs.h \
 189         sys/types.h \
 190         sys/un.h \
 191         sys/wait.h \
 192         windows.h \
 193         sys/xattr.h])
 194
 195 dnl Functions.
 196 AC_CHECK_FUNCS([\
 197         futimens \
 198         getxattr \
 199         htonl \
 200         htons \
 201         inotify_init1 \
 202         lgetxattr \
 203         listxattr \
 204         llistxattr \
 205         lsetxattr \
 206         lremovexattr \
 207         mknod \
 208         ntohl \
 209         ntohs \
 210         posix_fallocate \
 211         realpath \
 212         removexattr \
 213         setitimer \
 214         setxattr \
 215         sigaction \
 216         statvfs \
 217         sync])
 218
 219 dnl For modified printf in the daemon, we need glibc either (old-style)
 220 dnl register_printf_function or (new-style) register_printf_specifier.
 221 AC_CHECK_FUNC([register_printf_specifier],[
 222         AC_DEFINE([HAVE_REGISTER_PRINTF_SPECIFIER],[1],
 223                 [Define to 1 if you have new-style register_printf_specifier])
 224         ],[
 225         AC_CHECK_FUNC([register_printf_function],[
 226                 AC_DEFINE([HAVE_REGISTER_PRINTF_FUNCTION],[1],
 227                         [Define to 1 if you have old-style register_printf_function])
 228                 ],[
 229                 AC_MSG_FAILURE(
 230 [No support for glibc-style extended printf formatters.
 231
 232 This means you either have a very old glibc (pre-2.0) or you
 233 are using some other libc where this is not supported.])])])
 234
 235 dnl Build the daemon?
 236 AC_MSG_CHECKING([if we should build the daemon])
 237 AC_ARG_ENABLE([daemon],
 238         [AS_HELP_STRING([--enable-daemon],
 239           [enable building the daemon @<:@default=yes@:>@])],
 240         [],
 241         [enable_daemon=yes])
 242 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 243 AC_MSG_RESULT([$enable_daemon])
 244
 245 if test "x$enable_daemon" = "xyes"; then
 246         dnl Install the daemon (for libguestfs live service)
 247         AC_MSG_CHECKING([if we should install the daemon])
 248         AC_ARG_ENABLE([install-daemon],
 249                 [AS_HELP_STRING([--enable-install-daemon],
 250                   [enable installing the daemon under $sbindir @<:@default=no@:>@])],
 251                 [],
 252                 [enable_install_daemon=no])
 253         AM_CONDITIONAL([INSTALL_DAEMON],[test "x$enable_install_daemon" = "xyes"])
 254         AC_MSG_RESULT([$enable_install_daemon])
 255 fi
 256
 257 dnl Build the appliance?
 258 AC_MSG_CHECKING([if we should build the appliance])
 259 AC_ARG_ENABLE([appliance],
 260         [AS_HELP_STRING([--enable-appliance],
 261           [enable building the appliance @<:@default=yes@:>@])],
 262         [],
 263         [enable_appliance=yes])
 264 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 265 AC_MSG_RESULT([$enable_appliance])
 266
 267 if test "x$enable_appliance" = "xyes"; then
 268     dnl Check for febootstrap >= 3.0
 269     AC_CHECK_PROG([FEBOOTSTRAP],
 270                   [febootstrap],[febootstrap],[no])
 271     test "x$FEBOOTSTRAP" = "xno" &&
 272         AC_MSG_ERROR([febootstrap must be installed])
 273     dnl febootstrap 2.x did not support the --version parameter
 274     $FEBOOTSTRAP --version >&AS_MESSAGE_LOG_FD 2>&1 ||
 275         AC_MSG_ERROR([febootstrap >= 3.0 must be installed, your version is too old])
 276
 277     dnl Pass a febootstrap --yum-config option.
 278     AC_MSG_CHECKING([if user requested febootstrap --yum-config option])
 279     AC_ARG_WITH([febootstrap-yum-config],
 280         [AS_HELP_STRING([--with-febootstrap-yum-config=FILE],
 281           [pass febootstrap --yum-config option @<:@default=no@:>@])],
 282         [FEBOOTSTRAP_YUM_CONFIG="$withval"],
 283         [FEBOOTSTRAP_YUM_CONFIG=no])
 284     AC_MSG_RESULT([$FEBOOTSTRAP_YUM_CONFIG])
 285     AC_SUBST([FEBOOTSTRAP_YUM_CONFIG])
 286
 287     dnl Which distro?
 288     dnl
 289     dnl This used to be Very Important but is now just used to select
 290     dnl which packages to install in the appliance, since the package
 291     dnl names vary slightly across distros.  (See
 292     dnl appliance/packagelist.in and appliance/excludelist.in)
 293     AC_MSG_CHECKING([which Linux distro for package names])
 294     DISTRO=REDHAT
 295     if test -f /etc/debian_version; then
 296         DISTRO=DEBIAN
 297         if grep -q 'DISTRIB_ID=Ubuntu' /etc/lsb-release 2>&AS_MESSAGE_LOG_FD; then
 298             DISTRO=UBUNTU
 299         fi
 300     fi
 301     if test -f /etc/arch-release; then
 302         DISTRO=ARCHLINUX
 303     fi
 304     AC_MSG_RESULT([$DISTRO])
 305     AC_SUBST([DISTRO])
 306 fi
 307
 308 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 309 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 310 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 311 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 312         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 313         ])
 314
 315 dnl Check for Augeas (now optional).
 316 AC_CHECK_LIB([augeas],[aug_match],[
 317         have_augeas=yes
 318         AUGEAS_LIB="-laugeas"
 319
 320         old_LIBS="$LIBS"
 321         LIBS="$LIBS $AUGEAS_LIB"
 322         dnl Check for functions not available in earlier versions of Augeas.
 323         AC_CHECK_FUNCS([aug_load aug_defvar aug_defnode])
 324         LIBS="$old_LIBS"
 325
 326         ],[have_augeas=no])
 327 if test "x$have_augeas" = "xyes"; then
 328         AC_DEFINE([HAVE_AUGEAS],[1],[Define to 1 if you have Augeas])
 329 fi
 330 AC_SUBST([AUGEAS_LIB])
 331
 332 dnl Check for libselinux (optional).
 333 AC_CHECK_HEADERS([selinux/selinux.h])
 334 AC_CHECK_LIB([selinux],[setexeccon],[
 335         have_libselinux="$ac_cv_header_selinux_selinux_h"
 336         SELINUX_LIB="-lselinux"
 337
 338         old_LIBS="$LIBS"
 339         LIBS="$LIBS $SELINUX_LIB"
 340         AC_CHECK_FUNCS([setcon getcon])
 341         LIBS="$old_LIBS"
 342
 343         ],[have_libselinux=no])
 344 if test "x$have_libselinux" = "xyes"; then
 345         AC_DEFINE([HAVE_LIBSELINUX],[1],[Define to 1 if you have libselinux])
 346 fi
 347 AC_SUBST([SELINUX_LIB])
 348
 349 dnl Check for systemtap/DTrace userspace probes (optional).
 350 dnl http://sourceware.org/systemtap/wiki/AddingUserSpaceProbingToApps
 351 AC_CHECK_HEADERS([sys/sdt.h])
 352 dnl AC_CHECK_PROG([DTRACE],[dtrace],[dtrace],[no])
 353
 354 dnl Check for cpio which isn't in the default Pardus install amazingly.
 355 AC_CHECK_PROG([CPIO],[cpio],[cpio],[no])
 356 test "x$CPIO" = "xno" &&
 357      AC_MSG_ERROR([cpio must be installed])
 358
 359 dnl Check for gperf.
 360 AC_CHECK_PROG([GPERF],[gperf],[gperf],[no])
 361 test "x$GPERF" = "xno" &&
 362      AC_MSG_ERROR([gperf must be installed])
 363
 364 dnl Check for pod2man, pod2text, pod2html.
 365 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 366 test "x$POD2MAN" = "xno" &&
 367      AC_MSG_ERROR([pod2man must be installed])
 368 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 369 test "x$POD2TEXT" = "xno" &&
 370      AC_MSG_ERROR([pod2text must be installed])
 371 AC_CHECK_PROG([POD2HTML],[pod2html],[pod2html],[no])
 372 test "x$POD2HTML" = "xno" &&
 373      AC_MSG_ERROR([pod2html must be installed])
 374
 375 dnl Check if pod2man, pod2text take --stderr and -u options (not in RHEL 5).
 376 AC_MSG_CHECKING([if pod2man takes --stderr option])
 377 if "$POD2MAN" --stderr >&AS_MESSAGE_LOG_FD 2>&1; then
 378     AC_MSG_RESULT([yes])
 379     POD2_STDERR_OPTION="--stderr"
 380 else
 381     AC_MSG_RESULT([no])
 382     POD2_STDERR_OPTION=""
 383 fi
 384 AC_SUBST([POD2_STDERR_OPTION])
 385
 386 AC_MSG_CHECKING([if pod2man takes -u option])
 387 if "$POD2MAN" -u >&AS_MESSAGE_LOG_FD 2>&1; then
 388     AC_MSG_RESULT([yes])
 389     POD2_UTF8_OPTION="-u"
 390 else
 391     AC_MSG_RESULT([no])
 392     POD2_UTF8_OPTION=""
 393 fi
 394 AC_SUBST([POD2_UTF8_OPTION])
 395
 396 dnl Check for genisoimage.
 397 AC_PATH_PROGS([GENISOIMAGE],[genisoimage],[no],
 398         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 399 test "x$GENISOIMAGE" = "xno" && AC_MSG_ERROR([genisoimage must be installed])
 400
 401 dnl Check for optional xmllint.
 402 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 403 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 404
 405 dnl po4a for translating man pages and POD files (optional).
 406 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
 407 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
 408
 409 dnl Check for db_dump, db_load (optional).
 410 AC_CHECK_PROGS([DB_DUMP],
 411                [db_dump db4_dump db4.8_dump db4.7_dump db4.6_dump],[no])
 412 AC_CHECK_PROGS([DB_LOAD],
 413                [db_load db4_load db4.8_load db4.7_load db4.6_load],[no])
 414 if test "x$DB_DUMP" != "xno"; then
 415     AC_DEFINE_UNQUOTED([DB_DUMP],["$DB_DUMP"],[Name of db_dump program.])
 416 fi
 417 if test "x$DB_LOAD" != "xno"; then
 418     AC_DEFINE_UNQUOTED([DB_LOAD],["$DB_LOAD"],[Name of db_load program.])
 419 fi
 420
 421 dnl Check for QEMU for running binaries on this $host_cpu, fall
 422 dnl back to basic 'qemu'.  Allow the user to override it.
 423 default_qemu="qemu-kvm kvm qemu-system-$host_cpu qemu"
 424 AC_ARG_WITH([qemu],
 425         [AS_HELP_STRING([--with-qemu],
 426           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 427         [],
 428         [with_qemu="$default_qemu"])
 429 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 430         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 431 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 432 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 433
 434 dnl Check that the chosen qemu has virtio-serial support.
 435 if test "x$vmchannel_test" != "xno"; then
 436     AC_MSG_CHECKING([that $QEMU -help works])
 437     if $QEMU -help >&AS_MESSAGE_LOG_FD 2>&1; then
 438         AC_MSG_RESULT([yes])
 439     else
 440         AC_MSG_RESULT([no])
 441         AC_MSG_FAILURE(
 442 [$QEMU -help: command failed.
 443
 444 This could be a very old version of qemu, or qemu might not be
 445 working.
 446 ])
 447     fi
 448
 449     AC_MSG_CHECKING([for virtio-serial support in $QEMU])
 450     if $QEMU -nographic -device \? 2>&1 | grep -sq virtio-serial; then
 451         AC_MSG_RESULT([yes])
 452     else
 453         AC_MSG_RESULT([no])
 454         AC_MSG_FAILURE(
 455 [I did not find virtio-serial support in
 456 $QEMU.
 457
 458 virtio-serial support in qemu or KVM is essential for libguestfs
 459 to operate.
 460
 461 Usually this means that you have to install a newer version of qemu
 462 and/or KVM.  Please read the relevant section in the README file for
 463 more information about this.
 464
 465 You can override this test by setting the environment variable
 466 vmchannel_test=no  However if you don't have the right support
 467 in your qemu, then this just delays the pain.
 468
 469 If I am using the wrong qemu or you want to compile qemu from source
 470 and install it in another location, then you should configure with
 471 the --with-qemu option.
 472 ])
 473     fi
 474 fi
 475
 476 dnl Set default drive interface used by the guestfs_add_drive_opts call
 477 dnl ('-drive ...,if=...' option to qemu).
 478 dnl
 479 dnl If you encounter performance problems with virtio (RHBZ#509383)
 480 dnl then try '--with-drive-if=ide'.
 481 AC_ARG_WITH([drive-if],
 482         [AS_HELP_STRING([--with-drive-if],
 483           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 484         [],
 485         [with_drive_if=virtio])
 486 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 487
 488 dnl Set interface used by the network.  Normally you should
 489 dnl leave this at the default (virtio-net-pci) but you can use the
 490 dnl alternative (ne2k_pci) because of bugs in virtio networking
 491 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 492 AC_ARG_WITH([net-if],
 493         [AS_HELP_STRING([--with-net-if],
 494           [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
 495         [],
 496         [with_net_if=virtio-net-pci])
 497 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 498
 499 dnl Enable packet dumps when in verbose mode.  This generates lots
 500 dnl of debug info, only useful for people debugging the RPC mechanism.
 501 AC_ARG_ENABLE([packet-dump],
 502         [AS_HELP_STRING([--enable-packet-dump],
 503           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 504         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 505         [])
 506
 507 dnl Readline.
 508 AC_ARG_WITH([readline],
 509     [AS_HELP_STRING([--with-readline],
 510         [support fancy command line editing @<:@default=check@:>@])],
 511     [],
 512     [with_readline=check])
 513
 514 LIBREADLINE=
 515 AS_IF([test "x$with_readline" != xno],
 516     [AC_CHECK_LIB([readline], [main],
 517         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 518          AC_DEFINE([HAVE_LIBREADLINE], [1],
 519                    [Define if you have libreadline])
 520         ],
 521         [if test "x$with_readline" != xcheck; then
 522          AC_MSG_FAILURE(
 523              [--with-readline was given, but test for readline failed])
 524          fi
 525         ], -lncurses)
 526      old_LIBS="$LIBS"
 527      LIBS="$LIBS $LIBREADLINE"
 528      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 529      LIBS="$old_LIBS"
 530     ])
 531
 532 dnl For i18n.
 533 AM_GNU_GETTEXT([external])
 534
 535 dnl Check for PCRE (required)
 536 PKG_CHECK_MODULES([PCRE], [libpcre])
 537
 538 dnl libmagic (highly recommended)
 539 AC_CHECK_LIB([magic],[magic_file],
 540         [AC_CHECK_HEADER([magic.h],
 541                 [AC_SUBST([MAGIC_LIBS], ["-lmagic"])
 542                  AC_DEFINE([HAVE_LIBMAGIC],[1],[libmagic found at compile time.])
 543                 ], [])
 544         ],
 545         [AC_MSG_WARN([libmagic not found, some core features will be disabled])])
 546
 547 dnl libvirt (highly recommended)
 548 PKG_CHECK_MODULES([LIBVIRT], [libvirt],
 549         [AC_SUBST([LIBVIRT_CFLAGS])
 550          AC_SUBST([LIBVIRT_LIBS])
 551          AC_DEFINE([HAVE_LIBVIRT],[1],[libvirt found at compile time.])
 552         ],
 553         [AC_MSG_WARN([libvirt not found, some core features will be disabled])])
 554 AM_CONDITIONAL([HAVE_LIBVIRT],[test "x$LIBVIRT_LIBS" != "x"])
 555
 556 dnl libxml2 (highly recommended)
 557 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0],
 558         [AC_SUBST([LIBXML2_CFLAGS])
 559          AC_SUBST([LIBXML2_LIBS])
 560          AC_DEFINE([HAVE_LIBXML2],[1],[libxml2 found at compile time.])
 561         ],
 562         [AC_MSG_WARN([libxml2 not found, some core features will be disabled])])
 563 AM_CONDITIONAL([HAVE_LIBXML2],[test "x$LIBXML2_LIBS" != "x"])
 564
 565 dnl libconfig (highly recommended)
 566 PKG_CHECK_MODULES([LIBCONFIG], [libconfig],
 567         [AC_SUBST([LIBCONFIG_CFLAGS])
 568          AC_SUBST([LIBCONFIG_LIBS])
 569          AC_DEFINE([HAVE_LIBCONFIG],[1],[libconfig found at compile time.])
 570         ],
 571         [AC_MSG_WARN([libconfig not found, some features will be disabled])])
 572 AM_CONDITIONAL([HAVE_LIBCONFIG],[test "x$LIBCONFIG_LIBS" != "x"])
 573
 574 dnl hivex library (highly recommended)
 575 dnl This used to be a part of libguestfs, but was spun off into its
 576 dnl own separate upstream project in libguestfs 1.0.85.
 577 PKG_CHECK_MODULES([HIVEX], [hivex],
 578         [AC_SUBST([HIVEX_CFLAGS])
 579          AC_SUBST([HIVEX_LIBS])
 580          AC_DEFINE([HAVE_HIVEX],[1],[hivex library found at compile time.])
 581         ],
 582         [AC_MSG_WARN([hivex not found, some core features will be disabled])])
 583 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HIVEX_LIBS" != "x"])
 584
 585 dnl FUSE is optional to build the FUSE module.
 586 AC_ARG_ENABLE([fuse],
 587         AS_HELP_STRING([--disable-fuse], [Disable FUSE (guestmount) support]),
 588         [],
 589         [enable_fuse=yes])
 590 AS_IF([test "x$enable_fuse" != "xno"],
 591         [PKG_CHECK_MODULES([FUSE],[fuse],,[
 592                 enable_fuse=no
 593                 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])])
 594 AM_CONDITIONAL([HAVE_FUSE],[test "x$enable_fuse" != "xno"])
 595
 596 dnl Check for OCaml (optional, for OCaml bindings).
 597 OCAMLC=no
 598 OCAMLFIND=no
 599 AC_ARG_ENABLE([ocaml],
 600         AS_HELP_STRING([--disable-ocaml], [Disable OCaml language bindings]),
 601         [],
 602         [enable_ocaml=yes])
 603 AS_IF([test "x$enable_ocaml" != "xno"],
 604         [dnl OCAMLC and OCAMLFIND have to be unset first, otherwise
 605          dnl AC_CHECK_TOOL (inside AC_PROG_OCAML) will not look.
 606          OCAMLC=
 607          OCAMLFIND=
 608          AC_PROG_OCAML
 609          AC_PROG_FINDLIB
 610
 611          AS_IF([test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"],
 612                 [AC_CHECK_OCAML_PKG([pcre])])
 613         ])
 614 AM_CONDITIONAL([HAVE_OCAML],
 615                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
 616 AM_CONDITIONAL([HAVE_OCAML_PCRE],
 617                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno" && test "x$OCAML_PKG_pcre" != "xno"])
 618 AM_CONDITIONAL([HAVE_OCAMLDOC],
 619                [test "x$OCAMLDOC" != "xno"])
 620
 621 dnl Check for Perl (optional, for Perl bindings).
 622 PERL=no
 623 AC_ARG_ENABLE([perl],
 624         AS_HELP_STRING([--disable-perl], [Disable Perl language bindings]),
 625         [],
 626         [enable_perl=yes])
 627 AS_IF([test "x$enable_perl" != "xno"],
 628         [
 629         PERL=
 630         AC_CHECK_PROG([PERL],[perl],[perl],[no])
 631
 632         dnl Check for Perl modules that must be present to compile and
 633         dnl test the Perl bindings.
 634         missing_perl_modules=no
 635         for pm in Test::More ExtUtils::MakeMaker; do
 636             AC_MSG_CHECKING([for $pm])
 637             if ! perl -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
 638                 AC_MSG_RESULT([no])
 639                 missing_perl_modules=yes
 640             else
 641                 AC_MSG_RESULT([yes])
 642             fi
 643         done
 644         if test "x$missing_perl_modules" = "xyes"; then
 645             AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 646         fi
 647         ])
 648 AM_CONDITIONAL([HAVE_PERL],
 649     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 650
 651 dnl Check for Python (optional, for Python bindings).
 652 PYTHON_PREFIX=
 653 PYTHON_VERSION=
 654 PYTHON_INCLUDEDIR=
 655 PYTHON_INSTALLDIR=
 656
 657 AC_ARG_ENABLE([python],
 658         AS_HELP_STRING([--disable-python], [Disable Python language bindings]),
 659         [],
 660         [enable_python=yes])
 661 AS_IF([test "x$enable_python" != "xno"],
 662         [
 663         AC_CHECK_PROG([PYTHON],[python],[python],[no])
 664
 665         if test "x$PYTHON" != "xno"; then
 666             AC_MSG_CHECKING([Python prefix])
 667             PYTHON_PREFIX=`$PYTHON -c "import sys; print (sys.prefix)"`
 668             AC_MSG_RESULT([$PYTHON_PREFIX])
 669
 670             AC_MSG_CHECKING([Python version])
 671             PYTHON_VERSION=`$PYTHON -c "import sys; print (sys.version[[0:3]])"`
 672             AC_MSG_RESULT([$PYTHON_VERSION])
 673
 674             AC_MSG_CHECKING([for Python include path])
 675             if test -z "$PYTHON_INCLUDEDIR"; then
 676                 python_path=`$PYTHON -c "import distutils.sysconfig; \
 677                                          print (distutils.sysconfig.get_python_inc ());"`
 678                 PYTHON_INCLUDEDIR=$python_path
 679             fi
 680             AC_MSG_RESULT([$PYTHON_INCLUDEDIR])
 681
 682             AC_ARG_WITH([python-installdir],
 683                         [AS_HELP_STRING([--with-python-installdir],
 684                                         [directory to install python modules @<:@default=check@:>@])],
 685                         [PYTHON_INSTALLDIR="$withval"
 686                         AC_MSG_NOTICE([Python install dir $PYTHON_INSTALLDIR])],
 687                         [PYTHON_INSTALLDIR=check])
 688
 689             if test "x$PYTHON_INSTALLDIR" = "xcheck"; then
 690                 PYTHON_INSTALLDIR=
 691                 AC_MSG_CHECKING([for Python site-packages path])
 692                 if test -z "$PYTHON_INSTALLDIR"; then
 693                     PYTHON_INSTALLDIR=`$PYTHON -c "import distutils.sysconfig; \
 694                                                    print (distutils.sysconfig.get_python_lib(1,0));"`
 695                 fi
 696                 AC_MSG_RESULT([$PYTHON_INSTALLDIR])
 697             fi
 698
 699             old_LIBS="$LIBS"
 700             LIBS="$LIBS -lpython$PYTHON_VERSION"
 701             AC_CHECK_FUNCS([PyCapsule_New])
 702             LIBS="$old_LIBS"
 703         fi
 704
 705         AC_SUBST(PYTHON_PREFIX)
 706         AC_SUBST(PYTHON_VERSION)
 707         AC_SUBST(PYTHON_INCLUDEDIR)
 708         AC_SUBST(PYTHON_INSTALLDIR)
 709         ])
 710 AM_CONDITIONAL([HAVE_PYTHON],
 711     [test "x$PYTHON" != "xno" && test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_INSTALLDIR" != "x"])
 712
 713 dnl Check for Ruby and rake (optional, for Ruby bindings).
 714 AC_ARG_ENABLE([ruby],
 715         AS_HELP_STRING([--disable-ruby], [Disable Ruby language bindings]),
 716         [],
 717         [enable_ruby=yes])
 718 AS_IF([test "x$enable_ruby" != "xno"],
 719         [
 720         AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 721         AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 722         ])
 723 AM_CONDITIONAL([HAVE_RUBY],
 724     [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
 725
 726 dnl Check for Java.
 727 AC_ARG_WITH(java_home,
 728     [AS_HELP_STRING([--with-java-home],
 729         [specify path to JDK directory @<:@default=check@:>@])],
 730     [],
 731     [with_java_home=check])
 732
 733 if test "x$with_java_home" != "xno"; then
 734     if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
 735     then
 736         # Reject unsafe characters in $JAVA_HOME
 737         jh_lf='
 738 '
 739         case $JAVA_HOME in
 740           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 741             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 742         esac
 743         if test -d "$with_java_home"; then
 744             JAVA_HOME="$with_java_home"
 745         else
 746             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 747         fi
 748     fi
 749
 750     if test "x$JAVA_HOME" = "x"; then
 751         # Look for Java in some likely locations.
 752         for d in \
 753             /usr/lib/jvm/java \
 754             /usr/lib/jvm/java-6-openjdk
 755         do
 756             if test -d $d && test -f $d/bin/java; then
 757                 JAVA_HOME=$d
 758                 break
 759             fi
 760         done
 761     fi
 762
 763     if test "x$JAVA_HOME" != "x"; then
 764         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 765         if test ! -x "$JAVA_HOME/bin/java"; then
 766             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 767         else
 768             JAVA="$JAVA_HOME/bin/java"
 769         fi
 770         if test ! -x "$JAVA_HOME/bin/javac"; then
 771             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 772         else
 773             JAVAC="$JAVA_HOME/bin/javac"
 774         fi
 775         if test ! -x "$JAVA_HOME/bin/javah"; then
 776             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 777         else
 778             JAVAH="$JAVA_HOME/bin/javah"
 779         fi
 780         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 781             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 782         else
 783             JAVADOC="$JAVA_HOME/bin/javadoc"
 784         fi
 785         if test ! -x "$JAVA_HOME/bin/jar"; then
 786             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 787         else
 788             JAR="$JAVA_HOME/bin/jar"
 789         fi
 790         java_version=`$JAVA -version 2>&1 | grep "java version"`
 791         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 792
 793         dnl Find jni.h.
 794         AC_MSG_CHECKING([for jni.h])
 795         if test -f "$JAVA_HOME/include/jni.h"; then
 796             JNI_CFLAGS="-I$JAVA_HOME/include"
 797         else
 798             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 799                 head=`find $JAVA_HOME -name jni.h | tail -1`
 800                 dir=`dirname "$head"`
 801                 JNI_CFLAGS="-I$dir"
 802             else
 803                 AC_MSG_FAILURE([missing jni.h header file])
 804             fi
 805         fi
 806         AC_MSG_RESULT([$JNI_CFLAGS])
 807
 808         dnl Find jni_md.h.
 809         AC_MSG_CHECKING([for jni_md.h])
 810         case "$build_os" in
 811         *linux*) system="linux" ;;
 812         *SunOS*) system="solaris" ;;
 813         *cygwin*) system="win32" ;;
 814         *) system="$build_os" ;;
 815         esac
 816         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 817             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 818         else
 819             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 820                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 821                 dir=`dirname "$head"`
 822                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 823             else
 824                 AC_MSG_FAILURE([missing jni_md.h header file])
 825             fi
 826         fi
 827         AC_MSG_RESULT([$JNI_CFLAGS])
 828
 829         dnl Need extra version flag?
 830         AC_MSG_CHECKING([extra javac flags])
 831         JAVAC_FLAGS=
 832         javac_version=`$JAVAC -version 2>&1`
 833         case "$javac_version" in
 834         *Eclipse*)
 835             JAVAC_FLAGS="-source 1.5" ;;
 836         esac
 837         AC_MSG_RESULT([$JAVAC_FLAGS])
 838
 839         dnl Where to install jarfiles.
 840         dnl XXX How to make it configurable?
 841         JAR_INSTALL_DIR=\${prefix}/share/java
 842         JNI_INSTALL_DIR=\${libdir}
 843
 844         dnl JNI version.
 845         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 846         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 847         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 848         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 849     fi
 850 fi
 851
 852 AC_SUBST(JAVA_HOME)
 853 AC_SUBST(JAVA)
 854 AC_SUBST(JAVAC)
 855 AC_SUBST(JAVAH)
 856 AC_SUBST(JAVADOC)
 857 AC_SUBST(JAR)
 858 AC_SUBST(JNI_CFLAGS)
 859 AC_SUBST(JAVAC_FLAGS)
 860 AC_SUBST(JAR_INSTALL_DIR)
 861 AC_SUBST(JNI_INSTALL_DIR)
 862 AC_SUBST(JNI_VERSION_INFO)
 863
 864 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 865
 866 dnl Check for Haskell (GHC).
 867 GHC=no
 868 AC_ARG_ENABLE([haskell],
 869         AS_HELP_STRING([--disable-haskell], [Disable Haskell language bindings]),
 870         [],
 871         [enable_haskell=yes])
 872 AS_IF([test "x$enable_haskell" != "xno"],
 873         [
 874         GHC=
 875         AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 876         ])
 877 AM_CONDITIONAL([HAVE_HASKELL],
 878     [test "x$GHC" != "xno"])
 879
 880 dnl PHP
 881 PHP=no
 882 AC_ARG_ENABLE([php],
 883         AS_HELP_STRING([--disable-php], [Disable PHP language bindings]),
 884         [],
 885         [enable_php=yes])
 886 AS_IF([test "x$enable_php" != "xno"],
 887         [
 888         PHP=
 889         AC_CHECK_PROG([PHP],[php],[php],[no])
 890         AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
 891         ])
 892 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
 893
 894 dnl Erlang
 895 AC_ARG_ENABLE([erlang],
 896         AS_HELP_STRING([--disable-erlang], [Disable Erlang language bindings]),
 897         [],
 898         [enable_erlang=yes])
 899 AS_IF([test "x$enable_erlang" != "xno"],
 900         [
 901         AC_ERLANG_PATH_ERLC([no])
 902
 903         if test "x$ERLC" != "xno"; then
 904             AC_ERLANG_CHECK_LIB([erl_interface], [],
 905                                 [AC_MSG_FAILURE([Erlang erl_interface library not installed.  Use --disable-erlang to disable.])])
 906             AC_ERLANG_SUBST_LIB_DIR
 907         fi
 908         ])
 909 AM_CONDITIONAL([HAVE_ERLANG], [test "x$ERLC" != "xno"])
 910
 911 dnl Check for Perl modules needed by Perl virt tools (virt-df, etc.)
 912 AS_IF([test "x$PERL" != "xno"],
 913         [
 914         missing_perl_modules=no
 915         for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper Locale::TextDomain Win::Hivex Win::Hivex::Regedit String::ShellQuote; do
 916             AC_MSG_CHECKING([for $pm])
 917             if ! $PERL -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
 918                 AC_MSG_RESULT([no])
 919                 missing_perl_modules=yes
 920             else
 921                 AC_MSG_RESULT([yes])
 922             fi
 923         done
 924         if test "x$missing_perl_modules" = "xyes"; then
 925             AC_MSG_WARN([some Perl modules required to compile the Perl virt-* tools are missing])
 926         fi
 927         ])
 928
 929 AM_CONDITIONAL([HAVE_TOOLS],
 930     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 931
 932 dnl Library versioning.
 933 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 934 AC_SUBST(MAX_PROC_NR)
 935
 936 dnl Replace libtool with a wrapper that clobbers dependency_libs in *.la files
 937 dnl http://lists.fedoraproject.org/pipermail/devel/2010-November/146343.html
 938 LIBTOOL='bash $(top_srcdir)/libtool-kill-dependency_libs.sh $(top_builddir)/libtool'
 939 AC_SUBST([LIBTOOL])
 940
 941 dnl Produce output files.
 942 AC_CONFIG_HEADERS([config.h])
 943 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 944 AC_CONFIG_FILES([clone/virt-sysprep],
 945                 [chmod +x clone/virt-sysprep])
 946 AC_CONFIG_FILES([podwrapper.sh],
 947                 [chmod +x podwrapper.sh])
 948 AC_CONFIG_FILES([run],
 949                 [chmod +x run])
 950 AC_CONFIG_FILES([Makefile
 951                  align/Makefile
 952                  appliance/Makefile
 953                  capitests/Makefile
 954                  cat/Makefile
 955                  caution/Makefile
 956                  clone/Makefile
 957                  csharp/Makefile
 958                  daemon/Makefile
 959                  debian/changelog
 960                  df/Makefile
 961                  edit/Makefile
 962                  erlang/Makefile
 963                  erlang/examples/Makefile
 964                  examples/Makefile
 965                  fish/Makefile
 966                  fuse/Makefile
 967                  generator/Makefile
 968                  gnulib/lib/Makefile
 969                  gnulib/tests/Makefile
 970                  haskell/Makefile
 971                  images/Makefile
 972                  inspector/Makefile
 973                  java/Makefile
 974                  java/examples/Makefile
 975                  libguestfs.pc
 976                  ocaml/META
 977                  ocaml/Makefile
 978                  ocaml/examples/Makefile
 979                  perl/Makefile
 980                  perl/Makefile.PL
 981                  perl/examples/Makefile
 982                  php/Makefile
 983                  po-docs/Makefile
 984                  po-docs/ja/Makefile
 985                  po-docs/uk/Makefile
 986                  po/Makefile.in
 987                  python/Makefile
 988                  python/examples/Makefile
 989                  regressions/Makefile
 990                  rescue/Makefile
 991                  resize/Makefile
 992                  ruby/Makefile
 993                  ruby/Rakefile
 994                  ruby/examples/Makefile
 995                  sparsify/Makefile
 996                  src/Makefile
 997                  test-tool/Makefile
 998                  tools/Makefile])
 999 AC_OUTPUT
1000
1001 dnl Produce summary.
1002 echo
1003 echo
1004 echo "------------------------------------------------------------"
1005 echo "Thank you for downloading $PACKAGE_STRING"
1006 echo
1007 echo "This is how we have configured the optional components for you today:"
1008 echo
1009 echo    "Daemon .............................. $enable_daemon"
1010 echo    "Appliance ........................... $enable_appliance"
1011 echo    "QEMU ................................ $QEMU"
1012 echo -n "OCaml bindings ...................... "
1013 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1014 echo -n "Perl bindings ....................... "
1015 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1016 echo -n "Python bindings ..................... "
1017 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1018 echo -n "Ruby bindings ....................... "
1019 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1020 echo -n "Java bindings ....................... "
1021 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1022 echo -n "Haskell bindings .................... "
1023 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1024 echo -n "PHP bindings ........................ "
1025 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1026 echo -n "Erlang bindings ..................... "
1027 if test "x$HAVE_ERLANG_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1028 echo    "guestfish and C virt tools .......... yes"
1029 echo -n "Perl virt tools ..................... "
1030 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1031 echo -n "virt-resize ......................... "
1032 if test "x$HAVE_OCAML_TRUE" = "x" && test "x$HAVE_OCAML_PCRE_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1033 echo "FUSE filesystem ..................... $enable_fuse"
1034 echo
1035 echo "If any optional component is configured 'no' when you expected 'yes'"
1036 echo "then you should check the preceeding messages."
1037 echo
1038 echo "Please report bugs back to the mailing list:"
1039 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
1040 echo
1041 echo "Next you should type 'make' to build the package,"
1042 echo "then 'make check' to run the tests."
1043 echo "------------------------------------------------------------"