configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2010 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [5])
  21 m4_define([libguestfs_release], [0])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release[]libguestfs_extra)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 dnl Stable or unstable version?
  41 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  42 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  43             AC_MSG_RESULT([stable])
  44        ],[
  45             AC_MSG_RESULT([unstable])
  46             AC_MSG_NOTICE([
  47 ***
  48 This is a development version of libguestfs. Some APIs may be unstable
  49 until they appear in a stable release of libguestfs (at which point
  50 the C API and ABI is guaranteed to remain stable forever).  For
  51 more information about stable and development branches of libguestfs
  52 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  53 ***])
  54        ])
  55
  56 dnl Die if the user tries to configure as root, see:
  57 dnl https://www.redhat.com/archives/libguestfs/2010-April/msg00098.html
  58 AC_MSG_CHECKING([if you are trying to configure as root])
  59 AS_IF([test "`id -u`" = 0 ],[
  60             AC_MSG_RESULT([yes])
  61             AC_MSG_FAILURE([Don't run './configure' or 'make' as root.])
  62       ],[
  63             AC_MSG_RESULT([no])
  64       ])
  65
  66 dnl Early gnulib initialization.
  67 gl_EARLY
  68 gl_INIT
  69
  70 AC_PROG_LIBTOOL
  71
  72 dnl Check for basic C environment.
  73 AC_PROG_CC_STDC
  74 AC_PROG_INSTALL
  75 AC_PROG_CPP
  76
  77 AC_ARG_ENABLE([gcc-warnings],
  78   [AS_HELP_STRING([--enable-gcc-warnings],
  79                   [turn on lots of GCC warnings (for developers)])],
  80   [case $enableval in
  81      yes|no) ;;
  82      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  83    esac
  84    gl_gcc_warnings=$enableval],
  85   [gl_gcc_warnings=no]
  86 )
  87
  88 if test "$gl_gcc_warnings" = yes; then
  89   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  90   AC_SUBST([WERROR_CFLAGS])
  91
  92   nw=
  93   # This, $nw, is the list of warnings we disable.
  94   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  95   nw="$nw -Waggregate-return"       # anachronistic
  96   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  97   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  98   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  99   nw="$nw -Wcast-qual"              # Too many warnings for now
 100   nw="$nw -Wconversion"             # Too many warnings for now
 101   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 102   nw="$nw -Wsign-conversion"        # Too many warnings for now
 103   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 104   nw="$nw -Wunreachable-code"       # Too many warnings for now
 105   nw="$nw -Wpadded"                 # Our structs are not padded
 106   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 107   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 108   nw="$nw -Wvla"                    # two warnings in mount.c
 109   # things I might fix soon:
 110   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 111   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 112   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 113   # ?? -Wstrict-overflow
 114   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 115                                     # was not possible, safe to ignore
 116   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 117   nw="$nw -Wlong-long"              # Allow long long since it's required
 118                                     # by Python, Ruby and xstrtoll.
 119
 120   gl_MANYWARN_ALL_GCC([ws])
 121   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 122   for w in $ws; do
 123     gl_WARN_ADD([$w])
 124   done
 125   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 126   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 127   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 128
 129   # In spite of excluding -Wlogical-op above, it is enabled, as of
 130   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 131   gl_WARN_ADD([-Wno-logical-op])
 132
 133   gl_WARN_ADD([-fdiagnostics-show-option])
 134
 135   AC_SUBST([WARN_CFLAGS])
 136
 137   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 138   AC_DEFINE([_FORTIFY_SOURCE], [2],
 139     [enable compile-time and run-time bounds-checking, and some warnings])
 140   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 141 fi
 142
 143 AC_C_PROTOTYPES
 144 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 145
 146 AM_PROG_CC_C_O
 147
 148 dnl Work out how to specify the linker script to the linker.
 149 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 150 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 151     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 152 AC_SUBST(VERSION_SCRIPT_FLAGS)
 153
 154 dnl Check support for 64 bit file offsets.
 155 AC_SYS_LARGEFILE
 156
 157 dnl Check sizeof long.
 158 AC_CHECK_SIZEOF([long])
 159
 160 dnl Define a C symbol for the host CPU architecture.
 161 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 162
 163 dnl Headers.
 164 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 165
 166 dnl Functions.
 167 AC_CHECK_FUNCS([posix_fallocate])
 168
 169 dnl Build the daemon?
 170 AC_MSG_CHECKING([if we should build the daemon])
 171 AC_ARG_ENABLE([daemon],
 172         [AS_HELP_STRING([--enable-daemon],
 173           [enable building the daemon @<:@default=yes@:>@])],
 174         [],
 175         [enable_daemon=yes])
 176 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 177 AC_MSG_RESULT([$enable_daemon])
 178
 179 dnl Build the appliance?
 180 AC_MSG_CHECKING([if we should build the appliance])
 181 AC_ARG_ENABLE([appliance],
 182         [AS_HELP_STRING([--enable-appliance],
 183           [enable building the appliance @<:@default=yes@:>@])],
 184         [],
 185         [enable_appliance=yes])
 186 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 187 AC_MSG_RESULT([$enable_appliance])
 188
 189 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 190 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 191 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 192 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 193         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 194         ])
 195
 196 dnl Check for pod2man and pod2text.
 197 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 198 test "x$POD2MAN" = "xno" &&
 199      AC_MSG_ERROR([pod2man must be installed])
 200 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 201 test "x$POD2TEXT" = "xno" &&
 202      AC_MSG_ERROR([pod2text must be installed])
 203
 204 dnl Check for mkisofs.
 205 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 206         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 207 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 208
 209 dnl Check for optional xmllint.
 210 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 211 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 212
 213 dnl Check for QEMU for running binaries on this $host_cpu, fall
 214 dnl back to basic 'qemu'.  Allow the user to override it.
 215 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
 216 AC_ARG_WITH([qemu],
 217         [AS_HELP_STRING([--with-qemu],
 218           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 219         [],
 220         [with_qemu="$default_qemu"])
 221 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 222         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 223 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 224 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 225
 226 dnl Check that the chosen qemu has vmchannel support or we can
 227 dnl fallback to null vmchannel (still using SLIRP).  See the
 228 dnl discussion in the README file.
 229 if test "x$vmchannel_test" != "xno"; then
 230     AC_MSG_CHECKING([for guestfwd support in $QEMU])
 231     if $QEMU -nographic --help | grep -sq guestfwd; then
 232         AC_MSG_RESULT([yes])
 233         vmchannel_guestfwd=guestfwd
 234     else
 235         AC_MSG_RESULT([no])
 236         # Note that this test must be conditional on the previous
 237         # test failing.  This is because recent qemu will throw
 238         # up an SDL window and hang if we try to run this test.
 239         AC_MSG_CHECKING([for "-net channel" (old guestfwd) support in $QEMU])
 240         vmchannelout=`$QEMU -nographic -net channel /dev/zero 2>&1 ||:`
 241         echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
 242         if echo "$vmchannelout" | grep -sq "vmchannel wrong port number" ; then
 243             AC_MSG_RESULT([yes])
 244             vmchannel_guestfwd=net_channel
 245         else
 246             AC_MSG_RESULT([no])
 247             vmchannel_guestfwd=no
 248         fi
 249     fi
 250
 251     AC_MSG_CHECKING([for "-net user" (user mode network) support in $QEMU])
 252     if $QEMU -nographic --help | grep -sq -- "-net user"; then
 253         AC_MSG_RESULT([yes])
 254         vmchannel_net_user=yes
 255     else
 256         AC_MSG_RESULT([no])
 257         vmchannel_net_user=no
 258     fi
 259
 260     if test "x$vmchannel_net_user" = "xno" -a "x$vmchannel_guestfwd" = "xno"; then
 261         AC_MSG_FAILURE(
 262 [I did not find user mode network or vmchannel support in
 263 $QEMU.
 264
 265 Either user mode networking or vmchannel support is vital for
 266 libguestfs to operate.
 267
 268 Please read the relevant section in the README file for more
 269 information about this.
 270
 271 You can override this test by setting the environment variable
 272 vmchannel_test=no  However if you don't have the right support
 273 in your qemu, then this just delays the pain.
 274
 275 If I am using the wrong qemu or you want to compile qemu from source
 276 and install it in another location, then you should configure with
 277 the --with-qemu option.
 278 ])
 279     fi
 280 fi
 281
 282 dnl Set drive interface used by the guestfs_add_drive{,_ro} calls
 283 dnl ('-drive ...,if=...' option to qemu).
 284 dnl
 285 dnl If you encounter performance problems with virtio (RHBZ#509383)
 286 dnl then try '--with-drive-if=ide'.
 287 AC_ARG_WITH([drive-if],
 288         [AS_HELP_STRING([--with-drive-if],
 289           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 290         [],
 291         [with_drive_if=virtio])
 292 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 293
 294 dnl Set interface used by the network.  Normally you should
 295 dnl leave this at the default (virtio) but you can use the
 296 dnl alternative (ne2k_pci) because of bugs in virtio networking
 297 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 298 AC_ARG_WITH([net-if],
 299         [AS_HELP_STRING([--with-net-if],
 300           [set default net driver (virtio|ne2k_pci) @<:@default=virtio@:>@])],
 301         [],
 302         [with_net_if=virtio])
 303 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 304
 305 dnl Check for febootstrap etc.
 306 if test "x$enable_appliance" = "xyes"; then
 307     AC_CHECK_PROG([FEBOOTSTRAP],
 308                   [febootstrap],[febootstrap],[no])
 309     if test "x$FEBOOTSTRAP" != "xno"; then
 310       AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 311                     [febootstrap-run],[febootstrap-run],[no])
 312       test "x$FEBOOTSTRAP_RUN" = "xno" && \
 313           AC_MSG_ERROR([febootstrap-run must be installed])
 314       AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 315                     [febootstrap-install],[febootstrap-install],[no])
 316       test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 317           AC_MSG_ERROR([febootstrap-install must be installed])
 318       AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 319                     [febootstrap-minimize],[febootstrap-minimize],[no])
 320       test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 321           AC_MSG_ERROR([febootstrap-minimize must be installed])
 322       AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 323                     [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 324       test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 325           AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 326       AC_CHECK_PROG([FEBOOTSTRAP_TO_SUPERMIN],
 327                     [febootstrap-to-supermin],[febootstrap-to-supermin],[no])
 328       test "x$FEBOOTSTRAP_TO_SUPERMIN" = "xno" && \
 329           AC_MSG_ERROR([febootstrap-to-supermin must be installed])
 330
 331       dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 332       dnl of febootstrap, but old versions will fail with yum).
 333       AC_CHECK_PROG([FAKECHROOT],
 334                     [fakechroot],[fakechroot],[no])
 335       test "x$FAKECHROOT" = "xno" && \
 336          AC_MSG_ERROR([fakechroot must be installed])
 337
 338       AC_MSG_CHECKING([fakechroot version])
 339       fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 340       if test -z "$fakechroot_version"; then
 341         AC_MSG_RESULT([failed])
 342         AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 343       else
 344         AC_MSG_RESULT([$fakechroot_version])
 345         fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 346         fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 347         if test "$fakechroot_major" -lt 2 -o \
 348             \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
 349           AC_MSG_ERROR([fakechroot version must be >= 2.9])
 350         fi
 351       fi
 352       DIST="REDHAT"
 353     else
 354       # check for debootstrap and debirf
 355       AC_CHECK_PROG([DEBOOTSTRAP],
 356                     [debootstrap],[debootstrap],[no])
 357       test "x$DEBOOTSTRAP" = "xno" && \
 358           AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 359       AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 360       test "x$DEBIRF" = "xno" &&
 361           AC_MSG_ERROR([debirf must be installed])
 362       DIST="DEBIAN"
 363       case "$host_cpu" in
 364       *86)
 365           DEBIAN_KERNEL_ARCH=486
 366           ;;
 367       x86_64)
 368           DEBIAN_KERNEL_ARCH=amd64
 369           ;;
 370       *)
 371          DEBIAN_KERNEL_ARCH=$host_cpu
 372          ;;
 373       esac
 374       AC_SUBST(DEBIAN_KERNEL_ARCH)
 375     fi
 376     AC_SUBST(DIST)
 377
 378     dnl --with-updates to specify a Fedora updates repository.
 379     AC_ARG_WITH([updates],
 380         [AS_HELP_STRING([--with-updates],
 381           [set name of Fedora updates repository @<:@default=updates-released-f12@:>@])],
 382         [],
 383         [with_updates=updates-released-f12])
 384     UPDATES="$with_updates"
 385     AC_SUBST(UPDATES)
 386
 387     dnl --with-mirror to specify a local Fedora mirror.
 388     AC_ARG_WITH([mirror],
 389         [AS_HELP_STRING([--with-mirror],
 390           [set URI of a local Fedora mirror])],
 391         [],
 392         [with_mirror=])
 393     MIRROR="$with_mirror"
 394     AC_SUBST(MIRROR)
 395 fi
 396
 397 dnl --with-repo to specify a Fedora repository.
 398 AC_ARG_WITH([repo],
 399         [AS_HELP_STRING([--with-repo],
 400           [set name of Fedora repository @<:@default=fedora-12@:>@])],
 401         [],
 402         [with_repo=fedora-12])
 403 REPO="$with_repo"
 404 AC_SUBST(REPO)
 405 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 406
 407 dnl Build the supermin appliance?  Please see README file before
 408 dnl enabling this option.
 409 AC_ARG_ENABLE([supermin],
 410         [AS_HELP_STRING([--enable-supermin],
 411           [enable supermin appliance (see README) @<:@default=no@:>@])],
 412         [],
 413         [enable_supermin=no])
 414 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 415
 416 dnl Enable packet dumps when in verbose mode.  This generates lots
 417 dnl of debug info, only useful for people debugging the RPC mechanism.
 418 AC_ARG_ENABLE([packet-dump],
 419         [AS_HELP_STRING([--enable-packet-dump],
 420           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 421         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 422         [])
 423
 424 dnl Readline.
 425 AC_ARG_WITH([readline],
 426     [AS_HELP_STRING([--with-readline],
 427         [support fancy command line editing @<:@default=check@:>@])],
 428     [],
 429     [with_readline=check])
 430
 431 LIBREADLINE=
 432 AS_IF([test "x$with_readline" != xno],
 433     [AC_CHECK_LIB([readline], [main],
 434         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 435          AC_DEFINE([HAVE_LIBREADLINE], [1],
 436                    [Define if you have libreadline])
 437         ],
 438         [if test "x$with_readline" != xcheck; then
 439          AC_MSG_FAILURE(
 440              [--with-readline was given, but test for readline failed])
 441          fi
 442         ], -lncurses)
 443      old_LIBS="$LIBS"
 444      LIBS="$LIBS $LIBREADLINE"
 445      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 446      LIBS="$old_LIBS"
 447     ])
 448
 449 dnl For i18n.
 450 AM_GNU_GETTEXT([external])
 451 AM_GNU_GETTEXT_VERSION([0.17])
 452
 453 dnl hivex library (highly recommended).
 454 dnl This used to be a part of libguestfs, but was spun off into its
 455 dnl own separate upstream project in libguestfs 1.0.85.
 456 HAVE_HIVEX=yes
 457 PKG_CHECK_MODULES([HIVEX], [hivex],,[
 458         HAVE_HIVEX=no
 459         AC_MSG_WARN([Hivex library and headers are missing, so optional Windows Registry tools won't be built])])
 460 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HAVE_HIVEX" = "xyes"])
 461 AC_SUBST([HIVEX_CFLAGS])
 462 AC_SUBST([HIVEX_LIBS])
 463
 464 dnl FUSE is optional to build the FUSE module.
 465 HAVE_FUSE=yes
 466 PKG_CHECK_MODULES([FUSE],[fuse],,[
 467         HAVE_FUSE=no
 468         AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])
 469 AM_CONDITIONAL([HAVE_FUSE],[test "x$HAVE_FUSE" = "xyes"])
 470
 471 dnl Check for OCaml (optional, for OCaml bindings).
 472 AC_PROG_OCAML
 473 AC_PROG_FINDLIB
 474 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
 475
 476 dnl Optional xml-light for running the generator.
 477 OCAML_PKG_xml_light=no
 478 if test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"; then
 479     AC_CHECK_OCAML_PKG([xml-light])
 480 fi
 481 AM_CONDITIONAL([HAVE_XML_LIGHT],[test "x$OCAML_PKG_xml_light" != "xno"])
 482
 483 dnl Build the OCaml viewer example.  This has a lengthy list of
 484 dnl dependencies and we don't attempt to detect them all.  Read
 485 dnl the top of ocaml/examples/viewer.ml before enabling this.
 486 AC_ARG_ENABLE([ocaml-viewer],
 487         [AS_HELP_STRING([--enable-ocaml-viewer],
 488           [enable OCaml viewer (see ocaml/examples) @<:@default=no@:>@])],
 489         [],
 490         [enable_ocaml_viewer=no])
 491 AM_CONDITIONAL([BUILD_OCAML_VIEWER],[test "x$enable_ocaml_viewer" = "xyes"])
 492
 493 dnl Check for Perl (optional, for Perl bindings).
 494 dnl XXX This isn't quite right, we should check for Perl devel library.
 495 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 496
 497 dnl Check for Perl modules that must be present to compile and
 498 dnl test the Perl bindings.
 499 missing_perl_modules=no
 500 for pm in Test::More ExtUtils::MakeMaker; do
 501     AC_MSG_CHECKING([for $pm])
 502     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 503         AC_MSG_RESULT([no])
 504         missing_perl_modules=yes
 505     else
 506         AC_MSG_RESULT([yes])
 507     fi
 508 done
 509 if test "x$missing_perl_modules" = "xyes"; then
 510     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 511 fi
 512
 513 AM_CONDITIONAL([HAVE_PERL],
 514     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 515
 516 dnl Check for Python (optional, for Python bindings).
 517 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 518
 519 PYTHON_PREFIX=
 520 PYTHON_VERSION=
 521 PYTHON_INCLUDEDIR=
 522 PYTHON_SITE_PACKAGES=
 523
 524 if test "x$PYTHON" != "xno"; then
 525     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 526     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 527     for d in \
 528         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 529         /usr/include/python$PYTHON_VERSION \
 530         /usr/local/include/python$PYTHON_VERSION
 531     do
 532         AC_MSG_CHECKING([Python.h in $d])
 533         if test -r "$d/Python.h"; then
 534             AC_MSG_RESULT([found])
 535             PYTHON_INCLUDEDIR=$d
 536             break
 537         fi
 538         AC_MSG_RESULT([not found])
 539     done
 540     for d in \
 541         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 542         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 543         /usr/lib64/python$PYTHON_VERSION/site-packages \
 544         /usr/lib/python$PYTHON_VERSION/site-packages \
 545         /usr/local/lib/python$PYTHON_VERSION/site-packages
 546     do
 547         AC_MSG_CHECKING([for $d])
 548         if test -d "$d"; then
 549             AC_MSG_RESULT([found])
 550             PYTHON_SITE_PACKAGES=$d
 551             break
 552         fi
 553         AC_MSG_RESULT([not found])
 554     done
 555 fi
 556
 557 AC_SUBST(PYTHON_PREFIX)
 558 AC_SUBST(PYTHON_VERSION)
 559 AC_SUBST(PYTHON_INCLUDEDIR)
 560 AC_SUBST(PYTHON_SITE_PACKAGES)
 561
 562 AM_CONDITIONAL([HAVE_PYTHON],
 563     [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
 564
 565 dnl Check for Ruby and rake (optional, for Ruby bindings).
 566 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 567 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 568
 569 AM_CONDITIONAL([HAVE_RUBY],
 570     [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
 571
 572 dnl Check for Java.
 573 AC_ARG_WITH(java_home,
 574     [AS_HELP_STRING([--with-java-home],
 575         [specify path to JDK directory @<:@default=check@:>@])],
 576     [],
 577     [with_java_home=check])
 578
 579 if test "x$with_java_home" != "xno"; then
 580     if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
 581     then
 582         # Reject unsafe characters in $JAVA_HOME
 583         jh_lf='
 584 '
 585         case $JAVA_HOME in
 586           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 587             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 588         esac
 589         if test -d "$with_java_home"; then
 590             JAVA_HOME="$with_java_home"
 591         else
 592             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 593         fi
 594     fi
 595
 596     if test "x$JAVA_HOME" = "x"; then
 597         # Look for Java in some likely locations.
 598         for d in \
 599             /usr/lib/jvm/java \
 600             /usr/lib/jvm/java-6-openjdk
 601         do
 602             if test -d $d -a -f $d/bin/java; then
 603                 JAVA_HOME=$d
 604                 break
 605             fi
 606         done
 607     fi
 608
 609     if test "x$JAVA_HOME" != "x"; then
 610         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 611         if test ! -x "$JAVA_HOME/bin/java"; then
 612             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 613         else
 614             JAVA="$JAVA_HOME/bin/java"
 615         fi
 616         if test ! -x "$JAVA_HOME/bin/javac"; then
 617             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 618         else
 619             JAVAC="$JAVA_HOME/bin/javac"
 620         fi
 621         if test ! -x "$JAVA_HOME/bin/javah"; then
 622             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 623         else
 624             JAVAH="$JAVA_HOME/bin/javah"
 625         fi
 626         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 627             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 628         else
 629             JAVADOC="$JAVA_HOME/bin/javadoc"
 630         fi
 631         if test ! -x "$JAVA_HOME/bin/jar"; then
 632             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 633         else
 634             JAR="$JAVA_HOME/bin/jar"
 635         fi
 636         java_version=`$JAVA -version 2>&1 | grep "java version"`
 637         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 638
 639         dnl Find jni.h.
 640         AC_MSG_CHECKING([for jni.h])
 641         if test -f "$JAVA_HOME/include/jni.h"; then
 642             JNI_CFLAGS="-I$JAVA_HOME/include"
 643         else
 644             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 645                 head=`find $JAVA_HOME -name jni.h | tail -1`
 646                 dir=`dirname "$head"`
 647                 JNI_CFLAGS="-I$dir"
 648             else
 649                 AC_MSG_FAILURE([missing jni.h header file])
 650             fi
 651         fi
 652         AC_MSG_RESULT([$JNI_CFLAGS])
 653
 654         dnl Find jni_md.h.
 655         AC_MSG_CHECKING([for jni_md.h])
 656         case "$build_os" in
 657         *linux*) system="linux" ;;
 658         *SunOS*) system="solaris" ;;
 659         *cygwin*) system="win32" ;;
 660         *) system="$build_os" ;;
 661         esac
 662         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 663             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 664         else
 665             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 666                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 667                 dir=`dirname "$head"`
 668                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 669             else
 670                 AC_MSG_FAILURE([missing jni_md.h header file])
 671             fi
 672         fi
 673         AC_MSG_RESULT([$JNI_CFLAGS])
 674
 675         dnl Need extra version flag?
 676         AC_MSG_CHECKING([extra javac flags])
 677         JAVAC_FLAGS=
 678         javac_version=`$JAVAC -version 2>&1`
 679         case "$javac_version" in
 680         *Eclipse*)
 681             JAVAC_FLAGS="-source 1.5" ;;
 682         esac
 683         AC_MSG_RESULT([$JAVAC_FLAGS])
 684
 685         dnl Where to install jarfiles.
 686         dnl XXX How to make it configurable?
 687         JAR_INSTALL_DIR=\${prefix}/share/java
 688         JNI_INSTALL_DIR=\${libdir}
 689
 690         dnl JNI version.
 691         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 692         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 693         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 694         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 695     fi
 696 fi
 697
 698 AC_SUBST(JAVA_HOME)
 699 AC_SUBST(JAVA)
 700 AC_SUBST(JAVAC)
 701 AC_SUBST(JAVAH)
 702 AC_SUBST(JAVADOC)
 703 AC_SUBST(JAR)
 704 AC_SUBST(JNI_CFLAGS)
 705 AC_SUBST(JAVAC_FLAGS)
 706 AC_SUBST(JAR_INSTALL_DIR)
 707 AC_SUBST(JNI_INSTALL_DIR)
 708 AC_SUBST(JNI_VERSION_INFO)
 709
 710 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 711
 712 dnl Check for Haskell (GHC).
 713 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 714
 715 AM_CONDITIONAL([HAVE_HASKELL],
 716     [test "x$GHC" != "xno"])
 717
 718 dnl Check for Perl modules needed by virt-df, inspector, etc.
 719 missing_perl_modules=no
 720 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer Locale::TextDomain Win::Hivex Win::Hivex::Regedit; do
 721     AC_MSG_CHECKING([for $pm])
 722     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 723         AC_MSG_RESULT([no])
 724         missing_perl_modules=yes
 725     else
 726         AC_MSG_RESULT([yes])
 727     fi
 728 done
 729 if test "x$missing_perl_modules" = "xyes"; then
 730     AC_MSG_WARN([some Perl modules required to compile virt-inspector and the other virt-* tools are missing])
 731 fi
 732
 733 AM_CONDITIONAL([HAVE_INSPECTOR],
 734     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 735 AM_CONDITIONAL([HAVE_TOOLS],
 736     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 737
 738 dnl Library versioning.
 739 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 740 AC_SUBST(MAX_PROC_NR)
 741
 742 dnl Run in subdirs.
 743 if test "x$enable_daemon" = "xyes"; then
 744     AC_CONFIG_SUBDIRS([daemon])
 745 fi
 746
 747 dnl Produce output files.
 748 AC_CONFIG_HEADERS([config.h])
 749 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 750 AC_CONFIG_FILES([appliance/update.sh],
 751                 [chmod +x appliance/update.sh])
 752 AC_CONFIG_FILES([Makefile
 753                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 754                  appliance/Makefile
 755                  appliance/debian/debirf.conf
 756                  images/Makefile
 757                  capitests/Makefile
 758                  regressions/Makefile
 759                  test-tool/Makefile
 760                  ocaml/Makefile ocaml/examples/Makefile
 761                  perl/Makefile
 762                  python/Makefile
 763                  ruby/Makefile ruby/Rakefile
 764                  java/Makefile
 765                  haskell/Makefile
 766                  inspector/Makefile
 767                  tools/Makefile
 768                  libguestfs.pc
 769                  gnulib/lib/Makefile
 770                  gnulib/tests/Makefile
 771                  fuse/Makefile
 772                  ocaml/META perl/Makefile.PL])
 773 AC_OUTPUT
 774
 775 dnl Produce summary.
 776 echo
 777 echo
 778 echo "------------------------------------------------------------"
 779 echo "Thank you for downloading $PACKAGE_STRING"
 780 echo
 781 echo "This is how we have configured the optional components for you today:"
 782 echo
 783 echo    "Daemon .............................. $enable_daemon"
 784 echo    "Appliance ........................... $enable_appliance"
 785 echo    "QEMU ................................ $QEMU"
 786 echo -n "OCaml bindings ...................... "
 787 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 788 echo -n "Perl bindings ....................... "
 789 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 790 echo -n "Python bindings ..................... "
 791 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 792 echo -n "Ruby bindings ....................... "
 793 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 794 echo -n "Java bindings ....................... "
 795 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 796 echo -n "Haskell bindings .................... "
 797 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 798 echo -n "virt-inspector ...................... "
 799 if test "x$HAVE_INSPECTOR_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 800 echo -n "virt-* tools ........................ "
 801 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 802 echo "supermin appliance .................. $enable_supermin"
 803 echo "FUSE filesystem ..................... $HAVE_FUSE"
 804 echo
 805 echo "If any optional component is configured 'no' when you expected 'yes'"
 806 echo "then you should check the preceeding messages."
 807 echo
 808 echo "Please report bugs back to the mailing list:"
 809 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 810 echo
 811 echo "Next you should type 'make' to build the package,"
 812 echo "then 'make check' to run the tests."
 813 echo "------------------------------------------------------------"