configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2011 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [9])
  21 m4_define([libguestfs_release], [12])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 dnl Stable or unstable version?
  41 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  42 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  43             AC_MSG_RESULT([stable])
  44        ],[
  45             AC_MSG_RESULT([unstable])
  46             AC_MSG_NOTICE([
  47 ***
  48 This is a development version of libguestfs. Some APIs may be unstable
  49 until they appear in a stable release of libguestfs (at which point
  50 the C API and ABI is guaranteed to remain stable forever).  For
  51 more information about stable and development branches of libguestfs
  52 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  53 ***])
  54        ])
  55
  56 dnl Early gnulib initialization.
  57 gl_EARLY
  58 gl_INIT
  59
  60 AC_PROG_LIBTOOL
  61
  62 dnl Check for basic C environment.
  63 AC_PROG_CC_STDC
  64 AC_PROG_INSTALL
  65 AC_PROG_CPP
  66
  67 AC_ARG_ENABLE([gcc-warnings],
  68   [AS_HELP_STRING([--enable-gcc-warnings],
  69                   [turn on lots of GCC warnings (for developers)])],
  70   [case $enableval in
  71      yes|no) ;;
  72      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  73    esac
  74    gl_gcc_warnings=$enableval],
  75   [gl_gcc_warnings=no]
  76 )
  77
  78 if test "$gl_gcc_warnings" = yes; then
  79   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  80   AC_SUBST([WERROR_CFLAGS])
  81
  82   nw=
  83   # This, $nw, is the list of warnings we disable.
  84   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  85   nw="$nw -Waggregate-return"       # anachronistic
  86   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  87   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  88   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  89   nw="$nw -Wcast-qual"              # Too many warnings for now
  90   nw="$nw -Wconversion"             # Too many warnings for now
  91   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  92   nw="$nw -Wsign-conversion"        # Too many warnings for now
  93   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  94   nw="$nw -Wunreachable-code"       # Too many warnings for now
  95   nw="$nw -Wpadded"                 # Our structs are not padded
  96   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  97   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  98   nw="$nw -Wvla"                    # two warnings in mount.c
  99   # things I might fix soon:
 100   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 101   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 102   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 103   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 104                                     # was not possible, safe to ignore
 105   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 106   nw="$nw -Wlong-long"              # Allow long long since it's required
 107                                     # by Python, Ruby and xstrtoll.
 108   nw="$nw -Wstack-protector"        # Don't warn about stack-protector
 109                                     # failures (seen on Ubuntu).
 110
 111   gl_MANYWARN_ALL_GCC([ws])
 112   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 113   for w in $ws; do
 114     gl_WARN_ADD([$w])
 115   done
 116   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 117   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 118   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 119
 120   # In spite of excluding -Wlogical-op above, it is enabled, as of
 121   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 122   gl_WARN_ADD([-Wno-logical-op])
 123
 124   # Work around warning in src/inspect.c.  This seems to be a bug in gcc 4.5.1.
 125   gl_WARN_ADD([-Wno-strict-overflow])
 126
 127   gl_WARN_ADD([-fdiagnostics-show-option])
 128
 129   AC_SUBST([WARN_CFLAGS])
 130
 131   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 132   AC_DEFINE([_FORTIFY_SOURCE], [2],
 133     [enable compile-time and run-time bounds-checking, and some warnings])
 134   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 135 fi
 136
 137 AC_C_PROTOTYPES
 138 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 139
 140 AM_PROG_CC_C_O
 141
 142 dnl Work out how to specify the linker script to the linker.
 143 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 144 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 145     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 146 AC_SUBST(VERSION_SCRIPT_FLAGS)
 147
 148 dnl Check support for 64 bit file offsets.
 149 AC_SYS_LARGEFILE
 150
 151 dnl Check sizeof long.
 152 AC_CHECK_SIZEOF([long])
 153
 154 dnl Define a C symbol for the host CPU architecture.
 155 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 156
 157 dnl Headers.
 158 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 159
 160 dnl Functions.
 161 AC_CHECK_FUNCS([futimens posix_fallocate])
 162
 163 dnl Build the daemon?
 164 AC_MSG_CHECKING([if we should build the daemon])
 165 AC_ARG_ENABLE([daemon],
 166         [AS_HELP_STRING([--enable-daemon],
 167           [enable building the daemon @<:@default=yes@:>@])],
 168         [],
 169         [enable_daemon=yes])
 170 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 171 AC_MSG_RESULT([$enable_daemon])
 172
 173 dnl Build the appliance?
 174 AC_MSG_CHECKING([if we should build the appliance])
 175 AC_ARG_ENABLE([appliance],
 176         [AS_HELP_STRING([--enable-appliance],
 177           [enable building the appliance @<:@default=yes@:>@])],
 178         [],
 179         [enable_appliance=yes])
 180 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 181 AC_MSG_RESULT([$enable_appliance])
 182
 183 if test "x$enable_appliance" = "xyes"; then
 184     dnl Check for febootstrap >= 3.0
 185     AC_CHECK_PROG([FEBOOTSTRAP],
 186                   [febootstrap],[febootstrap],[no])
 187     test "x$FEBOOTSTRAP" = "xno" &&
 188         AC_MSG_ERROR([febootstrap must be installed])
 189     dnl febootstrap 2.x did not support the --version parameter
 190     $FEBOOTSTRAP --version >/dev/null 2>&1 ||
 191         AC_MSG_ERROR([febootstrap >= 3.0 must be installed, your version is too old])
 192
 193     dnl Pass a febootstrap --yum-config option.
 194     AC_MSG_CHECKING([if user requested febootstrap --yum-config option])
 195     AC_ARG_WITH([febootstrap-yum-config],
 196         [AS_HELP_STRING([--with-febootstrap-yum-config=FILE],
 197           [pass febootstrap --yum-config option @<:@default=no@:>@])],
 198         [FEBOOTSTRAP_YUM_CONFIG="$withval"],
 199         [FEBOOTSTRAP_YUM_CONFIG=no])
 200     AC_MSG_RESULT([$FEBOOTSTRAP_YUM_CONFIG])
 201     AC_SUBST([FEBOOTSTRAP_YUM_CONFIG])
 202
 203     dnl Which distro?
 204     dnl
 205     dnl This used to be Very Important but is now just used to select
 206     dnl which packages to install in the appliance, since the package
 207     dnl names vary slightly across distros.  (See
 208     dnl appliance/packagelist.in and appliance/excludelist.in)
 209     AC_MSG_CHECKING([which Linux distro for package names])
 210     DISTRO=REDHAT
 211     if test -f /etc/debian_version; then
 212         DISTRO=DEBIAN
 213         if grep -q 'DISTRIB_ID=Ubuntu' /etc/lsb-release 2>/dev/null; then
 214             DISTRO=UBUNTU
 215         fi
 216     fi
 217     if test -f /etc/arch-release; then
 218         DISTRO=ARCHLINUX
 219     fi
 220     AC_MSG_RESULT([$DISTRO])
 221     AC_SUBST([DISTRO])
 222 fi
 223
 224 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 225 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 226 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 227 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 228         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 229         ])
 230
 231 dnl Check for cpio which isn't in the default Pardus install amazingly.
 232 AC_CHECK_PROG([CPIO],[cpio],[cpio],[no])
 233 test "x$CPIO" = "xno" &&
 234      AC_MSG_ERROR([cpio must be installed])
 235
 236 dnl Check for gperf.
 237 AC_CHECK_PROG([GPERF],[gperf],[gperf],[no])
 238 test "x$GPERF" = "xno" &&
 239      AC_MSG_ERROR([gperf must be installed])
 240
 241 dnl Check for pod2man, pod2text, pod2html.
 242 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 243 test "x$POD2MAN" = "xno" &&
 244      AC_MSG_ERROR([pod2man must be installed])
 245 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 246 test "x$POD2TEXT" = "xno" &&
 247      AC_MSG_ERROR([pod2text must be installed])
 248 AC_CHECK_PROG([POD2HTML],[pod2html],[pod2html],[no])
 249 test "x$POD2HTML" = "xno" &&
 250      AC_MSG_ERROR([pod2html must be installed])
 251
 252 dnl Check if pod2man, pod2text take --stderr and -u options (not in RHEL 5).
 253 AC_MSG_CHECKING([if pod2man takes --stderr option])
 254 if "$POD2MAN" --stderr >/dev/null 2>&1; then
 255     AC_MSG_RESULT([yes])
 256     POD2_STDERR_OPTION="--stderr"
 257 else
 258     AC_MSG_RESULT([no])
 259     POD2_STDERR_OPTION=""
 260 fi
 261 AC_SUBST([POD2_STDERR_OPTION])
 262
 263 AC_MSG_CHECKING([if pod2man takes -u option])
 264 if "$POD2MAN" -u >/dev/null 2>&1; then
 265     AC_MSG_RESULT([yes])
 266     POD2_UTF8_OPTION="-u"
 267 else
 268     AC_MSG_RESULT([no])
 269     POD2_UTF8_OPTION=""
 270 fi
 271 AC_SUBST([POD2_UTF8_OPTION])
 272
 273 dnl Check for mkisofs.
 274 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 275         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 276 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 277
 278 dnl Check for optional xmllint.
 279 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 280 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 281
 282 dnl po4a for translating man pages and POD files (optional).
 283 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
 284 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
 285
 286 dnl Check for db_dump, db_load (optional).
 287 AC_CHECK_PROGS([DB_DUMP],
 288                [db_dump db4_dump db4.8_dump db4.7_dump db4.6_dump],[no])
 289 AC_CHECK_PROGS([DB_LOAD],
 290                [db_load db4_load db4.8_load db4.7_load db4.6_load],[no])
 291 if test "x$DB_DUMP" != "xno"; then
 292     AC_DEFINE_UNQUOTED([DB_DUMP],["$DB_DUMP"],[Name of db_dump program.])
 293 fi
 294 if test "x$DB_LOAD" != "xno"; then
 295     AC_DEFINE_UNQUOTED([DB_LOAD],["$DB_LOAD"],[Name of db_load program.])
 296 fi
 297
 298 dnl Check for QEMU for running binaries on this $host_cpu, fall
 299 dnl back to basic 'qemu'.  Allow the user to override it.
 300 default_qemu="qemu-kvm kvm qemu-system-$host_cpu qemu"
 301 AC_ARG_WITH([qemu],
 302         [AS_HELP_STRING([--with-qemu],
 303           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 304         [],
 305         [with_qemu="$default_qemu"])
 306 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 307         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 308 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 309 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 310
 311 dnl Check that the chosen qemu has virtio-serial support.
 312 if test "x$vmchannel_test" != "xno"; then
 313     AC_MSG_CHECKING([for virtio-serial support in $QEMU])
 314     if $QEMU -nographic -device \? 2>&1 | grep -sq virtio-serial; then
 315         AC_MSG_RESULT([yes])
 316     else
 317         AC_MSG_RESULT([no])
 318         AC_MSG_FAILURE(
 319 [I did not find virtio-serial support in
 320 $QEMU.
 321
 322 virtio-serial support in qemu or KVM is essential for libguestfs
 323 to operate.
 324
 325 Usually this means that you have to install a newer version of qemu
 326 and/or KVM.  Please read the relevant section in the README file for
 327 more information about this.
 328
 329 You can override this test by setting the environment variable
 330 vmchannel_test=no  However if you don't have the right support
 331 in your qemu, then this just delays the pain.
 332
 333 If I am using the wrong qemu or you want to compile qemu from source
 334 and install it in another location, then you should configure with
 335 the --with-qemu option.
 336 ])
 337     fi
 338 fi
 339
 340 dnl Set default drive interface used by the guestfs_add_drive_opts call
 341 dnl ('-drive ...,if=...' option to qemu).
 342 dnl
 343 dnl If you encounter performance problems with virtio (RHBZ#509383)
 344 dnl then try '--with-drive-if=ide'.
 345 AC_ARG_WITH([drive-if],
 346         [AS_HELP_STRING([--with-drive-if],
 347           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 348         [],
 349         [with_drive_if=virtio])
 350 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 351
 352 dnl Set interface used by the network.  Normally you should
 353 dnl leave this at the default (virtio-net-pci) but you can use the
 354 dnl alternative (ne2k_pci) because of bugs in virtio networking
 355 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 356 AC_ARG_WITH([net-if],
 357         [AS_HELP_STRING([--with-net-if],
 358           [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
 359         [],
 360         [with_net_if=virtio-net-pci])
 361 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 362
 363 dnl Enable packet dumps when in verbose mode.  This generates lots
 364 dnl of debug info, only useful for people debugging the RPC mechanism.
 365 AC_ARG_ENABLE([packet-dump],
 366         [AS_HELP_STRING([--enable-packet-dump],
 367           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 368         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 369         [])
 370
 371 dnl Readline.
 372 AC_ARG_WITH([readline],
 373     [AS_HELP_STRING([--with-readline],
 374         [support fancy command line editing @<:@default=check@:>@])],
 375     [],
 376     [with_readline=check])
 377
 378 LIBREADLINE=
 379 AS_IF([test "x$with_readline" != xno],
 380     [AC_CHECK_LIB([readline], [main],
 381         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 382          AC_DEFINE([HAVE_LIBREADLINE], [1],
 383                    [Define if you have libreadline])
 384         ],
 385         [if test "x$with_readline" != xcheck; then
 386          AC_MSG_FAILURE(
 387              [--with-readline was given, but test for readline failed])
 388          fi
 389         ], -lncurses)
 390      old_LIBS="$LIBS"
 391      LIBS="$LIBS $LIBREADLINE"
 392      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 393      LIBS="$old_LIBS"
 394     ])
 395
 396 dnl For i18n.
 397 AM_GNU_GETTEXT([external])
 398
 399 dnl libmagic (highly recommended)
 400 AC_CHECK_LIB([magic],[magic_file],
 401         [AC_CHECK_HEADER([magic.h],
 402                 [AC_SUBST([MAGIC_LIBS], ["-lmagic"])
 403                  AC_DEFINE([HAVE_LIBMAGIC],[1],[libmagic found at compile time.])
 404                 ], [])
 405         ],
 406         [AC_MSG_WARN([libmagic not found, some core features will be disabled])])
 407
 408 dnl Check for PCRE (highly recommended)
 409 PKG_CHECK_MODULES([PCRE], [libpcre],
 410         [AC_SUBST([PCRE_CFLAGS])
 411          AC_SUBST([PCRE_LIBS])
 412          AC_DEFINE([HAVE_PCRE],[1],[PCRE found at compile time.])
 413         ],
 414         [AC_MSG_WARN([PCRE not found, some core features will be disabled])])
 415
 416 dnl libvirt (highly recommended)
 417 PKG_CHECK_MODULES([LIBVIRT], [libvirt],
 418         [AC_SUBST([LIBVIRT_CFLAGS])
 419          AC_SUBST([LIBVIRT_LIBS])
 420          AC_DEFINE([HAVE_LIBVIRT],[1],[libvirt found at compile time.])
 421         ],
 422         [AC_MSG_WARN([libvirt not found, some core features will be disabled])])
 423 AM_CONDITIONAL([HAVE_LIBVIRT],[test "x$LIBVIRT_LIBS" != "x"])
 424
 425 dnl libxml2 (highly recommended)
 426 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0],
 427         [AC_SUBST([LIBXML2_CFLAGS])
 428          AC_SUBST([LIBXML2_LIBS])
 429          AC_DEFINE([HAVE_LIBXML2],[1],[libxml2 found at compile time.])
 430         ],
 431         [AC_MSG_WARN([libxml2 not found, some core features will be disabled])])
 432 AM_CONDITIONAL([HAVE_LIBXML2],[test "x$LIBXML2_LIBS" != "x"])
 433
 434 dnl hivex library (highly recommended)
 435 dnl This used to be a part of libguestfs, but was spun off into its
 436 dnl own separate upstream project in libguestfs 1.0.85.
 437 PKG_CHECK_MODULES([HIVEX], [hivex],
 438         [AC_SUBST([HIVEX_CFLAGS])
 439          AC_SUBST([HIVEX_LIBS])
 440          AC_DEFINE([HAVE_HIVEX],[1],[hivex library found at compile time.])
 441         ],
 442         [AC_MSG_WARN([hivex not found, some core features will be disabled])])
 443
 444 dnl FUSE is optional to build the FUSE module.
 445 AC_ARG_ENABLE([fuse],
 446         AS_HELP_STRING([--disable-fuse], [Disable FUSE (guestmount) support]),
 447         [],
 448         [enable_fuse=yes])
 449 AS_IF([test "x$enable_fuse" != "xno"],
 450         [PKG_CHECK_MODULES([FUSE],[fuse],,[
 451                 enable_fuse=no
 452                 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])])
 453 AM_CONDITIONAL([HAVE_FUSE],[test "x$enable_fuse" != "xno"])
 454
 455 dnl Check for OCaml (optional, for OCaml bindings).
 456 OCAMLC=no
 457 OCAMLFIND=no
 458 AC_ARG_ENABLE([ocaml],
 459         AS_HELP_STRING([--disable-ocaml], [Disable OCaml language bindings]),
 460         [],
 461         [enable_ocaml=yes])
 462 AS_IF([test "x$enable_ocaml" != "xno"],
 463         [dnl OCAMLC and OCAMLFIND have to be unset first, otherwise
 464          dnl AC_CHECK_TOOL (inside AC_PROG_OCAML) will not look.
 465          OCAMLC=
 466          OCAMLFIND=
 467          AC_PROG_OCAML
 468          AC_PROG_FINDLIB
 469         ])
 470 AM_CONDITIONAL([HAVE_OCAML],
 471                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
 472
 473 dnl Check for Perl (optional, for Perl bindings).
 474 PERL=no
 475 AC_ARG_ENABLE([perl],
 476         AS_HELP_STRING([--disable-perl], [Disable Perl language bindings]),
 477         [],
 478         [enable_perl=yes])
 479 AS_IF([test "x$enable_perl" != "xno"],
 480         [
 481         PERL=
 482         AC_CHECK_PROG([PERL],[perl],[perl],[no])
 483
 484         dnl Check for Perl modules that must be present to compile and
 485         dnl test the Perl bindings.
 486         missing_perl_modules=no
 487         for pm in Test::More ExtUtils::MakeMaker; do
 488             AC_MSG_CHECKING([for $pm])
 489             if ! perl -M$pm -e1 >/dev/null 2>&1; then
 490                 AC_MSG_RESULT([no])
 491                 missing_perl_modules=yes
 492             else
 493                 AC_MSG_RESULT([yes])
 494             fi
 495         done
 496         if test "x$missing_perl_modules" = "xyes"; then
 497             AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 498         fi
 499         ])
 500 AM_CONDITIONAL([HAVE_PERL],
 501     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 502
 503 dnl Check for Python (optional, for Python bindings).
 504 PYTHON_PREFIX=
 505 PYTHON_VERSION=
 506 PYTHON_INCLUDEDIR=
 507 PYTHON_INSTALLDIR=
 508
 509 AC_ARG_ENABLE([python],
 510         AS_HELP_STRING([--disable-python], [Disable Python language bindings]),
 511         [],
 512         [enable_python=yes])
 513 AS_IF([test "x$enable_python" != "xno"],
 514         [
 515         AC_CHECK_PROG([PYTHON],[python],[python],[no])
 516
 517         if test "x$PYTHON" != "xno"; then
 518             AC_MSG_CHECKING([Python prefix])
 519             PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 520             AC_MSG_RESULT([$PYTHON_PREFIX])
 521
 522             AC_MSG_CHECKING([Python version])
 523             PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 524             AC_MSG_RESULT([$PYTHON_VERSION])
 525
 526             for d in \
 527                 $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 528                 /usr/include/python$PYTHON_VERSION \
 529                 /usr/local/include/python$PYTHON_VERSION
 530             do
 531                 AC_MSG_CHECKING([Python.h in $d])
 532                 if test -r "$d/Python.h"; then
 533                     AC_MSG_RESULT([found])
 534                     PYTHON_INCLUDEDIR=$d
 535                     break
 536                 fi
 537                 AC_MSG_RESULT([not found])
 538             done
 539             if test "x$PYTHON_INCLUDEDIR" = "x"; then
 540                 AC_MSG_WARN([Python include directory not found])
 541             fi
 542
 543             AC_ARG_WITH([python-installdir],
 544                         [AS_HELP_STRING([--with-python-installdir],
 545                                         [directory to install python modules @<:@default=check@:>@])],
 546                         [PYTHON_INSTALLDIR="$withval"
 547                         AC_MSG_NOTICE([Python install dir $PYTHON_INSTALLDIR])],
 548                         [PYTHON_INSTALLDIR=check])
 549
 550             if test "x$PYTHON_INSTALLDIR" = "xcheck"; then
 551                 PYTHON_INSTALLDIR=
 552                 for d in \
 553                     $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 554                     $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 555                     /usr/lib64/python$PYTHON_VERSION/site-packages \
 556                     /usr/lib/python$PYTHON_VERSION/site-packages \
 557                     /usr/local/lib/python$PYTHON_VERSION/site-packages
 558                 do
 559                     AC_MSG_CHECKING([for $d])
 560                     if test -d "$d"; then
 561                         AC_MSG_RESULT([found])
 562                         PYTHON_INSTALLDIR=$d
 563                         break
 564                     fi
 565                     AC_MSG_RESULT([not found])
 566                 done
 567                 if test "x$PYTHON_INSTALLDIR" = "x"; then
 568                     AC_MSG_WARN([Python site-packages directory not found])
 569                 fi
 570             fi
 571
 572             old_LIBS="$LIBS"
 573             LIBS="$LIBS -lpython$PYTHON_VERSION"
 574             AC_CHECK_FUNCS([PyCapsule_New])
 575             LIBS="$old_LIBS"
 576         fi
 577
 578         AC_SUBST(PYTHON_PREFIX)
 579         AC_SUBST(PYTHON_VERSION)
 580         AC_SUBST(PYTHON_INCLUDEDIR)
 581         AC_SUBST(PYTHON_INSTALLDIR)
 582         ])
 583 AM_CONDITIONAL([HAVE_PYTHON],
 584     [test "x$PYTHON" != "xno" && test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_INSTALLDIR" != "x"])
 585
 586 dnl Check for Ruby and rake (optional, for Ruby bindings).
 587 AC_ARG_ENABLE([ruby],
 588         AS_HELP_STRING([--disable-ruby], [Disable Ruby language bindings]),
 589         [],
 590         [enable_ruby=yes])
 591 AS_IF([test "x$enable_ruby" != "xno"],
 592         [
 593         AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 594         AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 595         ])
 596 AM_CONDITIONAL([HAVE_RUBY],
 597     [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
 598
 599 dnl Check for Java.
 600 AC_ARG_WITH(java_home,
 601     [AS_HELP_STRING([--with-java-home],
 602         [specify path to JDK directory @<:@default=check@:>@])],
 603     [],
 604     [with_java_home=check])
 605
 606 if test "x$with_java_home" != "xno"; then
 607     if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
 608     then
 609         # Reject unsafe characters in $JAVA_HOME
 610         jh_lf='
 611 '
 612         case $JAVA_HOME in
 613           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 614             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 615         esac
 616         if test -d "$with_java_home"; then
 617             JAVA_HOME="$with_java_home"
 618         else
 619             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 620         fi
 621     fi
 622
 623     if test "x$JAVA_HOME" = "x"; then
 624         # Look for Java in some likely locations.
 625         for d in \
 626             /usr/lib/jvm/java \
 627             /usr/lib/jvm/java-6-openjdk
 628         do
 629             if test -d $d && test -f $d/bin/java; then
 630                 JAVA_HOME=$d
 631                 break
 632             fi
 633         done
 634     fi
 635
 636     if test "x$JAVA_HOME" != "x"; then
 637         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 638         if test ! -x "$JAVA_HOME/bin/java"; then
 639             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 640         else
 641             JAVA="$JAVA_HOME/bin/java"
 642         fi
 643         if test ! -x "$JAVA_HOME/bin/javac"; then
 644             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 645         else
 646             JAVAC="$JAVA_HOME/bin/javac"
 647         fi
 648         if test ! -x "$JAVA_HOME/bin/javah"; then
 649             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 650         else
 651             JAVAH="$JAVA_HOME/bin/javah"
 652         fi
 653         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 654             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 655         else
 656             JAVADOC="$JAVA_HOME/bin/javadoc"
 657         fi
 658         if test ! -x "$JAVA_HOME/bin/jar"; then
 659             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 660         else
 661             JAR="$JAVA_HOME/bin/jar"
 662         fi
 663         java_version=`$JAVA -version 2>&1 | grep "java version"`
 664         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 665
 666         dnl Find jni.h.
 667         AC_MSG_CHECKING([for jni.h])
 668         if test -f "$JAVA_HOME/include/jni.h"; then
 669             JNI_CFLAGS="-I$JAVA_HOME/include"
 670         else
 671             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 672                 head=`find $JAVA_HOME -name jni.h | tail -1`
 673                 dir=`dirname "$head"`
 674                 JNI_CFLAGS="-I$dir"
 675             else
 676                 AC_MSG_FAILURE([missing jni.h header file])
 677             fi
 678         fi
 679         AC_MSG_RESULT([$JNI_CFLAGS])
 680
 681         dnl Find jni_md.h.
 682         AC_MSG_CHECKING([for jni_md.h])
 683         case "$build_os" in
 684         *linux*) system="linux" ;;
 685         *SunOS*) system="solaris" ;;
 686         *cygwin*) system="win32" ;;
 687         *) system="$build_os" ;;
 688         esac
 689         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 690             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 691         else
 692             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 693                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 694                 dir=`dirname "$head"`
 695                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 696             else
 697                 AC_MSG_FAILURE([missing jni_md.h header file])
 698             fi
 699         fi
 700         AC_MSG_RESULT([$JNI_CFLAGS])
 701
 702         dnl Need extra version flag?
 703         AC_MSG_CHECKING([extra javac flags])
 704         JAVAC_FLAGS=
 705         javac_version=`$JAVAC -version 2>&1`
 706         case "$javac_version" in
 707         *Eclipse*)
 708             JAVAC_FLAGS="-source 1.5" ;;
 709         esac
 710         AC_MSG_RESULT([$JAVAC_FLAGS])
 711
 712         dnl Where to install jarfiles.
 713         dnl XXX How to make it configurable?
 714         JAR_INSTALL_DIR=\${prefix}/share/java
 715         JNI_INSTALL_DIR=\${libdir}
 716
 717         dnl JNI version.
 718         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 719         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 720         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 721         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 722     fi
 723 fi
 724
 725 AC_SUBST(JAVA_HOME)
 726 AC_SUBST(JAVA)
 727 AC_SUBST(JAVAC)
 728 AC_SUBST(JAVAH)
 729 AC_SUBST(JAVADOC)
 730 AC_SUBST(JAR)
 731 AC_SUBST(JNI_CFLAGS)
 732 AC_SUBST(JAVAC_FLAGS)
 733 AC_SUBST(JAR_INSTALL_DIR)
 734 AC_SUBST(JNI_INSTALL_DIR)
 735 AC_SUBST(JNI_VERSION_INFO)
 736
 737 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 738
 739 dnl Check for Haskell (GHC).
 740 GHC=no
 741 AC_ARG_ENABLE([haskell],
 742         AS_HELP_STRING([--disable-haskell], [Disable Haskell language bindings]),
 743         [],
 744         [enable_haskell=yes])
 745 AS_IF([test "x$enable_haskell" != "xno"],
 746         [
 747         GHC=
 748         AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 749         ])
 750 AM_CONDITIONAL([HAVE_HASKELL],
 751     [test "x$GHC" != "xno"])
 752
 753 dnl PHP
 754 PHP=no
 755 AC_ARG_ENABLE([php],
 756         AS_HELP_STRING([--disable-php], [Disable PHP language bindings]),
 757         [],
 758         [enable_php=yes])
 759 AS_IF([test "x$enable_php" != "xno"],
 760         [
 761         PHP=
 762         AC_CHECK_PROG([PHP],[php],[php],[no])
 763         AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
 764         ])
 765 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
 766
 767 dnl Check for Perl modules needed by Perl virt tools (virt-df, etc.)
 768 AS_IF([test "x$PERL" != "xno"],
 769         [
 770         missing_perl_modules=no
 771         for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper Locale::TextDomain Win::Hivex Win::Hivex::Regedit String::ShellQuote; do
 772             AC_MSG_CHECKING([for $pm])
 773             if ! $PERL -M$pm -e1 >/dev/null 2>&1; then
 774                 AC_MSG_RESULT([no])
 775                 missing_perl_modules=yes
 776             else
 777                 AC_MSG_RESULT([yes])
 778             fi
 779         done
 780         if test "x$missing_perl_modules" = "xyes"; then
 781             AC_MSG_WARN([some Perl modules required to compile the Perl virt-* tools are missing])
 782         fi
 783         ])
 784
 785 AM_CONDITIONAL([HAVE_TOOLS],
 786     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 787
 788 dnl Library versioning.
 789 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 790 AC_SUBST(MAX_PROC_NR)
 791
 792 dnl Replace libtool with a wrapper that clobbers dependency_libs in *.la files
 793 dnl http://lists.fedoraproject.org/pipermail/devel/2010-November/146343.html
 794 LIBTOOL='$(SHELL) $(top_srcdir)/libtool-kill-dependency_libs.sh $(top_builddir)/libtool'
 795 AC_SUBST([LIBTOOL])
 796
 797 dnl Run in subdirs.
 798 if test "x$enable_daemon" = "xyes"; then
 799     AC_CONFIG_SUBDIRS([daemon])
 800 fi
 801
 802 dnl Produce output files.
 803 AC_CONFIG_HEADERS([config.h])
 804 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 805 AC_CONFIG_FILES([podwrapper.sh],
 806                 [chmod +x podwrapper.sh])
 807 AC_CONFIG_FILES([Makefile
 808                  generator/Makefile
 809                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 810                  appliance/Makefile
 811                  images/Makefile
 812                  capitests/Makefile
 813                  regressions/Makefile
 814                  test-tool/Makefile
 815                  ocaml/Makefile ocaml/examples/Makefile
 816                  perl/Makefile perl/examples/Makefile
 817                  python/Makefile python/examples/Makefile
 818                  ruby/Makefile ruby/Rakefile ruby/examples/Makefile
 819                  java/Makefile
 820                  haskell/Makefile
 821                  inspector/Makefile
 822                  tools/Makefile
 823                  libguestfs.pc
 824                  gnulib/lib/Makefile
 825                  gnulib/tests/Makefile
 826                  fuse/Makefile
 827                  po-docs/Makefile
 828                  po-docs/ja/Makefile
 829                  php/Makefile
 830                  csharp/Makefile
 831                  cat/Makefile
 832                  df/Makefile
 833                  rescue/Makefile
 834                  debian/changelog
 835                  ocaml/META perl/Makefile.PL])
 836 AC_OUTPUT
 837
 838 dnl Produce summary.
 839 echo
 840 echo
 841 echo "------------------------------------------------------------"
 842 echo "Thank you for downloading $PACKAGE_STRING"
 843 echo
 844 echo "This is how we have configured the optional components for you today:"
 845 echo
 846 echo    "Daemon .............................. $enable_daemon"
 847 echo    "Appliance ........................... $enable_appliance"
 848 echo    "QEMU ................................ $QEMU"
 849 echo -n "OCaml bindings ...................... "
 850 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 851 echo -n "Perl bindings ....................... "
 852 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 853 echo -n "Python bindings ..................... "
 854 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 855 echo -n "Ruby bindings ....................... "
 856 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 857 echo -n "Java bindings ....................... "
 858 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 859 echo -n "Haskell bindings .................... "
 860 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 861 echo -n "PHP bindings ........................ "
 862 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 863 echo -n "virt-* tools ........................ "
 864 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 865 echo "FUSE filesystem ..................... $enable_fuse"
 866 echo
 867 echo "If any optional component is configured 'no' when you expected 'yes'"
 868 echo "then you should check the preceeding messages."
 869 echo
 870 echo "Please report bugs back to the mailing list:"
 871 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 872 echo
 873 echo "Next you should type 'make' to build the package,"
 874 echo "then 'make check' to run the tests."
 875 echo "------------------------------------------------------------"