configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [0])
  21 m4_define([libguestfs_release], [73])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release[]libguestfs_extra)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 gl_EARLY
  41 gl_INIT
  42
  43 AC_PROG_LIBTOOL
  44
  45 dnl Check for basic C environment.
  46 AC_PROG_CC_STDC
  47 AC_PROG_INSTALL
  48 AC_PROG_CPP
  49
  50 AC_ARG_ENABLE([gcc-warnings],
  51   [AS_HELP_STRING([--enable-gcc-warnings],
  52                   [turn on lots of GCC warnings (for developers)])],
  53   [case $enableval in
  54      yes|no) ;;
  55      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  56    esac
  57    gl_gcc_warnings=$enableval],
  58   [gl_gcc_warnings=no]
  59 )
  60
  61 if test "$gl_gcc_warnings" = yes; then
  62   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  63   AC_SUBST([WERROR_CFLAGS])
  64
  65   nw=
  66   # This, $nw, is the list of warnings we disable.
  67   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  68   nw="$nw -Waggregate-return"       # anachronistic
  69   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  70   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  71   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  72   nw="$nw -Wcast-qual"              # Too many warnings for now
  73   nw="$nw -Wconversion"             # Too many warnings for now
  74   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  75   nw="$nw -Wsign-conversion"        # Too many warnings for now
  76   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  77   nw="$nw -Wunreachable-code"       # Too many warnings for now
  78   nw="$nw -Wpadded"                 # Our structs are not padded
  79   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  80   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  81   nw="$nw -Wvla"                    # two warnings in mount.c
  82   # things I might fix soon:
  83   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
  84   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
  85   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
  86   # ?? -Wstrict-overflow
  87   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
  88                                     # was not possible, safe to ignore
  89
  90   gl_MANYWARN_ALL_GCC([ws])
  91   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
  92   for w in $ws; do
  93     gl_WARN_ADD([$w])
  94   done
  95   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
  96   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
  97   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
  98
  99   # In spite of excluding -Wlogical-op above, it is enabled, as of
 100   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 101   gl_WARN_ADD([-Wno-logical-op])
 102
 103   gl_WARN_ADD([-fdiagnostics-show-option])
 104
 105   AC_SUBST([WARN_CFLAGS])
 106
 107   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 108   AC_DEFINE([_FORTIFY_SOURCE], [2],
 109     [enable compile-time and run-time bounds-checking, and some warnings])
 110   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 111 fi
 112
 113 AC_C_PROTOTYPES
 114 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 115
 116 AM_PROG_CC_C_O
 117
 118 dnl Check support for 64 bit file offsets.
 119 AC_SYS_LARGEFILE
 120
 121 dnl Check sizeof long.
 122 AC_CHECK_SIZEOF([long])
 123
 124 dnl Headers.
 125 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h])
 126
 127 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 128 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 129 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 130 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 131         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 132         ])
 133
 134 dnl Check for pod2man and pod2text.
 135 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 136 test "x$POD2MAN" = "xno" &&
 137      AC_MSG_ERROR([pod2man must be installed])
 138 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 139 test "x$POD2TEXT" = "xno" &&
 140      AC_MSG_ERROR([pod2text must be installed])
 141
 142 dnl Check for mkisofs.
 143 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 144         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 145 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 146
 147 dnl Check for optional xmllint.
 148 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 149 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 150
 151 dnl Check for QEMU for running binaries on this $host_cpu, fall
 152 dnl back to basic 'qemu'.  Allow the user to override it.
 153 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
 154 AC_ARG_WITH([qemu],
 155         [AS_HELP_STRING([--with-qemu],
 156           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 157         [],
 158         [with_qemu="$default_qemu"])
 159 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 160         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 161 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 162 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 163
 164 dnl Check that the chosen qemu has vmchannel support or we can
 165 dnl fallback to null vmchannel (still using SLIRP).  See the
 166 dnl discussion in the README file.
 167 if test "x$vmchannel_test" != "xno"; then
 168     AC_MSG_CHECKING([for guestfwd support in $QEMU])
 169     if $QEMU --help | grep -sq guestfwd; then
 170         AC_MSG_RESULT([yes])
 171         vmchannel_guestfwd=guestfwd
 172     else
 173         AC_MSG_RESULT([no])
 174         # Note that this test must be conditional on the previous
 175         # test failing.  This is because recent qemu will throw
 176         # up an SDL window and hang if we try to run this test.
 177         AC_MSG_CHECKING([for "-net channel" (old guestfwd) support in $QEMU])
 178         vmchannelout=`$QEMU -net channel /dev/zero 2>&1 ||:`
 179         echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
 180         if echo "$vmchannelout" | grep -sq "vmchannel wrong port number" ; then
 181             AC_MSG_RESULT([yes])
 182             vmchannel_guestfwd=net_channel
 183         else
 184             AC_MSG_RESULT([no])
 185             vmchannel_guestfwd=no
 186         fi
 187     fi
 188
 189     AC_MSG_CHECKING([for "-net user" (user mode network) support in $QEMU])
 190     if $QEMU --help | grep -sq -- "-net user"; then
 191         AC_MSG_RESULT([yes])
 192         vmchannel_net_user=yes
 193     else
 194         AC_MSG_RESULT([no])
 195         vmchannel_net_user=no
 196     fi
 197
 198     if test "x$vmchannel_net_user" = "xno" -a "x$vmchannel_guestfwd" = "xno"; then
 199         AC_MSG_FAILURE(
 200 [I did not find user mode network or vmchannel support in
 201 $QEMU.
 202
 203 Either user mode networking or vmchannel support is vital for
 204 libguestfs to operate.
 205
 206 Please read the relevant section in the README file for more
 207 information about this.
 208
 209 You can override this test by setting the environment variable
 210 vmchannel_test=no  However if you don't have the right support
 211 in your qemu, then this just delays the pain.
 212
 213 If I am using the wrong qemu or you want to compile qemu from source
 214 and install it in another location, then you should configure with
 215 the --with-qemu option.
 216 ])
 217     fi
 218 fi
 219
 220 dnl Set drive interface used by the guestfs_add_drive{,_ro} calls
 221 dnl ('-drive ...,if=...' option to qemu).
 222 dnl
 223 dnl NB. We will change the default in future to virtio, but at the
 224 dnl moment this causes a performance problem, RHBZ#509383.
 225 AC_ARG_WITH([drive-if],
 226         [AS_HELP_STRING([--with-drive-if],
 227           [set default driver (ide|scsi|virtio) @<:@default=ide@:>@])],
 228         [],
 229         [with_drive_if=ide])
 230 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 231
 232 dnl Set interface used by the network.  Normally you should
 233 dnl leave this at the default (virtio) but you can use the
 234 dnl alternative (ne2k_pci) because of bugs in virtio networking
 235 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 236 AC_ARG_WITH([net-if],
 237         [AS_HELP_STRING([--with-net-if],
 238           [set default net driver (virtio|ne2k_pci) @<:@default=virtio@:>@])],
 239         [],
 240         [with_net_if=virtio])
 241 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 242
 243 dnl Check for febootstrap etc.
 244 AC_CHECK_PROG([FEBOOTSTRAP],
 245         [febootstrap],[febootstrap],[no])
 246 if test "x$FEBOOTSTRAP" != "xno"; then
 247   AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 248         [febootstrap-run],[febootstrap-run],[no])
 249   test "x$FEBOOTSTRAP_RUN" = "xno" && \
 250      AC_MSG_ERROR([febootstrap-run must be installed])
 251   AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 252         [febootstrap-install],[febootstrap-install],[no])
 253   test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 254      AC_MSG_ERROR([febootstrap-install must be installed])
 255   AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 256         [febootstrap-minimize],[febootstrap-minimize],[no])
 257   test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 258      AC_MSG_ERROR([febootstrap-minimize must be installed])
 259   AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 260         [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 261   test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 262      AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 263
 264   dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 265   dnl of febootstrap, but old versions will fail with yum).
 266   AC_CHECK_PROG([FAKECHROOT],
 267         [fakechroot],[fakechroot],[no])
 268   test "x$FAKECHROOT" = "xno" && \
 269     AC_MSG_ERROR([fakechroot must be installed])
 270
 271   AC_MSG_CHECKING([fakechroot version])
 272   fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 273   if test -z "$fakechroot_version"; then
 274     AC_MSG_RESULT([failed])
 275     AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 276   else
 277     AC_MSG_RESULT([$fakechroot_version])
 278     fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 279     fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 280     if test "$fakechroot_major" -lt 2 -o \
 281             \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
 282         AC_MSG_ERROR([fakechroot version must be >= 2.9])
 283     fi
 284   fi
 285   DIST="REDHAT"
 286 else
 287   # check for debootstrap and debirf
 288   AC_CHECK_PROG([DEBOOTSTRAP],
 289         [debootstrap],[debootstrap],[no])
 290   test "x$DEBOOTSTRAP" = "xno" && \
 291         AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 292   AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 293   test "x$DEBIRF" = "xno" &&
 294         AC_MSG_ERROR([debirf must be installed])
 295   DIST="DEBIAN"
 296   case "$host_cpu" in
 297       *86)
 298           DEBIAN_KERNEL_ARCH=486
 299           ;;
 300       x86_64)
 301           DEBIAN_KERNEL_ARCH=amd64
 302           ;;
 303       *)
 304          DEBIAN_KERNEL_ARCH=$host_cpu
 305          ;;
 306    esac
 307    AC_SUBST(DEBIAN_KERNEL_ARCH)
 308 fi
 309 AC_SUBST(DIST)
 310
 311
 312 dnl --with-repo to specify a Fedora repository.
 313 AC_ARG_WITH([repo],
 314         [AS_HELP_STRING([--with-repo],
 315           [set name of Fedora repository @<:@default=fedora-11@:>@])],
 316         [],
 317         [with_repo=fedora-11])
 318 REPO="$with_repo"
 319 AC_SUBST(REPO)
 320 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 321
 322 dnl --with-updates to specify a Fedora updates repository.
 323 AC_ARG_WITH([updates],
 324         [AS_HELP_STRING([--with-updates],
 325           [set name of Fedora updates repository @<:@default=updates-released-f11@:>@])],
 326         [],
 327         [with_updates=updates-released-f11])
 328 UPDATES="$with_updates"
 329 AC_SUBST(UPDATES)
 330
 331 dnl Define a symbol for the host CPU architecture.
 332 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 333
 334 dnl --with-mirror to specify a local Fedora mirror.
 335 AC_ARG_WITH([mirror],
 336         [AS_HELP_STRING([--with-mirror],
 337           [set URI of a local Fedora mirror])],
 338         [],
 339         [with_mirror=])
 340 MIRROR="$with_mirror"
 341 AC_SUBST(MIRROR)
 342
 343 dnl Build the supermin appliance?  Please see README file before
 344 dnl enabling this option.
 345 AC_ARG_ENABLE([supermin],
 346         [AS_HELP_STRING([--enable-supermin],
 347           [enable supermin appliance (see README) @<:@default=no@:>@])],
 348         [],
 349         [enable_supermin=no])
 350 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 351
 352 if test "x$enable_supermin" = "xyes"; then
 353     dnl Check febootstrap-to-initramfs accepts the --files option
 354     dnl (febootstrap >= 2.2).
 355     AC_MSG_CHECKING([for --files support in $FEBOOTSTRAP_TO_INITRAMFS])
 356     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 357     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 358     if ! echo "$out" | grep -sq -e --files ; then
 359         AC_MSG_RESULT([no])
 360         AC_MSG_FAILURE(
 361 [febootstrap-to-initramfs does not support the --files option.
 362
 363 To build the supermin appliance, you need to upgrade to the latest
 364 version of febootstrap.
 365 ])
 366     fi
 367     AC_MSG_RESULT([yes])
 368
 369     dnl Check febootstrap-to-initramfs accepts the --nocompress option
 370     dnl (febootstrap >= 2.3).
 371     AC_MSG_CHECKING([for --nocompress support in $FEBOOTSTRAP_TO_INITRAMFS])
 372     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 373     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 374     if ! echo "$out" | grep -sq -e --nocompress ; then
 375         AC_MSG_RESULT([no])
 376         AC_MSG_FAILURE(
 377 [febootstrap-to-initramfs does not support the --nocompress option.
 378
 379 To build the supermin appliance, you need to upgrade to the latest
 380 version of febootstrap.
 381 ])
 382     fi
 383     AC_MSG_RESULT([yes])
 384 fi
 385
 386 dnl Enable packet dumps when in verbose mode.  This generates lots
 387 dnl of debug info, only useful for people debugging the RPC mechanism.
 388 AC_ARG_ENABLE([packet-dump],
 389         [AS_HELP_STRING([--enable-packet-dump],
 390           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 391         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 392         [])
 393
 394 dnl Readline.
 395 AC_ARG_WITH([readline],
 396     [AS_HELP_STRING([--with-readline],
 397         [support fancy command line editing @<:@default=check@:>@])],
 398     [],
 399     [with_readline=check])
 400
 401 LIBREADLINE=
 402 AS_IF([test "x$with_readline" != xno],
 403     [AC_CHECK_LIB([readline], [main],
 404         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 405          AC_DEFINE([HAVE_LIBREADLINE], [1],
 406                    [Define if you have libreadline])
 407         ],
 408         [if test "x$with_readline" != xcheck; then
 409          AC_MSG_FAILURE(
 410              [--with-readline was given, but test for readline failed])
 411          fi
 412         ], -lncurses)])
 413
 414 dnl For i18n.
 415 AM_GNU_GETTEXT([external])
 416 AM_GNU_GETTEXT_VERSION([0.17])
 417
 418 dnl Check for OCaml (optional, for OCaml bindings).
 419 AC_PROG_OCAML
 420 AC_PROG_FINDLIB
 421 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
 422
 423 dnl Optional xml-light for building virt-inspector language bindings
 424 dnl from the virt-inspector.rng file.
 425 OCAML_PKG_xml_light=no
 426 if test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"; then
 427     AC_CHECK_OCAML_PKG([xml-light])
 428 fi
 429 AM_CONDITIONAL([HAVE_XML_LIGHT],[test "x$OCAML_PKG_xml_light" != "xno"])
 430
 431 dnl Build the OCaml viewer example.  This has a lengthy list of
 432 dnl dependencies and we don't attempt to detect them all.  Read
 433 dnl the top of ocaml/examples/viewer.ml before enabling this.
 434 AC_ARG_ENABLE([ocaml-viewer],
 435         [AS_HELP_STRING([--enable-ocaml-viewer],
 436           [enable OCaml viewer (see ocaml/examples) @<:@default=no@:>@])],
 437         [],
 438         [enable_ocaml_viewer=no])
 439 AM_CONDITIONAL([BUILD_OCAML_VIEWER],[test "x$enable_ocaml_viewer" = "xyes"])
 440
 441 dnl Check for Perl (optional, for Perl bindings).
 442 dnl XXX This isn't quite right, we should check for Perl devel library.
 443 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 444
 445 dnl Check for Perl modules that must be present to compile and
 446 dnl test the Perl bindings.
 447 missing_perl_modules=no
 448 for pm in Test::More Test::Pod Test::Pod::Coverage ExtUtils::MakeMaker; do
 449     AC_MSG_CHECKING([for $pm])
 450     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 451         AC_MSG_RESULT([no])
 452         missing_perl_modules=yes
 453     else
 454         AC_MSG_RESULT([yes])
 455     fi
 456 done
 457 if test "x$missing_perl_modules" = "xyes"; then
 458     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 459 fi
 460
 461 AM_CONDITIONAL([HAVE_PERL],
 462     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 463
 464 dnl Check for Python (optional, for Python bindings).
 465 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 466
 467 PYTHON_PREFIX=
 468 PYTHON_VERSION=
 469 PYTHON_INCLUDEDIR=
 470 PYTHON_SITE_PACKAGES=
 471
 472 if test "x$PYTHON" != "xno"; then
 473     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 474     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 475     for d in \
 476         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 477         /usr/include/python$PYTHON_VERSION \
 478         /usr/local/include/python$PYTHON_VERSION
 479     do
 480         AC_MSG_CHECKING([Python.h in $d])
 481         if test -r "$d/Python.h"; then
 482             AC_MSG_RESULT([found])
 483             PYTHON_INCLUDEDIR=$d
 484             break
 485         fi
 486         AC_MSG_RESULT([not found])
 487     done
 488     for d in \
 489         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 490         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 491         /usr/lib64/python$PYTHON_VERSION/site-packages \
 492         /usr/lib/python$PYTHON_VERSION/site-packages \
 493         /usr/local/lib/python$PYTHON_VERSION/site-packages
 494     do
 495         AC_MSG_CHECKING([for $d])
 496         if test -d "$d"; then
 497             AC_MSG_RESULT([found])
 498             PYTHON_SITE_PACKAGES=$d
 499             break
 500         fi
 501         AC_MSG_RESULT([not found])
 502     done
 503 fi
 504
 505 AC_SUBST(PYTHON_PREFIX)
 506 AC_SUBST(PYTHON_VERSION)
 507 AC_SUBST(PYTHON_INCLUDEDIR)
 508 AC_SUBST(PYTHON_SITE_PACKAGES)
 509
 510 AM_CONDITIONAL([HAVE_PYTHON],
 511     [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
 512
 513 dnl Check for Ruby and rake (optional, for Ruby bindings).
 514 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 515 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 516
 517 AM_CONDITIONAL([HAVE_RUBY],
 518     [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
 519
 520 dnl Check for Java.
 521 AC_ARG_WITH(java_home,
 522     [AS_HELP_STRING([--with-java-home],
 523         [specify path to JDK directory @<:@default=check@:>@])],
 524     [],
 525     [with_java_home=check])
 526
 527 if test "x$with_java_home" != "xno"; then
 528     if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
 529     then
 530         # Reject unsafe characters in $JAVA_HOME
 531         jh_lf='
 532 '
 533         case $JAVA_HOME in
 534           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 535             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 536         esac
 537         if test -d "$with_java_home"; then
 538             JAVA_HOME="$with_java_home"
 539         else
 540             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 541         fi
 542     fi
 543
 544     if test "x$JAVA_HOME" = "x"; then
 545         # Look for Java in some likely locations.
 546         for d in \
 547             /usr/lib/jvm/java \
 548             /usr/lib/jvm/java-6-openjdk
 549         do
 550             if test -d $d -a -f $d/bin/java; then
 551                 JAVA_HOME=$d
 552                 break
 553             fi
 554         done
 555     fi
 556
 557     if test "x$JAVA_HOME" != "x"; then
 558         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 559         if test ! -x "$JAVA_HOME/bin/java"; then
 560             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 561         else
 562             JAVA="$JAVA_HOME/bin/java"
 563         fi
 564         if test ! -x "$JAVA_HOME/bin/javac"; then
 565             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 566         else
 567             JAVAC="$JAVA_HOME/bin/javac"
 568         fi
 569         if test ! -x "$JAVA_HOME/bin/javah"; then
 570             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 571         else
 572             JAVAH="$JAVA_HOME/bin/javah"
 573         fi
 574         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 575             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 576         else
 577             JAVADOC="$JAVA_HOME/bin/javadoc"
 578         fi
 579         if test ! -x "$JAVA_HOME/bin/jar"; then
 580             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 581         else
 582             JAR="$JAVA_HOME/bin/jar"
 583         fi
 584         java_version=`$JAVA -version 2>&1 | grep "java version"`
 585         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 586
 587         dnl Find jni.h.
 588         AC_MSG_CHECKING([for jni.h])
 589         if test -f "$JAVA_HOME/include/jni.h"; then
 590             JNI_CFLAGS="-I$JAVA_HOME/include"
 591         else
 592             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 593                 head=`find $JAVA_HOME -name jni.h | tail -1`
 594                 dir=`dirname "$head"`
 595                 JNI_CFLAGS="-I$dir"
 596             else
 597                 AC_MSG_FAILURE([missing jni.h header file])
 598             fi
 599         fi
 600         AC_MSG_RESULT([$JNI_CFLAGS])
 601
 602         dnl Find jni_md.h.
 603         AC_MSG_CHECKING([for jni_md.h])
 604         case "$build_os" in
 605         *linux*) system="linux" ;;
 606         *SunOS*) system="solaris" ;;
 607         *cygwin*) system="win32" ;;
 608         *) system="$build_os" ;;
 609         esac
 610         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 611             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 612         else
 613             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 614                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 615                 dir=`dirname "$head"`
 616                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 617             else
 618                 AC_MSG_FAILURE([missing jni_md.h header file])
 619             fi
 620         fi
 621         AC_MSG_RESULT([$JNI_CFLAGS])
 622
 623         dnl Need extra version flag?
 624         AC_MSG_CHECKING([extra javac flags])
 625         JAVAC_FLAGS=
 626         javac_version=`$JAVAC -version 2>&1`
 627         case "$javac_version" in
 628         *Eclipse*)
 629             JAVAC_FLAGS="-source 1.5" ;;
 630         esac
 631         AC_MSG_RESULT([$JAVAC_FLAGS])
 632
 633         dnl Where to install jarfiles.
 634         dnl XXX How to make it configurable?
 635         JAR_INSTALL_DIR=\${prefix}/share/java
 636         JNI_INSTALL_DIR=\${libdir}
 637
 638         dnl JNI version.
 639         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 640         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 641         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 642         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 643     fi
 644 fi
 645
 646 AC_SUBST(JAVA_HOME)
 647 AC_SUBST(JAVA)
 648 AC_SUBST(JAVAC)
 649 AC_SUBST(JAVAH)
 650 AC_SUBST(JAVADOC)
 651 AC_SUBST(JAR)
 652 AC_SUBST(JNI_CFLAGS)
 653 AC_SUBST(JAVAC_FLAGS)
 654 AC_SUBST(JAR_INSTALL_DIR)
 655 AC_SUBST(JNI_INSTALL_DIR)
 656 AC_SUBST(JNI_VERSION_INFO)
 657
 658 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 659
 660 dnl Check for Haskell (GHC).
 661 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 662
 663 AM_CONDITIONAL([HAVE_HASKELL],
 664     [test "x$GHC" != "xno"])
 665
 666 dnl Check for Perl modules needed by virt-df, inspector, etc.
 667 missing_perl_modules=no
 668 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer Locale::TextDomain; do
 669     AC_MSG_CHECKING([for $pm])
 670     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 671         AC_MSG_RESULT([no])
 672         missing_perl_modules=yes
 673     else
 674         AC_MSG_RESULT([yes])
 675     fi
 676 done
 677 if test "x$missing_perl_modules" = "xyes"; then
 678     AC_MSG_WARN([some Perl modules required to compile virt-inspector and the other virt-* tools are missing])
 679 fi
 680
 681 AM_CONDITIONAL([HAVE_INSPECTOR],
 682     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 683 AM_CONDITIONAL([HAVE_TOOLS],
 684     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 685
 686 dnl Library versioning.
 687 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 688 AC_SUBST(MAX_PROC_NR)
 689
 690 dnl Run in subdirs.
 691 AC_CONFIG_SUBDIRS([daemon])
 692
 693 dnl Produce output files.
 694 AC_CONFIG_HEADERS([config.h])
 695 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 696 AC_CONFIG_FILES([appliance/make.sh],
 697                 [chmod +x appliance/make.sh])
 698 AC_CONFIG_FILES([appliance/update.sh],
 699                 [chmod +x appliance/update.sh])
 700 AC_CONFIG_FILES([appliance/supermin-split.sh],
 701                 [chmod +x appliance/supermin-split.sh])
 702 AC_CONFIG_FILES([appliance/supermin-make.sh],
 703                 [chmod +x appliance/supermin-make.sh])
 704 AC_CONFIG_FILES([appliance/libguestfs-supermin-helper],
 705                 [chmod +x appliance/libguestfs-supermin-helper])
 706 AC_CONFIG_FILES([Makefile
 707                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 708                  appliance/Makefile
 709                  appliance/debian/debirf.conf
 710                  images/Makefile
 711                  capitests/Makefile
 712                  regressions/Makefile
 713                  test-tool/Makefile
 714                  ocaml/Makefile ocaml/examples/Makefile
 715                  perl/Makefile
 716                  python/Makefile
 717                  ruby/Makefile ruby/Rakefile
 718                  java/Makefile
 719                  haskell/Makefile
 720                  inspector/Makefile
 721                  tools/Makefile
 722                  libguestfs.pc
 723                  gnulib/lib/Makefile
 724                  gnulib/tests/Makefile
 725                  ocaml/META perl/Makefile.PL])
 726 AC_OUTPUT
 727
 728 dnl Produce summary.
 729 echo
 730 echo
 731 echo "------------------------------------------------------------"
 732 echo "Thank you for downloading $PACKAGE_STRING"
 733 echo
 734 echo "This is how we have configured the optional components for you today:"
 735 echo
 736 echo    "QEMU ................................ $QEMU"
 737 echo -n "OCaml bindings ...................... "
 738 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 739 echo -n "Perl bindings ....................... "
 740 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 741 echo -n "Python bindings ..................... "
 742 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 743 echo -n "Ruby bindings ....................... "
 744 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 745 echo -n "Java bindings ....................... "
 746 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 747 echo -n "Haskell bindings .................... "
 748 if test "x$HAVE_HASKELL" = "x"; then echo "yes"; else echo "no"; fi
 749 echo -n "virt-inspector ...................... "
 750 if test "x$HAVE_INSPECTOR" = "x"; then echo "yes"; else echo "no"; fi
 751 echo -n "virt-* tools ........................ "
 752 if test "x$HAVE_TOOLS" = "x"; then echo "yes"; else echo "no"; fi
 753 echo "supermin appliance .................. $enable_supermin"
 754 echo
 755 echo "If any optional component is configured 'no' when you expected 'yes'"
 756 echo "then you should check the preceeding messages."
 757 echo
 758 echo "Please report bugs back to the mailing list:"
 759 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 760 echo
 761 echo "Next you should type 'make' to build the package,"
 762 echo "then 'make check' to run the tests."
 763 echo "------------------------------------------------------------"