configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2011 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # The major, minor, and release fields MUST be numbers.  Packagers can
  19 # add extra information using --with-extra="..." which may be any
  20 # freeform string.
  21 m4_define([libguestfs_major],   [1])
  22 m4_define([libguestfs_minor],   [13])
  23 m4_define([libguestfs_release], [11])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Stable or unstable version?
  35 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  36 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  37             AC_MSG_RESULT([stable])
  38        ],[
  39             AC_MSG_RESULT([unstable])
  40             AC_MSG_NOTICE([
  41 ***
  42 This is a development version of libguestfs. Some APIs may be unstable
  43 until they appear in a stable release of libguestfs (at which point
  44 the C API and ABI is guaranteed to remain stable forever).  For
  45 more information about stable and development branches of libguestfs
  46 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  47 ***])
  48        ])
  49
  50 dnl Extra string, a freeform string defined by packagers.
  51 AC_ARG_WITH([extra],
  52   [AS_HELP_STRING([--with-extra],
  53                   [extra version string (for use by packagers)])],
  54   [libguestfs_extra="$withval"],
  55   [libguestfs_extra=]
  56 )
  57
  58 AC_MSG_NOTICE([libguestfs version libguestfs_major.libguestfs_minor.libguestfs_release$libguestfs_extra])
  59
  60 dnl Split up the version string.
  61 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  62 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  63 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  64 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_EXTRA],["$libguestfs_extra"],[Extra version string])
  65
  66 dnl Early gnulib initialization.
  67 gl_EARLY
  68 gl_INIT
  69
  70 AC_PROG_LIBTOOL
  71
  72 AC_PROG_SED
  73
  74 dnl Check for basic C environment.
  75 AC_PROG_CC_STDC
  76 AC_PROG_INSTALL
  77 AC_PROG_CPP
  78
  79 AC_ARG_ENABLE([gcc-warnings],
  80   [AS_HELP_STRING([--enable-gcc-warnings],
  81                   [turn on lots of GCC warnings (for developers)])],
  82   [case $enableval in
  83      yes|no) ;;
  84      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  85    esac
  86    gl_gcc_warnings=$enableval],
  87   [gl_gcc_warnings=no]
  88 )
  89
  90 if test "$gl_gcc_warnings" = yes; then
  91   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  92   AC_SUBST([WERROR_CFLAGS])
  93
  94   nw=
  95   # This, $nw, is the list of warnings we disable.
  96   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  97   nw="$nw -Waggregate-return"       # anachronistic
  98   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  99   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 100   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 101   nw="$nw -Wcast-qual"              # Too many warnings for now
 102   nw="$nw -Wconversion"             # Too many warnings for now
 103   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 104   nw="$nw -Wsign-conversion"        # Too many warnings for now
 105   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 106   nw="$nw -Wunreachable-code"       # Too many warnings for now
 107   nw="$nw -Wpadded"                 # Our structs are not padded
 108   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 109   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 110   nw="$nw -Wvla"                    # two warnings in mount.c
 111   # things I might fix soon:
 112   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 113   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 114   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 115   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 116                                     # was not possible, safe to ignore
 117   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 118   nw="$nw -Wlong-long"              # Allow long long since it's required
 119                                     # by Python, Ruby and xstrtoll.
 120   nw="$nw -Wstack-protector"        # Don't warn about stack-protector
 121                                     # failures (seen on Ubuntu).
 122   nw="$nw -Wmissing-noreturn"       # Don't warn about missed noreturn funcs
 123                                     # (seen on Ubuntu).
 124
 125   gl_MANYWARN_ALL_GCC([ws])
 126   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 127   for w in $ws; do
 128     gl_WARN_ADD([$w])
 129   done
 130   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 131   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 132   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 133
 134   # In spite of excluding -Wlogical-op above, it is enabled, as of
 135   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 136   gl_WARN_ADD([-Wno-logical-op])
 137
 138   # Work around warning in src/inspect.c.  This seems to be a bug in gcc 4.5.1.
 139   gl_WARN_ADD([-Wno-strict-overflow])
 140
 141   gl_WARN_ADD([-fdiagnostics-show-option])
 142
 143   AC_SUBST([WARN_CFLAGS])
 144
 145   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 146   AC_DEFINE([_FORTIFY_SOURCE], [2],
 147     [enable compile-time and run-time bounds-checking, and some warnings])
 148   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 149 fi
 150
 151 AC_C_PROTOTYPES
 152 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 153
 154 AM_PROG_CC_C_O
 155
 156 dnl Work out how to specify the linker script to the linker.
 157 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 158 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 159     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 160 AC_SUBST(VERSION_SCRIPT_FLAGS)
 161
 162 dnl Check support for 64 bit file offsets.
 163 AC_SYS_LARGEFILE
 164
 165 dnl Check sizeof long.
 166 AC_CHECK_SIZEOF([long])
 167
 168 dnl Check if dirent (readdir) supports d_type member.
 169 AC_STRUCT_DIRENT_D_TYPE
 170
 171 dnl Check if stat has the required fields.
 172 AC_STRUCT_ST_BLOCKS
 173 AC_CHECK_MEMBER([struct stat.st_blksize],[
 174         AC_DEFINE([HAVE_STRUCT_STAT_ST_BLKSIZE],[1],[Define to 1 if 'st_blksize' is a member of 'struct stat'])])
 175
 176 dnl Define a C symbol for the host CPU architecture.
 177 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 178
 179 dnl Headers.
 180 AC_CHECK_HEADERS([\
 181         attr/xattr.h \
 182         byteswap.h \
 183         endian.h \
 184         errno.h \
 185         printf.h \
 186         sys/inotify.h \
 187         sys/socket.h \
 188         sys/statvfs.h \
 189         sys/types.h \
 190         sys/un.h \
 191         sys/wait.h \
 192         windows.h \
 193         sys/xattr.h])
 194
 195 dnl Functions.
 196 AC_CHECK_FUNCS([\
 197         futimens \
 198         getxattr \
 199         htonl \
 200         htons \
 201         inotify_init1 \
 202         lgetxattr \
 203         listxattr \
 204         llistxattr \
 205         lsetxattr \
 206         lremovexattr \
 207         mknod \
 208         ntohl \
 209         ntohs \
 210         posix_fallocate \
 211         realpath \
 212         removexattr \
 213         setitimer \
 214         setxattr \
 215         sigaction \
 216         statvfs \
 217         sync])
 218
 219 dnl For modified printf in the daemon, we need glibc either (old-style)
 220 dnl register_printf_function or (new-style) register_printf_specifier.
 221 AC_CHECK_FUNC([register_printf_specifier],[
 222         AC_DEFINE([HAVE_REGISTER_PRINTF_SPECIFIER],[1],
 223                 [Define to 1 if you have new-style register_printf_specifier])
 224         ],[
 225         AC_CHECK_FUNC([register_printf_function],[
 226                 AC_DEFINE([HAVE_REGISTER_PRINTF_FUNCTION],[1],
 227                         [Define to 1 if you have old-style register_printf_function])
 228                 ],[
 229                 AC_MSG_FAILURE(
 230 [No support for glibc-style extended printf formatters.
 231
 232 This means you either have a very old glibc (pre-2.0) or you
 233 are using some other libc where this is not supported.])])])
 234
 235 dnl Build the daemon?
 236 AC_MSG_CHECKING([if we should build the daemon])
 237 AC_ARG_ENABLE([daemon],
 238         [AS_HELP_STRING([--enable-daemon],
 239           [enable building the daemon @<:@default=yes@:>@])],
 240         [],
 241         [enable_daemon=yes])
 242 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 243 AC_MSG_RESULT([$enable_daemon])
 244
 245 if test "x$enable_daemon" = "xyes"; then
 246         dnl Install the daemon (for libguestfs live service)
 247         AC_MSG_CHECKING([if we should install the daemon])
 248         AC_ARG_ENABLE([install-daemon],
 249                 [AS_HELP_STRING([--enable-install-daemon],
 250                   [enable installing the daemon under $sbindir @<:@default=no@:>@])],
 251                 [],
 252                 [enable_install_daemon=no])
 253         AM_CONDITIONAL([INSTALL_DAEMON],[test "x$enable_install_daemon" = "xyes"])
 254         AC_MSG_RESULT([$enable_install_daemon])
 255 fi
 256
 257 dnl Build the appliance?
 258 AC_MSG_CHECKING([if we should build the appliance])
 259 AC_ARG_ENABLE([appliance],
 260         [AS_HELP_STRING([--enable-appliance],
 261           [enable building the appliance @<:@default=yes@:>@])],
 262         [],
 263         [enable_appliance=yes])
 264 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 265 AC_MSG_RESULT([$enable_appliance])
 266
 267 if test "x$enable_appliance" = "xyes"; then
 268     dnl Check for febootstrap >= 3.0
 269     AC_CHECK_PROG([FEBOOTSTRAP],
 270                   [febootstrap],[febootstrap],[no])
 271     test "x$FEBOOTSTRAP" = "xno" &&
 272         AC_MSG_ERROR([febootstrap must be installed])
 273     dnl febootstrap 2.x did not support the --version parameter
 274     $FEBOOTSTRAP --version >&AS_MESSAGE_LOG_FD 2>&1 ||
 275         AC_MSG_ERROR([febootstrap >= 3.0 must be installed, your version is too old])
 276
 277     dnl Pass a febootstrap --yum-config option.
 278     AC_MSG_CHECKING([if user requested febootstrap --yum-config option])
 279     AC_ARG_WITH([febootstrap-yum-config],
 280         [AS_HELP_STRING([--with-febootstrap-yum-config=FILE],
 281           [pass febootstrap --yum-config option @<:@default=no@:>@])],
 282         [FEBOOTSTRAP_YUM_CONFIG="$withval"],
 283         [FEBOOTSTRAP_YUM_CONFIG=no])
 284     AC_MSG_RESULT([$FEBOOTSTRAP_YUM_CONFIG])
 285     AC_SUBST([FEBOOTSTRAP_YUM_CONFIG])
 286
 287     dnl Which distro?
 288     dnl
 289     dnl This used to be Very Important but is now just used to select
 290     dnl which packages to install in the appliance, since the package
 291     dnl names vary slightly across distros.  (See
 292     dnl appliance/packagelist.in and appliance/excludelist.in)
 293     AC_MSG_CHECKING([which Linux distro for package names])
 294     DISTRO=REDHAT
 295     if test -f /etc/debian_version; then
 296         DISTRO=DEBIAN
 297         if grep -q 'DISTRIB_ID=Ubuntu' /etc/lsb-release 2>&AS_MESSAGE_LOG_FD; then
 298             DISTRO=UBUNTU
 299         fi
 300     fi
 301     if test -f /etc/arch-release; then
 302         DISTRO=ARCHLINUX
 303     fi
 304     AC_MSG_RESULT([$DISTRO])
 305     AC_SUBST([DISTRO])
 306 fi
 307
 308 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 309 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 310 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 311 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 312         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 313         ])
 314
 315 dnl Check for Augeas (now optional).
 316 AC_CHECK_LIB([augeas],[aug_match],[
 317         have_augeas=yes
 318         AUGEAS_LIB="-laugeas"
 319
 320         old_LIBS="$LIBS"
 321         LIBS="$LIBS $AUGEAS_LIB"
 322         dnl Check for functions not available in earlier versions of Augeas.
 323         AC_CHECK_FUNCS([aug_load aug_defvar aug_defnode])
 324         LIBS="$old_LIBS"
 325
 326         ],[have_augeas=no])
 327 if test "x$have_augeas" = "xyes"; then
 328         AC_DEFINE([HAVE_AUGEAS],[1],[Define to 1 if you have Augeas])
 329 fi
 330 AC_SUBST([AUGEAS_LIB])
 331
 332 dnl Check for libselinux (optional).
 333 AC_CHECK_HEADERS([selinux/selinux.h])
 334 AC_CHECK_LIB([selinux],[setexeccon],[
 335         have_libselinux="$ac_cv_header_selinux_selinux_h"
 336         SELINUX_LIB="-lselinux"
 337
 338         old_LIBS="$LIBS"
 339         LIBS="$LIBS $SELINUX_LIB"
 340         AC_CHECK_FUNCS([setcon getcon])
 341         LIBS="$old_LIBS"
 342
 343         ],[have_libselinux=no])
 344 if test "x$have_libselinux" = "xyes"; then
 345         AC_DEFINE([HAVE_LIBSELINUX],[1],[Define to 1 if you have libselinux])
 346 fi
 347 AC_SUBST([SELINUX_LIB])
 348
 349 dnl Check for cpio which isn't in the default Pardus install amazingly.
 350 AC_CHECK_PROG([CPIO],[cpio],[cpio],[no])
 351 test "x$CPIO" = "xno" &&
 352      AC_MSG_ERROR([cpio must be installed])
 353
 354 dnl Check for gperf.
 355 AC_CHECK_PROG([GPERF],[gperf],[gperf],[no])
 356 test "x$GPERF" = "xno" &&
 357      AC_MSG_ERROR([gperf must be installed])
 358
 359 dnl Check for pod2man, pod2text, pod2html.
 360 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 361 test "x$POD2MAN" = "xno" &&
 362      AC_MSG_ERROR([pod2man must be installed])
 363 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 364 test "x$POD2TEXT" = "xno" &&
 365      AC_MSG_ERROR([pod2text must be installed])
 366 AC_CHECK_PROG([POD2HTML],[pod2html],[pod2html],[no])
 367 test "x$POD2HTML" = "xno" &&
 368      AC_MSG_ERROR([pod2html must be installed])
 369
 370 dnl Check if pod2man, pod2text take --stderr and -u options (not in RHEL 5).
 371 AC_MSG_CHECKING([if pod2man takes --stderr option])
 372 if "$POD2MAN" --stderr >&AS_MESSAGE_LOG_FD 2>&1; then
 373     AC_MSG_RESULT([yes])
 374     POD2_STDERR_OPTION="--stderr"
 375 else
 376     AC_MSG_RESULT([no])
 377     POD2_STDERR_OPTION=""
 378 fi
 379 AC_SUBST([POD2_STDERR_OPTION])
 380
 381 AC_MSG_CHECKING([if pod2man takes -u option])
 382 if "$POD2MAN" -u >&AS_MESSAGE_LOG_FD 2>&1; then
 383     AC_MSG_RESULT([yes])
 384     POD2_UTF8_OPTION="-u"
 385 else
 386     AC_MSG_RESULT([no])
 387     POD2_UTF8_OPTION=""
 388 fi
 389 AC_SUBST([POD2_UTF8_OPTION])
 390
 391 dnl Check for genisoimage.
 392 AC_PATH_PROGS([GENISOIMAGE],[genisoimage],[no],
 393         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 394 test "x$GENISOIMAGE" = "xno" && AC_MSG_ERROR([genisoimage must be installed])
 395
 396 dnl Check for optional xmllint.
 397 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 398 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 399
 400 dnl po4a for translating man pages and POD files (optional).
 401 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
 402 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
 403
 404 dnl Check for db_dump, db_load (optional).
 405 AC_CHECK_PROGS([DB_DUMP],
 406                [db_dump db4_dump db4.8_dump db4.7_dump db4.6_dump],[no])
 407 AC_CHECK_PROGS([DB_LOAD],
 408                [db_load db4_load db4.8_load db4.7_load db4.6_load],[no])
 409 if test "x$DB_DUMP" != "xno"; then
 410     AC_DEFINE_UNQUOTED([DB_DUMP],["$DB_DUMP"],[Name of db_dump program.])
 411 fi
 412 if test "x$DB_LOAD" != "xno"; then
 413     AC_DEFINE_UNQUOTED([DB_LOAD],["$DB_LOAD"],[Name of db_load program.])
 414 fi
 415
 416 dnl Check for QEMU for running binaries on this $host_cpu, fall
 417 dnl back to basic 'qemu'.  Allow the user to override it.
 418 default_qemu="qemu-kvm kvm qemu-system-$host_cpu qemu"
 419 AC_ARG_WITH([qemu],
 420         [AS_HELP_STRING([--with-qemu],
 421           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 422         [],
 423         [with_qemu="$default_qemu"])
 424 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 425         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 426 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 427 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 428
 429 dnl Check that the chosen qemu has virtio-serial support.
 430 if test "x$vmchannel_test" != "xno"; then
 431     AC_MSG_CHECKING([that $QEMU -help works])
 432     if $QEMU -help >&AS_MESSAGE_LOG_FD 2>&1; then
 433         AC_MSG_RESULT([yes])
 434     else
 435         AC_MSG_RESULT([no])
 436         AC_MSG_FAILURE(
 437 [$QEMU -help: command failed.
 438
 439 This could be a very old version of qemu, or qemu might not be
 440 working.
 441 ])
 442     fi
 443
 444     AC_MSG_CHECKING([for virtio-serial support in $QEMU])
 445     if $QEMU -nographic -device \? 2>&1 | grep -sq virtio-serial; then
 446         AC_MSG_RESULT([yes])
 447     else
 448         AC_MSG_RESULT([no])
 449         AC_MSG_FAILURE(
 450 [I did not find virtio-serial support in
 451 $QEMU.
 452
 453 virtio-serial support in qemu or KVM is essential for libguestfs
 454 to operate.
 455
 456 Usually this means that you have to install a newer version of qemu
 457 and/or KVM.  Please read the relevant section in the README file for
 458 more information about this.
 459
 460 You can override this test by setting the environment variable
 461 vmchannel_test=no  However if you don't have the right support
 462 in your qemu, then this just delays the pain.
 463
 464 If I am using the wrong qemu or you want to compile qemu from source
 465 and install it in another location, then you should configure with
 466 the --with-qemu option.
 467 ])
 468     fi
 469 fi
 470
 471 dnl Set default drive interface used by the guestfs_add_drive_opts call
 472 dnl ('-drive ...,if=...' option to qemu).
 473 dnl
 474 dnl If you encounter performance problems with virtio (RHBZ#509383)
 475 dnl then try '--with-drive-if=ide'.
 476 AC_ARG_WITH([drive-if],
 477         [AS_HELP_STRING([--with-drive-if],
 478           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 479         [],
 480         [with_drive_if=virtio])
 481 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 482
 483 dnl Set interface used by the network.  Normally you should
 484 dnl leave this at the default (virtio-net-pci) but you can use the
 485 dnl alternative (ne2k_pci) because of bugs in virtio networking
 486 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 487 AC_ARG_WITH([net-if],
 488         [AS_HELP_STRING([--with-net-if],
 489           [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
 490         [],
 491         [with_net_if=virtio-net-pci])
 492 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 493
 494 dnl Enable packet dumps when in verbose mode.  This generates lots
 495 dnl of debug info, only useful for people debugging the RPC mechanism.
 496 AC_ARG_ENABLE([packet-dump],
 497         [AS_HELP_STRING([--enable-packet-dump],
 498           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 499         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 500         [])
 501
 502 dnl Readline.
 503 AC_ARG_WITH([readline],
 504     [AS_HELP_STRING([--with-readline],
 505         [support fancy command line editing @<:@default=check@:>@])],
 506     [],
 507     [with_readline=check])
 508
 509 LIBREADLINE=
 510 AS_IF([test "x$with_readline" != xno],
 511     [AC_CHECK_LIB([readline], [main],
 512         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 513          AC_DEFINE([HAVE_LIBREADLINE], [1],
 514                    [Define if you have libreadline])
 515         ],
 516         [if test "x$with_readline" != xcheck; then
 517          AC_MSG_FAILURE(
 518              [--with-readline was given, but test for readline failed])
 519          fi
 520         ], -lncurses)
 521      old_LIBS="$LIBS"
 522      LIBS="$LIBS $LIBREADLINE"
 523      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 524      LIBS="$old_LIBS"
 525     ])
 526
 527 dnl For i18n.
 528 AM_GNU_GETTEXT([external])
 529
 530 dnl Check for PCRE (required)
 531 PKG_CHECK_MODULES([PCRE], [libpcre])
 532
 533 dnl libmagic (highly recommended)
 534 AC_CHECK_LIB([magic],[magic_file],
 535         [AC_CHECK_HEADER([magic.h],
 536                 [AC_SUBST([MAGIC_LIBS], ["-lmagic"])
 537                  AC_DEFINE([HAVE_LIBMAGIC],[1],[libmagic found at compile time.])
 538                 ], [])
 539         ],
 540         [AC_MSG_WARN([libmagic not found, some core features will be disabled])])
 541
 542 dnl libvirt (highly recommended)
 543 PKG_CHECK_MODULES([LIBVIRT], [libvirt],
 544         [AC_SUBST([LIBVIRT_CFLAGS])
 545          AC_SUBST([LIBVIRT_LIBS])
 546          AC_DEFINE([HAVE_LIBVIRT],[1],[libvirt found at compile time.])
 547         ],
 548         [AC_MSG_WARN([libvirt not found, some core features will be disabled])])
 549 AM_CONDITIONAL([HAVE_LIBVIRT],[test "x$LIBVIRT_LIBS" != "x"])
 550
 551 dnl libxml2 (highly recommended)
 552 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0],
 553         [AC_SUBST([LIBXML2_CFLAGS])
 554          AC_SUBST([LIBXML2_LIBS])
 555          AC_DEFINE([HAVE_LIBXML2],[1],[libxml2 found at compile time.])
 556         ],
 557         [AC_MSG_WARN([libxml2 not found, some core features will be disabled])])
 558 AM_CONDITIONAL([HAVE_LIBXML2],[test "x$LIBXML2_LIBS" != "x"])
 559
 560 dnl libconfig (highly recommended)
 561 PKG_CHECK_MODULES([LIBCONFIG], [libconfig],
 562         [AC_SUBST([LIBCONFIG_CFLAGS])
 563          AC_SUBST([LIBCONFIG_LIBS])
 564          AC_DEFINE([HAVE_LIBCONFIG],[1],[libconfig found at compile time.])
 565         ],
 566         [AC_MSG_WARN([libconfig not found, some features will be disabled])])
 567 AM_CONDITIONAL([HAVE_LIBCONFIG],[test "x$LIBCONFIG_LIBS" != "x"])
 568
 569 dnl hivex library (highly recommended)
 570 dnl This used to be a part of libguestfs, but was spun off into its
 571 dnl own separate upstream project in libguestfs 1.0.85.
 572 PKG_CHECK_MODULES([HIVEX], [hivex],
 573         [AC_SUBST([HIVEX_CFLAGS])
 574          AC_SUBST([HIVEX_LIBS])
 575          AC_DEFINE([HAVE_HIVEX],[1],[hivex library found at compile time.])
 576         ],
 577         [AC_MSG_WARN([hivex not found, some core features will be disabled])])
 578 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HIVEX_LIBS" != "x"])
 579
 580 dnl FUSE is optional to build the FUSE module.
 581 AC_ARG_ENABLE([fuse],
 582         AS_HELP_STRING([--disable-fuse], [Disable FUSE (guestmount) support]),
 583         [],
 584         [enable_fuse=yes])
 585 AS_IF([test "x$enable_fuse" != "xno"],
 586         [PKG_CHECK_MODULES([FUSE],[fuse],,[
 587                 enable_fuse=no
 588                 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])])
 589 AM_CONDITIONAL([HAVE_FUSE],[test "x$enable_fuse" != "xno"])
 590
 591 dnl Check for OCaml (optional, for OCaml bindings).
 592 OCAMLC=no
 593 OCAMLFIND=no
 594 AC_ARG_ENABLE([ocaml],
 595         AS_HELP_STRING([--disable-ocaml], [Disable OCaml language bindings]),
 596         [],
 597         [enable_ocaml=yes])
 598 AS_IF([test "x$enable_ocaml" != "xno"],
 599         [dnl OCAMLC and OCAMLFIND have to be unset first, otherwise
 600          dnl AC_CHECK_TOOL (inside AC_PROG_OCAML) will not look.
 601          OCAMLC=
 602          OCAMLFIND=
 603          AC_PROG_OCAML
 604          AC_PROG_FINDLIB
 605
 606          AS_IF([test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"],
 607                 [AC_CHECK_OCAML_PKG([pcre])])
 608         ])
 609 AM_CONDITIONAL([HAVE_OCAML],
 610                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
 611 AM_CONDITIONAL([HAVE_OCAML_PCRE],
 612                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno" && test "x$OCAML_PKG_pcre" != "xno"])
 613 AM_CONDITIONAL([HAVE_OCAMLDOC],
 614                [test "x$OCAMLDOC" != "xno"])
 615
 616 dnl Check for Perl (optional, for Perl bindings).
 617 PERL=no
 618 AC_ARG_ENABLE([perl],
 619         AS_HELP_STRING([--disable-perl], [Disable Perl language bindings]),
 620         [],
 621         [enable_perl=yes])
 622 AS_IF([test "x$enable_perl" != "xno"],
 623         [
 624         PERL=
 625         AC_CHECK_PROG([PERL],[perl],[perl],[no])
 626
 627         dnl Check for Perl modules that must be present to compile and
 628         dnl test the Perl bindings.
 629         missing_perl_modules=no
 630         for pm in Test::More ExtUtils::MakeMaker; do
 631             AC_MSG_CHECKING([for $pm])
 632             if ! perl -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
 633                 AC_MSG_RESULT([no])
 634                 missing_perl_modules=yes
 635             else
 636                 AC_MSG_RESULT([yes])
 637             fi
 638         done
 639         if test "x$missing_perl_modules" = "xyes"; then
 640             AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 641         fi
 642         ])
 643 AM_CONDITIONAL([HAVE_PERL],
 644     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 645
 646 dnl Check for Python (optional, for Python bindings).
 647 PYTHON_PREFIX=
 648 PYTHON_VERSION=
 649 PYTHON_INCLUDEDIR=
 650 PYTHON_INSTALLDIR=
 651
 652 AC_ARG_ENABLE([python],
 653         AS_HELP_STRING([--disable-python], [Disable Python language bindings]),
 654         [],
 655         [enable_python=yes])
 656 AS_IF([test "x$enable_python" != "xno"],
 657         [
 658         AC_CHECK_PROG([PYTHON],[python],[python],[no])
 659
 660         if test "x$PYTHON" != "xno"; then
 661             AC_MSG_CHECKING([Python prefix])
 662             PYTHON_PREFIX=`$PYTHON -c "import sys; print (sys.prefix)"`
 663             AC_MSG_RESULT([$PYTHON_PREFIX])
 664
 665             AC_MSG_CHECKING([Python version])
 666             PYTHON_VERSION=`$PYTHON -c "import sys; print (sys.version[[0:3]])"`
 667             AC_MSG_RESULT([$PYTHON_VERSION])
 668
 669             AC_MSG_CHECKING([for Python include path])
 670             if test -z "$PYTHON_INCLUDEDIR"; then
 671                 python_path=`$PYTHON -c "import distutils.sysconfig; \
 672                                          print (distutils.sysconfig.get_python_inc ());"`
 673                 PYTHON_INCLUDEDIR=$python_path
 674             fi
 675             AC_MSG_RESULT([$PYTHON_INCLUDEDIR])
 676
 677             AC_ARG_WITH([python-installdir],
 678                         [AS_HELP_STRING([--with-python-installdir],
 679                                         [directory to install python modules @<:@default=check@:>@])],
 680                         [PYTHON_INSTALLDIR="$withval"
 681                         AC_MSG_NOTICE([Python install dir $PYTHON_INSTALLDIR])],
 682                         [PYTHON_INSTALLDIR=check])
 683
 684             if test "x$PYTHON_INSTALLDIR" = "xcheck"; then
 685                 PYTHON_INSTALLDIR=
 686                 AC_MSG_CHECKING([for Python site-packages path])
 687                 if test -z "$PYTHON_INSTALLDIR"; then
 688                     PYTHON_INSTALLDIR=`$PYTHON -c "import distutils.sysconfig; \
 689                                                    print (distutils.sysconfig.get_python_lib(1,0));"`
 690                 fi
 691                 AC_MSG_RESULT([$PYTHON_INSTALLDIR])
 692             fi
 693
 694             old_LIBS="$LIBS"
 695             LIBS="$LIBS -lpython$PYTHON_VERSION"
 696             AC_CHECK_FUNCS([PyCapsule_New])
 697             LIBS="$old_LIBS"
 698         fi
 699
 700         AC_SUBST(PYTHON_PREFIX)
 701         AC_SUBST(PYTHON_VERSION)
 702         AC_SUBST(PYTHON_INCLUDEDIR)
 703         AC_SUBST(PYTHON_INSTALLDIR)
 704         ])
 705 AM_CONDITIONAL([HAVE_PYTHON],
 706     [test "x$PYTHON" != "xno" && test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_INSTALLDIR" != "x"])
 707
 708 dnl Check for Ruby and rake (optional, for Ruby bindings).
 709 AC_ARG_ENABLE([ruby],
 710         AS_HELP_STRING([--disable-ruby], [Disable Ruby language bindings]),
 711         [],
 712         [enable_ruby=yes])
 713 AS_IF([test "x$enable_ruby" != "xno"],
 714         [
 715         AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 716         AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 717         ])
 718 AM_CONDITIONAL([HAVE_RUBY],
 719     [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
 720
 721 dnl Check for Java.
 722 AC_ARG_WITH(java_home,
 723     [AS_HELP_STRING([--with-java-home],
 724         [specify path to JDK directory @<:@default=check@:>@])],
 725     [],
 726     [with_java_home=check])
 727
 728 if test "x$with_java_home" != "xno"; then
 729     if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
 730     then
 731         # Reject unsafe characters in $JAVA_HOME
 732         jh_lf='
 733 '
 734         case $JAVA_HOME in
 735           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 736             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 737         esac
 738         if test -d "$with_java_home"; then
 739             JAVA_HOME="$with_java_home"
 740         else
 741             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 742         fi
 743     fi
 744
 745     if test "x$JAVA_HOME" = "x"; then
 746         # Look for Java in some likely locations.
 747         for d in \
 748             /usr/lib/jvm/java \
 749             /usr/lib/jvm/java-6-openjdk
 750         do
 751             if test -d $d && test -f $d/bin/java; then
 752                 JAVA_HOME=$d
 753                 break
 754             fi
 755         done
 756     fi
 757
 758     if test "x$JAVA_HOME" != "x"; then
 759         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 760         if test ! -x "$JAVA_HOME/bin/java"; then
 761             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 762         else
 763             JAVA="$JAVA_HOME/bin/java"
 764         fi
 765         if test ! -x "$JAVA_HOME/bin/javac"; then
 766             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 767         else
 768             JAVAC="$JAVA_HOME/bin/javac"
 769         fi
 770         if test ! -x "$JAVA_HOME/bin/javah"; then
 771             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 772         else
 773             JAVAH="$JAVA_HOME/bin/javah"
 774         fi
 775         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 776             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 777         else
 778             JAVADOC="$JAVA_HOME/bin/javadoc"
 779         fi
 780         if test ! -x "$JAVA_HOME/bin/jar"; then
 781             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 782         else
 783             JAR="$JAVA_HOME/bin/jar"
 784         fi
 785         java_version=`$JAVA -version 2>&1 | grep "java version"`
 786         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 787
 788         dnl Find jni.h.
 789         AC_MSG_CHECKING([for jni.h])
 790         if test -f "$JAVA_HOME/include/jni.h"; then
 791             JNI_CFLAGS="-I$JAVA_HOME/include"
 792         else
 793             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 794                 head=`find $JAVA_HOME -name jni.h | tail -1`
 795                 dir=`dirname "$head"`
 796                 JNI_CFLAGS="-I$dir"
 797             else
 798                 AC_MSG_FAILURE([missing jni.h header file])
 799             fi
 800         fi
 801         AC_MSG_RESULT([$JNI_CFLAGS])
 802
 803         dnl Find jni_md.h.
 804         AC_MSG_CHECKING([for jni_md.h])
 805         case "$build_os" in
 806         *linux*) system="linux" ;;
 807         *SunOS*) system="solaris" ;;
 808         *cygwin*) system="win32" ;;
 809         *) system="$build_os" ;;
 810         esac
 811         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 812             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 813         else
 814             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 815                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 816                 dir=`dirname "$head"`
 817                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 818             else
 819                 AC_MSG_FAILURE([missing jni_md.h header file])
 820             fi
 821         fi
 822         AC_MSG_RESULT([$JNI_CFLAGS])
 823
 824         dnl Need extra version flag?
 825         AC_MSG_CHECKING([extra javac flags])
 826         JAVAC_FLAGS=
 827         javac_version=`$JAVAC -version 2>&1`
 828         case "$javac_version" in
 829         *Eclipse*)
 830             JAVAC_FLAGS="-source 1.5" ;;
 831         esac
 832         AC_MSG_RESULT([$JAVAC_FLAGS])
 833
 834         dnl Where to install jarfiles.
 835         dnl XXX How to make it configurable?
 836         JAR_INSTALL_DIR=\${prefix}/share/java
 837         JNI_INSTALL_DIR=\${libdir}
 838
 839         dnl JNI version.
 840         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 841         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 842         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 843         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 844     fi
 845 fi
 846
 847 AC_SUBST(JAVA_HOME)
 848 AC_SUBST(JAVA)
 849 AC_SUBST(JAVAC)
 850 AC_SUBST(JAVAH)
 851 AC_SUBST(JAVADOC)
 852 AC_SUBST(JAR)
 853 AC_SUBST(JNI_CFLAGS)
 854 AC_SUBST(JAVAC_FLAGS)
 855 AC_SUBST(JAR_INSTALL_DIR)
 856 AC_SUBST(JNI_INSTALL_DIR)
 857 AC_SUBST(JNI_VERSION_INFO)
 858
 859 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 860
 861 dnl Check for Haskell (GHC).
 862 GHC=no
 863 AC_ARG_ENABLE([haskell],
 864         AS_HELP_STRING([--disable-haskell], [Disable Haskell language bindings]),
 865         [],
 866         [enable_haskell=yes])
 867 AS_IF([test "x$enable_haskell" != "xno"],
 868         [
 869         GHC=
 870         AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 871         ])
 872 AM_CONDITIONAL([HAVE_HASKELL],
 873     [test "x$GHC" != "xno"])
 874
 875 dnl PHP
 876 PHP=no
 877 AC_ARG_ENABLE([php],
 878         AS_HELP_STRING([--disable-php], [Disable PHP language bindings]),
 879         [],
 880         [enable_php=yes])
 881 AS_IF([test "x$enable_php" != "xno"],
 882         [
 883         PHP=
 884         AC_CHECK_PROG([PHP],[php],[php],[no])
 885         AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
 886         ])
 887 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
 888
 889 dnl Check for Perl modules needed by Perl virt tools (virt-df, etc.)
 890 AS_IF([test "x$PERL" != "xno"],
 891         [
 892         missing_perl_modules=no
 893         for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper Locale::TextDomain Win::Hivex Win::Hivex::Regedit String::ShellQuote; do
 894             AC_MSG_CHECKING([for $pm])
 895             if ! $PERL -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
 896                 AC_MSG_RESULT([no])
 897                 missing_perl_modules=yes
 898             else
 899                 AC_MSG_RESULT([yes])
 900             fi
 901         done
 902         if test "x$missing_perl_modules" = "xyes"; then
 903             AC_MSG_WARN([some Perl modules required to compile the Perl virt-* tools are missing])
 904         fi
 905         ])
 906
 907 AM_CONDITIONAL([HAVE_TOOLS],
 908     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 909
 910 dnl Library versioning.
 911 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 912 AC_SUBST(MAX_PROC_NR)
 913
 914 dnl Replace libtool with a wrapper that clobbers dependency_libs in *.la files
 915 dnl http://lists.fedoraproject.org/pipermail/devel/2010-November/146343.html
 916 LIBTOOL='bash $(top_srcdir)/libtool-kill-dependency_libs.sh $(top_builddir)/libtool'
 917 AC_SUBST([LIBTOOL])
 918
 919 dnl Produce output files.
 920 AC_CONFIG_HEADERS([config.h])
 921 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 922 AC_CONFIG_FILES([podwrapper.sh],
 923                 [chmod +x podwrapper.sh])
 924 AC_CONFIG_FILES([run],
 925                 [chmod +x run])
 926 AC_CONFIG_FILES([Makefile
 927                  appliance/Makefile
 928                  capitests/Makefile
 929                  cat/Makefile
 930                  caution/Makefile
 931                  csharp/Makefile
 932                  daemon/Makefile
 933                  debian/changelog
 934                  df/Makefile
 935                  edit/Makefile
 936                  examples/Makefile
 937                  fish/Makefile
 938                  fuse/Makefile
 939                  generator/Makefile
 940                  gnulib/lib/Makefile
 941                  gnulib/tests/Makefile
 942                  haskell/Makefile
 943                  images/Makefile
 944                  inspector/Makefile
 945                  java/Makefile
 946                  java/examples/Makefile
 947                  libguestfs.pc
 948                  ocaml/META
 949                  ocaml/Makefile
 950                  ocaml/examples/Makefile
 951                  perl/Makefile
 952                  perl/Makefile.PL
 953                  perl/examples/Makefile
 954                  php/Makefile
 955                  po-docs/Makefile
 956                  po-docs/ja/Makefile
 957                  po-docs/uk/Makefile
 958                  po/Makefile.in
 959                  python/Makefile
 960                  python/examples/Makefile
 961                  regressions/Makefile
 962                  rescue/Makefile
 963                  resize/Makefile
 964                  ruby/Makefile
 965                  ruby/Rakefile
 966                  ruby/examples/Makefile
 967                  src/Makefile
 968                  test-tool/Makefile
 969                  tools/Makefile])
 970 AC_OUTPUT
 971
 972 dnl Produce summary.
 973 echo
 974 echo
 975 echo "------------------------------------------------------------"
 976 echo "Thank you for downloading $PACKAGE_STRING"
 977 echo
 978 echo "This is how we have configured the optional components for you today:"
 979 echo
 980 echo    "Daemon .............................. $enable_daemon"
 981 echo    "Appliance ........................... $enable_appliance"
 982 echo    "QEMU ................................ $QEMU"
 983 echo -n "OCaml bindings ...................... "
 984 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 985 echo -n "Perl bindings ....................... "
 986 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 987 echo -n "Python bindings ..................... "
 988 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 989 echo -n "Ruby bindings ....................... "
 990 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 991 echo -n "Java bindings ....................... "
 992 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 993 echo -n "Haskell bindings .................... "
 994 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 995 echo -n "PHP bindings ........................ "
 996 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 997 echo    "guestfish and C virt tools .......... yes"
 998 echo -n "Perl virt tools ..................... "
 999 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1000 echo -n "virt-resize ......................... "
1001 if test "x$HAVE_OCAML_TRUE" = "x" && test "x$HAVE_OCAML_PCRE_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1002 echo "FUSE filesystem ..................... $enable_fuse"
1003 echo
1004 echo "If any optional component is configured 'no' when you expected 'yes'"
1005 echo "then you should check the preceeding messages."
1006 echo
1007 echo "Please report bugs back to the mailing list:"
1008 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
1009 echo
1010 echo "Next you should type 'make' to build the package,"
1011 echo "then 'make check' to run the tests."
1012 echo "------------------------------------------------------------"