configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 AC_INIT([libguestfs],[1.0.55])
  19 AM_INIT_AUTOMAKE([foreign])
  20
  21 AC_CONFIG_MACRO_DIR([m4])
  22
  23 AC_PROG_LIBTOOL
  24
  25 dnl Check for basic C environment.
  26 AC_PROG_CC_STDC
  27 AC_PROG_INSTALL
  28 AC_PROG_CPP
  29
  30 AC_C_PROTOTYPES
  31 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
  32
  33 AM_PROG_CC_C_O
  34
  35 dnl Check support for 64 bit file offsets.
  36 AC_SYS_LARGEFILE
  37
  38 dnl Check sizeof long.
  39 AC_CHECK_SIZEOF([long])
  40
  41 dnl Headers.
  42 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h])
  43
  44 dnl Check for rpcgen and XDR library.  rpcgen is optional.
  45 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
  46 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
  47 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
  48         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
  49         ])
  50
  51 dnl Check for pod2man and pod2text.
  52 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
  53 test "x$POD2MAN" = "xno" &&
  54      AC_MSG_ERROR([pod2man must be installed])
  55 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
  56 test "x$POD2TEXT" = "xno" &&
  57      AC_MSG_ERROR([pod2text must be installed])
  58
  59 dnl Check for mksquashfs.
  60 AC_PATH_PROGS([MKSQUASHFS],[mksquashfs],[no],
  61         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
  62 test "x$MKSQUASHFS" = "xno" && AC_MSG_ERROR([mksquashfs must be installed])
  63
  64 dnl Check for QEMU for running binaries on this $host_cpu, fall
  65 dnl back to basic 'qemu'.  Allow the user to override it.
  66 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
  67 AC_ARG_WITH([qemu],
  68         [AS_HELP_STRING([--with-qemu],
  69           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
  70         [],
  71         [with_qemu="$default_qemu"])
  72 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
  73         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
  74 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
  75 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
  76
  77 dnl Check that the chosen qemu has vmchannel support.
  78 dnl http://lists.gnu.org/archive/html/qemu-devel/2009-02/msg01042.html
  79 if test "x$vmchannel_test" != "xno"; then
  80     AC_MSG_CHECKING([for vmchannel support in $QEMU])
  81     vmchannelout=`$QEMU -net channel /dev/zero 2>&1 ||:`
  82     echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
  83     if ! echo $vmchannelout | grep -sq "vmchannel wrong port number" ; then
  84         AC_MSG_RESULT([no])
  85         AC_MSG_FAILURE(
  86 [I did not find vmchannel support in $QEMU.
  87
  88 vmchannel support is vital for libguestfs to operate.  You need a version
  89 of qemu >= 0.10, or the following patch backported to earlier versions:
  90
  91 http://lists.gnu.org/archive/html/qemu-devel/2009-02/msg01042.html
  92
  93 You can override this test by setting the environment variable
  94 vmchannel_test=no  However if you don't have vmchannel support
  95 in your qemu, then this just delays the pain.
  96
  97 If I am using the wrong qemu or you want to compile qemu from source
  98 and install it in another location, then you should configure with
  99 the --with-qemu option.
 100 ])
 101     fi
 102     AC_MSG_RESULT([yes])
 103 fi
 104
 105 dnl Set drive interface used by the guestfs_add_drive{,_ro} calls
 106 dnl ('-drive ...,if=...' option to qemu).
 107 dnl
 108 dnl NB. We will change the default in future to virtio, but at the
 109 dnl moment this causes a performance problem, RHBZ#509383.
 110 AC_ARG_WITH([drive-if],
 111         [AS_HELP_STRING([--with-drive-if],
 112           [set default driver (ide|scsi|virtio) @<:@default=ide@:>@])],
 113         [],
 114         [with_drive_if=ide])
 115 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 116
 117 dnl Check for febootstrap etc.
 118 AC_CHECK_PROG([FEBOOTSTRAP],
 119         [febootstrap],[febootstrap],[no])
 120 if test "x$FEBOOTSTRAP" != "xno"; then
 121   AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 122         [febootstrap-run],[febootstrap-run],[no])
 123   test "x$FEBOOTSTRAP_RUN" = "xno" && \
 124      AC_MSG_ERROR([febootstrap-run must be installed])
 125   AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 126         [febootstrap-install],[febootstrap-install],[no])
 127   test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 128      AC_MSG_ERROR([febootstrap-install must be installed])
 129   AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 130         [febootstrap-minimize],[febootstrap-minimize],[no])
 131   test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 132      AC_MSG_ERROR([febootstrap-minimize must be installed])
 133   AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 134         [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 135   test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 136      AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 137
 138   dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 139   dnl of febootstrap, but old versions will fail with yum).
 140   AC_CHECK_PROG([FAKECHROOT],
 141         [fakechroot],[fakechroot],[no])
 142   test "x$FAKECHROOT" = "xno" && \
 143     AC_MSG_ERROR([fakechroot must be installed])
 144
 145   AC_MSG_CHECKING([fakechroot version])
 146   fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 147   if test -z "$fakechroot_version"; then
 148     AC_MSG_RESULT([failed])
 149     AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 150   else
 151     AC_MSG_RESULT([$fakechroot_version])
 152     fakechroot_major=`echo $fakechroot_version | awk -F. '{print $1}'`
 153     fakechroot_minor=`echo $fakechroot_version | awk -F. '{print $2}'`
 154     if test "$fakechroot_major" -lt 2 -o \
 155             \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
 156         AC_MSG_ERROR([fakechroot version must be >= 2.9])
 157     fi
 158   fi
 159   DIST="REDHAT"
 160 else
 161   # check for debootstrap and debirf
 162   AC_CHECK_PROG([DEBOOTSTRAP],
 163         [debootstrap],[debootstrap],[no])
 164   test "x$DEBOOTSTRAP" = "xno" && \
 165         AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 166   AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 167   test "x$DEBIRF" = "xno" &&
 168         AC_MSG_ERROR([debirf must be installed])
 169   DIST="DEBIAN"
 170   case $host_cpu in
 171       *86)
 172           DEBIAN_KERNEL_ARCH=486
 173           ;;
 174       x86_64)
 175           DEBIAN_KERNEL_ARCH=amd64
 176           ;;
 177       *)
 178          DEBIAN_KERNEL_ARCH=$host_cpu
 179          ;;
 180    esac
 181    AC_SUBST(DEBIAN_KERNEL_ARCH)
 182 fi
 183 AC_SUBST(DIST)
 184
 185
 186 dnl --with-repo to specify a Fedora repository.
 187 AC_ARG_WITH([repo],
 188         [AS_HELP_STRING([--with-repo],
 189           [set name of Fedora repository @<:@default=fedora-11@:>@])],
 190         [],
 191         [with_repo=fedora-11])
 192 REPO="$with_repo"
 193 AC_SUBST(REPO)
 194 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 195
 196 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 197
 198 dnl --with-updates to specify a Fedora updates repository.
 199 AC_ARG_WITH([updates],
 200         [AS_HELP_STRING([--with-updates],
 201           [set name of Fedora updates repository @<:@default=updates-released-f11@:>@])],
 202         [],
 203         [with_updates=updates-released-f11])
 204 UPDATES="$with_updates"
 205 AC_SUBST(UPDATES)
 206 AC_DEFINE_UNQUOTED([UPDATES],["$UPDATES"],[Name of Fedora updates repository.])
 207
 208 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 209
 210 dnl --with-mirror to specify a local Fedora mirror.
 211 AC_ARG_WITH([mirror],
 212         [AS_HELP_STRING([--with-mirror],
 213           [set URI of a local Fedora mirror])],
 214         [],
 215         [with_mirror=])
 216 MIRROR="$with_mirror"
 217 AC_SUBST(MIRROR)
 218
 219 dnl Build the supermin appliance?  Please see README file before
 220 dnl enabling this option.
 221 AC_ARG_ENABLE([supermin],
 222         [AS_HELP_STRING([--enable-supermin],
 223           [enable supermin appliance (see README) @<:@default=no@:>@])],
 224         [],
 225         [enable_supermin=no])
 226 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 227
 228 if test "x$enable_supermin" = "xyes"; then
 229     dnl Check febootstrap-to-initramfs accepts the --files option
 230     dnl (febootstrap >= 2.2).
 231     AC_MSG_CHECKING([for --files support in $FEBOOTSTRAP_TO_INITRAMFS])
 232     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 233     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 234     if ! echo $out | grep -sq -- "--files" ; then
 235         AC_MSG_RESULT([no])
 236         AC_MSG_FAILURE(
 237 [febootstrap-to-initramfs does not support the --files option.
 238
 239 To build the supermin appliance, you need to upgrade to the latest
 240 version of febootstrap.
 241 ])
 242     fi
 243     AC_MSG_RESULT([yes])
 244
 245     dnl Check febootstrap-to-initramfs accepts the --nocompress option
 246     dnl (febootstrap >= 2.3).
 247     AC_MSG_CHECKING([for --nocompress support in $FEBOOTSTRAP_TO_INITRAMFS])
 248     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 249     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 250     if ! echo $out | grep -sq -- "--nocompress" ; then
 251         AC_MSG_RESULT([no])
 252         AC_MSG_FAILURE(
 253 [febootstrap-to-initramfs does not support the --nocompress option.
 254
 255 To build the supermin appliance, you need to upgrade to the latest
 256 version of febootstrap.
 257 ])
 258     fi
 259     AC_MSG_RESULT([yes])
 260 fi
 261
 262 dnl Readline.
 263 AC_ARG_WITH([readline],
 264     [AS_HELP_STRING([--with-readline],
 265         [support fancy command line editing @<:@default=check@:>@])],
 266     [],
 267     [with_readline=check])
 268
 269 LIBREADLINE=
 270 AS_IF([test "x$with_readline" != xno],
 271     [AC_CHECK_LIB([readline], [main],
 272         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 273          AC_DEFINE([HAVE_LIBREADLINE], [1],
 274                    [Define if you have libreadline])
 275         ],
 276         [if test "x$with_readline" != xcheck; then
 277          AC_MSG_FAILURE(
 278              [--with-readline was given, but test for readline failed])
 279          fi
 280         ], -lncurses)])
 281
 282 dnl For i18n.
 283 AM_GNU_GETTEXT([external])
 284 AM_GNU_GETTEXT_VERSION([0.14])
 285
 286 dnl Check for OCaml (optional, for OCaml bindings).
 287 AC_PROG_OCAML
 288 AC_PROG_FINDLIB
 289 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
 290
 291 dnl Check for Perl (optional, for Perl bindings).
 292 dnl XXX This isn't quite right, we should check for Perl devel library.
 293 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 294
 295 dnl Check for Perl modules that must be present to compile and
 296 dnl test the Perl bindings.
 297 missing_perl_modules=no
 298 for pm in Test::More Test::Pod Test::Pod::Coverage ExtUtils::MakeMaker; do
 299     AC_MSG_CHECKING([for $pm])
 300     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 301         AC_MSG_RESULT([no])
 302         missing_perl_modules=yes
 303     else
 304         AC_MSG_RESULT([yes])
 305     fi
 306 done
 307 if test "x$missing_perl_modules" = "xyes"; then
 308     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 309 fi
 310
 311 AM_CONDITIONAL([HAVE_PERL],
 312     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 313
 314 dnl Check for Python (optional, for Python bindings).
 315 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 316
 317 PYTHON_PREFIX=
 318 PYTHON_VERSION=
 319 PYTHON_INCLUDEDIR=
 320 PYTHON_SITE_PACKAGES=
 321
 322 if test "x$PYTHON" != "xno"; then
 323     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 324     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 325     for d in \
 326         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 327         /usr/include/python$PYTHON_VERSION \
 328         /usr/local/include/python$PYTHON_VERSION
 329     do
 330         AC_MSG_CHECKING([Python.h in $d])
 331         if test -r "$d/Python.h"; then
 332             AC_MSG_RESULT([found])
 333             PYTHON_INCLUDEDIR=$d
 334             break
 335         fi
 336         AC_MSG_RESULT([not found])
 337     done
 338     for d in \
 339         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 340         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 341         /usr/lib64/python$PYTHON_VERSION/site-packages \
 342         /usr/lib/python$PYTHON_VERSION/site-packages \
 343         /usr/local/lib/python$PYTHON_VERSION/site-packages
 344     do
 345         AC_MSG_CHECKING([for $d])
 346         if test -d "$d"; then
 347             AC_MSG_RESULT([found])
 348             PYTHON_SITE_PACKAGES=$d
 349             break
 350         fi
 351         AC_MSG_RESULT([not found])
 352     done
 353 fi
 354
 355 AC_SUBST(PYTHON_PREFIX)
 356 AC_SUBST(PYTHON_VERSION)
 357 AC_SUBST(PYTHON_INCLUDEDIR)
 358 AC_SUBST(PYTHON_SITE_PACKAGES)
 359
 360 AM_CONDITIONAL([HAVE_PYTHON],
 361     [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
 362
 363 dnl Check for Ruby and rake (optional, for Ruby bindings).
 364 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 365 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 366
 367 AM_CONDITIONAL([HAVE_RUBY],
 368     [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
 369
 370 dnl Check for Java.
 371 AC_ARG_WITH(java_home,
 372     [AS_HELP_STRING([--with-java-home],
 373         [specify path to JDK directory @<:@default=check@:>@])],
 374     [],
 375     [with_java_home=check])
 376
 377 if test "x$with_java_home" != "xno"; then
 378     if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
 379     then
 380         if test -d "$with_java_home"; then
 381             JAVA_HOME="$with_java_home"
 382         else
 383             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 384         fi
 385     fi
 386
 387     if test "x$JAVA_HOME" = "x"; then
 388         # Look for Java in some likely locations.
 389         for d in \
 390             /usr/lib/jvm/java \
 391             /usr/lib/jvm/java-6-openjdk
 392         do
 393             if test -d $d -a -f $d/bin/java; then
 394                 JAVA_HOME=$d
 395                 break
 396             fi
 397         done
 398     fi
 399
 400     if test "x$JAVA_HOME" != "x"; then
 401         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 402         if test ! -x "$JAVA_HOME/bin/java"; then
 403             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 404         else
 405             JAVA="$JAVA_HOME/bin/java"
 406         fi
 407         if test ! -x "$JAVA_HOME/bin/javac"; then
 408             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 409         else
 410             JAVAC="$JAVA_HOME/bin/javac"
 411         fi
 412         if test ! -x "$JAVA_HOME/bin/javah"; then
 413             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 414         else
 415             JAVAH="$JAVA_HOME/bin/javah"
 416         fi
 417         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 418             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 419         else
 420             JAVADOC="$JAVA_HOME/bin/javadoc"
 421         fi
 422         if test ! -x "$JAVA_HOME/bin/jar"; then
 423             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 424         else
 425             JAR="$JAVA_HOME/bin/jar"
 426         fi
 427         java_version=`$JAVA -version 2>&1 | grep "java version"`
 428         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 429
 430         dnl Find jni.h.
 431         AC_MSG_CHECKING([for jni.h])
 432         if test -f "$JAVA_HOME/include/jni.h"; then
 433             JNI_CFLAGS="-I$JAVA_HOME/include"
 434         else
 435             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 436                 head=`find $JAVA_HOME -name jni.h | tail -1`
 437                 dir=`dirname $head`
 438                 JNI_CFLAGS="-I$dir"
 439             else
 440                 AC_MSG_FAILURE([missing jni.h header file])
 441             fi
 442         fi
 443         AC_MSG_RESULT([$JNI_CFLAGS])
 444
 445         dnl Find jni_md.h.
 446         AC_MSG_CHECKING([for jni_md.h])
 447         case "$build_os" in
 448         *linux*) system="linux" ;;
 449         *SunOS*) system="solaris" ;;
 450         *cygwin*) system="win32" ;;
 451         *) system="$build_os" ;;
 452         esac
 453         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 454             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 455         else
 456             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 457                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 458                 dir=`dirname $head`
 459                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 460             else
 461                 AC_MSG_FAILURE([missing jni_md.h header file])
 462             fi
 463         fi
 464         AC_MSG_RESULT([$JNI_CFLAGS])
 465
 466         dnl Need extra version flag?
 467         AC_MSG_CHECKING([extra javac flags])
 468         JAVAC_FLAGS=
 469         javac_version=`$JAVAC -version 2>&1`
 470         case "$javac_version" in
 471         *Eclipse*)
 472             JAVAC_FLAGS="-source 1.5" ;;
 473         esac
 474         AC_MSG_RESULT([$JAVAC_FLAGS])
 475
 476         dnl Where to install jarfiles.
 477         dnl XXX How to make it configurable?
 478         JAR_INSTALL_DIR=\${prefix}/share/java
 479         JNI_INSTALL_DIR=\${libdir}
 480
 481         dnl JNI version.
 482         jni_major_version=`echo $VERSION | awk -F. '{print $1}'`
 483         jni_minor_version=`echo $VERSION | awk -F. '{print $2}'`
 484         jni_micro_version=`echo $VERSION | awk -F. '{print $3}'`
 485         JNI_VERSION_INFO=`expr $jni_major_version + $jni_minor_version`:$jni_micro_version:$jni_minor_version
 486     fi
 487 fi
 488
 489 AC_SUBST(JAVA_HOME)
 490 AC_SUBST(JAVA)
 491 AC_SUBST(JAVAC)
 492 AC_SUBST(JAVAH)
 493 AC_SUBST(JAVADOC)
 494 AC_SUBST(JAR)
 495 AC_SUBST(JNI_CFLAGS)
 496 AC_SUBST(JAVAC_FLAGS)
 497 AC_SUBST(JAR_INSTALL_DIR)
 498 AC_SUBST(JNI_INSTALL_DIR)
 499 AC_SUBST(JNI_VERSION_INFO)
 500
 501 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 502
 503 dnl Check for Haskell (GHC).
 504 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 505
 506 AM_CONDITIONAL([HAVE_HASKELL],
 507     [test "x$GHC" != "xno"])
 508
 509 dnl Check for Perl modules needed by the inspector.
 510 missing_perl_modules=no
 511 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer; do
 512     AC_MSG_CHECKING([for $pm])
 513     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 514         AC_MSG_RESULT([no])
 515         missing_perl_modules=yes
 516     else
 517         AC_MSG_RESULT([yes])
 518     fi
 519 done
 520 if test "x$missing_perl_modules" = "xyes"; then
 521     AC_MSG_WARN([some Perl modules required to compile virt-inspector are missing])
 522 fi
 523
 524 AM_CONDITIONAL([HAVE_INSPECTOR],
 525     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 526
 527 dnl Library versioning.
 528 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 529 AC_SUBST(MAX_PROC_NR)
 530
 531 dnl Run in subdirs.
 532 AC_CONFIG_SUBDIRS([daemon])
 533
 534 dnl Produce output files.
 535 AC_CONFIG_HEADERS([config.h])
 536 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 537 AC_CONFIG_FILES([appliance/make.sh],
 538                 [chmod +x appliance/make.sh])
 539 AC_CONFIG_FILES([appliance/update.sh],
 540                 [chmod +x appliance/update.sh])
 541 AC_CONFIG_FILES([appliance/supermin-split.sh],
 542                 [chmod +x appliance/supermin-split.sh])
 543 AC_CONFIG_FILES([appliance/supermin-make.sh],
 544                 [chmod +x appliance/supermin-make.sh])
 545 AC_CONFIG_FILES([appliance/libguestfs-supermin-helper],
 546                 [chmod +x appliance/libguestfs-supermin-helper])
 547 AC_CONFIG_FILES([Makefile
 548                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 549                  appliance/Makefile
 550                  appliance/debian/debirf.conf
 551                  images/Makefile
 552                  capitests/Makefile
 553                  regressions/Makefile
 554                  ocaml/Makefile ocaml/examples/Makefile
 555                  perl/Makefile
 556                  python/Makefile
 557                  ruby/Makefile ruby/Rakefile
 558                  java/Makefile
 559                  haskell/Makefile
 560                  inspector/Makefile
 561                  libguestfs.pc
 562                  ocaml/META perl/Makefile.PL])
 563 AC_OUTPUT
 564
 565 dnl Produce summary.
 566 echo
 567 echo
 568 echo "------------------------------------------------------------"
 569 echo "Thank you for downloading $PACKAGE_STRING"
 570 echo
 571 echo "This is how we have configured the optional components for you today:"
 572 echo
 573 echo    "QEMU ................................ $QEMU"
 574 echo -n "OCaml bindings ...................... "
 575 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 576 echo -n "Perl bindings ....................... "
 577 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 578 echo -n "Python bindings ..................... "
 579 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 580 echo -n "Ruby bindings ....................... "
 581 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 582 echo -n "Java bindings ....................... "
 583 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 584 echo -n "Haskell bindings .................... "
 585 if test "x$HAVE_HASKELL" = "x"; then echo "yes"; else echo "no"; fi
 586 echo -n "virt-inspector ...................... "
 587 if test "x$HAVE_INSPECTOR" = "x"; then echo "yes"; else echo "no"; fi
 588 echo "supermin appliance .................. $enable_supermin"
 589 echo
 590 echo "If any optional component is configured 'no' when you expected 'yes'"
 591 echo "then you should check the preceeding messages."
 592 echo
 593 echo "Please report bugs back to the fedora-virt mailing list:"
 594 echo "http://www.redhat.com/mailman/listinfo/fedora-virt"
 595 echo
 596 echo "Next you should type 'make' to build the package,"
 597 echo "then 'make check' to run the tests."
 598 echo "------------------------------------------------------------"